test/CMakeLists.txt

   1 add_custom_target (tests)
   2
   3 # have to add timer.c and mt19937ar.c as symbols are declared extern
   4 add_executable (testopt testfuncs.c testfuncs.h testopt.c
   5   ${PROJECT_SOURCE_DIR}/src/util/timer.c ${PROJECT_SOURCE_DIR}/src/util/mt19937ar.c ${PROJECT_SOURCE_DIR}/src/util/nlopt-getopt.c)
   6 target_link_libraries (testopt ${nlopt_lib})
   7 target_include_directories (testopt PRIVATE ${NLOPT_PRIVATE_INCLUDE_DIRS})
   8 add_dependencies (tests testopt)
   9
  10 foreach (algo_index RANGE 29)# 43
  11   foreach (obj_index RANGE 1)# 21
  12     set (enable_ TRUE)
  13     # cxx stogo
  14     if (NOT NLOPT_CXX)
  15       if (algo_index STREQUAL 8 OR algo_index STREQUAL 9)
  16         set (enable_ FALSE)
  17       endif ()
  18     endif ()
  19     # cxx11 ags
  20     if (NOT NLOPT_CXX11 AND algo_index STREQUAL 43)
  21       set (enable_ FALSE)
  22     endif ()
  23     # L-BFGS
  24     if (algo_index STREQUAL 10)
  25       set (enable_ FALSE)
  26     endif ()
  27     # LN_NEWUOA_BOUND timeouts on msvc
  28     if (algo_index STREQUAL 27)
  29       set (enable_ FALSE)
  30     endif ()
  31     if (enable_)
  32       add_test (NAME testopt_algo${algo_index}_obj${obj_index} COMMAND testopt -a ${algo_index} -o ${obj_index})
  33       if (WIN32)
  34         set_tests_properties (testopt_algo${algo_index}_obj${obj_index} PROPERTIES ENVIRONMENT "PATH=${PROJECT_BINARY_DIR}\\${CMAKE_BUILD_TYPE};$ENV{PATH}")  # to load dll
  35       endif ()
  36     endif ()
  37   endforeach ()
  38 endforeach ()
  39
  40 if (NUMPY_FOUND AND PYTHONLIBS_FOUND AND (SWIG_FOUND OR (EXISTS ${PROJECT_SOURCE_DIR}/src/swig/nlopt-python.cpp)))
  41   set (PYINSTALLCHECK_ENVIRONMENT "LD_LIBRARY_PATH=${PROJECT_BINARY_DIR}/src/swig"
  42                                   "PYTHONPATH=${PROJECT_BINARY_DIR}/src/swig"
  43     )
  44   add_test (NAME test_python COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/t_python.py)
  45   set_tests_properties (test_python PROPERTIES ENVIRONMENT "${PYINSTALLCHECK_ENVIRONMENT}")
  46 endif ()
  47
  48 if (OCTAVE_FOUND)
  49   add_test (NAME test_octave COMMAND ${OCTAVE_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/t_octave.m ${PROJECT_SOURCE_DIR}/src/octave ${PROJECT_BINARY_DIR}/src/octave)
  50 endif ()
  51
  52 if (GUILE_FOUND AND ((SWIG_FOUND AND SWIG_VERSION VERSION_GREATER 2.0.9) OR (EXISTS ${PROJECT_SOURCE_DIR}/src/swig/nlopt-guile.cpp)))
  53   set (GUILECHECK_ENVIRONMENT "LD_LIBRARY_PATH=${PROJECT_BINARY_DIR}/src/swig"
  54                               "GUILE_LOAD_PATH=${PROJECT_BINARY_DIR}/src/swig"
  55     )
  56   add_test (NAME test_guile COMMAND ${GUILE_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/t_guile.scm)
  57   set_tests_properties (test_guile PROPERTIES ENVIRONMENT "${GUILECHECK_ENVIRONMENT}")
  58 endif ()