regress/hsyscalls.i4

   1 m4_dnl hsyscalls.i4
   2 m4_dnl (part of complex test harness, not of the library)
   3 m4_dnl - list of syscalls to override/log and their args
   4
   5 m4_dnl  This file is part of adns, which is Copyright (C) 1997, 1998 Ian Jackson
   6 m4_dnl
   7 m4_dnl  This program is free software; you can redistribute it and/or modify
   8 m4_dnl  it under the terms of the GNU General Public License as published by
   9 m4_dnl  the Free Software Foundation; either version 2, or (at your option)
  10 m4_dnl  any later version.
  11 m4_dnl
  12 m4_dnl  This program is distributed in the hope that it will be useful,
  13 m4_dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 m4_dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 m4_dnl  GNU General Public License for more details.
  16 m4_dnl
  17 m4_dnl  You should have received a copy of the GNU General Public License
  18 m4_dnl  along with this program; if not, write to the Free Software Foundation,
  19 m4_dnl  Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 m4_dnl each system call has
  22 m4_dnl  hm_syscall(<name>,<returnvalue>,<args>
  23 m4_dnl <returnvalue> is one of
  24 m4_dnl  hm_rv_must       must succeed and return 0
  25 m4_dnl  hm_rv_any        any nonnegative return allowed, -1 means see errno
  26 m4_dnl  hm_rv_fd         file descriptor is returned, -1 means see errno
  27 m4_dnl  hm_rv_succfail   returns 0 (ok) or -1 (see errno)
  28 m4_dnl  hm_rv_len(<max>) returns length read/written, must be <=max, -1 => errno
  29 m4_dnl <args> is list of macros for arguments, each followed by hm_na
  30 m4_dnl  hm_arg_timeval_out_abs(<arg>)   struct timeval, absolute time is returned
  31 m4_dnl  hm_arg_nullptr(<type>,<arg>)    pointer of type type, must be null
  32 m4_dnl  hm_arg_int(<arg>)               signed integer
  33 m4_dnl  hm_arg_fdset_io(<arg>,<max>)    fd_set, max bit set is in max
  34 m4_dnl  hm_arg_timeval_in_rel_null(<t>) struct timeval*, pass in, relative, may be null
  35 m4_dnl  hm_arg_must(<type>,<arg>,<val>) must have correct value, or abort test
  36 m4_dnl  hm_arg_socktype(<arg>)          SOCK_STREAM or SOCK_DGRAM (an int)
  37 m4_dnl  hm_arg_ign(<type>,<arg>)        input parameter ignored
  38 m4_dnl  hm_arg_fd(<arg>)                fd
  39 m4_dnl  hm_arg_fcntl_cmd_arg(<ca>,<aa>) syscall is fcntl, do special processing
  40 m4_dnl  hm_arg_addr_in(<arg>,<len>)     struct sockaddr*, length given by <len> (an int)
  41 m4_dnl  hm_arg_bytes_in(<objtype>,<objarg>,<lentype>,<lenarg>)
  42 m4_dnl   some data from caller; <objarg> is of type pointer to const <objtype>
  43 m4_dnl   and points to <lenarg> bytes (<lenarg> is of type <lentype>)
  44 m4_dnl  hm_arg_bytes_out(<objtype>,<objarg>,<lentype>,<buflenarg>)
  45 m4_dnl   buffer for data from syscall; <objarg> is of type pointer to const <objtype>
  46 m4_dnl   and points to at least <lenarg> bytes (<lenarg> is of type <lentype>)
  47 m4_dnl   return value from syscall is supposed to be returned length
  48 m4_dnl  hm_arg_addr_out(<arg>,<lenptr>) struct sockaddr*, length io at <lenptr> (an int*)
  49
  50 hm_syscall(
  51         gettimeofday, `hm_rv_must', `
  52         hm_arg_timeval_out_abs(tv) hm_na
  53         hm_arg_nullptr(struct timezone*, tz) hm_na
  54 ')
  55
  56 hm_syscall(
  57         select, `hm_rv_any', `
  58         hm_arg_int(max) hm_na
  59         hm_arg_fdset_io(rfds,max) hm_na
  60         hm_arg_fdset_io(wfds,max) hm_na
  61         hm_arg_fdset_io(efds,max) hm_na
  62         hm_arg_timeval_in_rel_null(to) hm_na
  63 ')
  64
  65 hm_syscall(
  66         socket, `hm_rv_fd', `
  67         hm_arg_must(int,domain,AF_INET) hm_na
  68         hm_arg_socktype(type) hm_na
  69         hm_arg_ign(int,protocol) hm_na
  70 ')
  71
  72 hm_syscall(
  73         fcntl, `hm_rv_any', `
  74         hm_arg_fd(fd) hm_na
  75         hm_arg_fcntl_cmd_arg(cmd,arg) hm_na
  76 ')
  77
  78 hm_syscall(
  79         connect, `hm_rv_succfail', `
  80         hm_arg_fd(fd) hm_na
  81         hm_arg_addr_in(addr,addrlen) hm_na
  82 ')
  83
  84 hm_syscall(
  85         close, `hm_rv_succfail', `
  86         hm_arg_fd(fd) hm_na
  87 ')
  88
  89 hm_syscall(
  90         sendto, `hm_rv_any', `
  91         hm_arg_fd(fd) hm_na
  92         hm_arg_bytes_in(void,msg,int,msglen) hm_na
  93         hm_arg_must(unsigned int,flags,0) hm_na
  94         hm_arg_addr_in(addr,addrlen) hm_na
  95 ')
  96
  97 hm_syscall(
  98         recvfrom, `hm_rv_len(buflen)', `
  99         hm_arg_fd(fd) hm_na
 100         hm_arg_bytes_out(void,buf,int,buflen) hm_na
 101         hm_arg_must(unsigned int,flags,0) hm_na
 102         hm_arg_addr_out(addr,addrlen) hm_na
 103 ')
 104
 105 hm_syscall(
 106         read, `hm_rv_len(buflen)', `
 107         hm_arg_fd(fd) hm_na
 108         hm_arg_bytes_out(void,buf,size_t,buflen) hm_na
 109 ')
 110
 111 hm_syscall(
 112         write, `hm_rv_any', `
 113         hm_arg_fd(fd) hm_na
 114         hm_arg_bytes_in(void,buf,size_t,len) hm_na
 115 ')