X-Git-Url: http://www.chiark.greenend.org.uk/ucgi/~ianmdlvl/git?a=blobdiff_plain;f=Debian%2FDgit.pm;h=de37261d1820b86d54e874860932be631ab2f135;hb=9b34c3e59ee77136f100c2514524e841c4b30eab;hp=5b5591d5499695def37c47f023a00f854bfa1738;hpb=4523f77bba9b97925030bcf641584a4a74819178;p=dgit.git

diff --git a/Debian/Dgit.pm b/Debian/Dgit.pm
index 5b5591d5..de37261d 100644
--- a/Debian/Dgit.pm
+++ b/Debian/Dgit.pm
@@ -29,6 +29,8 @@ use Config;
 use Digest::SHA;
 use Data::Dumper;
 use IPC::Open2;
+use File::Path;
+use File::Basename;
 
 BEGIN {
     use Exporter   ();
@@ -42,7 +44,7 @@ BEGIN {
 		      server_branch server_ref
                       stat_exists link_ltarget
 		      hashfile
-                      fail ensuredir executable_on_path
+                      fail ensuredir must_getcwd executable_on_path
                       waitstatusmsg failedcmd_waitstatus
 		      failedcmd_report_cmd failedcmd
                       runcmd cmdoutput cmdoutput_errok
@@ -55,10 +57,17 @@ BEGIN {
                       initdebug enabledebug enabledebuglevel
                       printdebug debugcmd
                       $debugprefix *debuglevel *DEBUG
-                      shellquote printcmd messagequote);
+                      shellquote printcmd messagequote
+                      $negate_harmful_gitattrs
+		      changedir git_slurp_config_src
+		      playtree_setup);
     # implicitly uses $main::us
-    %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)] );
-    @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
+    %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
+		     playground => [qw(record_maindir $maindir $local_git_cfg
+				       fresh_playground $playground
+                                       ensure_a_playground)]);
+    @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
+		     @{ $EXPORT_TAGS{playground} } );
 }
 
 our @EXPORT_OK;
@@ -82,6 +91,8 @@ sub NOCOMMITCHECK () { return 0x8; }
 our $debugprefix;
 our $debuglevel = 0;
 
+our $negate_harmful_gitattrs = "-text -eol -crlf -ident -filter";
+
 our $forkcheck_mainprocess;
 
 sub forkcheck_setup () {
@@ -216,6 +227,12 @@ sub ensuredir ($) {
     die "mkdir $dir: $!";
 }
 
+sub must_getcwd () {
+    my $d = getcwd();
+    defined $d or fail "getcwd failed: $!";
+    return $d;
+}
+
 sub executable_on_path ($) {
     my ($program) = @_;
     return 1 if $program =~ m{/};
@@ -412,4 +429,145 @@ sub is_fast_fwd ($$) {
     }
 }
 
+sub changedir ($) {
+    my ($newdir) = @_;
+    printdebug "CD $newdir\n";
+    chdir $newdir or confess "chdir: $newdir: $!";
+}
+
+sub git_slurp_config_src ($) {
+    my ($src) = @_;
+    # returns $r such that $r->{KEY}[] = VALUE
+    my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
+    debugcmd "|",@cmd;
+
+    local ($debuglevel) = $debuglevel-2;
+    local $/="\0";
+
+    my $r = { };
+    open GITS, "-|", @cmd or die $!;
+    while (<GITS>) {
+	chomp or die;
+	printdebug "=> ", (messagequote $_), "\n";
+	m/\n/ or die "$_ ?";
+	push @{ $r->{$`} }, $'; #';
+    }
+    $!=0; $?=0;
+    close GITS
+	or ($!==0 && $?==256)
+	or failedcmd @cmd;
+    return $r;
+}
+
+# ========== playground handling ==========
+
+# terminology:
+#
+#   $maindir      user's git working tree
+#   $playground   area in .git/ where we can make files, unpack, etc. etc.
+#   playtree      git working tree sharing object store with the user's
+#                 inside playground, or identical to it
+#
+# other globals
+#
+#   $local_git_cfg    hash of arrays of values: git config from $maindir
+#
+# expected calling pattern
+#
+#  firstly
+#
+#    [record_maindir]
+#      must be run in directory containing .git
+#      assigns to $maindir if not already set
+#      also calls git_slurp_config_src to record git config
+#        in $local_git_cfg, unless it's already set
+#
+#    fresh_playground SUBDIR_PATH_COMPONENTS
+#      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
+#      default SUBDIR_PATH_COMPONENTS is $playground_subdir
+#      calls record_maindir
+#      sets up a new playground (destroying any old one)
+#      assigns to $playground and returns the same pathname
+#      caller may call multiple times with different subdir paths
+#       createing different playgrounds; but $playground global can
+#       refer only to one, obv.
+#
+#    ensure_a_playground SUBDIR_PATH_COMPONENTS
+#      like fresh_playground except:
+#      merely ensures the directory exists; does not delete an existing one
+#      never sets global $playground
+#
+#  then can use
+#
+#    changedir $playground
+#    changedir $maindir
+#
+#    playtree_setup $local_git_cfg
+#            # ^ call in some (perhaps trivial) subdir of $playground
+#
+#    rmtree $playground
+
+# ----- maindir -----
+
+our $maindir;
+our $local_git_cfg;
+
+sub record_maindir () {
+    $maindir //= must_getcwd();
+    $local_git_cfg //= git_slurp_config_src 'local';
+}
+
+# ----- playgrounds -----
+
+our $playground;
+
+sub ensure_a_playground_parent ($) {
+    my ($spc) = @_;
+    record_maindir();
+    $spc = ".git/$spc";
+    my $parent = dirname $spc;
+    mkdir $parent or $!==EEXIST or fail "failed to mkdir $parent: $!";
+    return $spc;
+}    
+
+sub ensure_a_playground ($) {
+    my ($spc) = @_;
+    $spc = ensure_a_playground_parent $spc;
+    mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
+    return $spc;
+}    
+
+sub fresh_playground ($) {
+    my ($spc) = @_;
+    $spc = ensure_a_playground_parent $spc;
+    rmtree $spc;
+    mkdir $spc or die "$spc $!";
+    return $playground = "$maindir/$spc";
+}
+
+# ----- playtrees -----
+
+sub playtree_setup (;$) {
+    my ($t_local_git_cfg) = @_;
+    $t_local_git_cfg //= $local_git_cfg;
+    # for use in the playtree
+    # $maindir must be set, eg by calling record_maindir or fresh_playground
+    runcmd qw(git init -q);
+    runcmd qw(git config gc.auto 0);
+    foreach my $copy (qw(user.email user.name user.useConfigOnly
+                         core.sharedRepository
+                         core.compression core.looseCompression
+                         core.bigFileThreshold core.fsyncObjectFiles)) {
+	my $v = $t_local_git_cfg->{$copy};
+	next unless $v;
+	runcmd qw(git config), $copy, $_ foreach @$v;
+    }
+    rmtree('.git/objects');
+    symlink "$maindir/.git/objects",'.git/objects' or die $!;
+    ensuredir '.git/info';
+    open GA, "> .git/info/attributes" or die $!;
+    print GA "* $negate_harmful_gitattrs\n" or die $!;
+    close GA or die $!;
+}
+
 1;