sysdeps/unix/sysv/linux/ia64/sysdep.S

   1 /* Copyright (C) 1999, 2000, 2001, 2003, 2004 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by David Mosberger-Tang <davidm@hpl.hp.com>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <features.h>
  22 #include <tls.h>
  23
  24 ENTRY(__syscall_error)
  25 #if RTLD_PRIVATE_ERRNO
  26         /*
  27          * Note that the gp has to be set properly for this to work.
  28          * As long as all syscalls are in the same load unit
  29          * (executable or shared library) as this routine, we should
  30          * be fine.  Otherwise, we would have to first load the global
  31          * pointer register from __gp.
  32          */
  33         addl    r2=@gprel(rtld_errno),gp
  34         ;;
  35         st4     [r2]=r8
  36         mov     r8=-1
  37 #elif USE___THREAD
  38 # ifndef NOT_IN_libc
  39 #  define SYSCALL_ERROR_ERRNO __libc_errno
  40 # else
  41 #  define SYSCALL_ERROR_ERRNO errno
  42 # endif
  43         addl    r2=@ltoff(@tprel(SYSCALL_ERROR_ERRNO)), gp;;
  44         ld8     r2=[r2]
  45         mov     r3=r8;;
  46         mov     r8=-1
  47         add     r2=r2,r13;;
  48         st4     [r2]=r3
  49 #elif defined _LIBC_REENTRANT
  50         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(0)
  51         alloc   r33=ar.pfs, 0, 4, 0, 0
  52         mov     r32=rp
  53         .body
  54         mov     r35=r8
  55         mov     r34=r1
  56         ;;
  57         br.call.sptk.many b0 = __errno_location
  58 .Lret0:         /* force new bundle */
  59         st4     [r8]=r35
  60         mov     r1=r34
  61         mov     rp=r32
  62         mov     r8=-1
  63         mov     ar.pfs=r33
  64 #else /* _LIBC_REENTRANT */
  65         /*
  66          * Note that the gp has to be set properly for this to work.
  67          * As long as all syscalls are in the same load unit
  68          * (executable or shared library) as this routine, we should
  69          * be fine.  Otherwise, we would have to first load the global
  70          * pointer register from __gp.
  71          */
  72         addl    r2=@ltoff(errno),gp
  73         ;;
  74         ld8     r2=[r2]
  75         mov     r3=r8
  76         mov     r8=-1
  77         ;;
  78         st4     [r2]=r3
  79 #endif /* _LIBC_REENTRANT */
  80         ret                     // ret is #define'd in syscall.h!
  81 END(__syscall_error)
  82
  83 ENTRY(__ia64_syscall)
  84         mov r15=r37             /* syscall number */
  85         break __BREAK_SYSCALL
  86         cmp.eq p6,p0=-1,r10     /* r10 = -1 on error */
  87 (p6)    br.cond.spnt.few __syscall_error
  88         ret
  89 PSEUDO_END(__ia64_syscall)