ports/sysdeps/vax/strstr.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 4. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(LIBC_SCCS) && !defined(lint)
  31         .asciz "@(#)strstr.s    5.2 (Berkeley) 8/21/90"
  32 #endif /* LIBC_SCCS and not lint */
  33
  34 /*
  35  * Find the first occurrence of s2 as a substring in s1.
  36  * If s2 is empty, return s1.
  37  *
  38  * char *strstr(s1, s2)
  39  *      const char *s1, *s2;
  40  */
  41 #include "DEFS.h"
  42
  43 ENTRY(strstr, 0)
  44         movq    4(ap),r3        /* r3 = s1, r4 = s2 */
  45         movzwl  $65535,r2       /* r2 = locc/matchc limit */
  46         locc    $0,r2,(r4)      /* find '\0' in s2 */
  47         beql    4f
  48         subl3   r4,r1,r5        /* r5 = strlen(s2) */
  49         beql    1f              /* if r5 == 0, return s1 */
  50
  51         /*
  52          * s2 is short enough to apply matchc.
  53          * If s1 is long, we have to do it in stages.
  54          */
  55 0:      locc    $0,r2,(r3)      /* find '\0' in s1 */
  56         beql    3f
  57
  58         /*
  59          * Both strings are `short'; we can use matchc directly.
  60          */
  61         subl3   r3,r1,r1        /* r1 = strlen(s1) */
  62         matchc  r5,(r4),r1,(r3) /* find substring */
  63         bneq    2f
  64
  65         /*
  66          * r3 points r5 bytes past match.  Return the match.
  67          */
  68 1:      subl3   r5,r3,r0        /* return (byte_past_match - strlen(s2)) */
  69         ret
  70
  71         /*
  72          * There is no matching substring.
  73          */
  74 2:      clrl    r0              /* return NULL */
  75         ret
  76
  77         /*
  78          * s1 is too long (> 65535 bytes) to apply matchc directly,
  79          * but s2 is short enough.  Apply s2 to s1, then (if not
  80          * found yet) advancing s1 by (65536-strlen(s2)) bytes and
  81          * loop.
  82          */
  83 3:      matchc  r5,(r4),r2,(r3) /* search */
  84         beql    1b              /* if found, go return it */
  85         decw    r2              /* from 0 to 65535 */
  86         incl    r3              /* already advanced 65535, now 65536 */
  87         subl2   r5,r3           /* ... minus strlen(s2) */
  88         brb     0b
  89
  90         /*
  91          * s2 is too long (> 65535 bytes) to bother with matchc.
  92          */
  93 4:      locc    $0,r2,(r1)      /* continue working on strlen(s2) */
  94         beql    4b
  95         subl3   r1,r4,r5        /* r5 = strlen(s2) */
  96         movb    (r4)+,r2        /* r2 = *s2++ */
  97         decl    r5              /* fix up length */
  98 5:      movb    (r3)+,r0        /* r0 = *s1++ */
  99         beql    2b              /* if '\0', return NULL */
 100         cmpb    r0,r2
 101         bneq    5b              /* loop until first char found */
 102         pushr   R5|R4|R3|R2     /* save c, s1, s2, n */
 103         pushr   R5|R4|R3        /* strncmp(s1, s2, n) */
 104         calls   $3,_strncmp
 105         popr    R2|R3|R4|R5     /* restore */
 106         tstl    r0
 107         bneq    5b              /* loop until strncmp says rest same too */
 108         subl3   $1,r3,r0        /* return previous s1 */
 109         ret