sysdeps/i386/fpu/s_expm1.S

   1 /* ix87 specific implementation of exp(x)-1.
   2    Copyright (C) 1996, 1997, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5    Based on code by John C. Bowman <bowman@ipp-garching.mpg.de>.
   6    Corrections by H.J. Lu (hjl@gnu.ai.mit.edu), 1997.
   7
   8    The GNU C Library is free software; you can redistribute it and/or
   9    modify it under the terms of the GNU Lesser General Public
  10    License as published by the Free Software Foundation; either
  11    version 2.1 of the License, or (at your option) any later version.
  12
  13    The GNU C Library is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    Lesser General Public License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public
  19    License along with the GNU C Library; if not, write to the Free
  20    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21    02111-1307 USA.  */
  22
  23         /* Using: e^x - 1 = 2^(x * log2(e)) - 1 */
  24
  25 #include <sysdep.h>
  26 #include <machine/asm.h>
  27
  28 #ifdef __ELF__
  29         .section .rodata
  30 #else
  31         .text
  32 #endif
  33         .align ALIGNARG(4)
  34         ASM_TYPE_DIRECTIVE(minus1,@object)
  35 minus1: .double -1.0
  36         ASM_SIZE_DIRECTIVE(minus1)
  37         ASM_TYPE_DIRECTIVE(one,@object)
  38 one:    .double 1.0
  39         ASM_SIZE_DIRECTIVE(one)
  40         ASM_TYPE_DIRECTIVE(l2e,@object)
  41 l2e:    .tfloat 1.442695040888963407359924681002
  42         ASM_SIZE_DIRECTIVE(l2e)
  43
  44 #ifdef PIC
  45 #define MO(op) op##@GOTOFF(%edx)
  46 #else
  47 #define MO(op) op
  48 #endif
  49
  50         .text
  51 ENTRY(__expm1)
  52         movzwl  4+6(%esp), %eax
  53         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  54         cmpl    $0xc086, %eax   // is num >= 704?
  55         jae     HIDDEN_JUMPTARGET (__exp)
  56
  57         fldl    4(%esp)         // x
  58         fxam                    // Is NaN or +-Inf?
  59         fstsw   %ax
  60         movb    $0x45, %ch
  61         andb    %ah, %ch
  62         cmpb    $0x40, %ch
  63         je      3f              // If +-0, jump.
  64 #ifdef  PIC
  65         LOAD_PIC_REG (dx)
  66 #endif
  67         cmpb    $0x05, %ch
  68         je      2f              // If +-Inf, jump.
  69
  70         fldt    MO(l2e)         // log2(e) : x
  71         fmulp                   // log2(e)*x
  72         fld     %st             // log2(e)*x : log2(e)*x
  73         frndint                 // int(log2(e)*x) : log2(e)*x
  74         fsubr   %st, %st(1)     // int(log2(e)*x) : fract(log2(e)*x)
  75         fxch                    // fract(log2(e)*x) : int(log2(e)*x)
  76         f2xm1                   // 2^fract(log2(e)*x)-1 : int(log2(e)*x)
  77         fscale                  // 2^(log2(e)*x)-2^int(log2(e)*x) : int(log2(e)*x)
  78         fxch                    // int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  79         fldl    MO(one)         // 1 : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  80         fscale                  // 2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  81         fsubrl  MO(one)         // 1-2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  82         fstp    %st(1)          // 1-2^int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  83         fsubrp  %st, %st(1)     // 2^(log2(e)*x)
  84         ret
  85
  86 2:      testl   $0x200, %eax    // Test sign.
  87         jz      3f              // If positive, jump.
  88         fstp    %st
  89         fldl    MO(minus1)      // Set result to -1.0.
  90 3:      ret
  91 END(__expm1)
  92 weak_alias (__expm1, expm1)