nailing-cargo

   1 #!/usr/bin/perl -w
   2
   3 #    nailing-cargo: wrapper to use unpublished local crates
   4 #
   5 #    Copyright (C) 2019-2020 Ian Jackson
   6 #
   7 #    This program is free software: you can redistribute it and/or modify
   8 #    it under the terms of the GNU Affero General Public License as
   9 #    published by the Free Software Foundation, either version 3 of the
  10 #    License, or (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU Affero General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU Affero General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # example usages:
  21 #   ../nailing-cargo/nailing-caretwgo make
  22 #   ../nailing-cargo/nailing-cargo cargo build
  23 #   CARGO='../nailing-cargo/nailing-cargo cargo' make
  24
  25 # Why do we need this ?
  26 #
  27 #  https://github.com/rust-lang/cargo/issues/6713
  28 #  https://stackoverflow.com/questions/33025887/how-to-use-a-local-unpublished-crate
  29 #  https://github.com/rust-lang/cargo/issues/1481
  30
  31 # Needs libtoml-perl
  32
  33 #: Cargo.nail:
  34 #
  35 #    [packages]
  36 #    package = subdir
  37 #    package = { subdir = ... }
  38 #
  39 #    [subdirs]
  40 #    subdir
  41
  42 our $self;
  43
  44 use strict;
  45 use POSIX;
  46 use Types::Serialiser;
  47
  48 our %archmap = (
  49     RPI => 'arm-unknown-linux-gnueabihf',
  50 );
  51
  52 BEGIN {
  53   $self = $0;  $self =~ s{^.*/(?=.)}{};
  54   my $deref = $0;
  55   while ($deref =~ m{^/}) {
  56     my $link = readlink $deref;
  57     if (!defined $link) {
  58       $! == EINVAL
  59         or die "$self: checking our script location $deref: $!\n";
  60       $deref =~ s{/[^/]+$}{}
  61         or die "$self: unexpected script path: $deref\n";
  62       unshift @INC, $deref."/TOML-Tiny/lib";
  63       last;
  64     }
  65     last if $link !~ m{^/};
  66     $deref = $link;
  67   }
  68 }
  69
  70 use Fcntl qw(LOCK_EX);
  71 use File::Compare;
  72 use TOML::Tiny::Faithful;
  73
  74 our $src_absdir = getcwd() // die "$self: getcwd failed: $!\n";
  75
  76 our $worksphere = $src_absdir;
  77 $worksphere =~ s{/([^/]+)$}{}
  78   or die "$self: cwd \`$worksphere' unsupported!\n";
  79 our $subdir = $1; # leafname
  80
  81 our $lockfile = "../.nailing-cargo.lock";
  82
  83 our $cargo_lock_update;
  84 our $cargo_manifest_args;
  85 our $alt_cargo_lock;
  86
  87 our @configs;
  88 our $verbose=1;
  89 our ($noact,$dump);
  90 our $target;
  91
  92 sub read_or_enoent ($) {
  93   my ($fn) = @_;
  94   if (!open R, '<', $fn) {
  95     return undef if $!==ENOENT;
  96     die "$self: open $fn: $!\n";
  97   }
  98   local ($/) = undef;
  99   my ($r) = <R> // die "$self: read $fn: $!\n";
 100   $r;
 101 }
 102
 103 sub stat_exists ($$) {
 104   my ($fn, $what) = @_;
 105   if (stat $fn) { return 1; }
 106   $!==ENOENT or die "$self: stat $what: $fn: $!\n";
 107   return 0;
 108 }
 109
 110 sub toml_or_enoent ($$) {
 111   my ($f,$what) = @_;
 112   my $toml = read_or_enoent($f) // return;
 113   my ($v,$e) = from_toml($toml);
 114   if (!defined $v) {
 115     chomp $e;
 116     die "$self: parse TOML: $what: $f: $e\n";
 117   }
 118   die "$e ?" if length $e;
 119   $v;
 120 }
 121
 122 sub load1config ($) {
 123   my ($f) = @_;
 124   my $toml = toml_or_enoent($f, "config file");
 125   push @configs, $toml if defined $toml;
 126 }
 127
 128 sub loadconfigs () {
 129   my $cfgleaf = ".nailing-cargo-cfg.toml";
 130   load1config("/etc/nailing-cargo/cfg.toml");
 131   load1config("$worksphere/$cfgleaf");
 132   load1config("$ENV{HOME}/$cfgleaf") if defined $ENV{HOME};
 133 }
 134
 135 sub getcfg ($$) {
 136   my ($k, $def) = @_;
 137   foreach my $cfg (@configs) {
 138     my $v = $cfg->{$k};
 139     return $v if defined $v;
 140   }
 141   return $def;
 142 }
 143
 144 sub unlink_or_enoent ($) { unlink $_[0] or $!==ENOENT; }
 145
 146 sub same_file ($$) {
 147   my ($x,$y) = @_;
 148   "@$x[0..5]" eq "@$y[0..5]";
 149 }
 150
 151 sub takelock () {
 152   for (;;) {
 153     open LOCK, ">", $lockfile or die "$self: open/create $lockfile: $!\n";
 154     flock LOCK, LOCK_EX or die "$self: lock $lockfile: $!\n";
 155     my @fstat = stat LOCK or die "$self: fstat: $!\n";
 156     my @stat  = stat $lockfile;
 157     if (!@stat) {
 158       next if $! == ENOENT;
 159       die "$self: stat $lockfile: $!\n";
 160     }
 161     last if same_file(\@fstat,\@stat);
 162   }
 163 }
 164 sub unlock () {
 165   unlink $lockfile or die "$self: removing lockfile: $!\n";
 166 }
 167
 168 our $nail;
 169
 170 sub badcfg {
 171   my $m = pop @_;
 172   $" = '.';
 173   die "$self: config key \`@_': $m\n";
 174 }
 175
 176 sub cfg_uc {
 177   my $v = $nail;
 178   foreach my $k (@_) {
 179     last unless defined $v;
 180     ref($v) eq 'HASH' or badcfg @_, "parent key \`$k' is not a hash";
 181     $v = $v->{$k};
 182   }
 183   return $v;
 184 }
 185
 186 sub cfge {
 187   my $exp = shift @_;
 188   my $v = cfg_uc @_;
 189   my $got = ref($v) || 'scalar';
 190   return $v if !defined($v) || $got eq $exp;
 191   badcfg @_, "found \L$got\E, expected \L$exp\E";
 192   # ^ toml doesn't make refs to scalars, so this is unambiguous
 193 }
 194
 195 sub cfgn {
 196   my $exp = shift @_;
 197   (cfge $exp, @_) // badcfg @_, "missing";
 198 }
 199
 200 sub cfgs  { cfge 'scalar', @_ }
 201 sub cfgsn { cfgn 'scalar', @_ }
 202
 203 sub cfg_bool {
 204   my $v = cfg_uc @_;
 205   return $v if !defined($v) || Types::Serialiser::is_bool $v;
 206   badcfg @_, "expected boolean";
 207 }
 208
 209 sub cfgn_list {
 210   my $l = cfge 'ARRAY', @_;
 211   foreach my $x (@$l) {
 212     !ref $x or badcfg @_, "list contains non-scalar element";
 213   }
 214   @$l
 215 }
 216
 217 sub readnail () {
 218   my $nailfile = "../Cargo.nail";
 219   open N, '<', $nailfile or die "$self: open $nailfile: $!\n";
 220   local ($/) = undef;
 221   my $toml = <N> // die "$self: read $nailfile: $!";
 222   my $transformed;
 223   if ($toml !~ m{^\s*\[/}m &&
 224       $toml !~ m{^[^\n\#]*\=}m &&
 225       # old non-toml syntax
 226       $toml =~ s{^[ \t]*([-_0-9a-z]+)[ \t]+(\S+)[ \t]*$}{$1 = \"$2\"}mig) {
 227     $toml =~ s{^}{[packages\]\n};
 228     my @sd;
 229     $toml =~ s{^[ \t]*\-[ \t]*\=[ \t]*(\"[-_0-9a-z]+\"\n?)$}{
 230       push @sd, $1; '';
 231     }mige;
 232     $toml = "subdirs = [\n".(join '', map { "$_\n" } @sd)."]\n".$toml;
 233     $transformed = 1;
 234   }
 235   my $e;
 236   ($nail,$e) = from_toml($toml);
 237   if (!defined $nail) {
 238     if ($transformed) {
 239       $toml =~ s/^/    /mg;
 240       print STDERR "$self: $nailfile transformed into TOML:\n$toml\n";
 241     }
 242     $/="\n"; chomp $e;
 243     die "$self: parse $nailfile: $e\n";
 244   }
 245   die "$e ?" if length $e;
 246
 247   if (!ref $nail->{subdirs}) {
 248     $nail->{subdirs} = [
 249       grep /^[^\#]/,
 250       map { s/^\s+//; s/\s+$//; $_; }
 251       split m{\n},
 252       $nail->{subdirs}
 253     ];
 254   }
 255 }
 256
 257 our @alt_cargo_lock_stat;
 258
 259 sub consider_alt_cargo_lock () {
 260   my @ck = qw(alt_cargo_lock);
 261   # User should *either* have Cargo.lock in .gitignore,
 262   # or expect to commit Cargo.lock.example ($alt_cargo_lock)
 263
 264   $alt_cargo_lock = (cfg_uc @ck);
 265
 266   my $force = 0;
 267   if (defined($alt_cargo_lock) && ref($alt_cargo_lock) eq 'HASH') {
 268     $force = cfg_bool qw(alt_cargo_lock force);
 269     my @ck = qw(alt_cargo_lock file);
 270     $alt_cargo_lock = cfg_uc @ck;
 271   }
 272   $alt_cargo_lock //= Types::Serialiser::true;
 273
 274   if (Types::Serialiser::is_bool $alt_cargo_lock) {
 275     if (!$alt_cargo_lock) { $alt_cargo_lock = undef; return; }
 276     $alt_cargo_lock = 'Cargo.lock.example';
 277   }
 278
 279   if (ref($alt_cargo_lock) || $alt_cargo_lock =~ m{/}) {
 280     badcfg @ck, "expected boolean, or leafname";
 281   }
 282
 283   if (!stat_exists $alt_cargo_lock, "alt_cargo_lock") {
 284     $alt_cargo_lock = undef unless $force;
 285     return;
 286   }
 287
 288   @alt_cargo_lock_stat = stat _;
 289 }
 290
 291 our $oot_dir;      # oot.dir or "Build"
 292
 293 sub consider_oot () {
 294   $oot_dir = cfgs qw(oot dir);
 295   my $use = cfgs qw(oot use);
 296   unless (defined($oot_dir) || defined($use)) {
 297     die "$self: specified --cargo-lock-update but not out-of-tree build!\n"
 298       if $cargo_lock_update;
 299     $cargo_lock_update=0;
 300     return;
 301   }
 302   $oot_dir //= 'Build';
 303 }
 304
 305 our %manifests;
 306 our %packagemap;
 307
 308 sub read_manifest ($) {
 309   my ($subdir) = @_;
 310   my $manifest = "../$subdir/Cargo.toml";
 311   print STDERR "$self: reading $manifest...\n" if $verbose>=4;
 312   if (defined $manifests{$manifest}) {
 313     print STDERR
 314  "$self: warning: $subdir: specified more than once!\n";
 315     return undef;
 316   }
 317   foreach my $try ("$manifest.unnailed", "$manifest") {
 318     my $toml = toml_or_enoent($try, "package manifest") // next;
 319     my $p = $toml->{package}{name};
 320     if (!defined $p) {
 321       print STDERR
 322  "$self: warning: $subdir: missing package.name in $try, ignoring\n";
 323       next;
 324     }
 325     $manifests{$manifest} = $toml;
 326     return $p;
 327   }
 328   return undef;
 329 }
 330
 331 sub readorigs () {
 332   foreach my $p (keys %{ $nail->{packages} }) {
 333     my $v = $nail->{packages}{$p};
 334     my $subdir = ref($v) ? $v->{subdir} : $v;
 335     my $gotpackage = read_manifest($subdir) // '<nothing!>';
 336     if ($gotpackage ne $p) {
 337       print STDERR
 338  "$self: warning: honouring Cargo.nail packages.$subdir=$p even though $subdir contains package $gotpackage!\n";
 339     }
 340     die if defined $packagemap{$p};
 341     $packagemap{$p} = $subdir;
 342   }
 343   foreach my $subdir (@{ $nail->{subdirs} }) {
 344     my $gotpackage = read_manifest($subdir);
 345     if (!defined $gotpackage) {
 346       print STDERR
 347  "$self: warning: ignoring subdir $subdir which has no Cargo.toml\n";
 348       next;
 349     }
 350     $packagemap{$gotpackage} //= $subdir;
 351   }
 352 }
 353
 354 sub calculate () {
 355   foreach my $p (sort keys %packagemap) {
 356     print STDERR "$self: package $p in $packagemap{$p}\n" if $verbose>=2;
 357   }
 358   foreach my $mf (keys %manifests) {
 359     my $toml = $manifests{$mf};
 360     foreach my $k (qw(dependencies build-dependencies dev-dependencies)) {
 361       my $deps = $toml->{$k};
 362       next unless $deps;
 363       foreach my $p (keys %packagemap) {
 364         my $info = $deps->{$p};
 365         next unless defined $info;
 366         $deps->{$p} = $info = { } unless ref $info;
 367         delete $info->{version};
 368         $info->{path} = $worksphere.'/'.$packagemap{$p};
 369       }
 370     }
 371     my $nailing = "$mf.nailing~";
 372     unlink_or_enoent $nailing or die "$self: remove old $nailing: $!\n";
 373     open N, '>', $nailing or die "$self: create new $nailing: $!\n";
 374     print N to_toml($toml) or die "$self: write new $nailing: $!\n";
 375     close N or die "$self: close new $nailing: $!\n";
 376   }
 377 }
 378
 379 sub addargs () {
 380   if (@ARGV>=2 &&
 381       $ARGV[0] =~ m{\bcargo\b} &&
 382       $ARGV[1] =~ m/generate-lockfile|update/) {
 383     $cargo_lock_update //= 1;
 384   } else {
 385     $cargo_lock_update //= 0;
 386   }
 387   $cargo_manifest_args //=
 388     (defined $oot_dir) && !$cargo_lock_update;
 389
 390   if ($cargo_manifest_args) {
 391     push @ARGV, "--manifest-path=${src_absdir}/Cargo.toml",
 392       qw(--locked --target-dir=target);
 393   }
 394
 395   if (defined $target) {
 396     if ($target =~ m{^[A-Z]}) {
 397       $target = (cfgs 'arch', $target) // $archmap{$target}
 398         // die "$self: --target=$target alias specified; not in cfg or map\n";
 399     }
 400     push @ARGV, "--target=$target";
 401   }
 402 }
 403
 404 our $oot_absdir;
 405 our $build_absdir; # .../Build/<subdir>
 406
 407 sub oot_massage_cmdline () {
 408   return unless defined $oot_dir;
 409
 410   my $use = cfgs qw(oot use);
 411   $oot_absdir = ($oot_dir !~ m{^/} ? "$worksphere/" : ""). $oot_dir;
 412   $build_absdir = "$oot_absdir/$subdir";
 413
 414   my ($pre,$post);
 415   my @xargs;
 416   if (!$cargo_lock_update) {
 417     push @xargs, $build_absdir;
 418     ($pre, $post) = ('cd "$1"; shift; ', '');
 419   } else {
 420     push @xargs, $oot_absdir, $subdir, $src_absdir;
 421     $pre =  <<'END';
 422         cd "$1"; shift;
 423         mkdir -p -- "$1"; cd "$1"; shift;
 424         cp -- "$1"/Cargo.toml
 425 END
 426     $pre .= <<'ENDLK' if stat_exists 'Cargo.lock', 'working cargo lockfile';
 427               "$1"/Cargo.lock
 428 ENDLK
 429     $pre .= <<'ENDCP';
 430                               .;
 431 ENDCP
 432     $pre .= <<'ENDPRE';
 433         shift;
 434         mkdir -p src; >src/lib.rs;
 435 ENDPRE
 436     $post = <<'ENDPOST';
 437         rm -r src Cargo.toml;
 438 ENDPOST
 439   }
 440   my $addpath = (cfg_uc qw(oot path_add)) //
 441     $use eq 'really' ? Types::Serialiser::true : Types::Serialiser::false;
 442   $addpath =
 443     !Types::Serialiser::is_bool $addpath ? $addpath           :
 444     $addpath                             ? '$HOME/.cargo/bin' :
 445                                            undef;
 446   if (defined $addpath) {
 447     $pre .= <<END
 448         PATH=$addpath:\${PATH-/usr/local/bin:/bin:/usr/bin};
 449         export PATH;
 450 END
 451   }
 452   $pre  =~ s/^\s+//mg; $pre  =~ s/\s+/ /g;
 453   $post =~ s/^\s+//mg; $post =~ s/\s+/ /g;
 454
 455   my $getuser = sub { cfgsn qw(oot user) };
 456   my @command;
 457   my $xe = $verbose >= 2 ? 'xe' : 'e';
 458   my $sh_ec = sub {
 459     if (!length $post) {
 460       @command = (@_, 'sh',"-${xe}c",$pre.'exec "$@"','--',@xargs);
 461     } else {
 462       @command = (@_, 'sh',"-${xe}c",$pre.'"$@"; '.$post,'--',@xargs);
 463     }
 464     push @command, @ARGV;
 465   };
 466   my $command_sh = sub {
 467     my $quoted = join ' ', map {
 468       return $_ if !m/\W/;
 469       s/\'/\'\\'\'/g;
 470       "'$_'"
 471     } @ARGV;
 472     @command = @_, "set -${xe}; $pre $quoted; $post";
 473   };
 474   print STDERR "$self: out-of-tree, building in: \`$build_absdir'\n"
 475     if $verbose;
 476   if ($use eq 'really') {
 477     my $user = $getuser->();
 478     my @pw = getpwnam $user or die "$self: oot.user \`$user' lookup failed\n";
 479     my $homedir = $pw[7];
 480     $sh_ec->('really','-u',$user,'env',"HOME=$homedir");
 481     print STDERR "$self: using really to run as user \`$user'\n" if $verbose;
 482   } elsif ($use eq 'ssh') {
 483     my $user = $getuser->();
 484     $user .= '@localhost' unless $user =~ m/\@/;
 485     $command_sh->('ssh',$user);
 486     print STDERR "$self: using ssh to run as \`$user'\n" if $verbose;
 487   } elsif ($use eq 'command_args') {
 488     my @c = cfgn_list qw(oot command);
 489     $sh_ec->(@c);
 490     print STDERR "$self: out-of-tree, adverbial command: @c\n" if $verbose;
 491   } elsif ($use eq 'command_sh') {
 492     my @c = cfgn_list qw(oot command);
 493     $command_sh->(@c);
 494     print STDERR "$self: out-of-tree, ssh'ish command: @c\n" if $verbose;
 495   } elsif ($use eq 'null') {
 496     $sh_ec->();
 497   } else {
 498     die "$self: oot.use mode $use not recognised\n";
 499   }
 500   die unless @command;
 501   @ARGV = @command;
 502 }
 503
 504 sub setenvs () {
 505   $ENV{NAILINGCARGO_WORKSPHERE}   = $worksphere;
 506   $ENV{NAILINGCARGO_MANIFEST_DIR} = $src_absdir;
 507   $ENV{NAILINGCARGO_BUILDSPHERE}  = $oot_absdir;
 508   delete $ENV{NAILINGCARGO_BUILDSPHERE} unless $oot_absdir;
 509   $ENV{NAILINGCARGO_BUILD_DIR}    = $build_absdir // $src_absdir;
 510 }
 511
 512 our $want_uninstall;
 513
 514 END {
 515   if ($want_uninstall) {
 516     local ($?);
 517     foreach my $mf (keys %manifests) {
 518       eval { uninstall1($mf,1); 1; } or warn "$@";
 519     }
 520     eval { unaltcargolock(1); 1; } or warn "$@";
 521   }
 522 }
 523
 524 our $cleanup_cargo_lock;
 525 sub makebackups () {
 526   foreach my $mf (keys %manifests) {
 527     link "$mf", "$mf.unnailed" or $!==EEXIST
 528       or die "$self: make backup link $mf.unnailed: $!\n";
 529   }
 530
 531   if (defined($alt_cargo_lock)) {
 532     if (@alt_cargo_lock_stat) {
 533       print STDERR "$self: using alt_cargo_lock `$alt_cargo_lock'..."
 534         if $verbose>=3;
 535       if (link $alt_cargo_lock, 'Cargo.lock') {
 536         print STDERR " linked\n" if $verbose>=3;
 537       } elsif ($! != EEXIST) {
 538         print STDERR "\n" if $verbose>=3;
 539         die "$self: make \`Cargo.lock' available as \`$alt_cargo_lock': $!\n";
 540       } else {
 541         print STDERR "checking quality." if $verbose>=3;
 542         my @lock_stat = stat 'Cargo.lock'
 543           or die "$self: stat Cargo.lock (for alt check: $!\n";
 544         same_file(\@alt_cargo_lock_stat, \@lock_stat)
 545           or die
 546 "$self: \`Cargo.lock' and alt file \`$alt_cargo_lock' both exist and are not the same file!\n";
 547       }
 548       $cleanup_cargo_lock = 1;
 549     } else {
 550       $cleanup_cargo_lock = 1;
 551       # If Cargo.lock exists and alt doesn't, that means either
 552       # that a previous run was interrupted, or that the user has
 553       # messed up.
 554     }
 555   }
 556 }
 557
 558 sub nailed ($) {
 559   my ($mf) = @_;
 560   my $nailed  = "$mf.nailed~"; $nailed =~ s{/([^/]+)$}{/.$1} or die;
 561   $nailed;
 562 }
 563
 564 sub install () {
 565   foreach my $mf (keys %manifests) {
 566     my $nailing = "$mf.nailing~";
 567     my $nailed = nailed($mf);
 568     my ($use, $rm);
 569     my $diff;
 570     if (open NN, '<', $nailed) {
 571       $diff = compare($nailing, \*NN);
 572       die "$self: compare $nailing and $nailed: $!" if $diff<0;
 573     } else {
 574       $!==ENOENT or die "$self: check previous $nailed: $!\n";
 575       $diff = 1;
 576     }
 577     if ($diff) {
 578       $use = $nailing;
 579       $rm  = $nailed;
 580     } else {
 581       $use = $nailed;
 582       $rm  = $nailing;
 583     }
 584     rename $use, $mf or die "$self: install nailed $use: $!\n";
 585     unlink_or_enoent $rm or die "$self: remove old $rm: $!\n";
 586     print STDERR "$self: nailed $mf\n" if $verbose>=3;
 587   }
 588 }
 589
 590 sub invoke () {
 591   my $r = system @ARGV;
 592   if (!$r) {
 593     return 0;
 594   } elsif ($r<0) {
 595     print STDERR "$self: could not execute $ARGV[0]: $!\n";
 596     return 127;
 597   } elsif ($r & 0xff00) {
 598     print STDERR "$self: $ARGV[0] failed (exit status $r)\n";
 599     return $r >> 8;
 600   } else {
 601     print STDERR "$self: $ARGV[0] died due to signal! (wait status $r)\n";
 602     return 125;
 603   }
 604 }
 605
 606 sub cargo_lock_update_after () {
 607   if ($cargo_lock_update) {
 608     # avoids importing File::Copy and the error handling is about as good
 609     $!=0; $?=0;
 610     my $r= system qw(cp --), "$build_absdir/Cargo.lock", "Cargo.lock";
 611     die "$self: run cp: $! $?" if $r<0 || $r & 0xff;
 612     die "$self: failed to update local Cargo.lock (wait status $r)\n" if $r;
 613   }
 614 }
 615
 616 sub uninstall1 ($$) {
 617   my ($mf, $enoentok) = @_;
 618   my $unnailed = "$mf.unnailed";
 619   rename $unnailed, $mf or ($enoentok && $!==ENOENT)
 620     or die "$self: failed to restore: rename $unnailed back to $mf: $!\n";
 621 }
 622
 623 sub unaltcargolock ($) {
 624   my ($enoentok) = @_;
 625   return unless $cleanup_cargo_lock;
 626   die 'internal error!' unless defined $alt_cargo_lock;
 627
 628   # we ignore $enoentok because we don't know if one was supposed to
 629   # have been created.
 630
 631   rename('Cargo.lock', $alt_cargo_lock) or $!==ENOENT or die
 632  "$self: cleanup: rename possibly-updated \`Cargo.lock' to \`$alt_cargo_lock': $!\n";
 633
 634   unlink 'Cargo.lock' or $!==ENOENT or die
 635  "$self: cleanup: remove \`Cargo.lock' in favour of \`$alt_cargo_lock': $!\n";
 636   # ^ this also helps clean up the stupid rename() corner case
 637 }
 638
 639 sub uninstall () {
 640   foreach my $mf (keys %manifests) {
 641     my $nailed = nailed($mf);
 642     link $mf, $nailed or die "$self: preserve (link) $mf as $nailed: $!\n";
 643     uninstall1($mf,0);
 644   }
 645   unaltcargolock(0);
 646 }
 647
 648 while (@ARGV && $ARGV[0] =~ m/^-/) {
 649   $_ = shift @ARGV;
 650   last if m{^--$};
 651   if (m{^-[^-]}) {
 652     while (m{^-.}) {
 653       if (s{^-v}{-}) {
 654         $verbose++;
 655       } elsif (s{^-q}{-}) {
 656         $verbose=0;
 657       } elsif (s{^-n}{-}) {
 658         $noact++;
 659       } elsif (s{^-D}{-}) {
 660         $dump++;
 661       } elsif (s{^-T(.+)}{-}s) {
 662         $target = $1;
 663       } elsif (s{^-([uU])}{-}) {
 664         $cargo_lock_update= $1=~m/[a-z]/;
 665       } elsif (s{^-([mM])}{-}) {
 666         $cargo_manifest_args= $1=~m/[a-z]/;
 667       } else {
 668         die "$self: unknown short option(s) $_\n";
 669       }
 670     }
 671   } elsif (s{^--target=}{}) {
 672     $target = $_;
 673   } elsif (m{^--(no-)?cargo-lock-update}) {
 674     $cargo_lock_update= !!$1;
 675   } elsif (m{^--(no-)?cargo-manifest-args}) {
 676     $cargo_manifest_args= !!$1;
 677   } else {
 678     die "$self: unknown long option $_\n";
 679   }
 680 }
 681
 682 die "$self: need command to run\n" unless @ARGV || $noact;
 683
 684 takelock();
 685 readnail();
 686 consider_alt_cargo_lock();
 687 consider_oot();
 688 readorigs();
 689 calculate();
 690 addargs();
 691 our @display_cmd = @ARGV;
 692 oot_massage_cmdline();
 693 setenvs();
 694
 695 if ($dump) {
 696   eval '
 697     use Data::Dumper;
 698     print STDERR Dumper(\%manifests) if $dump>=2;
 699     print STDERR Dumper(\%packagemap, \@ARGV,
 700                         { src_absdir => $src_absdir,
 701                           worksphere => $worksphere,
 702                           subdir => $subdir,
 703                           oot_dir => $oot_dir,
 704                           oot_absdir => $oot_absdir,
 705                           build_absdir => $build_absdir });
 706   ' or die $@;
 707 }
 708
 709 exit 0 if $noact;
 710
 711 $want_uninstall = 1;
 712 makebackups();
 713 install();
 714
 715 printf STDERR "$self: nailed (%s manifests, %s packages)%s\n",
 716   (scalar keys %manifests), (scalar keys %packagemap),
 717   (defined($alt_cargo_lock) and ", using `$alt_cargo_lock'")
 718   if $verbose;
 719
 720 print STDERR "$self: invoking: @display_cmd\n" if $verbose;
 721 my $estatus = invoke();
 722
 723 cargo_lock_update_after();
 724
 725 uninstall();
 726 $want_uninstall = 0;
 727
 728 print STDERR "$self: unnailed.  status $estatus.\n" if $verbose;
 729
 730 exit $estatus;