src/systemadm.vala

   1 /***
   2   This file is part of systemd.
   3
   4   Copyright 2010 Lennart Poettering
   5
   6   systemd is free software; you can redistribute it and/or modify it
   7   under the terms of the GNU General Public License as published by
   8   the Free Software Foundation; either version 2 of the License, or
   9   (at your option) any later version.
  10
  11   systemd is distributed in the hope that it will be useful, but
  12   WITHOUT ANY WARRANTY; without even the implied warranty of
  13   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14   General Public License for more details.
  15
  16   You should have received a copy of the GNU General Public License
  17   along with systemd; If not, see <http://www.gnu.org/licenses/>.
  18 ***/
  19
  20 using Gtk;
  21 using GLib;
  22 using Pango;
  23
  24 static bool user = false;
  25
  26 public string format_time(uint64 time_ns) {
  27         if (time_ns <= 0)
  28                 return "";
  29         Time timestamp = Time.local((time_t) (time_ns / 1000000));
  30         return timestamp.format("%a, %d %b %Y %H:%M:%S");
  31 }
  32
  33 public void new_column(TreeView view, int column_id, string title) {
  34         TreeViewColumn col;
  35         col = new TreeViewColumn.with_attributes(title, new CellRendererText(), "text", column_id);
  36         col.set_sort_column_id(column_id);
  37         view.insert_column(col, -1);
  38 }
  39
  40 public class LeftLabel : Label {
  41         public LeftLabel(string? text = null) {
  42                 if (text != null)
  43                         set_markup("<b>%s</b>".printf(text));
  44                 set_alignment(0, 0);
  45                 set_padding(6, 0);
  46         }
  47 }
  48
  49 public class RightLabel : WrapLabel {
  50
  51         public RightLabel(string? text = null) {
  52                 set_selectable(true);
  53                 set_text_or_na(text);
  54         }
  55
  56         public void set_text_or_na(string? text = null) {
  57                 if (text == null || text == "")
  58                         set_markup("<i>n/a</i>");
  59                 else
  60                         set_text(text);
  61         }
  62
  63         public void set_markup_or_na(string? text = null) {
  64                 if (text == null || text == "")
  65                         set_markup("<i>n/a</i>");
  66                 else
  67                         set_markup(text);
  68         }
  69 }
  70
  71 public class MainWindow : Window {
  72
  73         private string? current_unit_id;
  74         private uint32 current_job_id;
  75
  76         private TreeView unit_view;
  77         private TreeView job_view;
  78
  79         private ListStore unit_model;
  80         private ListStore job_model;
  81
  82         private Gee.HashMap<string, Unit> unit_map;
  83
  84         private Button start_button;
  85         private Button stop_button;
  86         private Button restart_button;
  87         private Button reload_button;
  88         private Button cancel_button;
  89
  90         private Entry unit_load_entry;
  91         private Button unit_load_button;
  92
  93         private Button server_snapshot_button;
  94         private Button server_reload_button;
  95
  96         private Manager manager;
  97
  98         private RightLabel unit_id_label;
  99         private RightLabel unit_aliases_label;
 100         private RightLabel unit_dependency_label;
 101         private RightLabel unit_description_label;
 102         private RightLabel unit_load_state_label;
 103         private RightLabel unit_active_state_label;
 104         private RightLabel unit_sub_state_label;
 105         private RightLabel unit_fragment_path_label;
 106         private RightLabel unit_active_enter_timestamp_label;
 107         private RightLabel unit_active_exit_timestamp_label;
 108         private RightLabel unit_can_start_label;
 109         private RightLabel unit_can_reload_label;
 110         private RightLabel unit_cgroup_label;
 111
 112         private RightLabel job_id_label;
 113         private RightLabel job_state_label;
 114         private RightLabel job_type_label;
 115
 116         private ComboBox unit_type_combo_box;
 117         private CheckButton inactive_checkbox;
 118
 119         public MainWindow() throws IOError {
 120                 title = user ? "systemd User Service Manager" : "systemd System Manager";
 121                 set_position(WindowPosition.CENTER);
 122                 set_default_size(1000, 700);
 123                 set_border_width(12);
 124                 destroy.connect(Gtk.main_quit);
 125
 126                 Notebook notebook = new Notebook();
 127                 add(notebook);
 128
 129                 Box unit_vbox = new VBox(false, 12);
 130                 notebook.append_page(unit_vbox, new Label("Units"));
 131                 unit_vbox.set_border_width(12);
 132
 133                 Box job_vbox = new VBox(false, 12);
 134                 notebook.append_page(job_vbox, new Label("Jobs"));
 135                 job_vbox.set_border_width(12);
 136
 137                 unit_type_combo_box = new ComboBox.text();
 138                 Box type_hbox = new HBox(false, 6);
 139                 type_hbox.pack_start(unit_type_combo_box, false, false, 0);
 140                 unit_vbox.pack_start(type_hbox, false, false, 0);
 141
 142                 unit_type_combo_box.append_text("All unit types");
 143                 unit_type_combo_box.append_text("Targets");
 144                 unit_type_combo_box.append_text("Services");
 145                 unit_type_combo_box.append_text("Devices");
 146                 unit_type_combo_box.append_text("Mounts");
 147                 unit_type_combo_box.append_text("Automounts");
 148                 unit_type_combo_box.append_text("Swaps");
 149                 unit_type_combo_box.append_text("Sockets");
 150                 unit_type_combo_box.append_text("Paths");
 151                 unit_type_combo_box.append_text("Timers");
 152                 unit_type_combo_box.append_text("Snapshots");
 153                 unit_type_combo_box.set_active(0); // Show All
 154                 unit_type_combo_box.changed.connect(unit_type_changed);
 155
 156                 inactive_checkbox = new CheckButton.with_label("inactive too");
 157                 inactive_checkbox.toggled.connect(unit_type_changed);
 158                 type_hbox.pack_start(inactive_checkbox, false, false, 0);
 159
 160                 unit_load_entry = new Entry();
 161                 unit_load_button = new Button.with_mnemonic("_Load");
 162                 unit_load_button.set_sensitive(false);
 163
 164                 unit_load_entry.changed.connect(on_unit_load_entry_changed);
 165                 unit_load_entry.activate.connect(on_unit_load);
 166                 unit_load_button.clicked.connect(on_unit_load);
 167
 168                 Box unit_load_hbox = new HBox(false, 6);
 169                 unit_load_hbox.pack_start(unit_load_entry, false, true, 0);
 170                 unit_load_hbox.pack_start(unit_load_button, false, true, 0);
 171
 172                 server_snapshot_button = new Button.with_mnemonic("Take S_napshot");
 173                 server_reload_button = new Button.with_mnemonic("Reload _Configuration");
 174
 175                 server_snapshot_button.clicked.connect(on_server_snapshot);
 176                 server_reload_button.clicked.connect(on_server_reload);
 177
 178                 type_hbox.pack_end(server_snapshot_button, false, true, 0);
 179                 type_hbox.pack_end(server_reload_button, false, true, 0);
 180                 type_hbox.pack_end(unit_load_hbox, false, true, 24);
 181
 182                 unit_model = new ListStore(7, typeof(string), typeof(string), typeof(string), typeof(string), typeof(string), typeof(string), typeof(Unit));
 183                 job_model = new ListStore(6, typeof(string), typeof(string), typeof(string), typeof(string), typeof(Job), typeof(uint32));
 184
 185                 unit_map = new Gee.HashMap<string, Unit>();
 186
 187                 TreeModelFilter unit_model_filter;
 188                 unit_model_filter = new TreeModelFilter(unit_model, null);
 189                 unit_model_filter.set_visible_func(unit_filter);
 190
 191                 TreeModelSort unit_model_sort = new TreeModelSort.with_model(unit_model_filter);
 192
 193                 unit_view = new TreeView.with_model(unit_model_sort);
 194                 job_view = new TreeView.with_model(job_model);
 195
 196                 unit_view.cursor_changed.connect(unit_changed);
 197                 job_view.cursor_changed.connect(job_changed);
 198
 199                 new_column(unit_view, 2, "Load State");
 200                 new_column(unit_view, 3, "Active State");
 201                 new_column(unit_view, 4, "Unit State");
 202                 new_column(unit_view, 0, "Unit");
 203                 new_column(unit_view, 5, "Job");
 204
 205                 new_column(job_view, 0, "Job");
 206                 new_column(job_view, 1, "Unit");
 207                 new_column(job_view, 2, "Type");
 208                 new_column(job_view, 3, "State");
 209
 210                 ScrolledWindow scroll = new ScrolledWindow(null, null);
 211                 scroll.set_policy(PolicyType.AUTOMATIC, PolicyType.AUTOMATIC);
 212                 scroll.set_shadow_type(ShadowType.IN);
 213                 scroll.add(unit_view);
 214                 unit_vbox.pack_start(scroll, true, true, 0);
 215
 216                 scroll = new ScrolledWindow(null, null);
 217                 scroll.set_policy(PolicyType.AUTOMATIC, PolicyType.AUTOMATIC);
 218                 scroll.set_shadow_type(ShadowType.IN);
 219                 scroll.add(job_view);
 220                 job_vbox.pack_start(scroll, true, true, 0);
 221
 222                 unit_id_label = new RightLabel();
 223                 unit_aliases_label = new RightLabel();
 224                 unit_dependency_label = new RightLabel();
 225                 unit_description_label = new RightLabel();
 226                 unit_load_state_label = new RightLabel();
 227                 unit_active_state_label = new RightLabel();
 228                 unit_sub_state_label = new RightLabel();
 229                 unit_fragment_path_label = new RightLabel();
 230                 unit_active_enter_timestamp_label = new RightLabel();
 231                 unit_active_exit_timestamp_label = new RightLabel();
 232                 unit_can_start_label = new RightLabel();
 233                 unit_can_reload_label = new RightLabel();
 234                 unit_cgroup_label = new RightLabel();
 235
 236                 job_id_label = new RightLabel();
 237                 job_state_label = new RightLabel();
 238                 job_type_label = new RightLabel();
 239
 240                 unit_dependency_label.set_track_visited_links(false);
 241                 unit_dependency_label.set_selectable(false);
 242                 unit_dependency_label.activate_link.connect(on_activate_link);
 243
 244                 unit_fragment_path_label.set_track_visited_links(false);
 245
 246                 Table unit_table = new Table(8, 6, false);
 247                 unit_table.set_row_spacings(6);
 248                 unit_table.set_border_width(0);
 249                 unit_vbox.pack_start(unit_table, false, true, 0);
 250
 251                 Table job_table = new Table(2, 2, false);
 252                 job_table.set_row_spacings(6);
 253                 job_table.set_border_width(0);
 254                 job_vbox.pack_start(job_table, false, true, 0);
 255
 256                 unit_table.attach(new LeftLabel("Id:"),                     0, 1, 0, 1, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 257                 unit_table.attach(unit_id_label,                            1, 6, 0, 1, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 258                 unit_table.attach(new LeftLabel("Aliases:"),                0, 1, 1, 2, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 259                 unit_table.attach(unit_aliases_label,                       1, 6, 1, 2, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 260                 unit_table.attach(new LeftLabel("Description:"),            0, 1, 2, 3, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 261                 unit_table.attach(unit_description_label,                   1, 6, 2, 3, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 262                 unit_table.attach(new LeftLabel("Dependencies:"),           0, 1, 3, 4, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 263                 unit_table.attach(unit_dependency_label,                    1, 6, 3, 4, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 264                 unit_table.attach(new LeftLabel("Fragment Path:"),          0, 1, 4, 5, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 265                 unit_table.attach(unit_fragment_path_label,                 1, 6, 4, 5, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 266                 unit_table.attach(new LeftLabel("Control Group:"),          0, 1, 5, 6, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 267                 unit_table.attach(unit_cgroup_label,                        1, 6, 5, 6, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 268
 269                 unit_table.attach(new LeftLabel("Load State:"),             0, 1, 6, 7, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 270                 unit_table.attach(unit_load_state_label,                    1, 2, 6, 7, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 271                 unit_table.attach(new LeftLabel("Active State:"),           0, 1, 7, 8, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 272                 unit_table.attach(unit_active_state_label,                  1, 2, 7, 8, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 273                 unit_table.attach(new LeftLabel("Unit State:"),             0, 1, 8, 9, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 274                 unit_table.attach(unit_sub_state_label,                     1, 2, 8, 9, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 275
 276                 unit_table.attach(new LeftLabel("Active Enter Timestamp:"), 2, 3, 7, 8, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 277                 unit_table.attach(unit_active_enter_timestamp_label,        3, 4, 7, 8, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 278                 unit_table.attach(new LeftLabel("Active Exit Timestamp:"),  2, 3, 8, 9, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 279                 unit_table.attach(unit_active_exit_timestamp_label,         3, 4, 8, 9, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 280
 281                 unit_table.attach(new LeftLabel("Can Start/Stop:"),         4, 5, 7, 8, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 282                 unit_table.attach(unit_can_start_label,                     5, 6, 7, 8, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 283                 unit_table.attach(new LeftLabel("Can Reload:"),             4, 5, 8, 9, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 284                 unit_table.attach(unit_can_reload_label,                    5, 6, 8, 9, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 285
 286                 job_table.attach(new LeftLabel("Id:"),                      0, 1, 0, 1, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 287                 job_table.attach(job_id_label,                              1, 2, 0, 1, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 288                 job_table.attach(new LeftLabel("State:"),                   0, 1, 1, 2, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 289                 job_table.attach(job_state_label,                           1, 2, 1, 2, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 290                 job_table.attach(new LeftLabel("Type:"),                    0, 1, 2, 3, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 291                 job_table.attach(job_type_label,                            1, 2, 2, 3, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 292
 293                 ButtonBox bbox = new HButtonBox();
 294                 bbox.set_layout(ButtonBoxStyle.START);
 295                 bbox.set_spacing(6);
 296                 unit_vbox.pack_start(bbox, false, true, 0);
 297
 298                 start_button = new Button.with_mnemonic("_Start");
 299                 stop_button = new Button.with_mnemonic("Sto_p");
 300                 reload_button = new Button.with_mnemonic("_Reload");
 301                 restart_button = new Button.with_mnemonic("Res_tart");
 302
 303                 start_button.clicked.connect(on_start);
 304                 stop_button.clicked.connect(on_stop);
 305                 reload_button.clicked.connect(on_reload);
 306                 restart_button.clicked.connect(on_restart);
 307
 308                 bbox.pack_start(start_button, false, true, 0);
 309                 bbox.pack_start(stop_button, false, true, 0);
 310                 bbox.pack_start(restart_button, false, true, 0);
 311                 bbox.pack_start(reload_button, false, true, 0);
 312
 313                 bbox = new HButtonBox();
 314                 bbox.set_layout(ButtonBoxStyle.START);
 315                 bbox.set_spacing(6);
 316                 job_vbox.pack_start(bbox, false, true, 0);
 317
 318                 cancel_button = new Button.with_mnemonic("_Cancel");
 319
 320                 cancel_button.clicked.connect(on_cancel);
 321
 322                 bbox.pack_start(cancel_button, false, true, 0);
 323
 324                 manager = Bus.get_proxy_sync(
 325                                 user ? BusType.SESSION : BusType.SYSTEM,
 326                                 "org.freedesktop.systemd1",
 327                                 "/org/freedesktop/systemd1");
 328
 329                 manager.unit_new.connect(on_unit_new);
 330                 manager.job_new.connect(on_job_new);
 331                 manager.unit_removed.connect(on_unit_removed);
 332                 manager.job_removed.connect(on_job_removed);
 333
 334                 manager.subscribe();
 335
 336                 clear_unit();
 337                 clear_job();
 338                 populate_unit_model();
 339                 populate_job_model();
 340         }
 341
 342         public void populate_unit_model() throws IOError {
 343                 unit_model.clear();
 344
 345                 var list = manager.list_units();
 346
 347                 foreach (var i in list) {
 348                         TreeIter iter;
 349
 350                         Properties p = Bus.get_proxy_sync(
 351                                         user ? BusType.SESSION : BusType.SYSTEM,
 352                                         "org.freedesktop.systemd1",
 353                                         i.unit_path);
 354
 355                         p.properties_changed.connect(on_unit_changed);
 356
 357                         Unit u = Bus.get_proxy_sync(
 358                                         user ? BusType.SESSION : BusType.SYSTEM,
 359                                         "org.freedesktop.systemd1",
 360                                         i.unit_path);
 361
 362                         unit_map[i.id] = u;
 363
 364                         unit_model.append(out iter);
 365                         unit_model.set(iter,
 366                                        0, i.id,
 367                                        1, i.description,
 368                                        2, i.load_state,
 369                                        3, i.active_state,
 370                                        4, i.sub_state,
 371                                        5, i.job_type != "" ? "→ %s".printf(i.job_type) : "",
 372                                        6, u);
 373                 }
 374         }
 375
 376         public void populate_job_model() throws IOError {
 377                 job_model.clear();
 378
 379                 var list = manager.list_jobs();
 380
 381                 foreach (var i in list) {
 382                         TreeIter iter;
 383
 384                         Properties p = Bus.get_proxy_sync(
 385                                         user ? BusType.SESSION : BusType.SYSTEM,
 386                                         "org.freedesktop.systemd1",
 387                                         i.job_path);
 388
 389                         p.properties_changed.connect(on_job_changed);
 390
 391                         Job j = Bus.get_proxy_sync(
 392                                         user ? BusType.SESSION : BusType.SYSTEM,
 393                                         "org.freedesktop.systemd1",
 394                                         i.job_path);
 395
 396                         job_model.append(out iter);
 397                         job_model.set(iter,
 398                                       0, "%u".printf(i.id),
 399                                       1, i.name,
 400                                       2, "→ %s".printf(i.type),
 401                                       3, i.state,
 402                                       4, j,
 403                                       5, i.id);
 404                 }
 405         }
 406
 407         public Unit? get_current_unit() {
 408                 TreePath p;
 409                 unit_view.get_cursor(out p, null);
 410
 411                 if (p == null)
 412                         return null;
 413
 414                 TreeModel model = unit_view.get_model();
 415                 TreeIter iter;
 416                 Unit u;
 417
 418                 model.get_iter(out iter, p);
 419                 model.get(iter, 6, out u);
 420
 421                 return u;
 422         }
 423
 424         public Unit? get_unit(string id) {
 425                 return this.unit_map[id];
 426         }
 427
 428         public void unit_changed() {
 429                 Unit u = get_current_unit();
 430
 431                 if (u == null)
 432                         clear_unit();
 433                 else
 434                         show_unit(u);
 435         }
 436
 437         public void clear_unit() {
 438                 current_unit_id = null;
 439
 440                 start_button.set_sensitive(false);
 441                 stop_button.set_sensitive(false);
 442                 reload_button.set_sensitive(false);
 443                 restart_button.set_sensitive(false);
 444
 445                 unit_id_label.set_text_or_na();
 446                 unit_aliases_label.set_text_or_na();
 447                 unit_description_label.set_text_or_na();
 448                 unit_description_label.set_text_or_na();
 449                 unit_load_state_label.set_text_or_na();
 450                 unit_active_state_label.set_text_or_na();
 451                 unit_sub_state_label.set_text_or_na();
 452                 unit_fragment_path_label.set_text_or_na();
 453                 unit_active_enter_timestamp_label.set_text_or_na();
 454                 unit_active_exit_timestamp_label.set_text_or_na();
 455                 unit_can_reload_label.set_text_or_na();
 456                 unit_can_start_label.set_text_or_na();
 457                 unit_cgroup_label.set_text_or_na();
 458         }
 459
 460         public string make_dependency_string(string? prefix, string word, string[] dependencies) {
 461                 bool first = true;
 462                 string r;
 463
 464                 if (prefix == null)
 465                         r = "";
 466                 else
 467                         r = prefix;
 468
 469                 foreach (string i in dependencies) {
 470                         if (r != "")
 471                                 r += first ? "\n" : ",";
 472
 473                         if (first) {
 474                                 r += word;
 475                                 first = false;
 476                         }
 477
 478                         r += " <a href=\"" + i + "\">" + i + "</a>";
 479                 }
 480
 481                 return r;
 482         }
 483
 484         public void show_unit(Unit unit) {
 485                 current_unit_id = unit.id;
 486
 487                 unit_id_label.set_text_or_na(current_unit_id);
 488
 489                 string a = "";
 490                 foreach (string i in unit.names) {
 491                         if (i == current_unit_id)
 492                                 continue;
 493
 494                         if (a == "")
 495                                 a = i;
 496                         else
 497                                 a += "\n" + i;
 498                 }
 499
 500                 unit_aliases_label.set_text_or_na(a);
 501
 502                 string[]
 503                         requires = unit.requires,
 504                         requires_overridable = unit.requires_overridable,
 505                         requisite = unit.requisite,
 506                         requisite_overridable = unit.requisite_overridable,
 507                         wants = unit.wants,
 508                         required_by = unit.required_by,
 509                         required_by_overridable = unit.required_by_overridable,
 510                         wanted_by = unit.wanted_by,
 511                         conflicts = unit.conflicts,
 512                         before = unit.before,
 513                         after = unit.after;
 514
 515                 unit_dependency_label.set_markup_or_na(
 516                                 make_dependency_string(
 517                                 make_dependency_string(
 518                                 make_dependency_string(
 519                                 make_dependency_string(
 520                                 make_dependency_string(
 521                                 make_dependency_string(
 522                                 make_dependency_string(
 523                                 make_dependency_string(
 524                                 make_dependency_string(
 525                                 make_dependency_string(
 526                                 make_dependency_string(null,
 527                                 "requires", requires),
 528                                 "overridable requires", requires_overridable),
 529                                 "requisite", requisite),
 530                                 "overridable requisite", requisite_overridable),
 531                                 "wants", wants),
 532                                 "conflicts", conflicts),
 533                                 "required by", required_by),
 534                                 "overridable required by", required_by_overridable),
 535                                 "wanted by", wanted_by),
 536                                 "after", after),
 537                                 "before", before));
 538
 539                 unit_description_label.set_text_or_na(unit.description);
 540                 unit_load_state_label.set_text_or_na(unit.load_state);
 541                 unit_active_state_label.set_text_or_na(unit.active_state);
 542                 unit_sub_state_label.set_text_or_na(unit.sub_state);
 543
 544                 string fp = unit.fragment_path;
 545                 if (fp != "")
 546                         unit_fragment_path_label.set_markup_or_na("<a href=\"file://" + fp +"\">" + fp + "</a>" );
 547                 else
 548                         unit_fragment_path_label.set_text_or_na();
 549
 550
 551                 unit_active_enter_timestamp_label.set_text_or_na(format_time(unit.active_enter_timestamp));
 552
 553                 unit_active_exit_timestamp_label.set_text_or_na(format_time(unit.active_exit_timestamp));
 554
 555                 bool b = unit.can_start;
 556                 start_button.set_sensitive(b);
 557                 stop_button.set_sensitive(b);
 558                 restart_button.set_sensitive(b);
 559                 unit_can_start_label.set_text_or_na(b ? "Yes" : "No");
 560
 561                 b = unit.can_reload;
 562                 reload_button.set_sensitive(b);
 563                 unit_can_reload_label.set_text_or_na(b ? "Yes" : "No");
 564
 565                 unit_cgroup_label.set_text_or_na(unit.default_control_group);
 566         }
 567
 568         public Job? get_current_job() {
 569                 TreePath p;
 570                 job_view.get_cursor(out p, null);
 571
 572                 if (p == null)
 573                         return null;
 574
 575                 TreeIter iter;
 576                 TreeModel model = job_view.get_model();
 577                 Job *j;
 578
 579                 model.get_iter(out iter, p);
 580                 model.get(iter, 4, out j);
 581
 582                 return j;
 583         }
 584
 585         public void job_changed() {
 586                 Job j = get_current_job();
 587
 588                 if (j == null)
 589                         clear_job();
 590                 else
 591                         show_job(j);
 592         }
 593
 594         public void clear_job() {
 595                 current_job_id = 0;
 596
 597                 job_id_label.set_text_or_na();
 598                 job_state_label.set_text_or_na();
 599                 job_type_label.set_text_or_na();
 600
 601                 cancel_button.set_sensitive(false);
 602         }
 603
 604         public void show_job(Job job) {
 605                 current_job_id = job.id;
 606
 607                 job_id_label.set_text_or_na("%u".printf(current_job_id));
 608                 job_state_label.set_text_or_na(job.state);
 609                 job_type_label.set_text_or_na(job.job_type);
 610
 611                 cancel_button.set_sensitive(true);
 612         }
 613
 614         public void on_start() {
 615                 Unit u = get_current_unit();
 616
 617                 if (u == null)
 618                         return;
 619
 620                 try {
 621                         u.start("replace");
 622                 } catch (IOError e) {
 623                         show_error(e.message);
 624                 }
 625         }
 626
 627         public void on_stop() {
 628                 Unit u = get_current_unit();
 629
 630                 if (u == null)
 631                         return;
 632
 633                 try {
 634                         u.stop("replace");
 635                 } catch (IOError e) {
 636                         show_error(e.message);
 637                 }
 638         }
 639
 640         public void on_reload() {
 641                 Unit u = get_current_unit();
 642
 643                 if (u == null)
 644                         return;
 645
 646                 try {
 647                         u.reload("replace");
 648                 } catch (IOError e) {
 649                         show_error(e.message);
 650                 }
 651         }
 652
 653         public void on_restart() {
 654                 Unit u = get_current_unit();
 655
 656                 if (u == null)
 657                         return;
 658
 659                 try {
 660                         u.restart("replace");
 661                 } catch (IOError e) {
 662                         show_error(e.message);
 663                 }
 664         }
 665
 666         public void on_cancel() {
 667                 Job j = get_current_job();
 668
 669                 if (j == null)
 670                         return;
 671
 672                 try {
 673                         j.cancel();
 674                 } catch (IOError e) {
 675                         show_error(e.message);
 676                 }
 677         }
 678
 679         public void update_unit_iter(TreeIter iter, string id, Unit u) {
 680
 681                 try  {
 682                         string t = "";
 683                         Unit.JobLink jl = u.job;
 684
 685                         if (jl.id != 0) {
 686                                 Job j = Bus.get_proxy_sync(
 687                                                 user ? BusType.SESSION : BusType.SYSTEM,
 688                                                 "org.freedesktop.systemd1",
 689                                                 jl.path);
 690
 691                                 t = j.job_type;
 692                         }
 693
 694                         unit_model.set(iter,
 695                                        0, id,
 696                                        1, u.description,
 697                                        2, u.load_state,
 698                                        3, u.active_state,
 699                                        4, u.sub_state,
 700                                        5, t != "" ? "→ %s".printf(t) : "",
 701                                        6, u);
 702                 } catch (IOError e) {
 703                         show_error(e.message);
 704                 }
 705         }
 706
 707         public void on_unit_new(string id, ObjectPath path) {
 708                 try {
 709
 710                         Properties p = Bus.get_proxy_sync(
 711                                         user ? BusType.SESSION : BusType.SYSTEM,
 712                                         "org.freedesktop.systemd1",
 713                                         path);
 714
 715                         p.properties_changed.connect(on_unit_changed);
 716
 717                         TreeIter iter;
 718                         unit_model.append(out iter);
 719
 720                         Unit u = Bus.get_proxy_sync(
 721                                         user ? BusType.SESSION : BusType.SYSTEM,
 722                                         "org.freedesktop.systemd1",
 723                                         path);
 724
 725                         unit_map[id] = u;
 726
 727                         update_unit_iter(iter, id, u);
 728                 } catch (IOError e) {
 729                         show_error(e.message);
 730                 }
 731         }
 732
 733         public void update_job_iter(TreeIter iter, uint32 id, Job j) {
 734                 job_model.set(iter,
 735                               0, "%u".printf(id),
 736                               1, j.unit.id,
 737                               2, "→ %s".printf(j.job_type),
 738                               3, j.state,
 739                               4, j,
 740                               5, id);
 741         }
 742
 743         public void on_job_new(uint32 id, ObjectPath path) {
 744
 745                 try  {
 746
 747                         Properties p = Bus.get_proxy_sync(
 748                                         user ? BusType.SESSION : BusType.SYSTEM,
 749                                         "org.freedesktop.systemd1",
 750                                         path);
 751
 752                         p.properties_changed.connect(on_job_changed);
 753
 754                         TreeIter iter;
 755                         job_model.append(out iter);
 756
 757                         Job j = Bus.get_proxy_sync(
 758                                         user ? BusType.SESSION : BusType.SYSTEM,
 759                                         "org.freedesktop.systemd1",
 760                                         path);
 761
 762                         update_job_iter(iter, id, j);
 763
 764                 } catch (IOError e) {
 765                         show_error(e.message);
 766                 }
 767         }
 768
 769         public void on_unit_removed(string id, ObjectPath path) {
 770                 TreeIter iter;
 771                 if (!(unit_model.get_iter_first(out iter)))
 772                         return;
 773
 774                 do {
 775                         string name;
 776
 777                         unit_model.get(iter, 0, out name);
 778
 779                         if (id == name) {
 780                                 if (current_unit_id == name)
 781                                         clear_unit();
 782
 783                                 unit_model.remove(iter);
 784                                 break;
 785                         }
 786
 787                 } while (unit_model.iter_next(ref iter));
 788
 789                 unit_map.unset(id);
 790         }
 791
 792         public void on_job_removed(uint32 id, ObjectPath path, string res) {
 793                 TreeIter iter;
 794                 if (!(job_model.get_iter_first(out iter)))
 795                         return;
 796
 797                 do {
 798                         uint32 j;
 799
 800                         job_model.get(iter, 5, out j);
 801
 802                         if (id == j) {
 803                                 if (current_job_id == j)
 804                                         clear_job();
 805
 806                                 job_model.remove(iter);
 807
 808                                 break;
 809                         }
 810
 811                 } while (job_model.iter_next(ref iter));
 812         }
 813
 814         public void on_unit_changed(Properties p, string iface, HashTable<string, Value?> changed_properties, string[] invalidated_properties) {
 815
 816                 try {
 817                         TreeIter iter;
 818                         string id;
 819
 820                         Unit u = Bus.get_proxy_sync(
 821                                         user ? BusType.SESSION : BusType.SYSTEM,
 822                                         p.get_name(),
 823                                         p.get_object_path());
 824
 825                         if (!(unit_model.get_iter_first(out iter)))
 826                                 return;
 827
 828                         id = u.id;
 829
 830                         do {
 831                                 string name;
 832
 833                                 unit_model.get(iter, 0, out name);
 834
 835                                 if (id == name) {
 836                                         update_unit_iter(iter, id, u);
 837
 838                                         if (current_unit_id == id)
 839                                                 show_unit(u);
 840
 841                                         break;
 842                                 }
 843
 844                         } while (unit_model.iter_next(ref iter));
 845
 846                 } catch (IOError e) {
 847                         show_error(e.message);
 848                 }
 849         }
 850
 851         public void on_job_changed(Properties p, string iface, HashTable<string, Value?> changed_properties, string[] invalidated_properties) {
 852                 try {
 853                         TreeIter iter;
 854                         uint32 id;
 855
 856                         Job j = Bus.get_proxy_sync(
 857                                         user ? BusType.SESSION : BusType.SYSTEM,
 858                                         p.get_name(),
 859                                         p.get_object_path());
 860
 861                         if (!(job_model.get_iter_first(out iter)))
 862                                 return;
 863
 864                         id = j.id;
 865
 866                         do {
 867                                 uint32 k;
 868
 869                                 job_model.get(iter, 5, out k);
 870
 871                                 if (id == k) {
 872                                         update_job_iter(iter, id, j);
 873
 874                                         if (current_job_id == id)
 875                                                 show_job(j);
 876
 877                                         break;
 878                                 }
 879
 880                         } while (job_model.iter_next(ref iter));
 881
 882                 } catch (IOError e) {
 883                         show_error(e.message);
 884                 }
 885         }
 886
 887         public bool unit_filter(TreeModel model, TreeIter iter) {
 888                 string id, active_state, job;
 889
 890                 model.get(iter, 0, out id, 3, out active_state, 5, out job);
 891
 892                 if (id == null)
 893                         return false;
 894
 895                 if (!inactive_checkbox.get_active()
 896                     && active_state == "inactive" && job == "")
 897                         return false;
 898
 899                 switch (unit_type_combo_box.get_active()) {
 900                 case 0:
 901                         return true;
 902                 case 1:
 903                         return id.has_suffix(".target");
 904                 case 2:
 905                         return id.has_suffix(".service");
 906                 case 3:
 907                         return id.has_suffix(".device");
 908                 case 4:
 909                         return id.has_suffix(".mount");
 910                 case 5:
 911                         return id.has_suffix(".automount");
 912                 case 6:
 913                         return id.has_suffix(".swap");
 914                 case 7:
 915                         return id.has_suffix(".socket");
 916                 case 8:
 917                         return id.has_suffix(".path");
 918                 case 9:
 919                         return id.has_suffix(".timer");
 920                 case 10:
 921                         return id.has_suffix(".snapshot");
 922                 default:
 923                         assert(false);
 924                         return false;
 925                 }
 926         }
 927
 928         public void unit_type_changed() {
 929                 TreeModelFilter model = (TreeModelFilter) ((TreeModelSort) unit_view.get_model()).get_model();
 930
 931                 model.refilter();
 932         }
 933
 934         public void on_server_reload() {
 935                 try {
 936                         manager.reload();
 937                 } catch (IOError e) {
 938                         show_error(e.message);
 939                 }
 940         }
 941
 942         public void on_server_snapshot() {
 943                 try {
 944                         manager.create_snapshot();
 945
 946                         if (unit_type_combo_box.get_active() != 0)
 947                                 unit_type_combo_box.set_active(8);
 948
 949                 } catch (IOError e) {
 950                         show_error(e.message);
 951                 }
 952         }
 953
 954         public void on_unit_load() {
 955                 string t = unit_load_entry.get_text();
 956
 957                 if (t == "")
 958                         return;
 959
 960                 try {
 961                         var path = manager.load_unit(t);
 962
 963                         Unit u = Bus.get_proxy_sync(
 964                                         user ? BusType.SESSION : BusType.SYSTEM,
 965                                         "org.freedesktop.systemd1",
 966                                         path);
 967
 968                         var m = new MessageDialog(this,
 969                                                   DialogFlags.DESTROY_WITH_PARENT,
 970                                                   MessageType.INFO,
 971                                                   ButtonsType.CLOSE,
 972                                                   "Unit available as id %s", u.id);
 973                         m.title = "Unit";
 974                         m.run();
 975                         m.destroy();
 976
 977                         show_unit(u);
 978                 } catch (IOError e) {
 979                         show_error(e.message);
 980                 }
 981         }
 982
 983         public void on_unit_load_entry_changed() {
 984                 unit_load_button.set_sensitive(unit_load_entry.get_text() != "");
 985         }
 986
 987         public bool on_activate_link(string uri) {
 988
 989                 try {
 990                         string path = manager.get_unit(uri);
 991
 992                         Unit u = Bus.get_proxy_sync(
 993                                         user ? BusType.SESSION : BusType.SYSTEM,
 994                                         "org.freedesktop.systemd1",
 995                                         path);
 996
 997                         show_unit(u);
 998                 } catch (IOError e) {
 999                         show_error(e.message);
1000                 }
1001
1002                 return true;
1003         }
1004
1005         public void show_error(string e) {
1006                 var m = new MessageDialog(this,
1007                                           DialogFlags.DESTROY_WITH_PARENT,
1008                                           MessageType.ERROR,
1009                                           ButtonsType.CLOSE, "%s", e);
1010                 m.title = "Error";
1011                 m.run();
1012                 m.destroy();
1013         }
1014
1015 }
1016
1017 static const OptionEntry entries[] = {
1018         { "user",    0,   0,                   OptionArg.NONE, out user, "Connect to user service manager", null },
1019         { "system",  0,   OptionFlags.REVERSE, OptionArg.NONE, out user, "Connect to system manager",       null },
1020         { null }
1021 };
1022
1023 void show_error(string e) {
1024         var m = new MessageDialog(null, 0, MessageType.ERROR, ButtonsType.CLOSE, "%s", e);
1025         m.run();
1026         m.destroy();
1027 }
1028
1029 int main(string[] args) {
1030
1031         try {
1032                 Gtk.init_with_args(ref args, "[OPTION...]", entries, "systemadm");
1033
1034                 MainWindow window = new MainWindow();
1035                 window.show_all();
1036
1037                 Gtk.main();
1038         } catch (IOError e) {
1039                 show_error(e.message);
1040         } catch (GLib.Error e) {
1041                 stderr.printf("%s\n", e.message);
1042         }
1043
1044         return 0;
1045 }