sysdeps/unix/sysv/linux/ia64/__longjmp.S

   1 /* Copyright (C) 1999, 2000, 2001, 2005 Free Software Foundation, Inc.
   2    Contributed by David Mosberger-Tang <davidm@hpl.hp.com>.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.
  18
  19    Note that __sigsetjmp() did NOT flush the register stack.  Instead,
  20    we do it here since __longjmp() is usually much less frequently
  21    invoked than __sigsetjmp(). The only difficulty is that __sigsetjmp()
  22    didn't (and wouldn't be able to) save ar.rnat either.  This is a problem
  23    because if we're not careful, we could end up loading random NaT bits.
  24    There are two cases:
  25
  26         (i)  ar.bsp < ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  27                 ar.rnat contains the desired bits---preserve ar.rnat
  28                 across loadrs and write to ar.bspstore
  29
  30         (ii) ar.bsp >= ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  31                 The desired ar.rnat is stored in
  32                 ia64_rse_rnat_addr(jmpbuf.ar_bsp).  Load those
  33                 bits into ar.rnat after setting ar.bspstore. */
  34
  35 #include <sysdep.h>
  36 #include <features.h>
  37
  38 #       define  pPos    p6      /* is rotate count positive? */
  39 #       define  pNeg    p7      /* is rotate count negative? */
  40
  41
  42         /* __longjmp(__jmp_buf buf, int val) */
  43
  44 LEAF(__longjmp)
  45 #ifdef CHECK_RSP
  46         alloc r8=ar.pfs,2,1,1,0
  47 #else
  48         alloc r8=ar.pfs,2,1,0,0
  49 #endif
  50         mov r27=ar.rsc
  51         add r2=0x98,in0         // r2 <- &jmpbuf.orig_jmp_buf_addr
  52         ;;
  53         ld8 r8=[r2],-16         // r8 <- orig_jmp_buf_addr
  54         mov r10=ar.bsp
  55         and r11=~0x3,r27        // clear ar.rsc.mode
  56         ;;
  57         flushrs                 // flush dirty regs to backing store (must be first in insn grp)
  58         ld8 r23=[r2],8          // r23 <- jmpbuf.ar_bsp
  59         sub r8=r8,in0           // r8 <- &orig_jmpbuf - &jmpbuf
  60         ;;
  61         ld8 r25=[r2]            // r25 <- jmpbuf.ar_unat
  62         extr.u r8=r8,3,6        // r8 <- (&orig_jmpbuf - &jmpbuf)/8 & 0x3f
  63         ;;
  64         cmp.lt pNeg,pPos=r8,r0
  65         mov r2=in0
  66         ;;
  67 (pPos)  mov r16=r8
  68 (pNeg)  add r16=64,r8
  69 (pPos)  sub r17=64,r8
  70 (pNeg)  sub r17=r0,r8
  71         ;;
  72         mov ar.rsc=r11          // put RSE in enforced lazy mode
  73         shr.u r8=r25,r16
  74         add r3=8,in0            // r3 <- &jmpbuf.r1
  75         shl r9=r25,r17
  76         ;;
  77         ld8.fill.nta r28=[r2],16        // r28 <- jmpbuf.sp
  78         or r25=r8,r9
  79         ;;
  80         mov r26=ar.rnat
  81         mov ar.unat=r25         // setup ar.unat (NaT bits for r1, r4-r7, and r12)
  82         ;;
  83 #ifdef CHECK_RSP
  84         CHECK_RSP (r28)
  85 #endif
  86         ld8.fill.nta gp=[r3],16         // r1 (gp)
  87         dep r11=-1,r23,3,6      // r11 <- ia64_rse_rnat_addr(jmpbuf.ar_bsp)
  88         mov sp=r28              // r12 (sp)
  89         ;;
  90         ld8.nta r16=[r2],16             // caller's unat
  91         ld8.nta r17=[r3],16             // fpsr
  92         ;;
  93         ld8.fill.nta r4=[r2],16 // r4
  94         ld8.fill.nta r5=[r3],16         // r5 (gp)
  95         cmp.geu p8,p0=r10,r11   // p8 <- (ar.bsp >= jmpbuf.ar_bsp)
  96         ;;
  97         ld8.fill.nta r6=[r2],16 // r6
  98         ld8.fill.nta r7=[r3],16         // r7
  99         ;;
 100         mov ar.unat=r16                 // restore caller's unat
 101         mov ar.fpsr=r17                 // restore fpsr
 102         ;;
 103         ld8.nta r16=[r2],16             // b0
 104         ld8.nta r17=[r3],16             // b1
 105         ;;
 106 (p8)    ld8 r26=[r11]           // r26 <- *ia64_rse_rnat_addr(jmpbuf.ar_bsp)
 107         mov ar.bspstore=r23     // restore ar.bspstore
 108         ;;
 109         ld8.nta r18=[r2],16             // b2
 110         ld8.nta r19=[r3],16             // b3
 111         ;;
 112 #ifdef PTR_DEMANGLE
 113         PTR_DEMANGLE (r16, r24)
 114 #endif
 115         ld8.nta r20=[r2],16             // b4
 116         ld8.nta r21=[r3],16             // b5
 117         ;;
 118         ld8.nta r11=[r2],16             // ar.pfs
 119         ld8.nta r22=[r3],56             // ar.lc
 120         ;;
 121         ld8.nta r24=[r2],32             // pr
 122         mov b0=r16
 123         ;;
 124         ldf.fill.nta f2=[r2],32
 125         ldf.fill.nta f3=[r3],32
 126         mov b1=r17
 127         ;;
 128         ldf.fill.nta f4=[r2],32
 129         ldf.fill.nta f5=[r3],32
 130         mov b2=r18
 131         ;;
 132         ldf.fill.nta f16=[r2],32
 133         ldf.fill.nta f17=[r3],32
 134         mov b3=r19
 135         ;;
 136         ldf.fill.nta f18=[r2],32
 137         ldf.fill.nta f19=[r3],32
 138         mov b4=r20
 139         ;;
 140         ldf.fill.nta f20=[r2],32
 141         ldf.fill.nta f21=[r3],32
 142         mov b5=r21
 143         ;;
 144         ldf.fill.nta f22=[r2],32
 145         ldf.fill.nta f23=[r3],32
 146         mov ar.lc=r22
 147         ;;
 148         ldf.fill.nta f24=[r2],32
 149         ldf.fill.nta f25=[r3],32
 150         cmp.eq p8,p9=0,in1
 151         ;;
 152         ldf.fill.nta f26=[r2],32
 153         ldf.fill.nta f27=[r3],32
 154         mov ar.pfs=r11
 155         ;;
 156         ldf.fill.nta f28=[r2],32
 157         ldf.fill.nta f29=[r3],32
 158         ;;
 159         ldf.fill.nta f30=[r2]
 160         ldf.fill.nta f31=[r3]
 161 (p8)    mov r8=1
 162
 163         mov ar.rnat=r26         // restore ar.rnat
 164         ;;
 165         mov ar.rsc=r27          // restore ar.rsc
 166 (p9)    mov r8=in1
 167
 168         invala                  // virt. -> phys. regnum mapping may change
 169         mov pr=r24,-1
 170         ret
 171 END(__longjmp)