+sub cmd_record_ffq_prev () {
+ badusage "no arguments allowed" if @ARGV;
+ my ($status, $msg) = record_ffq_prev_deferred();
+ if ($status eq 'exists' && $opt_noop_ok) {
+ print "Previous head already recorded\n" or die $!;
+ } elsif ($status eq 'deferred') {
+ run_deferred_updates 'record-ffq-prev';
+ } else {
+ fail "Could not preserve: $msg";
+ }
+}
+
+sub cmd_anchor () {
+ badusage "no arguments allowed" if @ARGV;
+ my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
+ print "$bw\n" or die $!;
+}
+
+sub cmd_breakwater () {
+ badusage "no arguments allowed" if @ARGV;
+ my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
+ print "$bw\n" or die $!;
+}
+
+sub cmd_status () {
+ badusage "no arguments allowed" if @ARGV;
+
+ # todo: gdr status should print divergence info
+ # todo: gdr status should print upstream component(s) info
+ # todo: gdr should leave/maintain some refs with this kind of info ?
+
+ my $oldest = { Badness => 0 };
+ my $newest;
+ my $note = sub {
+ my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
+ if ($oldest->{Badness} < $badness) {
+ $oldest = $newest = undef;
+ }
+ $oldest = {
+ Badness => $badness,
+ CommitId => $cl->{CommitId},
+ OurMsg => $ourmsg,
+ KcMsg => $kcmsg,
+ };
+ $newest //= $oldest;
+ };
+ my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
+ sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
+ sub { $note->(2, 'branch is unlaundered', @_); },
+ sub { $note->(3, 'branch needs laundering', @_); },
+ sub { $note->(4, 'branch not in git-debrebase form', @_); };
+
+ my $prcommitinfo = sub {
+ my ($cid) = @_;
+ flush STDOUT or die $!;
+ runcmd @git, qw(--no-pager log -n1),
+ '--pretty=format: %h %s%n',
+ $cid;
+ };
+
+ print "current branch contents, in git-debrebase terms:\n";
+ if (!$oldest->{Badness}) {
+ print " branch is laundered\n";
+ } else {
+ print " $oldest->{OurMsg}\n";
+ my $printed = '';
+ foreach my $info ($oldest, $newest) {
+ my $cid = $info->{CommitId};
+ next if $cid eq $printed;
+ $printed = $cid;
+ print " $info->{KcMsg}\n";
+ $prcommitinfo->($cid);
+ }
+ }
+
+ my $prab = sub {
+ my ($cid, $what) = @_;
+ if (!defined $cid) {
+ print " $what is not well-defined\n";
+ } else {
+ print " $what\n";
+ $prcommitinfo->($cid);
+ }
+ };
+ print "key git-debrebase commits:\n";
+ $prab->($anchor, 'anchor');
+ $prab->($bw, 'breakwater');
+
+ my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
+ ffq_prev_branchinfo();
+
+ print "branch and ref status, in git-debrebase terms:\n";
+ if ($ffq_msg) {
+ print " $ffq_msg\n";
+ } else {
+ $ffq_prev = git_get_ref $ffq_prev;
+ $gdrlast = git_get_ref $gdrlast;
+ if ($ffq_prev) {
+ print " unstitched; previous tip was:\n";
+ $prcommitinfo->($ffq_prev);
+ } elsif (!$gdrlast) {
+ print " stitched? (no record of git-debrebase work)\n";
+ } elsif (is_fast_fwd $gdrlast, 'HEAD') {
+ print " stitched\n";
+ } else {
+ print " not git-debrebase (diverged since last stitch)\n"
+ }
+ }
+ print "you are currently rebasing\n" if currently_rebasing();
+}
+
+sub cmd_stitch () {
+ my $prose = 'stitch';
+ getoptions("stitch",
+ 'prose=s', \$prose);
+ badusage "no arguments allowed" if @ARGV;
+ do_stitch $prose, 0;
+}
+sub cmd_prepush () { cmd_stitch(); }
+
+sub cmd_quick () {
+ badusage "no arguments allowed" if @ARGV;
+ do_launder_head 'launder for git-debrebase quick';
+ do_stitch 'quick';
+}
+
+sub cmd_conclude () {
+ my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
+ if (!$ffq_prev_commitish) {
+ fail "No ongoing git-debrebase session." unless $opt_noop_ok;
+ return;
+ }
+ my $dangling_head = get_head();
+
+ badusage "no arguments allowed" if @ARGV;
+ do_launder_head 'launder for git-debrebase quick';
+ do_stitch 'quick';
+}
+
+sub cmd_scrap () {
+ if (currently_rebasing()) {
+ runcmd @git, qw(rebase --abort);
+ }
+ my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
+ if (!$ffq_prev_commitish) {
+ fail "No ongoing git-debrebase session." unless $opt_noop_ok;
+ finish 0;
+ }
+ my $scrapping_head = get_head();
+ badusage "no arguments allowed" if @ARGV;
+ push @deferred_updates,
+ "update $gdrlast $ffq_prev_commitish $git_null_obj",
+ "update $ffq_prev $git_null_obj $ffq_prev_commitish";
+ snags_maybe_bail();
+ update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
+}
+
+sub make_patches_staged ($) {
+ my ($head) = @_;
+ # Produces the patches that would result from $head if it were
+ # laundered.
+ my ($secret_head, $secret_bw, $last_anchor) = walk $head;
+ fresh_workarea();
+ in_workarea sub {
+ gbp_pq_export 'bw', $secret_bw, $secret_head;
+ };
+}
+
+sub make_patches ($) {
+ my ($head) = @_;
+ keycommits $head, 0, \&snag;
+ make_patches_staged $head;
+ my $out;
+ in_workarea sub {
+ my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
+ runcmd @git, qw(read-tree), $head;
+ read_tree_subdir 'debian/patches', $ptree;
+ $out = make_commit [$head], [
+ 'Commit patch queue (exported by git-debrebase)',
+ '[git-debrebase: export and commit patches]',
+ ];
+ };
+ return $out;
+}
+
+sub cmd_make_patches () {
+ my $opt_quiet_would_amend;
+ getoptions("make-patches",
+ 'quiet-would-amend!', \$opt_quiet_would_amend);
+ badusage "no arguments allowed" if @ARGV;
+ bail_if_rebasing();
+ my $old_head = get_head();
+ my $new = make_patches $old_head;
+ my $d = get_differs $old_head, $new;
+ if ($d == 0) {
+ fail "No (more) patches to export." unless $opt_noop_ok;
+ return;
+ } elsif ($d == D_PAT_ADD) {
+ snags_maybe_bail();
+ update_head_checkout $old_head, $new, 'make-patches';
+ } else {
+ print STDERR failmsg
+ "Patch export produced patch amendments".
+ " (abandoned output commit $new).".
+ " Try laundering first."
+ unless $opt_quiet_would_amend;
+ finish 7;
+ }
+}
+
+sub cmd_convert_from_gbp () {
+ badusage "want only 1 optional argument, the upstream git commitish"
+ unless @ARGV<=1;
+
+ my $clogp = parsechangelog();
+ my $version = $clogp->{'Version'}
+ // die "missing Version from changelog";
+
+ my ($upstream_spec) = @ARGV;
+
+ my $upstream_version = upstreamversion $version;
+ my $upstream =
+ resolve_upstream_version($upstream_spec, $upstream_version);
+
+ my $old_head = get_head();
+
+ my $upsdiff = get_differs $upstream, $old_head;
+ if ($upsdiff & D_UPS) {
+ runcmd @git, qw(--no-pager diff --stat),
+ $upstream, $old_head,
+ qw( -- :!/debian :/);
+ fail <<END;
+upstream ($upstream_spec) and HEAD are not
+identical in upstream files. See diffstat above, or run
+ git diff $upstream_spec HEAD -- :!/debian :/
+END
+ }
+
+ if (!is_fast_fwd $upstream, $old_head) {
+ snag 'upstream-not-ancestor',
+ "upstream ($upstream) is not an ancestor of HEAD";
+ } else {
+ my $wrong = cmdoutput
+ (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
+ qw(-- :/ :!/debian));
+ if (length $wrong) {
+ snag 'unexpected-upstream-changes',
+ "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
+ print STDERR "list expected changes with: git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
+ }
+ }
+
+ if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
+ snag 'upstream-has-debian',
+ "upstream ($upstream) contains debian/ directory";
+ }
+
+ my $previous_dgit_view = eval {
+ my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
+ my ($lvsn, $suite);
+ parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
+ my ($stz, $desc) = @_;
+ no warnings qw(exiting);
+ printdebug 'CHANGELOG ', Dumper($desc, $stz);
+ next unless $stz->{Date};
+ next unless $stz->{Distribution} ne 'UNRELEASED';
+ $lvsn = $stz->{Version};
+ $suite = $stz->{Distribution};
+ last;
+ };
+ die "neither of the first two changelog entries are released\n"
+ unless defined $lvsn;
+ print "last finished-looking changelog entry: ($lvsn) $suite\n";
+ my $mtag_pat = debiantag_maintview $lvsn, '*';
+ my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
+ $mtag_pat;
+ die "could not find suitable maintainer view tag $mtag_pat\n"
+ unless $mtag_pat =~ m{/};
+ is_fast_fwd $mtag, 'HEAD' or
+ die "HEAD is not FF from maintainer tag $mtag!";
+ my $dtag = "archive/$mtag";
+ is_fast_fwd $mtag, $dtag or
+ die "dgit view tag $dtag is not FF from maintainer tag $mtag";
+ print "will stitch in dgit view, $dtag\n";
+ git_rev_parse $dtag;
+ };
+ if (!$previous_dgit_view) {
+ $@ =~ s/^\n+//;
+ chomp $@;
+ print STDERR "cannot stitch in dgit view: $@\n";
+ }
+
+ snags_maybe_bail_early();
+
+ my $work;
+
+ fresh_workarea();
+ in_workarea sub {
+ runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
+ # make a branch out of the patch queue - we'll want this in a mo
+ runcmd qw(gbp pq import);
+ # strip the patches out
+ runcmd @git, qw(checkout -q gdr-internal~0);
+ rm_subdir_cached 'debian/patches';
+ $work = make_commit ['HEAD'], [
+ 'git-debrebase convert-from-gbp: drop patches from tree',
+ 'Delete debian/patches, as part of converting to git-debrebase format.',
+ '[git-debrebase convert-from-gbp: drop patches from tree]'
+ ];
+ # make the anchor merge
+ # the tree is already exactly right
+ $work = make_commit [$work, $upstream], [
+ 'git-debrebase import: declare upstream',
+ 'First breakwater merge.',
+ '[git-debrebase anchor: declare upstream]'
+ ];
+
+ # rebase the patch queue onto the new breakwater
+ runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
+ runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
+ $work = git_rev_parse 'HEAD';
+
+ if ($previous_dgit_view) {
+ $work = make_commit [$work, $previous_dgit_view], [
+ 'git-debrebase import: declare ff from dgit archive view',
+ '[git-debrebase pseudomerge: import-from-gbp]',
+ ];
+ }
+ };
+
+ ffq_check $work;
+ snags_maybe_bail();
+ update_head_checkout $old_head, $work, 'convert-from-gbp';
+}
+
+sub cmd_convert_to_gbp () {
+ badusage "no arguments allowed" if @ARGV;
+ my $head = get_head();
+ my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
+ keycommits $head, 0;
+ my $out;
+ make_patches_staged $head;
+ in_workarea sub {
+ $out = make_commit ['HEAD'], [
+ 'Commit patch queue (converted from git-debrebase format)',
+ '[git-debrebase convert-to-gbp: commit patches]',
+ ];
+ };
+ if (defined $ffq) {
+ push @deferred_updates, "delete $ffq";
+ push @deferred_updates, "delete $gdrlast";
+ }
+ snags_maybe_bail();
+ update_head_checkout $head, $out, "convert to gbp (v0)";
+ print <<END or die $!;
+git-debrebase: converted to git-buildpackage branch format
+git-debrebase: WARNING: do not now run "git-debrebase" any more
+git-debrebase: WARNING: doing so would drop all upstream patches!
+END
+}
+
+sub cmd_convert_from_dgit_view () {
+ my $clogp = parsechangelog();
+
+ my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
+ my $do_origs = 1;
+ my $do_tags = 1;
+ my $always = 0;
+ my $diagnose = 0;
+
+ getoptions("convert-from-dgit-view",
+ 'diagnose!', \$diagnose,
+ 'build-products-dir:s', \$bpd,
+ 'origs!', \$do_origs,
+ 'tags!', \$do_tags,
+ 'always-convert-anyway!', \$always);
+ fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
+
+ my @upstreams;
+
+ if (@ARGV) {
+ my $spec = shift @ARGV;
+ my $commit = git_rev_parse "$spec^{commit}";
+ push @upstreams, { Commit => $commit,
+ Source => "$ARGV[0], from command line",
+ Only => 1,
+ };
+ }
+
+ my $head = get_head();
+
+ if (!$always) {
+ my $troubles = 0;
+ my $trouble = sub { $troubles++; };
+ keycommits $head, sub{}, sub{}, $trouble, $trouble;
+ printdebug "troubles=$troubles\n";
+ if (!$troubles) {
+ print STDERR <<END;
+$us: Branch already seems to be in git-debrebase format!
+$us: --always-convert-anyway would do the conversion operation anyway
+$us: but is probably a bad idea. Probably, you wanted to do nothing.
+END
+ fail "Branch already in git-debrebase format." unless $opt_noop_ok;
+ finish 0;
+ }
+ }
+
+ snags_maybe_bail_early();
+
+ my $version = upstreamversion $clogp->{Version};
+ print STDERR "Considering possible commits corresponding to upstream:\n";
+
+ if (!@upstreams) {
+ if ($do_tags) {
+ my @tried;
+ my $ups_tag = upstream_commitish_search $version, \@tried;
+ if ($ups_tag) {
+ my $this = "git tag $tried[-1]";
+ push @upstreams, { Commit => $ups_tag,
+ Source => $this,
+ };
+ } else {
+ printf STDERR
+ " git tag: no suitable tag found (tried %s)\n",
+ "@tried";
+ }
+ }
+ if ($do_origs) {
+ my $p = $clogp->{'Source'};
+ # we do a quick check to see if there are plausible origs
+ my $something=0;
+ if (!opendir BPD, $bpd) {
+ die "$bpd: opendir: $!" unless $!==ENOENT;
+ } else {
+ while ($!=0, my $f = readdir BPD) {
+ next unless is_orig_file_of_p_v $f, $p, $version;
+ printf STDERR
+ " orig: found what looks like a .orig, %s\n",
+ "$bpd/$f";
+ $something=1;
+ last;
+ }
+ die "read $bpd: $!" if $!;
+ closedir BPD;
+ }
+ if ($something) {
+ my $tree = cmdoutput
+ @dgit, qw(--build-products-dir), $bpd,
+ qw(print-unapplied-treeish);
+ fresh_workarea();
+ in_workarea sub {
+ runcmd @git, qw(reset --quiet), $tree, qw(-- .);
+ rm_subdir_cached 'debian';
+ $tree = cmdoutput @git, qw(write-tree);
+ my $ups_synth = make_commit [], [ <<END, <<END,
+Import effective orig tree for upstream version $version
+END
+This includes the contents of the .orig(s), minus any debian/ directory.
+
+[git-debrebase import-from-dgit-view upstream-import-convert: $version]
+END
+ ];
+ push @upstreams, { Commit => $ups_synth,
+ Source => "orig(s) imported via dgit",
+ };
+ }
+ } else {
+ printf STDERR
+ " orig: no suitable origs found (looked for %s in %s)\n",
+ "${p}_".(stripeoch $version)."...", $bpd;
+ }
+ }
+ }
+
+ my $some_patches = stat_exists 'debian/patches/series';
+
+ print STDERR "Evaluating possible commits corresponding to upstream:\n";
+
+ my $result;
+ foreach my $u (@upstreams) {
+ my $work = $head;
+ fresh_workarea();
+ in_workarea sub {
+ runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
+ runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
+ runcmd @git, qw(clean -xdff);
+ runcmd @git, qw(checkout), $head, qw(-- debian);
+ if ($some_patches) {
+ rm_subdir_cached 'debian/patches';
+ $work = make_commit [ $work ], [
+ 'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
+ "Drop upstream changes, and delete debian/patches, as part of converting\n".
+ "to git-debrebase format. Upstream changes will appear as commits.",
+ '[git-debrebase convert-from-dgit-view: drop patches from tree]'
+ ];
+ }
+ $work = make_commit [ $work, $u->{Commit} ], [
+ 'git-debrebase convert-from-dgit-view: declare upstream',
+ '(Re)constructed breakwater merge.',
+ '[git-debrebase anchor: declare upstream]'
+ ];
+ runcmd @git, qw(checkout --quiet -b mk), $work;
+ if ($some_patches) {
+ runcmd @git, qw(checkout), $head, qw(-- debian/patches);
+ runcmd @git, qw(reset --quiet);
+ my @gbp_cmd = (qw(gbp pq import));
+ if (!$diagnose) {
+ my $gbp_err = "../gbp-pq-err";
+ @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
+ }
+ my $r = system @gbp_cmd;
+ if ($r) {
+ printf STDERR
+ " %s: couldn't apply patches: gbp pq %s",
+ $u->{Source}, waitstatusmsg();
+ return;
+ }
+ }
+ my $work = git_rev_parse qw(HEAD);
+ my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
+ if (length $diffout) {
+ print STDERR
+ " $u->{Source}: applying patches gives different tree\n";
+ print STDERR $diffout if $diagnose;
+ return;
+ }
+ # OMG!
+ $u->{Result} = $work;
+ $result = $u;
+ };
+ last if $result;
+ }
+
+ if (!$result) {
+ fail <<END;
+Could not find or construct a suitable upstream commit.
+Rerun adding --diagnose after convert-from-dgit-view, or pass a
+upstream commmit explicitly or provide suitable origs.
+END
+ }
+
+ printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
+
+ ffq_check $result->{Result};
+ snags_maybe_bail();
+ update_head_checkout $head, $result->{Result},
+ 'convert-from-dgit-view';
+}
+