sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 8;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 frontcurve_strt_len = 60;
 104 frontcurve_dualcurve_angle = 90 - 65;
 105
 106 // calculated
 107
 108 TEST = false;
 109
 110 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 111
 112 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 113
 114 hole_slop = (ply_hole_dia - post_dia)/2;
 115 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 118          tile_hard_edge_hole_dist));
 119
 120 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 121          tile_hard_edge_hole_dist + round_edge_rad));
 122
 123 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 124 thehd_tr = thehd;
 125 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 126 thehd_bl = -thehd_tr;
 127 thehd_br = -thehd_tl;
 128
 129 tablet_z_slop = rearcurve_z_slop;
 130
 131 interlock_rad = interlock_dia/2;
 132 interlock_negative_rad = interlock_rad + 0.125;
 133
 134 interlock_sq_adj = 0.2; // arbitrary
 135
 136 first_front = machine_front_profile[len(machine_front_profile)-1];
 137
 138 m4_define(`POST_TCROSSSZ',
 139           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 140
 141 module Post(){
 142   mirror([0,0,1]) {
 143     difference(){
 144       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 145       translate([0,0, tile_th]) {
 146         cylinder(r= screw_big_dia/2, h= screw_big_len);
 147         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 148       }
 149     }
 150     if (TEST) {
 151       translate([0,0, tile_th/2]) {
 152         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 153         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 154       }
 155     }
 156   }
 157 }
 158
 159 module Posts(posts) {
 160   for (p= posts) {
 161     translate(concat(p, [0]))
 162       Post();
 163   }
 164 }
 165
 166 module TileBase(botleft, topright){
 167   size = topright - botleft;
 168   botleft_post = botleft + thehd_tr;
 169   topright_post = topright + thehd_bl;
 170   difference(){
 171     mirror([0,0,1])
 172       translate(concat(botleft, [0]))
 173       cube(concat(size, [tile_th]));
 174     if (!TEST) {
 175       cidsz = topright_post-botleft_post
 176         + [-post_dia,-post_dia]
 177         + [0, thehd[1]];
 178       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 179       echo("CID",cidsz,cidszr);
 180       translate( concat(botleft_post, [ -tile_th ])
 181                  + 0.5 * [ post_dia, post_dia, 0 ]
 182                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 183         Commitid_BestCount_M(cidszr);
 184     }
 185     if (TEST) {
 186       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 187       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 188       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 189       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 190         Commitid_BestCount(cidszr);
 191       difference(){
 192         mirror([0,0,1]) {
 193           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 194             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 195           translate(concat(botleft_post, [-1]))
 196             cube(concat(topright_post-botleft_post, [tile_th+2]));
 197         }
 198         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 199         minkowski(){
 200           MachineEnvelope();
 201           cube(shufflesz, center=true);
 202         }
 203       }
 204     }
 205   }
 206 }
 207
 208 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 209 m4_define(`INREFFRAME',`
 210   length_vec = ($2) - ($1);
 211   length = dist2d([0,0], length_vec);
 212   length_uvec = length_vec / length;
 213   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 214   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 215         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 216         [ 0,              0,              1,            0, ],
 217         [ 0,              0,              0,            1, ] ];
 218   $3
 219   multmatrix(m)
 220 ')
 221
 222 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 223 m4_dnl    INREFFRAME_EDGE { body; }
 224 m4_define(`INREFFRAME_EDGE',`
 225   translate([0,0, -round_edge_rad])
 226 ')
 227
 228 module RoundEdge(left_cnr, right_cnr) {
 229   INREFFRAME(left_cnr, right_cnr)
 230     INREFFRAME_EDGE {
 231     difference(){
 232       rotate([0,90,0])
 233         cylinder(r= round_edge_rad, h= length, $fn=50);
 234       translate([-1, 0, -20])
 235         cube([length+2, 20, 20]);
 236     }
 237   }
 238 }
 239
 240 module RoundCorner_selector(ci, adj) {
 241   r = round_cnr_rad - round_edge_rad;
 242   cube(r*2 + adj, center=true);
 243 }
 244
 245 module RoundCornerCut(ci) {
 246   // ci should be [this_cnr, right_cnr, left_cnr]
 247   // where right_cnr is to the right (ie, anticlockwise)
 248   this_cnr = ci[0];
 249   right_cnr = ci[1];
 250   left_cnr = ci[2];
 251   bigr= round_cnr_rad - round_edge_rad;
 252   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 253     difference(){
 254       RoundCorner_selector(ci, -0.1);
 255       translate([bigr, bigr, 0])
 256         cylinder(center=true, h=20, r= bigr);
 257     }
 258   }
 259 }
 260
 261 module RoundCornerAdd(ci) {
 262   this_cnr = ci[0];
 263   right_cnr = ci[1];
 264   left_cnr = ci[2];
 265   bigr = round_cnr_rad - round_edge_rad;
 266   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 267     intersection(){
 268       RoundCorner_selector(ci, +0.1);
 269       translate([bigr, bigr, 0])
 270         rotate_extrude(convexity=10, $fn=50)
 271         translate([bigr, 0])
 272         difference(){
 273           circle(r= round_edge_rad, $fn=50);
 274           mirror([1,1])
 275             square([20,20]);
 276         }
 277     }
 278   }
 279 }
 280
 281 module InterlockLobePlan(negative) {
 282   r = negative ? interlock_negative_rad : interlock_rad;
 283   ymir = negative ? 0 : 1;
 284
 285   dx = sqrt(3) * r;
 286   $fn= 80;
 287   translate([thehd[0], 0]){
 288     mirror([0,ymir]){
 289       circle(r=r);
 290       difference(){
 291         translate([-dx, -0.1])
 292           square([ dx*2, r/2 + 0.1 ]);
 293         for (xi = [-1, 1]) {
 294           translate([ xi*dx, r ])
 295             circle(r=r);
 296         }
 297       }
 298     }
 299   }
 300 }
 301
 302 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 303   for (lobei = [ 0 : nlobes-1 ]) {
 304     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 305     translate([lobex, 0, 0]) {
 306       InterlockLobePlan(negative);
 307     }
 308   }
 309
 310   if (dosquare) {
 311     iadj = 0;
 312     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 313     mirror([0, negative])
 314       translate([slotshorter, iadj])
 315       square([length - slotshorter*2, interlock_fine + iadj*2]);
 316   }
 317 }
 318
 319 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 320   plusth = negative * 1.0;
 321   protr = interlock_fine + interlock_sq_adj;
 322
 323   z2 = -tile_th/2;
 324   z1 = -tile_th/2 - protr / interlock_fine_slope;
 325   z3 = -tile_th/2 + protr / interlock_fine_slope;
 326
 327   negsign = negative ? -1 : +1;
 328   yprotr = negsign * protr;
 329
 330   INREFFRAME(left_cnr, right_cnr) {
 331     for (vsect = [ // zs0            zs1      ys0,            ys1
 332                   [ -tile_th-plusth, plusth,  0,              0],
 333                   [ z1,              z2,      0, yprotr],
 334                   [ z2,              z3,      yprotr, 0],
 335                   ]) {
 336       zs0 = vsect[0];
 337       zs1 = vsect[1];
 338       zsd = zs1-zs0;
 339       ys0 = vsect[2];
 340       ys1 = vsect[3];
 341       ysd = ys1-ys0;
 342       sl = ysd/zsd;
 343       m = [ [ 1,0,   0,    0 ],
 344             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 345             [ 0,0,   1,  zs0 ],
 346             [ 0,0,   0,    1 ] ];
 347       multmatrix(m)
 348         linear_extrude(height=zsd, convexity=10)
 349         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 350     }
 351   }
 352 }
 353
 354 function TestPiece_holes2corners(holes) =
 355   [ holes[0] + thehd_bl,
 356     holes[1] + thehd_br,
 357     holes[1] + thehd_tr,
 358     holes[0] + thehd_tl ];
 359
 360 module TestPiece1(){ ////toplevel
 361   holes = [ [-100, 0],
 362             [   0, 0]
 363             ];
 364   corners = TestPiece_holes2corners(holes);
 365   rcs = [corners[0], corners[1]];
 366   difference(){
 367     union(){
 368       TileBase(corners[0], corners[2]);
 369       Posts(holes);
 370       RoundEdge(corners[0], corners[1]);
 371       RoundEdge(corners[3], corners[0]);
 372     }
 373     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 374     RoundCornerCut(rcs);
 375   }
 376   RoundCornerAdd(rcs);
 377 }
 378
 379 module TestPiece2(){ ////toplevel
 380   holes = [ [   0, 0],
 381             [  50, 0]
 382             ];
 383   corners = TestPiece_holes2corners(holes);
 384   TileBase(corners[0], corners[2]);
 385   Posts(holes);
 386   RoundEdge(corners[0], corners[1]);
 387   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 388 }
 389
 390 module TestDemo(){ ////toplevel
 391   translate([ -thehd[0], 0 ])
 392     color("blue")
 393     TestPiece1();
 394   translate([ +thehd[0] + demo_slop, 0 ])
 395     TestPiece2();
 396 }
 397
 398 module Machine_Arm(){
 399   ysz = cutout_l_end_y_total;
 400   // assume the round end is arc of a circle
 401   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 402   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 403
 404   translate([0,0,-30]) linear_extrude(height=60) {
 405     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 406       intersection(){
 407         translate([-50, -ysz/2])
 408           square([400, ysz]);
 409         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 410           circle(r=endrad, $fa=0.01,$fd=5);
 411       }
 412     }
 413   }
 414 }
 415
 416 module Machine_Profile(){
 417   first_rear = machine_rear_profile[0];
 418   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 419   pol = concat( machine_rear_profile,
 420                 [ below_point ],
 421                 machine_front_profile);
 422   skew_angle = atan2( first_front[1] - first_rear[1],
 423                       first_front[0] - first_rear[0] );
 424   //echo(below_point, pol, skew_angle);
 425   hull(){
 426     for (z=[0,-40]) {
 427       translate([0,z]) {
 428         //scale([1,5])
 429         rotate([0,0, -skew_angle ]){
 430           //translate( - first_front )
 431           polygon(pol);
 432         }
 433       }
 434     }
 435   }
 436 }
 437
 438 module Machine_NewRearProfile(){
 439   // figures copied out of xfig edit boxes
 440   // best not to edit the posbox size if poss - just move it
 441   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 442   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 443   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 444   scaleline_mm = 12+5+10+5+3;
 445   sh = -[abs(posbox[0]), abs(posbox[1])];
 446   rot = atan2(-sideline[0], sideline[1]);
 447   sc = scaleline_mm / scaleline;
 448   //echo("SH",sh,rot,sc);
 449   scale(sc) rotate(rot) translate(sh){
 450     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 451   }
 452 }
 453
 454 module Machine_NewRearCurve(){
 455   slant = atan2(4,210-10);
 456   //echo("SL",slant);
 457   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 458     translate([ rearcurve_double_inrad,
 459                 0,
 460                 -rearcurve_double_inrad + 10 ]){
 461       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 462         hull(){
 463           Machine_NewRearProfile();
 464           translate([0,-100]) Machine_NewRearProfile();
 465         }
 466       }
 467     }
 468     rotate([0,90,0]) rotate([90,0,0]) {
 469       intersection(){
 470         rotate_extrude(convexity=10, $fn=64)
 471           rotate(90)
 472           translate([ 0, -rearcurve_double_inrad ])
 473           Machine_NewRearProfile();
 474         translate([0,0,-500])
 475           cube([500,500,1000]);
 476       }
 477     }
 478     translate([1,0,-rearcurve_double_inrad])
 479       rotate([0,-90,0]) rotate([0,0,-90])
 480       linear_extrude(height= rearcurve_strt_len + 1)
 481       Machine_NewRearProfile();
 482   }
 483 }
 484
 485 module Machine_RearProfile(){ ////toplevel
 486   intersection(){
 487     Machine_Profile();
 488     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 489       square([200,200]);
 490     }
 491   }
 492 }
 493
 494 module Machine_FrontProfile(){
 495   intersection(){
 496     Machine_Profile();
 497     translate([ machine_rear_to_front/2, -100 ]) {
 498       square([200,200]);
 499     }
 500   }
 501 }
 502
 503 module Machine_Curves(){ ////toplevel
 504   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 505               cutout_tile11_y,
 506               0 ]){
 507     //%cube([20,20,20]);
 508     translate([ -reartablet_x,
 509                 -1,
 510                 -reartablet_z + tablet_z_slop])
 511       mirror([0,0,1])
 512       cube([ reartablet_x+1,
 513              reartablet_y+1,
 514              20 ]);
 515   }
 516   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 517               cutout_tile11_y,
 518               frontcurve_z_slop ]){
 519     translate([ 0, -first_front[0] , 0 ])
 520       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 521                   [0,  1,   0, 0],
 522                   [0,  0,   1, 0],
 523                   [0,  0,   0, 1]])
 524       translate([ 0, first_front[0] , 0 ])
 525       mirror([1,0,0]){
 526       rotate([0,-90,0])rotate([0,0,-90]){
 527         linear_extrude(height= 200)
 528           Machine_FrontProfile();
 529       }
 530     }
 531     translate([ rearcurve_strt_len,
 532                 0,
 533                 rearcurve_z_slop ]){
 534       Machine_NewRearCurve();
 535     }
 536   }
 537 }
 538
 539 module Machine(){ ////toplevel
 540   Machine_Arm();
 541   Machine_Curves();
 542 }
 543
 544 module MachineEnvelope(){
 545   // used for testing
 546   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
 547   y_arm_t  = cutout_tile11_y;
 548   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
 549   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 550
 551   translate([0,0,-50]) linear_extrude(height= 100){
 552     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 553     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 554   }
 555 }
 556
 557 function Rectangle_corners(c0, sz) =
 558   // returns the corners of a rectangle from c0 to c0+sz
 559   // if sz is positive, the corners are anticlockwise starting with c0
 560   [ c0 + [ 0,     0     ],
 561     c0 + [ sz[0], 0     ],
 562     c0 + [ sz[0], sz[1] ],
 563     c0 + [ 0,     sz[1] ] ];
 564
 565 function Rectangle_corners2posts(c) =
 566   [ c[0] + thehd_tr,
 567     c[1] + thehd_tl,
 568     c[2] + thehd_bl,
 569     c[3] + thehd_br ];
 570
 571 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 572
 573 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 574
 575 m4_dnl   R_EDGE(c,ix)
 576 m4_dnl        c is from Rectangle_corners and
 577 m4_dnl        ix is a corner number
 578 m4_dnl    expands to two comma-separated corners:
 579 m4_dnl    that denoted by ix, and the next one anticlockwise
 580 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 581
 582 module FitTest_general(c0,sz, dobrace=false){
 583   c = Rectangle_corners(c0, sz);
 584   brace = [7,7,9];
 585   difference(){
 586     union(){
 587       Rectangle_TileBase(c);
 588       if (dobrace) {
 589         translate(concat(c0, [-brace[2] + 0.1])){
 590           difference(){
 591             cube(concat(sz,[brace[2]]) - [5,0,0]);
 592             translate(brace + [0,0, -25])
 593               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 594           }
 595         }
 596       }
 597       RoundEdge(R_EDGE(c,1));
 598     }
 599     Machine();
 600   }
 601 }
 602
 603 module FitTest_Entire(){ ////toplevel
 604   FitTest_general([-40,-80], [275,180], dobrace=true);
 605 }
 606
 607 module FitTest_RearCurve(){ ////toplevel
 608   FitTest_general([110,0], [170,100]);
 609 }
 610
 611 module Tile02(){ ////toplevel
 612   sz = [100,170];
 613   c0 = tile02_tr + -sz;
 614   c = Rectangle_corners(c0, sz);
 615   posts = Rectangle_corners2posts(c);
 616   rcs = [R_EDGE(c,0)];
 617   difference(){
 618     union(){
 619       Rectangle_TileBase(c);
 620       Posts(posts);
 621       RoundEdge(R_EDGE(c,0));
 622       RoundEdge(R_EDGE(c,3));
 623       InterlockEdge(R_EDGE(c,2), 0);
 624     }
 625     InterlockEdge(R_EDGE(c,1), 1);
 626     RoundCornerCut(rcs);
 627   }
 628   RoundCornerAdd(rcs);
 629 }
 630
 631 module Tile12(){ ////toplevel
 632   sz = [100,250];
 633   c0 = tile02_tr + [-sz[0], 0];
 634   c = Rectangle_corners(c0, sz);
 635   posts = Rectangle_corners2posts(c);
 636   rcs = [R_EDGE(c,3)];
 637   difference(){
 638     union(){
 639       Rectangle_TileBase(c);
 640       Posts(posts);
 641       RoundEdge(R_EDGE(c,2));
 642       RoundEdge(R_EDGE(c,3));
 643     }
 644     InterlockEdge(R_EDGE(c,0), 1);
 645     InterlockEdge(R_EDGE(c,1), 1);
 646     RoundCornerCut(rcs);
 647   }
 648   RoundCornerAdd(rcs);
 649 }
 650
 651 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 652 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 653 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 654
 655 module Tile11(){ ////toplevel
 656   sz = [250,250];
 657   c0 = tile01_tr + [-sz[0],0];
 658   c = Rectangle_corners(c0, sz);
 659   cnr_posts = Rectangle_corners2posts(c);
 660   posts = concat(
 661                  Posts_interpolate_one(cnr_posts[0],
 662                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 663                  [ cnr_posts[1] + [0, cutout_tile11_y],
 664                    cnr_posts[2],
 665                    cnr_posts[3]
 666                    ]);
 667   difference(){
 668     union(){
 669       Rectangle_TileBase(c);
 670       Posts(posts);
 671       RoundEdge(R_EDGE(c,2));
 672       InterlockEdge(R_EDGE(c,3));
 673     }
 674     InterlockEdge(c[0], tile_01_11_cnr, 1);
 675     InterlockEdge(tile_11_10_cnr, c[2], 1);
 676     Machine();
 677   }
 678 }
 679
 680 module Tile01(){ ////toplevel
 681   sz = [250,170];
 682   c0 = tile01_tr + -sz;
 683   c = Rectangle_corners(c0, sz);
 684   cnr_posts = Rectangle_corners2posts(c);
 685   posts = concat(
 686                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 687                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 688                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 689                                        cnr_posts[3])
 690                  );
 691   difference(){
 692     union(){
 693       Rectangle_TileBase(c);
 694       Posts(posts);
 695       RoundEdge(R_EDGE(c,0));
 696       InterlockEdge(tile_01_11_cnr, c[3]);
 697       InterlockEdge(R_EDGE(c,3));
 698     }
 699     InterlockEdge(c[1], tile_01_00_cnr, 1);
 700     Machine();
 701   }
 702 }
 703
 704 module Tile10(){ ////toplevel
 705   sz = [250,250];
 706   c0 = tile01_tr + [0,0];
 707   c = Rectangle_corners(c0, sz);
 708   cnr_posts = Rectangle_corners2posts(c);
 709   cty = cutout_tile11_y;
 710   rcy = cty + rearcurve_avoid_y;
 711   posts = [ cnr_posts[0] + [ 0,                             cty ],
 712             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 713             cnr_posts[1] + [ 0,                             rcy ],
 714             cnr_posts[2],
 715             cnr_posts[3] ];
 716   rcs = [R_EDGE(c,2)];
 717   difference(){
 718     union(){
 719       Rectangle_TileBase(c);
 720       Posts(posts);
 721       RoundEdge(R_EDGE(c,1));
 722       RoundEdge(R_EDGE(c,2));
 723       InterlockEdge(c[3], tile_11_10_cnr);
 724     }
 725     RoundCornerCut(rcs);
 726     Machine();
 727   }
 728   RoundCornerAdd(rcs);
 729 }
 730
 731 module Tile00(){ ////toplevel
 732   sz = [250,170];
 733   c0 = tile01_tr + [0,-sz[1]];
 734   c = Rectangle_corners(c0, sz);
 735
 736   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 737   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
 738   c1bis = [ c[1][0],
 739             c[2][1] -
 740             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 741
 742   cnr_posts = Rectangle_corners2posts(c);
 743   cty = cutout_tile01_y;
 744   rcy = cty + frontcurve_avoid_y;
 745   posts = [ cnr_posts[0],
 746             cnr_posts[1],
 747             cnr_posts[2] + [ 0,                             -rcy ],
 748             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 749             cnr_posts[3] + [ 0,                             -cty ]
 750             ];
 751   rcs = [R_EDGE(c,1)];
 752   difference(){
 753     union(){
 754       difference(){
 755         union(){
 756           Rectangle_TileBase(c);
 757           Posts(posts);
 758           RoundEdge(R_EDGE(c,0));
 759           RoundEdge(c[1], c1bis);
 760           InterlockEdge(tile_01_00_cnr, c[0]);
 761         }
 762         RoundCornerCut(rcs);
 763         translate([0,0,-20]) linear_extrude(height=40) {
 764           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 765         }
 766       }
 767       RoundEdge(c1bis, c2bis);
 768     }
 769     Machine();
 770   }
 771   RoundCornerAdd(rcs);
 772   RoundCornerAdd([c1bis,c2bis,c[1]]);
 773 }
 774
 775 module FitTest_FrontCurve(){ ////toplevel
 776   p0 = [110,-80];
 777   sz = [170,80];
 778   intersection() {
 779     Tile00();
 780     translate([0,0,-8]) linear_extrude(height=18) {
 781       translate(p0) square(sz);
 782     }
 783   }
 784 }
 785
 786 module RoundCornerDemo_plat(cnr){
 787   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
 788 }
 789
 790 module RoundCornerDemo(){ ////toplevel
 791   cnr = [ [0,0], [15,0], [-10,10] ];
 792   translate([0,25,0]) RoundCornerDemo_plat(cnr);
 793   translate([25,0,0]) RoundCornerAdd(cnr);
 794   translate([-25,0,0]) RoundCornerCut(cnr);
 795   difference(){
 796     RoundCornerDemo_plat(cnr);
 797     RoundCornerCut(cnr);
 798   }
 799   RoundCornerAdd(cnr);
 800 }
 801
 802 module Demo(){ ////toplevel
 803   translate(demo_slop*[-2,1]) color("blue") Tile12();
 804   translate(demo_slop*[-2,0]) color("red")  Tile02();
 805   translate(demo_slop*[-2,1]) color("orange") Tile11();
 806   translate(demo_slop*[-2,0]) color("purple") Tile01();
 807   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 808   translate(demo_slop*[-3,0]) color("red")    Tile00();
 809   %Machine();
 810 }
 811
 812 //TestPiece1();
 813 //TestPiece2();
 814 //Demo();
 815
 816 //Machine_Profile();
 817 //Machine_NewRearProfile();
 818 //Machine_NewRearCurve();
 819 //Machine_Curves();
 820 //Machine();
 821 //FitTest();
 822 //MachineEnvelope();