make-probes.tcl

   1 #!/usr/bin/tclsh
   2
   3 # core packet generator for vinegar-ip
   4 #
   5 # This file is part of vinegar-ip, tools for IP transparency testing.
   6 # vinegar-ip is Copyright (C) 2002 Ian Jackson
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2, or (at your option)
  11 # any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  21 #
  22 # $Id$
  23
  24 proc debug {level str} {
  25     global debug_level
  26     if {$level <= $debug_level} { puts stderr "debug\[$level] $str" }
  27 }
  28
  29 proc manyset {list args} {
  30     foreach val $list var $args {
  31         upvar 1 $var my
  32         set my $val
  33     }
  34 }
  35
  36
  37 proc start_gen {seed} {
  38     global getlog_log
  39     random-bytes-init $seed
  40     set getlog_log {}
  41 }
  42
  43 proc packet-len {p} { expr {[string length $p]/2} }
  44
  45 proc packet-csum-ip {packet} {
  46     set cs 0
  47     append packet 00
  48     while {[regexp {^([0-9a-f]{4})(.*)$} $packet dummy this packet]} {
  49         set cs [expr "\$cs + 0x$this"]
  50         debug 7 [format "0x%s 0x%08x" $this $cs]
  51     }
  52     while {$cs > 0xffff} {
  53         set cs [expr {($cs & 0xffff) + (($cs >> 16) & 0xffff)}]
  54     }
  55     return [expr {$cs ^ 0xffff}]
  56 }
  57
  58 proc packet-fromstring {s} {
  59     binary scan $s H* y
  60     return $y
  61 }
  62
  63 namespace eval Random-Bytes {
  64     namespace export random-bytes random-bytes-init
  65
  66     proc random-bytes-init {seed} {
  67         variable fh
  68         catch { set h $fh; unset fh; close $h }
  69         set fh [open |[list openssl bf-ofb < /dev/zero -e -k " $seed"] r]
  70         fconfigure $fh -translation binary
  71     }
  72     proc random-bytes {n} {
  73         variable fh
  74         set x [read $fh $n]
  75         if {[string length $x] != $n} {
  76             set h $fh; unset fh; close $h
  77             error "openssl bf-ofb exited unexpectedly"
  78         }
  79         set y [packet-fromstring $x]
  80         return $y
  81     }
  82 }
  83
  84 namespace import Random-Bytes::*
  85
  86 proc choice-int {min max} {
  87     set rv 0x[random-bytes 3]
  88     return [expr {
  89         int( double($rv) / double(0x1000000) * double($max+1-$min) )
  90         + $min
  91     }]
  92 }
  93
  94 proc choice-prob {cv def} {
  95     set prob [config $cv $def]
  96     set rv 0x[random-bytes 3]
  97     return [expr {$rv < double($prob)*0x1000000}]
  98 }
  99
 100 proc choice-mult {args} {
 101     if {!([llength $args] % 2)} { error "choice-mult must have default" }
 102     set h 0x[random-bytes 3]
 103     set x [expr { double($h) / double(0x1000000) }]
 104     set cump 0.0
 105     set def [lindex $args end]
 106     set args [lreplace $args end end]
 107     foreach {val p} $args {
 108         set cump [expr {$cump + double($p)}]
 109         if {$x < $cump} { return $val }
 110     }
 111     return $def
 112 }
 113
 114 proc getlog {msg} {
 115     upvar #0 getlog_log log
 116     append log " $msg"
 117     debug 2 "getlog $msg"
 118 }
 119
 120 proc config {cv def} {
 121     upvar #0 config/$cv v
 122     if {[info exists v]} { return $v }
 123     return $def
 124 }
 125
 126
 127 proc define {enum val name argnames body} {
 128     upvar #0 enum/val2name/$enum v2n
 129     upvar #0 enum/name2val/$enum n2v
 130     set v2n($val) $name
 131     set n2v($name) $val
 132     proc enum/val/$enum/$val $argnames $body
 133 }
 134
 135 proc depending-on {scope enum_and_var mtu mtuadjust args} {
 136     upvar 1 $enum_and_var val
 137     set mtu [expr {$mtu + $mtuadjust}]
 138     set procname enum/val/$scope-$enum_and_var/[format %d $val]
 139     if {[choice-prob $enum_and_var-unstruct 0.1] ||
 140             [catch { info body $procname }]} {
 141         getlog (junk)
 142         get-for $scope-fill
 143         get data rand 0 $mtu 1
 144         return $data
 145     } else {
 146         uplevel 1 [list $procname] $mtu $args
 147     }
 148 }
 149
 150
 151 proc get-for {scope} {
 152     upvar 1 get/scope ns
 153     set ns $scope
 154 }
 155
 156 proc get {variable kind args} {
 157     upvar 1 get/scope scope
 158     upvar 1 $variable var
 159     set var [eval [list get/$kind $scope $variable] $args]
 160 }
 161
 162 proc get-config/number {val min max} { return $val }
 163 proc get-config/v4addr {val} {
 164     if {![regexp {^(\d+)\.(\d+)\.(\d+)\.(\d+)$} $val dummy a b c d]} {
 165         error "bad v4addr ?$val?"
 166     }
 167     return [format 0x%02x%02x%02x%02x $a $b $c $d]
 168 }
 169 proc get-config/linkaddr {val} {
 170     return $val
 171 }
 172
 173 proc get-config {variable def kind args} {
 174     # args currently ignored
 175     upvar 1 get/scope scope
 176     upvar 1 $variable var
 177     set val [config $scope-$variable $def]
 178     set var [eval [list get-config/$kind $val] $args]
 179 }
 180
 181 proc get-enum-got {s v rv} {
 182     upvar #0 enum/val2name/$s-$v v2n
 183     if {[info exists v2n($rv)]} {
 184         getlog "$v=$v2n($rv)\[$rv]"
 185     } else {
 186         getlog "$v=$rv"
 187     }
 188     return $rv
 189 }
 190
 191 proc get/enum-rand {s v min max} {
 192     set rv [choice-int $min $max]
 193     return [get-enum-got $s $v $rv]
 194 }
 195
 196 proc get/enum-def {s v} {
 197     upvar #0 enum/val2name/$s-$v v2n
 198     set rv [choice-int 1 [array size v2n]]
 199     set rv [lindex [lsort [array names v2n]] [expr {$rv-1}]]
 200     return [get-enum-got $s $v $rv]
 201 }
 202
 203 proc get/enum {s v min max prand} {
 204     get-for $s-$v
 205     get any choice $prand
 206     if {$any} {
 207         return [get/enum-rand $s $v $min $max]
 208     } else {
 209         return [get/enum-def $s $v]
 210     }
 211 }
 212
 213 proc get/number {s v min max} {
 214     set rv [choice-int $min $max]
 215     getlog "$v=$rv"
 216     return $rv
 217 }
 218
 219 proc get/hex {s v min max} {
 220     set rv [choice-int $min $max]
 221     getlog [format %s=0x%x $v $rv]
 222     return $rv
 223 }
 224
 225 proc get/hex32 {s v} {
 226     set rv [random-bytes 4]
 227     getlog "$v=0x$rv"
 228     return 0x$rv
 229 }
 230
 231 proc get/flag {s v defprob} {
 232     set rv [choice-prob $s-$v $defprob]
 233     if {$rv} { getlog "$v" } else { getlog "!$v" }
 234     return $rv
 235 }
 236
 237 proc get/choice {s v defprob} {
 238     set rv [choice-prob $s-$v $defprob]
 239     if {$rv} { getlog "($v)" } else { getlog "(!$v)" }
 240     return $rv
 241 }
 242
 243 proc get/rand {s v minlen maxlen blockbytes} {
 244     get-for $s-$v
 245     if {$maxlen<0} { getlog (full!); return {} }
 246     get l number [expr {$minlen/$blockbytes}] [expr {$maxlen/$blockbytes}]
 247     return [random-bytes [expr {$l*$blockbytes}]]
 248 }
 249
 250 proc get/ip-timestamp {s v} {
 251     set rv [expr {[clock seconds] | 0x80000000}]
 252     getlog "$v=[format %x $rv]"
 253     return $rv
 254 }
 255
 256 proc get/v4addr {s v} {
 257     set rv 0x
 258     set p {}
 259     set d {}
 260     for {set i 0} {$i<4} {incr i} {
 261         set b [random-bytes 1]
 262         append rv $b
 263         append p $d [format %d 0x$b]
 264         set d .
 265     }
 266     getlog "$v=$p"
 267     return $rv
 268 }
 269
 270 proc get/choice-mult {s v args} {
 271     set rv [eval choice-mult $args]
 272     getlog "($rv)"
 273     return $rv
 274 }
 275
 276 proc get/string {s v minlen maxlen first rest} {
 277     set o {}
 278     set now $first
 279     for {set l [choice-int $minlen $maxlen]} {$l>0} {incr l -1} {
 280         set cn [choice-int 0 [expr {[string length $now]-1}]]
 281         append o [string index $now $cn]
 282         set now $rest
 283     }
 284     getlog "$v=\"$o\""
 285     return [packet-fromstring $o]
 286 }
 287
 288 proc get/ntstring {s v minlen maxlen first rest} {
 289     set s [get/string $s $v $minlen $maxlen $first $rest]
 290     append s 00
 291     append s [random-bytes $maxlen]
 292     return [string range $s 0 [expr {$maxlen*2-1}]]
 293 }
 294
 295 namespace eval Assembler {
 296     namespace export assemble assembly-overwrite
 297
 298     proc assemble {outvarname format} {
 299         # format should look like those RFC diagrams.  +-+-+ stuff and
 300         # good formatting is mandatory.  You can have a single data
 301         # item at the end ending in ..., which means append that data
 302         # item.
 303         #
 304         # Field names are converted to lowercase; internal spaces
 305         # are replaced with _.  They are then assumed to be
 306         # variable names in the caller's scope.  The packet is
 307         # assembled from those values (which must all be set)
 308         # and stored in $varname in the caller's scope.
 309         #
 310         # Variables ?_whatever will be *set* with the location of the
 311         # field in the string (in internal format); the corresponding
 312         # `whatever' (with the ?_ stripped) will be read when assembling.
 313         #
 314         # Field names starting with digits are literal values instead.
 315
 316         variable cache
 317         upvar 1 $outvarname out
 318         if {[catch { set parsed $cache($format) }]} {
 319             set parsed [parse $format]
 320             set cache($format) $parsed
 321         }
 322
 323         manyset $parsed outbytes lout
 324         set out [string repeat 00 $outbytes]
 325         foreach {?_location varname locvarname} $lout {
 326             if {[regexp {^[0-9]} $varname]} {
 327                 set value $varname
 328             } else {
 329                 set value [uplevel 1 [list set $varname]]
 330             }
 331             if {[string length $locvarname]} {
 332                 upvar 1 $locvarname lv
 333                 set lv ${?_location}
 334             }
 335             if {[catch {
 336                 assembly-overwrite out location $value
 337             } emsg]} {
 338                 global errorInfo errorCode
 339                 error $emsg \
 340                         "$errorInfo\n    setting\n$varname at ${?_location}" \
 341                         $errorCode
 342             }
 343         }
 344     }
 345
 346     proc parse {format} {
 347         set lno 0
 348         set outbytes 0
 349         set atend 0
 350         debug 7 "ASSEMBLY $format"
 351         set format [exec expand << $format]
 352         foreach l [split $format "\n"] {
 353             incr lno
 354             if {[regexp -nocase {^ *\| +\| *$} $l]} {
 355                 if {![info exists wordbits]} {
 356                     error "vspace not in data @$lno\n?$l?"
 357                 }
 358                 incr words
 359             } elseif {[regexp -nocase {^ *[|? a-z0-9.]+$} $l]} {
 360                 if {[info exists words]} {
 361                     error "data without delimline @$lno\n?$l?"
 362                 }
 363                 set words 1
 364                 set cue $l
 365             } elseif {[regexp {^ *[-+]+ *$} $l]} {
 366                 set wordbits 0
 367                 set newlineform {}
 368                 while {[regexp {^([-= ]+)\+(.*)$} $l dummy before after]} {
 369                     set atpos([string length $before]) $wordbits
 370                     incr wordbits
 371                     set l "$before=$after"
 372                     append newlineform "@[string length $before]:$wordbits "
 373                 }
 374                 incr wordbits -1
 375                 append newlineform $wordbits
 376                 if {[info exists lineform]} {
 377                     if {"$newlineform" != "$lineform"} {
 378  error "format change @$lno\n?$l?\n$wordformat != $oldwordformat"
 379                     }
 380                     if {![info exists words] || $words<0} {
 381                         error "consecutive delimlines @$lno\n?$l?"
 382                     }
 383                     incr outbytes [expr {$words*$wordbits/8}]
 384                     set l $cue
 385                     while {[regexp -nocase \
 386                             {^([ =]*)\|( *[? a-z0-9]*[a-z0-9] *\.* *)\|(.*)$} \
 387                             $l dummy before midpart after]} {
 388                         debug 7 "RWORKG ?$l?"
 389                         if {$atend} {
 390                             error "two things at end @$lno\n?$l?"
 391                         }
 392                         set varname [string tolower [string trim $midpart]]
 393                         if {[regexp {(.*[a-z0-9])\s*\.\.\.$} $varname \
 394                                 dummy realvarname]} {
 395                             set varname $realvarname
 396                             set atend 1
 397                         }
 398                         set varname [string map {{ } _} $varname]
 399                         set p1 [string length $before]
 400                         set p2 [expr {
 401                             [string length $before] +
 402                             [string length $midpart] + 1
 403                         }]
 404                         if {![info exists atpos($p1)] ||
 405                             ![info exists atpos($p2)]} {
 406  error "vdelims not found @$lno $varname $p1 $p2 -- $lineform ?$cue?"
 407                         }
 408                         set bit1 [expr {
 409                             $outbytes*8
 410                             - $words*$wordbits
 411                             + $atpos($p1)
 412                         }]
 413                         set bitlen [expr {
 414                             $atpos($p2) - $atpos($p1) + ($words-1)*$wordbits
 415                         }]
 416                         if {$atend} {
 417                             if {$bit1 % 8} {
 418                                 error "atend not at byte @$lno\n?$l?"
 419                             }
 420                             set outbytes [expr {$bit1/8}]
 421                             set location [list $bit1 0 $varname]
 422                         } else {
 423                             set location [list $bit1 $bitlen $varname]
 424                         }
 425                         if {[regexp {^\?_(.*)} $varname dummy realvarname]} {
 426                             debug 7 "LOCATING $varname $location"
 427                             set locvarname $varname
 428                             set varname $realvarname
 429                         } else {
 430                             set locvarname {}
 431                         }
 432                         lappend lout $location $varname $locvarname
 433                         set l "$before="
 434                         append l [string repeat = [string length $midpart]]
 435                         append l |$after
 436                     }
 437                     debug 7 "REMAIN ?$l?"
 438                     if {![regexp {^[ =]*\|? *$} $l]} {
 439                         error "unclear @$lno\n?$l?"
 440                     }
 441                 } else {
 442                     if {$wordbits % 8 || $wordbits >32} {
 443                         error "bad wordbits $wordbits @$lno ?$l? $newlineform"
 444                     }
 445                     set lineform $newlineform
 446                 }
 447                 catch { unset words }
 448             } elseif {[regexp {^ *$} $l]} {
 449             } else {
 450                 error "huh? @$lno ?$l?"
 451             }
 452         }
 453         debug 7 "ASSEMBLY\n$outbytes\n$lout\n"
 454         return [list $outbytes $lout]
 455     }
 456
 457     proc assembly-overwrite {outvarname locvarnameex value} {
 458         upvar 1 $outvarname out
 459         upvar 1 ?_$locvarnameex location
 460         manyset $location bit1 bitlen diag
 461         if {$bitlen > 0 && $bitlen != 32 && $value >= (1<<$bitlen)} {
 462             error "$diag $value >= 2**$bitlen"
 463         }
 464         if {!($bit1 % 8) && !($bitlen % 8)} {
 465             set char0no [expr {$bit1/4}]
 466             set charlen [expr {$bitlen/4}]
 467             set chareno [expr {$char0no + $charlen -1}]
 468             if {$bitlen > 0} {
 469  debug 8 "ASSEMBLY $diag == $value == 0x[format %x $value] (@$bit1+$bitlen)"
 470                 set repl [format %0${charlen}x $value]
 471                 set out [string replace $out $char0no $chareno $repl]
 472             } else {
 473  debug 8 "ASSEMBLY-ADD $diag (@$bit1)"
 474                 # bitlen==0 => append
 475                 set out [string range $out 0 $chareno]
 476                 append out $value
 477             }
 478         } else {
 479             while {$bitlen > 0} {
 480                 set byteno [expr {$bit1 / 8}]
 481                 set char0no [expr {$byteno*2}]
 482                 set char1no [expr {$char0no+1}]
 483                 set bytebit [expr {128>>($bit1 % 8)}]
 484                 set byte 0x[string range $out $char0no $char1no]
 485                 debug 7 "< $bit1+$bitlen $byteno $char0no $bytebit $byte $out"
 486                 set byte [expr {
 487                     ($value & (1<<($bitlen-1)))
 488                     ? ($byte | $bytebit)
 489                     : ($byte & ~$bytebit)
 490                 }]
 491                 set out [string replace $out $char0no $char1no \
 492                         [format %02x $byte]]
 493  debug 8 "> $bit1+$bitlen $byteno $char0no $bytebit 0x[format %02x $byte] $out"
 494                 incr bitlen -1
 495                 incr bit1
 496             }
 497         }
 498     }
 499 }
 500 namespace import Assembler::*
 501
 502 proc gen_1_ip {mtu source_spec dest_spec} {
 503     # RFC791
 504     upvar #0 ip_proto proto
 505     upvar #0 ip_source source
 506     upvar #0 ip_dest dest
 507
 508     set source $source_spec
 509     set dest $dest_spec
 510
 511     get-for ip
 512     set version 4
 513     get tos hex 0x00 0xff
 514     get id number 0x0000 0xffff
 515     get df flag 0.5
 516     if {$df || ![choice-prob ip-midfrag 0.05]} {
 517         set mf 0
 518         set frag 0
 519     } {
 520         get mf flag 0.5
 521         get frag number 0 0x1fff
 522     }
 523     get-config ttl 255 number 0 255
 524     get proto enum 1 255 0.05
 525     set flags [expr {$df*2 + $mf}]
 526
 527     set header_checksum 0
 528     set ihl 0
 529     set total_length 0
 530     assemble ip {
 531    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 532    |Version| ? IHL |TOS            |       ? Total Length          |
 533    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 534    |         Id                    |Flags|      Frag               |
 535    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 536    |  TTL          |    Proto      |      ? Header Checksum        |
 537    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 538    |                       Source                                  |
 539    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 540    |                    Dest                                       |
 541    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 542     }
 543     # we don't do any IP options
 544
 545     set ihl [packet-len $ip]
 546     if {$ihl % 4} { error "ihl not mult of 4 bytes" }
 547     assembly-overwrite ip ihl [expr {$ihl / 4}]
 548
 549     set body [depending-on ip proto $mtu -$ihl]
 550     set total_length [expr {[packet-len $ip] + [packet-len $body]}]
 551
 552     assembly-overwrite ip total_length $total_length
 553     assembly-overwrite ip header_checksum [packet-csum-ip $ip]
 554
 555     append ip $body
 556     return $ip
 557 }
 558
 559 define ip-proto 1 icmp {mtu} {
 560     # RFC792
 561     get-for icmp
 562     get type enum 0 255 0.2
 563     manyset [depending-on icmp type $mtu -4] body code
 564     if {![string length $code]} { get code number 0 255 }
 565     set checksum 0
 566     assemble icmp {
 567    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 568    |     Type      |     Code      |        ? Checksum             |
 569    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 570    |     Body ...                                                  |
 571    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 572     }
 573     assembly-overwrite icmp checksum [packet-csum-ip $icmp]
 574     return $icmp
 575 }
 576
 577 proc define-icmp-type-vanilla {num name} {
 578     define icmp-type $num $name {mbl} "icmp-vanilla \$mbl [list $name]"
 579 }
 580 proc icmp-vanilla {mbl typename} {
 581     get-for icmp-$typename
 582     get code enum 0 255 0.4
 583     get body rand 0 $mbl 1
 584     return [list $body $code]
 585 }
 586
 587 define-icmp-type-vanilla 3 unreach
 588 define icmp-unreach-code 0 net {} {}
 589 define icmp-unreach-code 1 host {} {}
 590 define icmp-unreach-code 2 proto {} {}
 591 define icmp-unreach-code 3 port {} {}
 592 define icmp-unreach-code 4 fragneeded {} {}
 593 define icmp-unreach-code 5 sourceroutefail {} {}
 594
 595 define-icmp-type-vanilla 11 timeout
 596 define icmp-timeout-code 0 intransit {} {}
 597 define icmp-timeout-code 1 fragment {} {}
 598
 599 define-icmp-type-vanilla 12 parameters
 600 define icmp-parameters-code 0 seepointer {} {}
 601
 602 define-icmp-type-vanilla 4 sourcequench
 603 define icmp-sourcequench-code 0 quench {} {}
 604
 605 define icmp-type 5 redirect {mbl} {
 606     get-for icmp-redirect
 607     get code enum 0 255 0.4
 608     get gateway v4addr
 609     get data rand 0 [expr {$mbl-4}] 1
 610     assemble body {
 611    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 612    |                 Gateway                                       |
 613    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 614    |     Data ...                                                  |
 615    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 616     }
 617     return [list $body $code]
 618 }
 619
 620 define icmp-redirect-code 0 net {} {}
 621 define icmp-redirect-code 1 host {} {}
 622 define icmp-redirect-code 2 net+tos {} {}
 623 define icmp-redirect-code 3 host+tos {} {}
 624
 625 define icmp-type 8 ping {mbl} { icmp-echo $mbl }
 626 define icmp-type 0 pong {mbl} { icmp-echo $mbl }
 627 proc icmp-echo {mbl} {
 628     get-for icmp-echo
 629     get code enum 0 255 0.4
 630     get id hex 0 0xffff
 631     get seq hex 0 0xffff
 632     get data rand 0 [expr {$mbl-8}] 1
 633     assemble body {
 634    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 635    |       Id                      |        Seq                    |
 636    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 637    |     Data ...                                                  |
 638    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 639     }
 640     return [list $body $code]
 641 }
 642 define icmp-echo-code 0 echo {} {}
 643
 644 define icmp-type 13 timestamp {mbl} { icmp-timestamp }
 645 define icmp-type 14 timestampreply {mbl} { icmp-timestamp }
 646 proc icmp-timestamp {} {
 647     get-for icmp-timestamp
 648     get code enum 0 255 0.4
 649     get id hex 0 0xffff
 650     get seq hex 0 0xffff
 651     get originate ip-timestamp
 652     get receive ip-timestamp
 653     get transmit ip-timestamp
 654     assemble body {
 655    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 656    |           Id                  |        Seq                    |
 657    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 658    |     Originate                                                 |
 659    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 660    |     Receive                                                   |
 661    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 662    |     Transmit                                                  |
 663    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 664     }
 665     return [list $body $code]
 666 }
 667 define icmp-timestamp-code 0 timestamp {} {}
 668
 669 define icmp-type 15 inforequest {mbl} { icmp-inforeq }
 670 define icmp-type 16 inforeply {mbl} { icmp-inforeq }
 671 proc icmp-inforeq {} {
 672     get-for icmp-inforeq
 673     get code enum 0 255 0.4
 674     get id hex 0 0xffff
 675     get seq hex 0 0xffff
 676     assemble body {
 677    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 678    |           Id                  |        Seq                    |
 679    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 680     }
 681     return [list $body $code]
 682 }
 683 define icmp-inforeq-code 0 timestamp {} {}
 684
 685 # MAYADD ICMP traceroute RFC1393
 686 # MAYADD ICMP router discovery RFC1256
 687
 688
 689 define ip-proto 4 ip {mtu} {
 690     # RFC2003
 691     get-for ip-ip
 692     get source v4addr
 693     get dest v4addr
 694     gen_1_ip $mtu $source $dest
 695 }
 696
 697
 698 define ip-proto 2 igmp {mtu} {
 699     get-for igmp
 700     get type enum 0 255 0.5
 701     get timeout number 0 255
 702     get group v4addr
 703     set checksum 0
 704     set extra {}
 705     assemble igmp {
 706    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 707    |      Type     |   Timeout     |         ? Checksum            |
 708    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 709    |                         Group                                 |
 710    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 711    |                       ? Extra ...                             |
 712    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 713     }
 714
 715     if {[choice-prob igmp-extra 0.3]} {
 716         get extra rand 1 [expr {$mtu - [packet-len $igmp]}] 1
 717         assembly-overwrite igmp extra $extra
 718     }
 719
 720     assembly-overwrite igmp checksum [packet-csum-ip $igmp]
 721     return $igmp
 722 }
 723
 724 define igmp-type 17 membquery {} {}
 725 define igmp-type 16 membreport {} {}
 726 define igmp-type 23 leavegroup {} {}
 727 define igmp-type 18 membreport {} {}
 728
 729
 730 define ip-proto 51 ah {mtu} {
 731     # RFC1826
 732     get-for ah
 733     get next number 0 255
 734     get reserved hex 0 0xffff
 735     get spi hex32
 736     get auth_data rand 0 [expr {$mtu-8 > 50 ? 50 : $mtu-8}] 4
 737     set length [packet-len $auth_data]
 738     assemble ah {
 739      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 740      | Next          |   Length      |           RESERVED            |
 741      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 742      |                    SPI                                        |
 743      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 744      |                 Auth Data ...                                 |
 745      +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 746     }
 747     get payload rand 0 [expr {$mtu - [packet-len $ah]}] 1
 748     append ah $payload
 749     return $ah
 750 }
 751
 752 proc udp-rport {} {
 753     get-for udp
 754     get port enum-rand 0 0xffff
 755     return $port
 756 }
 757
 758 define ip-proto 17 udp {mtu} {
 759     # RFC768
 760     get-for udp
 761
 762     set csum_mode [choice-mult \
 763             checksum_bad 0.10 \
 764             checksum_none 0.20 \
 765             checksum_good]
 766
 767     get style choice-mult \
 768             request 0.15 \
 769             reply 0.15 \
 770             servers 0.20 \
 771             random
 772
 773     if {"$style" != "random"} {
 774         get port enum-def
 775         set def_port $port
 776     } else {
 777         set def_port x
 778     }
 779     switch -exact $style {
 780         random  { set source_port [udp-rport]; set dest_port [udp-rport] }
 781         request { set source_port [udp-rport]; set dest_port $def_port   }
 782         reply   { set source_port $def_port;   set dest_port [udp-rport] }
 783         servers { set source_port $def_port;   set dest_port $def_port   }
 784     }
 785
 786     if {"$style" != "random"} {
 787         set port $def_port
 788         set data [depending-on udp port $mtu -8 $style]
 789     } else {
 790         get data rand 0 [expr {$mtu-8}] 1
 791     }
 792
 793     set length 0
 794     set checksum 0
 795     assemble udp {
 796    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 797    |       Source Port             |        Dest Port              |
 798    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 799    |       ? Length                |      ? Checksum               |
 800    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 801    |     Data ...                                                  |
 802    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 803     }
 804     set udp_length [packet-len $udp]
 805     assembly-overwrite udp length $udp_length
 806
 807     if {"$csum_mode" == "checksum_none"} {
 808         set checksum 0
 809         getlog (nocsum)
 810     } else {
 811         global ip_source ip_dest ip_proto
 812         assemble pseudo {
 813    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 814    |       IP Source                                               |
 815    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 816    |       IP Dest                                                 |
 817    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 818    |       0       | IP Proto      |        UDP length             |
 819    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 820         }
 821         set checksum [packet-csum-ip "$pseudo$udp"]
 822         if {!$checksum} { set checksum 0xffff }
 823         if {"$csum_mode" == "checksum_bad"} {
 824             get csumerror hex 1 0xffff
 825             set checksum [expr {$checksum ^ $csumerror}]
 826         }
 827     }
 828     assembly-overwrite udp checksum $checksum
 829     return $udp
 830 }
 831
 832 define udp-port 50 remailck {mtu style} {
 833     # RFC1339
 834     get-for remailck
 835     if {"$style" == "request"} {
 836         get what choice-mult \
 837                 req-baduser 0.15 \
 838                 req-auth 0.15 \
 839                 resp-ok 0.15 \
 840                 resp-auth 0.15 \
 841                 req-user
 842     } else {
 843         get what choice-mult \
 844                 req-baduser 0.15 \
 845                 req-auth 0.15 \
 846                 resp-auth 0.15 \
 847                 req-user 0.15 \
 848                 resp-ok
 849     }
 850     switch -exact $what {
 851         req-user {
 852             set auth 0
 853             get user string 1 8 \
 854                     abcdefghijklmnopqrustuvwxyz \
 855                     abcdefghijklmnopqrustuvwxyz-0123456789_
 856         }
 857         req-baduser {
 858             set auth 0
 859             get user rand 0 [expr {$mtu - 4}] 1
 860         }
 861         req-auth {
 862             get auth enum 0 31 0.5
 863             set user [depending-on remailck auth $mtu -4]
 864         }
 865         resp-auth {
 866             get auth hex 0 0xffff
 867             set modified 0
 868             set read 0
 869         }
 870         resp-ok {
 871             get mail choice-mult \
 872                     newmail 0.15 \
 873                     oldmail 0.15 \
 874                     nomail 0.20 \
 875                     times
 876             set auth 0
 877             switch -exact $mail {
 878                 newmail {
 879                     set modified 0
 880                     set read 1
 881                 }
 882                 oldmail {
 883                     set modified 1
 884                     set read 0
 885                 }
 886                 nomail {
 887                     set modified 0
 888                     set read 0
 889                 }
 890                 times {
 891                     get modified number 1 600
 892                     get read number 1 600
 893                 }
 894                 default { error "mail? $mail" }
 895             }
 896         }
 897         default { error "what? $what" }
 898     }
 899     switch -glob $what {
 900         req-* {
 901             assemble payload {
 902    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 903    |         Auth                                                  |
 904    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 905    |     User ...                                                  |
 906    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 907             }
 908         }
 909         resp-* {
 910             assemble payload {
 911    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 912    |         Auth                                                  |
 913    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 914    |         Modified                                              |
 915    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 916    |         Read                                                  |
 917    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 918             }
 919         }
 920         default { error "what?? $what" }
 921     }
 922     return $payload
 923 }
 924
 925 define remailck-auth 31 passwd {mtu} {
 926     get-for remailck-passwd
 927     get passwd string 6 8 \
 928             0123456789abcdefghijklmnopqrstuvxwyz \
 929             0123456789abcdefghijklmnopqrstuvxwyz
 930     return $passwd
 931 }
 932
 933 define udp-port 67 dhcpserv {mtu style} { return [dhcp $mtu] }
 934 define udp-port 68 dhcpclient {mtu style} { return [dhcp $mtu] }
 935 proc dhcp {mtu} {
 936     get-for dhcp
 937     get op enum 0 255 0.2
 938     get htype enum 0 255 0.2
 939     set hlen 6
 940     get hops number 0 255
 941     get xid hex32
 942     get secs number 0 300
 943     get flags hex 0 255
 944     get ciaddr v4addr
 945     get yiaddr v4addr
 946     get siaddr v4addr
 947     get giaddr v4addr
 948     set chaddr [random-bytes 16]
 949     get sname ntstring 0 64 \
 950             0123456789abcdefghijklmnopqrstuvwxyz \
 951             0123456789abcdefghijklmnopqrstuvwxyz.-+
 952     get file ntstring 0 128 / \
 953             0123456789abcdefghijklmnopqrstuvwxyz.-+/_
 954
 955     assemble dhcp {
 956    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 957    |     op        |   htype       |   hlen        |   hops        |
 958    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 959    |                            xid                                |
 960    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 961    |           secs                |           flags               |
 962    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 963    |                          ciaddr                               |
 964    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 965    |                          yiaddr                               |
 966    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 967    |                          siaddr                               |
 968    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 969    |                          giaddr                               |
 970    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 971     }
 972     append dhcp $chaddr $sname $file
 973
 974     return $dhcp
 975 }
 976 define dhcp-op 1 request {} {}
 977 define dhcp-op 2 reply {} {}
 978 define dhcp-htype 1 ethernet {} {}
 979
 980
 981 define ip-proto 6 tcp {mtu} {
 982     # RFC793
 983     get-for tcp
 984
 985     get source_port number 0 65535
 986     get dest_port number 0 65535
 987     get event choice-mult \
 988             connect 0.15 \
 989             accept 0.15 \
 990             close 0.15 \
 991             reset 0.15 \
 992             weird 0.15 \
 993             data
 994     set s 0
 995     set a 1
 996     set f 0
 997     set r 0
 998     switch -exact $event {
 999         connect { set s 1; set a 0 }
1000         accept { set s 1 }
1001         close { set f 1 }
1002         reset { set a 0; set r 1 }
1003         data { }
1004         weird {
1005             get s flag 0.5
1006             get a flag 0.5
1007             get f flag 0.5
1008             get r flag 0.5
1009         }
1010         default { error "event? $event" }
1011     }
1012     get seq hex32
1013     get ack hex32
1014     if {[choice-prob tcp-smallwindow 0.7]} {
1015         get window number 0 1
1016     } else {
1017         get window hex 0 0xffff
1018     }
1019     get p flag 0.5
1020     get u flag 0.3
1021     get urg hex 0 0xffff
1022
1023     set options {}
1024     get optmode choice-mult badopt 0.3 opt 0.3 noopt
1025     switch -exact $optmode {
1026         noopt { }
1027         badopt {
1028             get options rand 1 60 1
1029         }
1030         opt {
1031             set nooi 1
1032             while {$nooi || [choice-prob tcp-opts-more 0.4]} {
1033                 set nooi 0
1034                 get opt enum 1 255 0.5
1035                 if {$opt == 1} {
1036                     assemble option {
1037    +-+-+-+-+-+-+-+-+
1038    |  Opt          |
1039    +-+-+-+-+-+-+-+-+
1040                     }
1041                 } else {
1042                     set data [depending-on tcp opt 6 0]
1043                     set option_len 0
1044                     assemble option {
1045    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1046    |  Opt          | ? Option Len  |
1047    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1048    |      Data ...                 |
1049    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1050                     }
1051                     assembly-overwrite option option_len [packet-len $option]
1052                 }
1053                 append options $option
1054             }
1055         }
1056     }
1057
1058     if {[choice-prob reserved-nonzero 0.25]} {
1059         get reserved hex 0 0x3f
1060     } else {
1061         set reserved 0
1062     }
1063
1064     if {[packet-len $options] % 4 || [get optxpad choice 0.15]} {
1065         if {"$optmode" != "badopt"} { append options 00 }
1066         set padlen [expr {3 - ([packet-len $options] + 3) % 4}]
1067         append options [random-bytes $padlen]
1068     }
1069
1070     set d_off 0
1071     set checksum 0
1072     assemble packet {
1073    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1074    |          Source Port          |       Dest Port               |
1075    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1076    |                        Seq                                    |
1077    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1078    |                    Ack                                        |
1079    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1080    |? D Off| Reserved  |U|A|P|R|S|F|            Window             |
1081    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1082    |         ? Checksum            |         Urg                   |
1083    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1084    |                    Options     ...                            |
1085    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1086     }
1087
1088     set d_off [expr {([packet-len $packet]/4) & 0x0f}]
1089     assembly-overwrite packet d_off $d_off
1090
1091     if {!($s || $r) || [get unexpdata flag 0.2]} {
1092         get data rand 0 [expr {$mtu - [packet-len $packet]}] 1
1093         append packet $data
1094     }
1095     set tcp_length [packet-len $packet]
1096
1097     global ip_source ip_dest ip_proto
1098     assemble pseudo {
1099    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1100    |       IP Source                                               |
1101    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1102    |       IP Dest                                                 |
1103    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1104    |       0       | IP Proto      |        TCP length             |
1105    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1106     }
1107
1108     set csum [packet-csum-ip "$pseudo$packet"]
1109     if {[choice-prob tcp-badcsum 0.1]} {
1110         get csumerror hex 1 0xffff
1111         set csum [expr {$csum ^ $csumerror}]
1112     }
1113     assembly-overwrite packet checksum $csum
1114     return $packet
1115 }
1116
1117 define tcp-opt 2 mss {mdl} {
1118     get-for tcp-opt
1119     get mss hex 0 0xffff
1120     assemble od {
1121    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1122    |        MSS                    |
1123    +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
1124     }
1125     return $od
1126 }
1127
1128
1129 namespace eval PCap {
1130     namespace export pcap_open pcap_write pcap_write_raw pcap_close
1131
1132     proc pcap_open {fn} {
1133         variable fh
1134         catch { close $fh }
1135         set fh [open $fn w]
1136         fconfigure $fh -translation binary
1137     }
1138
1139     proc pcap_close {} {
1140         variable fh
1141         if {![info exists fh]} return
1142         close $fh
1143         unset fh
1144     }
1145
1146     proc pcap_write_raw {packet} {
1147         variable fh
1148         if {![info exists fh]} return
1149         puts -nonewline $fh [binary format H* $packet]
1150     }
1151
1152     proc pcap_write {valdeflist} {
1153         foreach {kind valvar} $valdeflist {
1154             if {![regexp {^([usx])([0-9]+)} $kind dummy mode bits]} {
1155                 error "unknown kind $kind for $valvar"
1156             }
1157             set value [uplevel 1 [list set $valvar]]
1158             if {$bits % 8} { error "bits must be mult 8 in $kind for $valvar" }
1159             if {"$mode" != "x"} {
1160                 set v {}
1161                 set ov $value
1162                 for {set i 0} {$i<$bits/8} {incr i} {
1163                     append v [format %02x [expr {$value & 0xff}]]
1164                     set value [expr {$value >> 8}]
1165                 }
1166                 if {$value != 0 && $value != -1} {
1167                     error "value $ov more than $bits bits (residue=$value)"
1168                 }
1169                 set value $v
1170             }
1171             if {[string length $value] != $bits/4} {
1172                 error "$valvar value $value wrong length, not $bits bits"
1173             }
1174             pcap_write_raw $value
1175         }
1176     }
1177 }
1178 namespace import PCap::*
1179
1180 proc emit {seed} {
1181     global getlog_log errorInfo mtu fake_time_t
1182     global minframelen linktypename
1183
1184     get-for ip
1185     get-config source 127.0.0.1 v4addr
1186     get-config dest 127.0.0.1 v4addr
1187
1188     if {[catch {
1189         start_gen $seed
1190         set packet [gen_1_ip $mtu $source $dest]
1191         puts stdout "[format %6s $seed] $getlog_log\n       $packet"
1192     } emsg]} {
1193         puts stderr "\nERROR\n$seed\n\n$emsg\n\n$errorInfo\n\n"
1194         puts stdout "[format %6s $seed] error"
1195     } else {
1196         set ts_sec [incr fake_time_t]
1197         set ts_usec 0
1198
1199         set l [packet-len $packet]
1200         if {$l < $minframelen} {
1201             append packet [string repeat 00 [expr {$minframelen - $l}]]
1202         }
1203
1204         set llpkt [link/$linktypename/linkencap $packet]
1205
1206         set len [packet-len "$llpkt"]
1207         pcap_write {
1208             u32 ts_sec
1209             u32 ts_usec
1210             u32 len
1211             u32 len
1212         }
1213         pcap_write_raw $llpkt
1214     }
1215 }
1216
1217
1218 # link/ether - RFC894
1219 proc link/ether/linkparams {} { return {1 46} }
1220 proc link/ether/defaddr {} { return 00:00:00:00:00:00 }
1221 proc link/ether/procaddr {input sd} {
1222     set v [string tolower $input]
1223     if {[regexp {^([0-9a-f]{1,2}\:){6}$} $v:]} {
1224         set o {}
1225         foreach b [split $v :] { append o [format %02x 0x$b] }
1226         set v $o
1227     }
1228     if {![regexp -nocase {^[0-9a-f]{12}$} $v]} {
1229         error "invalid $sd ethernet addr $input ($v)"
1230     }
1231     return $v
1232 }
1233 proc link/ether/linkencap {packet} {
1234     global link_source link_dest
1235     set llpkt {}
1236     append llpkt $link_dest $link_source 0800
1237     append llpkt $packet
1238     return $llpkt
1239 }
1240
1241
1242 proc nextarg {} {
1243     global argv
1244     if {![llength $argv]} { error "need another arg" }
1245     set a [lindex $argv 0]
1246     set argv [lrange $argv 1 end]
1247     return $a
1248 }
1249
1250 proc nextarg_num {} { return [expr {[nextarg] + 0}] }
1251 proc nextarg_il {} {
1252     set a [nextarg]
1253     if {![regexp -nocase {^([0-9.]+)/(.+)$} $a dummy i l]} {
1254         error "--source/--dest needs <ip-addr>/<link-addr>"
1255     }
1256     return [list $i $l]
1257 }
1258
1259 set debug_level 0
1260 set mtu 100
1261 set upto {}
1262 set xseed {}
1263 set linktypename ether
1264 while {[regexp {^\-\-} [lindex $argv 0]]} {
1265     set o [nextarg]
1266     switch -exact -- $o {
1267         --infinite { set upto -1 }
1268         --debug { set debug_level [nextarg_num] }
1269         --upto { set upto [nextarg_num] }
1270         --write { pcap_open [nextarg] }
1271         --mtu { set mtu [nextarg_num] }
1272         --xseed { set xseed [nextarg] }
1273         --linktype { set linktypename [nextarg] }
1274         --source { manyset [nextarg_il] config/ip-source config/link-source }
1275         --dest { manyset [nextarg_il] config/ip-dest config/link-dest }
1276         default { error "bad option $o" }
1277     }
1278 }
1279
1280 proc process_linkaddr {sd} {
1281     global linktypename
1282     upvar #0 link_$sd l
1283     get-for link
1284     get-config $sd [link/$linktypename/defaddr] linkaddr
1285     set l [link/$linktypename/procaddr [set $sd] $sd]
1286 }
1287
1288 manyset [link/$linktypename/linkparams] linktype minframelen
1289 process_linkaddr source
1290 process_linkaddr dest
1291
1292 set magic d4c3b2a1
1293 set version_major 2
1294 set version_minor 4
1295 set thiszone 0
1296 set sigfigs 0
1297 set snaplen 131073
1298
1299 pcap_write {
1300     x32 magic
1301     u16 version_major
1302     u16 version_minor
1303     s32 thiszone
1304     s32 sigfigs
1305     s32 snaplen
1306     s32 linktype
1307 }
1308
1309 set fake_time_t [clock seconds]
1310
1311 if {[llength $argv]} {
1312     foreach count $argv { emit "$xseed$count" }
1313 } else {
1314     if {![string length $upto]} { set upto 100 }
1315     for {set count 1} {$upto<0 || $count<=$upto} {incr count} {
1316         emit "$xseed$count"
1317     }
1318 }
1319
1320 pcap_close