+AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
+
+AC_PATH_PROG([XSLTPROC], [xsltproc])
+AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
+
+AC_PATH_PROG([M4], [m4])
+
+AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware or other]))
+if test "z$with_distro" = "z"; then
+ if test "$cross_compiling" = yes; then
+ AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
+ else
+ AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
+ AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
+ AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
+ if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
+ with_distro="ubuntu"
+ fi
+ AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
+ AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
+ AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
+ fi
+ if test "z$with_distro" = "z"; then
+ with_distro=`uname -s`
+ fi
+fi
+with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
+AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
+
+# Default generic names
+SPECIAL_SYSLOG_SERVICE=syslog.service
+
+# Location of the init scripts as mandated by LSB
+SYSTEM_SYSVINIT_PATH=/etc/init.d
+
+M4_DISTRO_FLAG=
+
+case $with_distro in
+ fedora)
+ SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
+ SYSTEM_SYSVRCND_PATH=/etc/rc.d
+
+ # A little background why we define this special unit
+ # names here in configure.ac: SysV services currently
+ # cannot have aliases. As long as syslog is started
+ # via a SysV init script we hence define this name to
+ # the actual SysV name here. Later on when SysV init
+ # scripts are not used anymore it is advisable to use
+ # the generic name instead and use symlinks in the
+ # unit directories to point to the right native unit
+ # file.
+
+ SPECIAL_SYSLOG_SERVICE=rsyslog.service
+ AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
+ M4_DISTRO_FLAG=-DTARGET_FEDORA=1
+ ;;
+ suse)
+ SYSTEM_SYSVRCND_PATH=/etc/init.d
+ AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
+ M4_DISTRO_FLAG=-DTARGET_SUSE=1
+ ;;
+ debian)
+ SYSTEM_SYSVRCND_PATH=/etc
+ SPECIAL_SYSLOG_SERVICE=rsyslog.service
+ AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
+ M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
+ ;;
+ ubuntu)
+ SYSTEM_SYSVRCND_PATH=/etc
+ SPECIAL_SYSLOG_SERVICE=rsyslog.service
+ AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
+ M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
+ ;;
+ arch)
+ SYSTEM_SYSVINIT_PATH=/etc/rc.d
+ SYSTEM_SYSVRCND_PATH=/etc
+ SPECIAL_SYSLOG_SERVICE=syslog-ng.service
+ AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
+ M4_DISTRO_FLAG=-DTARGET_ARCH=1
+ ;;
+ gentoo)
+ SYSTEM_SYSVINIT_PATH=
+ SYSTEM_SYSVRCND_PATH=
+ SPECIAL_SYSLOG_SERVICE=syslog-ng.service
+ AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
+ M4_DISTRO_FLAG=-DTARGET_GENTOO=1
+ ;;
+ slackware)
+ SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
+ SYSTEM_SYSVRCND_PATH=/etc/rc.d
+ AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
+ M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
+ ;;
+ other)
+ AS_IF([test "x$with_syslog_service" = "x"],
+ [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
+ ;;
+ *)
+ AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
+ ;;
+esac
+
+AC_ARG_WITH([sysvinit-path],
+ [AS_HELP_STRING([--with-sysvinit-path=PATH],
+ [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
+ [SYSTEM_SYSVINIT_PATH="$withval"],
+ [])
+
+AC_ARG_WITH([sysvrcd-path],
+ [AS_HELP_STRING([--with-sysvrcd-path=PATH],
+ [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
+ [SYSTEM_SYSVRCND_PATH="$withval"],
+ [])
+
+AC_ARG_WITH([syslog-service],
+ [AS_HELP_STRING([--with-syslog-service=UNIT],
+ [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
+ [SPECIAL_SYSLOG_SERVICE="$withval"],
+ [])
+
+AC_SUBST(SYSTEM_SYSVINIT_PATH)
+AC_SUBST(SYSTEM_SYSVRCND_PATH)
+AC_SUBST(SPECIAL_SYSLOG_SERVICE)
+AC_SUBST(M4_DISTRO_FLAG)
+
+if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
+ AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
+ SYSTEM_SYSV_COMPAT="yes"
+elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
+ AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
+else
+ SYSTEM_SYSV_COMPAT="no"
+fi
+
+AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
+AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
+AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
+AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
+AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
+AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
+AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
+AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
+
+AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
+
+AC_ARG_WITH([dbuspolicydir],
+ AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
+ [],
+ [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
+
+AC_ARG_WITH([dbussessionservicedir],
+ AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
+ [],
+ [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
+
+AC_ARG_WITH([dbussystemservicedir],
+ AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
+ [],
+ [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
+
+AC_ARG_WITH([dbusinterfacedir],
+ AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
+ [],
+ [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
+
+AC_ARG_WITH([udevrulesdir],
+ AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
+ [],
+ [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
+
+AC_ARG_WITH([pamlibdir],
+ AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
+ [],
+ [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
+
+AC_ARG_WITH([rootdir],
+ AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
+ [],
+ [with_rootdir=${ac_default_prefix}])
+
+AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
+AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
+AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
+AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
+AC_SUBST([udevrulesdir], [$with_udevrulesdir])
+AC_SUBST([pamlibdir], [$with_pamlibdir])
+AC_SUBST([rootdir], [$with_rootdir])
+
+AC_CONFIG_FILES([Makefile])
+AC_OUTPUT
+
+echo "
+ $PACKAGE_NAME $VERSION