sysdeps/sparc/sparc64/add_n.S

   1 /* SPARC v9 __mpn_add_n -- Add two limb vectors of the same length > 0 and
   2    store sum in a third limb vector.
   3
   4    Copyright (C) 1995, 1996, 1997, 1999 Free Software Foundation, Inc.
   5
   6    This file is part of the GNU MP Library.
   7
   8    The GNU MP Library is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU Lesser General Public License as published by
  10    the Free Software Foundation; either version 2.1 of the License, or (at your
  11    option) any later version.
  12
  13    The GNU MP Library is distributed in the hope that it will be useful, but
  14    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16    License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public License
  19    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21    MA 02111-1307, USA.  */
  22
  23
  24 #include <sysdep.h>
  25
  26
  27 /* INPUT PARAMETERS
  28    res_ptr      %o0
  29    s1_ptr       %o1
  30    s2_ptr       %o2
  31    size         %o3  */
  32
  33
  34 ENTRY(__mpn_add_n)
  35
  36         sub     %g0,%o3,%g5
  37         sllx    %o3,3,%g1
  38         add     %o1,%g1,%o1             ! make s1_ptr point at end
  39         add     %o2,%g1,%o2             ! make s2_ptr point at end
  40         add     %o0,%g1,%o0             ! make res_ptr point at end
  41         mov     0,%o4                   ! clear carry variable
  42         sllx    %g5,3,%o5               ! compute initial address index
  43
  44 1:      ldx     [%o2+%o5],%g1           ! load s2 limb
  45         add     %g5,1,%g5               ! increment loop count
  46         ldx     [%o1+%o5],%o3           ! load s1 limb
  47         addcc   %g1,%o4,%g1             ! add s2 limb and carry variable
  48         movcc   %xcc,0,%o4              ! if carry-out, o4 was 1; clear it
  49         addcc   %g1,%o3,%g1             ! add s1 limb to sum
  50         stx     %g1,[%o0+%o5]           ! store result
  51         add     %o5,8,%o5               ! increment address index
  52         brnz,pt %g5,1b
  53          movcs  %xcc,1,%o4              ! if s1 add gave carry, record it
  54
  55         retl
  56          mov %o4,%o0
  57
  58 END(__mpn_add_n)