lipo-flat-mount.scad

   1 // -*- C -*-
   2
   3 include <nutbox.scad>
   4 include <utils.scad>
   5
   6 // pimoroni 3000mAh
   7 battery = [ 51.5,
   8             81.3,
   9             8.0 ];
  10
  11 battery_wall = 2.0;
  12 battery_wall_unsupp = 4.0;
  13 battery_wall_top_gap = 0.75;
  14
  15 battery_keeper_m_th = 4;
  16 battery_keeper_m_w = 4;
  17 battery_keeper_x_gap = 0.75; // each side
  18 battery_keeper_y_gap_overhang = 0.75;
  19 battery_keeper_y_gap_nutbox = 1.0;
  20 battery_keeper_z_gap_nutbox = 0.50;
  21 battery_keeper_z_gap_overhang = 0.75;
  22
  23 battery_keeper_x_th_min = 1.5 * 1.5;
  24 battery_keeper_x_th_max = 2.5 * 1.5;
  25 battery_keeper_x_w  = 5;
  26 battery_keeper_x_n  = 5;
  27
  28 battery_keeper_screw_x_off = -2.5;
  29
  30 battery_wire_y = 4;
  31
  32 battery_nutbox = nutbox_data_M3;
  33
  34 // calculated
  35
  36 battery_fix_sz = NutBox_outer_size(battery_nutbox);
  37
  38 battery_nutbox_z = max( battery[2] + battery_wall_top_gap,
  39                         NutBox_h_base(battery_nutbox) );
  40 battery_keeper_overhang_z = battery[2] + battery_keeper_m_th
  41   + battery_keeper_z_gap_overhang;
  42 battery_keeper_overhang_wall = battery_keeper_m_w;
  43 battery_keeper_overhang_th = battery_keeper_m_th;
  44
  45 // calculated outputs
  46
  47 battery_keeper_tab_top_z = battery_nutbox_z
  48      + battery_keeper_z_gap_nutbox + battery_keeper_m_th;
  49      // NB does not include screw head
  50
  51 battery_keeper_legs_top_z = battery_keeper_overhang_z
  52                             + battery_keeper_overhang_th;
  53
  54 battery_keeper_frame_top_z = battery[2] + battery_keeper_m_th;
  55
  56 module BatteryPlan(){
  57   rectfromto([ -battery[0]/2, 0          ],
  58              [ +battery[0]/2, battery[1] ]);
  59 }
  60
  61 module BatteryBase(){ ////toplevel
  62   // wall
  63   linextr(-0.1, battery[2] - battery_wall_top_gap, convexity=7) {
  64     difference(){
  65       union(){
  66         offset(r=battery_wall) BatteryPlan();
  67         rectfromto([ 0,0 ],
  68                    [ -(battery[0]/2 + battery_wall_unsupp), battery[1]/3 ]);
  69       }
  70       BatteryPlan();
  71       rectfromto([ battery_fix_sz/2 - 0.5
  72                    + battery_keeper_screw_x_off, -30 ],
  73                  [ -battery[0], battery_wire_y ]);
  74     }
  75   }
  76
  77   // nutbox
  78   translate([battery_keeper_screw_x_off, -battery_fix_sz/2, battery_nutbox_z])
  79     NutBox(battery_nutbox, battery_nutbox_z + 0.1);
  80
  81   // overhang for legs at rear
  82   for (m=[0,1]) {
  83     mirror([m,0,0]) {
  84       translate([ battery[0]/2, battery[1], 0]) {
  85         difference(){
  86           linextr(-0.1,
  87                   battery_keeper_overhang_z
  88                   + battery_keeper_overhang_th,
  89                   convexity=1)
  90             rectfromto([ -battery_keeper_m_w*2, -battery_keeper_m_w ],
  91                        [ battery_keeper_overhang_wall, battery_wall ]);
  92           linextr(-1, battery_keeper_overhang_z,
  93                   convexity=1)
  94             rectfromto([-20, -20], [0,0]);
  95         }
  96       }
  97     }
  98   }
  99 }
 100
 101 module BatteryKeeper(){ ////toplevel
 102   // A-frame
 103   translate([0,0, battery[2]]) {
 104     linextr(0, battery_keeper_m_th) {
 105       intersection(){
 106         // main legs
 107         translate([0,  +battery[1], 0])
 108           multmatrix([[ 1, -battery_keeper_screw_x_off/battery[1], 0, 0, ],
 109                       [ 0,1,0, 0, ],
 110                       [ 0,0,1, 0, ]])
 111           translate([0, -battery[1], 0])
 112         for (sx=[-1,+1]) {
 113           multmatrix([[ 1,0,0, 0, ],
 114                       [ 0,1,0, 0, ],
 115                       [ 0,0,1, 0, ]] +
 116                      sx *
 117                      ( battery[0]/2 - 0.5 * battery_keeper_m_w
 118                        - battery_keeper_x_gap ) /
 119                      ( battery[1] - 0.5 * battery_keeper_m_w )
 120                      *
 121                      [[ 0,1,0, 0, ],
 122                       [ 0,0,0, 0, ],
 123                       [ 0,0,0, 0, ]])
 124             rectfromto([ -battery_keeper_m_w/2,
 125                          battery_keeper_y_gap_nutbox ],
 126                        [ +battery_keeper_m_w/2,
 127                          battery[1] - battery_keeper_y_gap_overhang ]);
 128         }
 129
 130         // shape to round off the leg end corners
 131         hull(){
 132           for (sx=[-1,+1]) {
 133             translate([ sx * ( battery[0]/2 - battery_keeper_m_w/2
 134                                -battery_keeper_x_gap) ,
 135                         battery[1] - battery_keeper_m_w/2
 136                         -battery_keeper_y_gap_overhang ])
 137               circle(r = battery_keeper_m_w/2);
 138           }
 139           square(center=true, [ battery[0], 1 ]);
 140         }
 141       }
 142     }
 143
 144     // x struts
 145     for (i=[0 : battery_keeper_x_n-1]) {
 146       linextr(0,
 147               battery_keeper_x_th_min +
 148               (battery_keeper_x_th_max - battery_keeper_x_th_min)
 149               * pow( i/(battery_keeper_x_n-1)*2 - 1 , 2)
 150               ) {
 151         difference(){
 152           translate([0, battery[1] * ((i + 0.5) / battery_keeper_x_n)])
 153             square(center=true, [ battery[0], battery_keeper_x_w ]);
 154           children(0);
 155         }
 156       }
 157     }
 158   }
 159
 160   // tab for screw and nutbox
 161   translate([battery_keeper_screw_x_off,
 162              0,
 163              battery_nutbox_z + battery_keeper_z_gap_nutbox])
 164     linextr(0, battery_keeper_m_th, convexity=4) {
 165     difference(){
 166       rectfromto([ -battery_fix_sz/2, -battery_fix_sz ],
 167                  [ +battery_fix_sz/2,
 168                    0.5 * battery[1] / battery_keeper_x_n +
 169                    0.5 * battery_keeper_m_w ]);
 170       translate([ 0, -battery_fix_sz/2 ])
 171         circle(r = battery_nutbox[0]/2);
 172     }
 173   }
 174 }
 175
 176 module BatteryDemo(){ ////toplevel
 177   color("grey") BatteryBase();
 178   BatteryKeeper() { union(){ } }
 179 }
 180