fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153
 154 camera_pos_tl = [  7.350,  7.500 ]; // from tl corner (as seen from back)
 155 camera_edge_rad = 9.0;
 156 camera_sz = 32.92;
 157
 158 // this is disabled, FP4 doesn't have one
 159 jack_pos = [ 13.83, 8.485 ];
 160 jack_dia = 10.64 + .5; // some jack I had lying around
 161
 162 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 163 led_pos = []; // [ 13.98, 10.00 ];
 164 led_aperture = 9;
 165 led_window_ledge = 0.75; // each side
 166
 167 noisecancelmic_pos = [ 15.08, 4.35 ];   // from rhs, from top edge
 168 noisecancelmic_dia = 4.00;
 169
 170 mainmic_pos = [ 21.0, 4.35 ];   // from lhs, from top edge
 171 mainmic_dia = 4.00;
 172
 173 lhshole_pos = [ phone[1]/2, 4.35 ];
 174
 175 // fingerpushhole_dias = [];
 176 fingerpushhole_dias = [ 15, 18 ]; // this is for testing
 177
 178 lanyard_half_dia = 1.15;
 179 lanyard_entry_rel_breadth = 2;
 180 lanyard_channel_len = 8;
 181 //rearspeaker_pos_bl = [ 12.64, 18.72 ];
 182 //rearspeaker_size   = [  3.76,  7.36 ];
 183
 184 bottomspeaker_size = [ 11.35, 1.40 ] + [1,1] * 0.5;
 185 bottomspeaker_pos = [ 19.45, 4.82 ];
 186
 187 microusb_above = 1.64 - 0.25;
 188 microusb_below = 2.42;
 189 microusb_width = 12.16 + 2.0 + 1.25;
 190
 191 case_th_bottom = 2.5;
 192 case_th_lid = 3.0;
 193 case_th_side = 2.3;
 194 case_th_lip = 1.2;
 195
 196 lid_screen_gap_extra = .66;
 197
 198 case_struts_count = 6;
 199 case_struts_solid_below = 1.00;
 200 case_struts_solid_above = 0.75;
 201 case_struts_width = 0.10;
 202
 203 keeper_th_z = 0.75;
 204 keeper_th_x = 0.75;
 205 keeper_inner_width = 2.75;
 206 keeper_inner_height = 2.75;
 207 keeper_slant_slope = 2; // larger means steeper
 208
 209 keeper_gap_z_top = 0.25;
 210 keeper_gap_z_bot = 0.75;
 211 keeper_gap_x     = 0.25;
 212 keeper_gap_x_holes = 0.75;
 213
 214 keeper_side = 0; // 0 = lhs; 1 = rhs
 215
 216 case_lip = 1.25;
 217
 218 lid_gap_x = 0.25;
 219 lid_gap_z = 0.25;
 220 lid_lip = 1.75;
 221 lid_edgepart_width = 5.0;
 222 lid_buttoncover_thick = 1.3;
 223 lid_buttoncover_reinf = 0.65;
 224
 225 foldover_gap = 0.50;
 226 foldover_lever_gap = 0.50;
 227
 228 // xxx replace hinge screw with nail plan
 229
 230 // properties of the hinge fasteners
 231 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 232 hingescrew_shaft_len = 12;
 233 hingescrew_fasteners_extra_thick = 0.40;
 234 // ^ amount of thread protruding if everything was completely nominal
 235 //   and we are using two nuts
 236 hingescrew_nut_access_dia = 4.72 + 0.50;
 237 // ^ washer is 4.72 dia
 238 //   also, want to get pliers or tiny spanner in to do up locknut
 239 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 240 hingescrew_nut_thick = 1.93;
 241 hingescrew_head_th = 1.38 + 0.75;
 242 hingescrew_head_dia = 3.92;
 243
 244 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 245
 246 lever_cover_th = 0.75;
 247 hingemount_th = 2.5;
 248 hingemount_wd = 4.8725;
 249
 250 $fa = 5;
 251 $fs = 0.1;
 252
 253 button_l_fudge = 4.4;
 254 buttonishleg_default_l_is_fudge = 10;
 255
 256 hinge_base_slope = 1.5; // bigger is steeper
 257
 258 strut_min_at_end = 1.5;
 259
 260 hinge_x_gap = 0.125;
 261 hinge_x_postscrew_gap = 0.75;
 262 hinge_x_arms_gap = 0.35;
 263 hinge_r_arms_gap = 0.55;
 264 hinge_over_nut_plate = 1.0;
 265
 266 // there isn't one of these, speaker is by hinge
 267 // rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 268
 269 thumbrecess_depth = 1.3;
 270 thumbrecess_width = 16.5;
 271 thumbrecess_topcurve_r = 5.0;
 272
 273 prop_recess_under = 0.50;
 274 prop_recess_slop = 0.200; // each side
 275 prop_end_dia = 0.5;
 276 prop_main_th = 3;
 277 prop_taper_len = 6;
 278 prop_main_width = 4;
 279 prop_side_gap = 0.75; // each side
 280 prop_lidrecess_behind = 0.75;
 281 prop_caserecess_behind = 0.75;
 282 prop_caserecess_taper = 0.45; // one side only
 283 prop_prop_gap = 0.5;
 284 prop_prong_heel_slope = 0.5;
 285
 286 lid_fold_clearance_antislop = 0.5;
 287
 288 $button_leg_only = false;
 289 $suppress_forward_holes = false;
 290
 291 // ---------- calculated ----------
 292
 293 phone_total_thick = phone_edge_thick;
 294
 295 phone_width =  (phone + bumper*2)[0];
 296 phone_height = (phone + bumper*2)[1];
 297
 298 inside_br = [phone_width, -phone_height];
 299
 300 prop_prong_h = prop_main_th;
 301
 302 //echo(camera_pos_tl + bumper,
 303 //     camera_pos_br + bumper);
 304
 305 // ----- could be changed -----
 306 lid_buttoncover_gap = lid_gap_x;
 307 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 308
 309 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 310
 311 //prop_nose_len = case_th_lid - prop_recess_under;
 312 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 313 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 314
 315
 316 //lid_lip_overlap_width xxx bad name = ;
 317 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 318
 319 epp0 = [0,0];
 320 epp1 = [0, -phone_edge_thick];
 321 epp2i = epp1; // conflated for FP4
 322 epp2o = epp2i;
 323 epp3 = epp2i + [10, 0];
 324 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 325 epp4 = epp5 + [-1,0] * case_th_side;
 326
 327 kppe = [0,0];
 328 kppd = kppe + [1,0] * keeper_inner_width;
 329 kppc = kppd + [0,1] * keeper_th_z;
 330 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 331 kppf = kppe - [0,1] * keeper_inner_height;
 332 kppa = [ kppb[0], kppf[1] ];
 333
 334 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 335 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 336
 337 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 338 // exact x posn not very important; must extend past end of keeper
 339
 340 lpp15 = [ lpp14[0],
 341           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 342           + lid_screen_gap_extra ];
 343 // ^ beam theory says to maximise force before contact,
 344 //   the gap below the `beam' (the lid) must be 1/3
 345 //   the thickness (ie the lid thickness) if the beam
 346 //   is solid, or 1/2 if it has a top and bottom only.
 347 //   ours is mostly solid.
 348
 349 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 350              case_th_lip);
 351
 352 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 353 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 354
 355 case_bottom_z = epp2o[1] - case_th_bottom;
 356
 357 // button profile
 358 bppM = epp4 + [0,5];
 359 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 360 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 361 bppS = [ epp1[0], bppR[1] ];
 362 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 363 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 364 bppO = [ bppN[0], bppP[1] ];
 365 bppL = lpp10 + [5,0];
 366 bppK = [ bppL[0], bppN[1] ];
 367 bppJ = [ bppN[0], bppL[1] ];
 368 bppU = [ bppJ[0], lpp12[1] ];
 369 bppV = lpp11;
 370 bppW = lpp10;
 371
 372 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 373
 374 // notification led aperture
 375
 376 nla_r0 = led_aperture/2;
 377 nla_r1 = nla_r0 + led_window_ledge;
 378 nla_r2 = nla_r1 + multicolour_gap;
 379 nla_t =
 380   led_window_style >= 3 ? initial_layer_thick :
 381   led_window_style >= 2 ? led_window_ledge : 0;
 382
 383
 384 // hinge plan
 385 hp_rn = hingescrew_nut_access_dia/2;
 386 hp_r2_min = hp_rn + lever_cover_th;
 387 hp_rs = hingescrew_shaft_dia/2;
 388 hp_r1_min = hp_rs + hingemount_th;
 389
 390 hp_r1 = max(hp_r1_min, hp_r2_min);
 391 hp_r2 = hp_r1;
 392
 393 hppU = lpp13;
 394 hppS = epp2o + [0,-1] * case_th_bottom;
 395 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 396
 397 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 398          0.5 * (hppU + hppS)[1] ];
 399 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 400 hppB = hppT + [0,-1] * hp_k;
 401
 402 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 403 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 404 hppE = [ hppE_x, hppE_y ];
 405
 406 // hinge elevation x coords
 407
 408 hex20 = max(epp2o[0],
 409             phone_cnr_rad,
 410             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 411 hex21 = hex20 + hingemount_wd;
 412 hex22 = hex21 + hinge_x_gap;
 413 hex27 = hex20 + hingescrew_shaft_len;
 414 hex24 = hex27 + hinge_x_postscrew_gap;
 415 hex23 = hex27 - (hingescrew_nut_thick*2
 416                  + hingescrew_fasteners_extra_thick);
 417 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 418
 419 //echo(hex20, hex21, hex22, hex23, hex24);
 420 ////  6, 10.8725, 10.9975, 13.74, 18.75
 421 //module chk(act,exp) {
 422 //  if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 423 //  else echo("ok", act);
 424 //}
 425 //chk(hex20, 6);
 426 //chk(hex21, 10.8725);
 427 //chk(hex22, 10.9975);
 428 //chk(hex23, 13.74);
 429 //chk(hex24, 18.75);
 430
 431 lid_fold_clearance_skew =
 432   (lpp10[1] - hppB[1]) /
 433   (lpp10[0] - hppB[0]);
 434
 435 echo("SK",lid_fold_clearance_skew);
 436
 437 // thumb recess (used to be "catch" hence cpp*
 438
 439 cppA = epp4 + [thumbrecess_depth, 0];
 440 cppB = [ cppA[0], epp1[1] ];
 441
 442 // lanyard
 443
 444 ly_r = lanyard_half_dia / 2;
 445 ly_rc = ly_r * 2;
 446
 447 ly_theta = 90;
 448 ly_o = epp2i + 3 * ly_r * [0,1];
 449
 450 max_case_bottom_edge_thickness =
 451   case_th_bottom;
 452
 453 ly_q_z = -(ly_rc + ly_r);
 454 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 455
 456 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 457
 458 // prop recess in case
 459
 460 prop_x_pos = phone_width/2;
 461
 462 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 463
 464 prc_r1 = prop_end_dia/2;
 465 prc_r3 = prc_r1 + prop_recess_slop;
 466
 467 prcp2 = [ epp4[0] + prop_buildout_less,
 468           case_bottom_z ];
 469
 470 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 471
 472 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 473           epp2i[1] - prc_r3 - prop_recess_under];
 474
 475 // prop recess in lid
 476
 477 prl_r10 = prop_end_dia/2;
 478 prl_r10o = prl_r10 + prop_recess_slop;
 479
 480 prlp10 = lpp10 + [1,1] * prl_r10o
 481   + [1,0] * prop_lidrecess_behind
 482   + [0,1] * prop_recess_under;
 483
 484 // prop
 485
 486 $prpp10 = [0,0];
 487 $prpp11 = [0, prop_taper_len];
 488
 489 $prp_r10 = prl_r10;
 490
 491 // ---------- modules ----------
 492
 493 module AdhocMultiprintFrame(phase, z0, zs) {
 494   // from z0 to z0 + zs*layer
 495   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 496   xextra = extra + -epp4[0];
 497   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 498   yextra = extra + -epp4[0];
 499   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 500   p0 = [ xrange[0], yrange[0] ];
 501   p1 = [ xrange[1], yrange[1] ];
 502   echo(p0, p1);
 503   translate([0,0, z0])
 504     mirror([0,0, zs<0 ? 1 : 0])
 505     linear_extrude(height= initial_layer_thick)
 506     difference(){
 507       rectfromto(p0 - [1,1] * initial_layer_width,
 508                  p1 + [1,1] * initial_layer_width);
 509       rectfromto(p0, p1);
 510     }
 511 }
 512
 513 module KeeperProfile(slant=0){
 514   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 515   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 516 }
 517
 518 module EdgeProfile(){
 519   difference(){
 520     hull(){
 521       translate(epp3) square(case_th_bottom*2, center=true);
 522       circleat(epp2o, r=case_th_bottom);
 523       circleat(epp1, r=case_th_side);
 524       rectfromto(epp0, epp4);
 525     }
 526     polygon([ epp5 + [0,10],
 527               epp1,
 528               epp3 + [10,0] ]);
 529   }
 530 }
 531
 532 module LanyardLanyardProfile(entry=false){
 533   hull(){
 534     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 535       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 536         circle(r= lanyard_half_dia/2);
 537   }
 538 }
 539
 540 module LanyardCurveChannelProfile(){
 541   translate([0, -ly_r])
 542     LanyardLanyardProfile();
 543 }
 544
 545 module LanyardEntryChannelProfile(){
 546   LanyardLanyardProfile(true);
 547 }
 548
 549 module LanyardMainChannelProfile(){
 550   LanyardCurveChannelProfile();
 551   difference(){
 552     square(center=true, ly_r * [6, 2]);
 553     for (xs=[-1,+1])
 554       translate(ly_r * [3 * xs, -1])
 555         circle(r = ly_r);
 556   }
 557 }
 558
 559 module LanyardEntryOuterProfile(){
 560   circleat([ly_re + ly_r, 0], ly_re);
 561 }
 562
 563 module LanyardEntry(){
 564   q_z = ly_q_z;
 565   oec_y = ly_oec_y;
 566
 567   d_x = -ly_rc;
 568
 569   translate([d_x, 0, q_z]) {
 570     intersection(){
 571       rotate([90,0,0])
 572         rotate_extrude(convexity=10)
 573         rotate(90)
 574         translate([0, -q_z])
 575         LanyardCurveChannelProfile();
 576       translate([0,-10,0])
 577         cube([20,20,20]);
 578     }
 579   }
 580
 581   mirror([0,0,1])
 582     translate([0,0,-1])
 583     linear_extrude(height=20)
 584     rotate(-90)
 585     LanyardEntryChannelProfile();
 586
 587   translate([0, ly_r*2, 0])
 588     rotate([90,0,0])
 589     linear_extrude(height = ly_r*4){
 590     difference(){
 591       rectfromto([d_x, q_z], [ly_r, 0]);
 592       circleat([d_x, q_z], ly_rc);
 593     }
 594   }
 595
 596   translate([0,0,q_z]){
 597     for (my=[0,1])
 598       mirror([0,my,0]){
 599         translate([0, oec_y, 0]){
 600           difference(){
 601             translate(ly_re * [-1,0,-2])
 602               cube(ly_re * [2,1,2]);
 603             rotate_extrude(convexity=10)
 604               LanyardEntryOuterProfile();
 605           }
 606         }
 607       }
 608     difference(){
 609       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 610         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 611       for (mx=[0,1])
 612         mirror([mx,0,0])
 613           rotate([90,0,0])
 614           translate([0,0,-10])
 615           linear_extrude(height=20)
 616           LanyardEntryOuterProfile();
 617     }
 618   }
 619 }
 620
 621 module LanyardCutout(l){
 622   rotate([0,-90,0])
 623     linear_extrude(height=l)
 624     rotate(-90)
 625     LanyardMainChannelProfile();
 626
 627   for (ee=[0,1]){
 628     translate(ee * l * [-1,0])
 629       mirror([ee,0,0])
 630       LanyardEntry();
 631   }
 632 }
 633
 634 module LidEdgeProfile(){
 635   polygon([ lpp10,
 636             lpp11,
 637             lpp12,
 638             lpp13,
 639             lpp13 + [10, 0],
 640             lpp15 + [10, 0],
 641             lpp15,
 642             lpp14,
 643             ]);
 644   intersection(){
 645     circleat(lpp12, r=lp_r12);
 646     rectfromto( lpp12 + [-10,   0],
 647                 lpp12 + [+10, +10] );
 648   }
 649 }
 650
 651 module LidEdgeFoldClearanceProfile(){
 652   translate([-lid_fold_clearance_antislop, 0])
 653     polygon([ lpp10,
 654               lpp11,
 655               lpp11 + [-20,  0],
 656               lpp11 + [-20, 20],
 657               lpp11 + [+20, 20],
 658               lpp10 + [+20,  0] ]);
 659 }
 660
 661 module ButtonCoverProfile(){
 662   intersection(){
 663     polygon(concat([ bppM, bppP, bppO, bppJ ],
 664                    (enable_support && !$button_suppress_over_keeper
 665                     ? [ bppU, bppV, bppW ] : []),
 666                    [ bppL, bppK ]));
 667     hull(){
 668       EdgeProfile();
 669       LidEdgeProfile();
 670     }
 671   }
 672 }
 673
 674 module ButtonPlan(l, deep, cut){
 675   epsilon =
 676     (cut  ? 0 : lid_buttoncover_gap);
 677
 678   delta =
 679     (deep ? lid_buttoncover_overlap : 0);
 680
 681   C = [0,0]; // by definition
 682   T = [ 0, epp4[1] ];
 683   G = T + [0,10];
 684
 685   B0 = C + [0,-1] * button_cutout_depth;
 686   B1 = B0 + [0,1] * epsilon;
 687
 688   r0 = 0.5 * (T[1] - B0[1]);
 689   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 690   H = A + [0,-1] * delta;
 691
 692   D = A + [-2,0] * r0;
 693   F = D + [0,10];
 694
 695   E0 = 0.5 * (D + A);
 696   E1 = E0 + [1,0] * epsilon;
 697
 698   I0 = [ E0[0], H[1] ];
 699   I1 = [ E1[0], H[1] ];
 700
 701   hull(){
 702     for (m=[0,1]) mirror([m,0])
 703       circleat(H, r0 - epsilon);
 704   }
 705   for (m=[0,1]) mirror([m,0]) {
 706     difference(){
 707       polygon([ E1,
 708                 I1,
 709                 H,
 710                 B1,
 711                 G,
 712                 F,
 713                 D
 714                 ]);
 715       circleat(D, r0 + epsilon);
 716     }
 717   }
 718 }
 719
 720 module ButtonCoverReinf(){ ////toplevel
 721   minkowski(){
 722     rotate([90,0,0])
 723       linear_extrude(height=0.01)
 724       intersection(){
 725         ButtonCoverProfile();
 726         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 727           square([100,100]);
 728     }
 729     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 730       circle(r= lid_buttoncover_reinf);
 731       translate([-20,0]) square(40, center=true);
 732     }
 733   }
 734 }
 735
 736 module ThumbRecessCutProfile(){
 737   difference(){
 738     polygon([ cppA + [-10,0],
 739               cppB + [-10,0],
 740               cppB,
 741               cppA ]);
 742     circleat(epp1, r=case_th_side);
 743   }
 744 }
 745
 746 module Flip_rhs(yn=[0,1]) {
 747   for ($rhsflip=yn) {
 748     translate([phone_width/2, 0, 0])
 749       mirror([$rhsflip,0,0])
 750       translate([-phone_width/2, 0, 0])
 751       children();
 752   }
 753 }
 754
 755 module Flip_bot(yn=[0,1]) {
 756   for ($botflip=yn) {
 757     translate([0, -phone_height/2, 0])
 758       mirror([0, $botflip, 0])
 759       translate([0, phone_height/2, 0])
 760       children();
 761   }
 762 }
 763
 764 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 765   // sides
 766   Flip_rhs(){
 767     translate([0, -phone_cnr_rad, 0])
 768       rotate([90,0,0])
 769       linear_extrude(height = phone_height - phone_cnr_rad*2)
 770       children(0);
 771   }
 772   // corners
 773   Flip_rhs() Flip_bot() {
 774     translate([+1,-1] * phone_cnr_rad)
 775       intersection(){
 776         rotate_extrude()
 777           intersection(){
 778             mirror([1,0,0])
 779               translate([-1,0] * phone_cnr_rad)
 780               children(0);
 781             rectfromto([0,-20],[10,20]);
 782           }
 783         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 784           cube([10,10,40]);
 785       }
 786   }
 787   // top and bottom
 788   Flip_bot(){
 789     translate([ phone_width - phone_cnr_rad, 0,0 ])
 790       rotate([90,0,-90])
 791       linear_extrude(height = phone_width - phone_cnr_rad*2)
 792       children(0);
 793   }
 794   // fill
 795   translate([0,0, fill_zstart])
 796     mirror([0,0, fill_downwards])
 797     linear_extrude(height = fill_th)
 798     rectfromto([+1,-1] * phone_cnr_rad,
 799                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 800 }
 801
 802 module CaseAperture(pos, dia, $fn, topbottom=0) {
 803   theta = 180/$fn;
 804   translate([ bumper[0],
 805               -epp2i[0],
 806                0 ])
 807     rotate([0,0, 90*topbottom])
 808     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 809     rotate([-90, theta, 0])
 810     cylinder(r = dia/2 / cos(theta),
 811              h = 60);
 812 }
 813
 814 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 815   // y_ref_sign:
 816   //   +1  measured from top    of actual phone to top    of button
 817   //   -1  measured from bottom of actual phone to bottom of button
 818   //    0  y is centre of button in coordinate system
 819   $button_l= l;
 820   $button_suppress_over_keeper= suppress_over_keeper;
 821   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 822           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 823           y;
 824   //echo(eff_y);
 825   translate([0, eff_y, 0])
 826     children();
 827 }
 828
 829 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 830   $button_leg_only = true;
 831   SideButton(y, y_ref_sign, l) children();
 832 }
 833
 834 module Buttons(){
 835   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 836   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 837   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 838   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 839   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 840   // xxx need hole for whatever that hole is on lhs
 841 }
 842
 843 module Struts(x_start, z_min, th){
 844   // if th is negative, starts at z_min and works towards -ve z
 845   // and object should then be printed other way up
 846   for (i= [1 : 1 : case_struts_count]) {
 847     translate([0,
 848                0,
 849                z_min])
 850       mirror([0,0, th<0 ? 1 : 0])
 851       translate([0,
 852                  -phone_height * i / (case_struts_count+1),
 853                  case_struts_solid_below])
 854       linear_extrude(height= abs(th)
 855                      -(case_struts_solid_below+case_struts_solid_above))
 856       rectfromto([               x_start, -0.5 * case_struts_width ],
 857                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 858   }
 859 }
 860
 861 module OrdinaryRearAperture(rhs,bot, pos){
 862   Flip_rhs(rhs) Flip_bot(bot)
 863     linextr(-20, 20)
 864     mirror([0,1])
 865     translate(pos + bumper)
 866     children();
 867 }
 868
 869 module MicroUSBEtc(){
 870   Flip_bot(1){
 871     rotate([90,0,0])
 872       mirror([0,0,1])
 873       linextr(-epp2i[0], 60)
 874       translate([0.5 * phone_width, 0, 0])
 875       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 876                  [+microusb_width/2, epp0[1] + -microusb_above]);
 877   }
 878 }
 879
 880 module OrdinaryBottomEdgeApertures(){
 881   Flip_bot(1)
 882     CaseAperture(mainmic_pos, mainmic_dia, 8);
 883
 884   Flip_bot(1) Flip_rhs(1) {
 885     linextr_y_xz(-epp2i[0], 60)
 886       hull()
 887       for (x= [-1,+1]) {
 888         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 889                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 890                     0 ])
 891           rotate(360/16)
 892           circle(r = bottomspeaker_size[1], $fn = 8);
 893       }
 894   }
 895 }
 896
 897 module OrdinaryRearApertures(){
 898   // rear speaker
 899   //  OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 900   //    rectfromto(-rearspeaker_gap,
 901   //           rearspeaker_size + rearspeaker_gap);
 902 }
 903
 904 module NotInTestFrameRearApertures(){
 905   // finger hole to remove phone
 906   if (len(fingerpushhole_dias))
 907     OrdinaryRearAperture(0,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 908                                 phone[1]/2 ])
 909     scale(fingerpushhole_dias)
 910     circle(r= 0.5 );
 911 }
 912
 913 module RearCameraAperture(){
 914   Flip_rhs(1)
 915     mirror([0, 0, 1])
 916     translate([0,0,0])
 917     hull() // there is some kind of bug if hull() is done in 2D here!
 918     linear_extrude(height = 20)
 919     mirror([0, 1, 0])
 920     translate(bumper)
 921     translate(camera_pos_tl)
 922     for (xy = [ [0,0], [0,1], [1,0] ]) {
 923       translate(
 924           camera_edge_rad * [1,1] +
 925           xy * (camera_sz - camera_edge_rad * 2)
 926                 )
 927         circle(r = camera_edge_rad);
 928     }
 929 }
 930
 931 module HingeLidProfile(){
 932   hull(){
 933     circleat(hppT, hp_r1);
 934     circleat(lpp12, lp_r12);
 935     polygon([lpp10,
 936              lpp13 + [2,0],
 937              lpp12,
 938              hppT]);
 939   }
 940 }
 941
 942 module HingeBaseProfile(){
 943   difference(){
 944     hull(){
 945       circleat(hppB, hp_r1);
 946       circleat(hppE, hp_r1);
 947       circleat(epp2o, case_th_bottom);
 948       circleat(hppB + [10,0], hp_r1);
 949     }
 950     polygon([epp5, epp1, epp3, bppL]);
 951   }
 952 }
 953
 954 module HingeLeverOuterProfile(){
 955   hull(){
 956     circleat(hppT, hp_r2);
 957     circleat(hppB, hp_r2);
 958   }
 959 }
 960
 961 module HingeLeverInnerProfile(){
 962   for (s = [-1,+1]) {
 963     c = s > 0 ? hppT : hppB;
 964     translate(c)
 965       mirror([0,0, s>0 ? 1 : 0])
 966       rotate(s<0 ? -40 : 0)
 967       hull()
 968       for (x=[-20,20])
 969         for (y=[0, s * 10])
 970           translate([x,y])
 971             circle(hp_rn);
 972   }
 973 }
 974
 975 module HingeLeverNutProfile(){
 976   for (c= [hppB, hppT]) {
 977     translate(c)
 978       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 979   }
 980 }
 981
 982 module Flip_hinge(doflip=1){
 983   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 984   translate(hinge_origin)
 985     rotate([doflip*180,0,0])
 986     translate(-hinge_origin)
 987     children();
 988 }
 989
 990 module HingePortion(x0,x1){
 991   Flip_rhs() Flip_bot(1)
 992     translate([x0,0,0])
 993     mirror([1,0,0])
 994     rotate([90,0,-90])
 995     linear_extrude(height=x1-x0)
 996     children();
 997 }
 998
 999 module ThumbRecessApply(ztop){
1000   width = thumbrecess_width;
1001   w = width + thumbrecess_topcurve_r*2 + 1;
1002   translate([phone_width/2, 0,0]){
1003     difference(){
1004       rotate([90,0,-90])
1005         linextr(-w/2, w/2)
1006         children(0);
1007       translate([0, 50, 0])
1008         rotate([90,0,0])
1009         linear_extrude(height=100){
1010         for (m=[0,1]) mirror([m,0,0]) {
1011           hull(){
1012             translate([w/2, ztop - thumbrecess_topcurve_r])
1013               circle(thumbrecess_topcurve_r);
1014             translate([w/2, -50])
1015               square(thumbrecess_topcurve_r*2, center=true);
1016           }
1017         }
1018       }
1019     }
1020   }
1021 }
1022
1023 module CaseBase(){
1024   AroundEdges(epp3[1], case_th_bottom, 1)
1025     EdgeProfile();
1026 }
1027
1028 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1029
1030 module PropProfileAssignments(gamma){
1031   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1032   x = prop_x(gamma);
1033   p = phone_height + prlp10[0] - hppB[0];
1034   b = p + x;
1035
1036   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1037   a = q + x;
1038   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1039   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1040
1041   $prp_theta = 90 - $prp_alpha;
1042   beta = 180 - $prp_alpha - gamma;
1043   psi = 90 - beta;
1044
1045   //echo("abc", a,b,c);
1046
1047   v1 = [ [ cos(psi), -sin(psi) ],    // x
1048          [ sin(psi),  cos(psi) ] ];  // y
1049
1050   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1051
1052   $prp_r1 = prc_r1;
1053   $prp_r11 = prop_main_th/2;
1054
1055   $prpp1 = $prpp7 + [1,0] *
1056     // this is approximate, but will do
1057     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1058   $prpp3 = $prpp1 +
1059     v1[0] * -$prp_r1 +
1060     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1061   $prpp12 = $prpp3 + v1[0] *
1062     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1063   $prp_r8 = prop_main_th;
1064   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1065   $prp_r5 = $prp_r8;
1066   $prpp5 = [ $prpp12[0] - $prp_r5,
1067             $prpp3[1] - prop_prong_h + $prp_r5 ];
1068   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1069          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1070   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1071   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1072
1073   children();
1074 }
1075
1076 module PropProfile(gamma, cut=0, rot=0){
1077   PropProfileAssignments(gamma){
1078
1079     //#circleat($prpp3,1);
1080     //#circleat($prpp12,1);
1081
1082     if (!cut) {
1083       hull(){
1084         translate($prpp8)
1085           intersection(){
1086             circle($prp_r8);
1087             polygon([[-20,-0], [20,20], [0,0]]);
1088           }
1089         rectfromto($prpp6, $prpp9);
1090         translate($prpp5) intersection(){
1091           circle($prp_r5);
1092           polygon([[-10,-10], [0,0], [10,0]]);
1093         }
1094         rectfromto($prpp12 + [0,-0.1], $prpp3);
1095       }
1096       hull(){
1097         circleat($prpp1, $prp_r1);
1098         rectfromto($prpp12 + [0,-0.1], $prpp3);
1099       }
1100     }
1101     // main shaft
1102     rotate([0,0, rot*-$prp_theta]){
1103       hull(){
1104         extra = cut ? prop_recess_slop : 0;
1105         rectfromto($prpp6, $prpp9);
1106         circleat($prpp11, $prp_r11 + extra);
1107         circleat($prpp10, $prp_r10 + extra);
1108       }
1109     }
1110   }
1111 }
1112
1113 module PropAggregateProfile(){
1114   for (angle = prop_angles)
1115     PropProfile(angle, 0,0);
1116 }
1117
1118 module Prop(){ ////toplevel
1119   hw = prop_main_width/2;
1120   linextr(-hw, +hw)
1121     PropAggregateProfile();
1122 }
1123
1124 module Case(){ ////toplevel
1125   difference(){
1126     union(){
1127       CaseBase();
1128
1129       // ledge (fixed keeper)
1130       Flip_rhs(1-keeper_side) intersection(){
1131         rotate([90, 0, 0])
1132           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1133           KeeperProfile(1);
1134
1135         // outline of the whole case, to stop it protruding
1136         translate([0,0, -25])
1137           linear_extrude(height = 50)
1138           hull()
1139           Flip_bot()
1140           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1141       }
1142
1143       // hinge
1144       HingePortion(hex20, hex21) HingeBaseProfile();
1145
1146       // buildout for prop recess
1147       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1148         linextr(case_bottom_z, epp2i[1])
1149         hull() {
1150           for (dxs = [-1,+1])
1151             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1152                        -epp2o[0] ],
1153                      r = epp2o[0] - prcp2[0]);
1154         }
1155     }
1156
1157     // slot for keeper
1158     Flip_rhs(keeper_side)
1159       translate([0, -phone_cnr_rad, 0])
1160       rotate([90, 0, 0])
1161       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1162       minkowski(){
1163         KeeperProfile();
1164         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1165                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1166       }
1167
1168     // front camera
1169     RearCameraAperture();
1170
1171     // struts (invisible, because they're buried in the case)
1172     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1173
1174     Buttons(){
1175       mirror([1,0,0])
1176         rotate([90,0,90]) {
1177           if (!($button_leg_only && enable_support))
1178           intersection(){
1179             translate([0,0,-10])
1180               linear_extrude(height= 20)
1181               ButtonPlan($button_l, 0,1);
1182             if ($button_leg_only)
1183               rotate([-90,90,0])
1184                 translate([phone_width/2, -400, kppe[1]])
1185                 mirror([1-abs($rhsflip - keeper_side),0,0])
1186                 cube([400, 800, 50]);
1187             if (enable_support && !$button_suppress_over_keeper)
1188               rotate([-90,90,0])
1189               translate([-400, -400, kppd[1]])
1190                 mirror([0,0,1])
1191                 cube([800,800,100]);
1192           }
1193           translate([0,0, -bppR[0]])
1194             linear_extrude(height= 20)
1195             ButtonPlan($button_l, 1,1);
1196         }
1197
1198     }
1199
1200     // apertures along top edge
1201     if (!$suppress_forward_holes) {
1202       // CaseAperture(jack_pos, jack_dia, 8);
1203       Flip_rhs(1)
1204         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1205       CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1206     }
1207
1208     OrdinaryBottomEdgeApertures();
1209
1210     OrdinaryRearApertures();
1211     NotInTestFrameRearApertures();
1212
1213     MicroUSBEtc();
1214
1215     // gaps for the lid's hinge arms
1216     HingePortion(hex20 - hinge_x_arms_gap,
1217                  hex21 + hinge_x_arms_gap)
1218       minkowski(){
1219         HingeLidProfile();
1220         circle(r= hinge_r_arms_gap, $fn= 8);
1221       }
1222
1223     // screw holes in the hinge arms
1224     HingeScrews();
1225
1226     // thumb recess
1227     ThumbRecessApply(epp4[1])
1228       ThumbRecessCutProfile();
1229
1230     // lanyard
1231     Flip_bot(1)
1232       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1233       rotate([0, ly_theta, 0])
1234       rotate([0,0,90])
1235       LanyardCutout(lanyard_channel_len);
1236
1237     // prop recess
1238     Flip_rhs(1)
1239       translate([prop_x_pos,0,0])
1240       mirror([0,1,0])
1241       rotate([90,0,90])
1242       linextr(-prop_recess_hw, +prop_recess_hw)
1243       hull(){
1244         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1245           circleat(prcp1 + 20*d,
1246                    prc_r3);
1247       }
1248   }
1249 }
1250
1251 module LidAdhocMultiprintFrame(phase){
1252   if (led_window_style >= 3) {
1253     AdhocMultiprintFrame(phase, lpp13[1], -1);
1254   }
1255 }
1256
1257 module LidAroundEdges(){
1258   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1259     children();
1260 }
1261
1262 module Lid(){ ////toplevel
1263   skew_centre = [0, lpp11[0], lpp11[1]];
1264   difference(){
1265     union(){
1266       intersection(){
1267         LidAroundEdges()
1268           LidEdgeProfile();
1269
1270         translate(skew_centre)
1271           multmatrix([[ 1, 0, 0, 0 ],
1272                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1273                       [ 0, 0, 1, 0 ],
1274                       [ 0, 0, 0, 1 ]])
1275           translate(-skew_centre)
1276           LidAroundEdges()
1277           LidEdgeFoldClearanceProfile();
1278       }
1279
1280       // button covers
1281       Buttons(){
1282         intersection(){
1283           rotate([90,0,90])
1284             translate([0,0,-10])
1285             linear_extrude(height= 20)
1286             ButtonPlan($button_l, 1,0);
1287           union(){
1288             rotate([90,0,0])
1289               translate([0,0,-100])
1290               linear_extrude(height= 200)
1291               ButtonCoverProfile();
1292             hull()
1293               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1294                                  - lid_buttoncover_reinf))
1295                 translate([0,y,0])
1296                   ButtonCoverReinf();
1297           }
1298         }
1299       }
1300
1301       // hinge arms
1302       HingePortion(hex20, hex21) {
1303         LidEdgeProfile();
1304         HingeLidProfile();
1305       }
1306     }
1307     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1308
1309     // screw holes in the hinge arms
1310     HingeScrews();
1311
1312     // prop recess
1313     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1314       mirror([0,1,0])
1315       rotate([90,0,90])
1316       linextr(-prop_recess_hw, +prop_recess_hw)
1317       hull()
1318       for (pa = prop_angles)
1319         PropProfile(pa, 1,1);
1320
1321     // notification led aperture
1322     if (led_window_style)
1323       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1324         translate([0,0,-10])
1325           cylinder(r=nla_r0, h=20);
1326         if (led_window_style >= 2)
1327           translate([0,0, -nla_t])
1328             cylinder(r=nla_r2, height=20);
1329       }
1330
1331     }
1332
1333   LidAdhocMultiprintFrame(1);
1334 }
1335
1336 module HingeLever(){ ////toplevel
1337   difference() {
1338     // outer body, positive
1339     HingePortion(hex22, hex22 + phone_width/2)
1340       HingeLeverOuterProfile();
1341
1342     // space for the screws
1343     HingePortion(hex26, hex24)
1344       HingeLeverInnerProfile();
1345
1346     // recesses for the nuts
1347     HingePortion(hex23, hex26+1)
1348       HingeLeverNutProfile();
1349
1350     // bores for the screws
1351     HingeScrews();
1352
1353     // space for the charging cable and speaker and micc apertures
1354     hull() {
1355       for (x = [-1,+1]) {
1356         multmatrix([[ 1,0,
1357
1358                      x
1359                      * ( (hex24 + hinge_over_nut_plate) -
1360                          (phone_width/2 - microusb_width/2)
1361                         )
1362                      / ( (epp0[1] - microusb_above)
1363                          -
1364                          (hppB[1] - hp_r2) ),
1365
1366                      x * (epp0[1] - microusb_above)
1367
1368                       ],
1369                     [ 0,1,0, 0 ],
1370                     [ 0,0,1, 0 ]]) {
1371           union(){
1372             MicroUSBEtc();
1373             Flip_hinge() MicroUSBEtc();
1374           }
1375         }
1376       }
1377     }
1378   }
1379 }
1380
1381 module LidWindow(){ ////toplevel
1382   translate([led_pos[0], -led_pos[1], lpp13[1]])
1383     mirror([0,0,1])
1384     cylinder(r= nla_r1, h=nla_t);
1385   LidAdhocMultiprintFrame(0);
1386 }
1387
1388 module LidWindowPrint(){ ////toplevel
1389   rotate([0,180,0])
1390     LidWindow();
1391 }
1392
1393 module DemoLidWindowSelect(){
1394   translate([led_pos[0], led_pos[1], -100]) {
1395     translate([0, -30, 0]) cube([400, 400, 200]);
1396   }
1397 }
1398
1399 module DemoLidWindow(){ ////toplevel
1400   %Lid();
1401   LidWindow();
1402   translate([0,40,0]){
1403     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1404     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1405   }
1406 }
1407
1408 module HingeLeverPrint(){ ////toplevel
1409   rotate([-90,0,0])
1410     translate([-phone_width/2, phone_height, 0])
1411     HingeLever();
1412 }
1413
1414 module TestSelectLength(){
1415   translate([-30, -200, -20])
1416     cube([30 + 15, 250, 40]);
1417 }
1418
1419 module TestLength(){ ////toplevel
1420   intersection(){
1421     Case();
1422     TestSelectLength();
1423   }
1424 }
1425
1426 module TestLengthRight(){ ////toplevel
1427   intersection(){
1428     Case();
1429     Flip_rhs(1)
1430       TestSelectLength();
1431   }
1432 }
1433
1434 module TestSelectWidth(){
1435   translate([-30, -(phone_height - 25), -20])
1436     mirror([0, 1, 0])
1437     cube([200, 50, 40]);
1438 }
1439
1440 module TestWidth(){ ////toplevel
1441   intersection(){
1442     Case();
1443     TestSelectWidth();
1444   }
1445 }
1446
1447 module TestLidWidthPrint(){ ////toplevel
1448   rotate([0,180.0]) intersection(){
1449     Lid();
1450     TestSelectWidth();
1451   }
1452 }
1453
1454 module TestSelectRearAperture(){
1455   minkowski(){
1456     union() children();
1457     translate([20, 0,0])
1458       cube([42, 2, 1], center=true);
1459   }
1460 }
1461
1462 module TestSelectCamera(){
1463   minkowski(){
1464     TestSelectRearAperture()
1465       RearCameraAperture();
1466     cube([0.1, 50, 0.1]);
1467   }
1468 }
1469
1470 module TestSelectOrdinaryRearApertures(){
1471   TestSelectRearAperture()
1472     OrdinaryRearApertures();
1473 }
1474
1475 module TestCamera(){ ////toplevel
1476   intersection(){
1477     Case();
1478     TestSelectCamera();
1479   }
1480 }
1481
1482 module TestLidByCamera(){ ////toplevel
1483   intersection(){
1484     Lid();
1485     TestSelectCamera();
1486   }
1487 }
1488
1489 module TestLidByCameraPrint(){ ////toplevel
1490   rotate([180,0,0]) TestLidByCamera();
1491 }
1492
1493 module DemoByCamera(){ ////toplevel
1494   color("blue") TestLidByCamera();
1495   color("red")  TestCamera();
1496 }
1497
1498 module OneKeeper(){ ////toplevel
1499   translate([0, -phone_cnr_rad, 0])
1500     rotate([90, 0, 0])
1501     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1502     KeeperProfile();
1503 }
1504
1505 module OneKeeperPrint(){ ////toplevel
1506   rotate([0,180,0])
1507     OneKeeper();
1508 }
1509
1510 module LidPrint(){ ////toplevel
1511   rotate([0,180,0])
1512     Lid();
1513 }
1514
1515 module TestSelectFrame(){
1516   include = [1,-1] * (epp2i[0] + 4);
1517
1518   difference(){
1519     cube(1000, center=true);
1520     translate([0,0, -100])
1521       linear_extrude(height=200)
1522       rectfromto(include,  inside_br - include);
1523   }
1524 }
1525
1526 module TestSelectLidFrame(){
1527   TestSelectFrame();
1528   if (len(led_pos))
1529     translate([led_pos[0], -led_pos[1], -50])
1530     cylinder(r= nla_r2+3, h=100);
1531 }
1532
1533 module TestFrameCase(){ ////toplevel
1534   intersection(){
1535     Case();
1536     union(){
1537       TestSelectFrame();
1538       TestSelectCamera();
1539       TestSelectOrdinaryRearApertures();
1540     }
1541   }
1542 }
1543
1544 module TestSelectTopApertures(){
1545   translate([-100, -35, -100])
1546     cube([400, 100, 200]);
1547   LidAdhocMultiprintFrame(0);
1548   LidAdhocMultiprintFrame(1);
1549 }
1550
1551 module TestTopApertures(){ ////toplevel
1552   intersection(){
1553     Case();
1554     TestSelectFrame();
1555     TestSelectTopApertures();
1556   }
1557 }
1558
1559 module TestLidTopAperturesPrint(){ ////toplevel
1560   rotate([0,180,0]) intersection(){
1561     Lid();
1562     TestSelectLidFrame();
1563     TestSelectTopApertures();
1564   }
1565 }
1566
1567 module TestLidWindowTopAperturesPrint(){ ////toplevel
1568   rotate([0,180,0]) intersection(){
1569     LidWindow();
1570     TestSelectTopApertures();
1571   }
1572 }
1573
1574 module TestFrameLidPrint(){ ////toplevel
1575   rotate([0,180,0]) intersection(){
1576     Lid();
1577     TestSelectLidFrame();
1578   }
1579 }
1580
1581 module ButtonPlanForDemo(z, deep, cut){
1582   translate([0,0,z])
1583     ButtonPlan(8, deep, cut);
1584 }
1585
1586 module HingeScrews(){
1587   Flip_rhs() Flip_bot(1){
1588     for (c= [ hppT, hppB ])
1589       translate([ hex20,
1590                   -c[0],
1591                   c[1] ]){
1592         rotate([0,90,0])
1593           translate([0,0,-.2])
1594           cylinder( r= hingescrew_shaft_dia/2,
1595                     h = hingescrew_shaft_len+0.2 );
1596         rotate([0,-90,0])
1597           translate([0,0,+.1])
1598           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1599       }
1600   }
1601 }
1602
1603 module DemoPropAngleSelect(c){
1604   color(c) difference(){
1605     union(){ children(); }
1606     translate([ prop_x_pos, -400, -200 ])
1607       cube([ 400,800,400 ]);
1608   }
1609 }
1610
1611 module DemoPropAngle(ang){
1612   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1613   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1614
1615   translate(hL)
1616     rotate([ang/2,0,0])
1617     translate(-hL)
1618     translate(hC)
1619     rotate([ang/2,0,0])
1620     translate(-hC) {
1621       DemoPropAngleSelect("red") Case();
1622
1623       color("orange")
1624         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1625         PropProfileAssignments(ang) {
1626           echo($prpp1);
1627           rotate([-$prp_theta, 0, 0])
1628           translate([0, $prpp1[0], -$prpp1[1]])
1629           rotate([90,0,-90])
1630           Prop();
1631         }
1632     }
1633
1634   translate([0,0, -hp_k*2])
1635     DemoPropAngleSelect("blue")
1636     Lid();
1637 }
1638
1639 module DemoPropAngles(){ ////toplevel
1640   for (i=[0 : len(prop_angles)-1])
1641     translate(i * [0, -100, 100])
1642     DemoPropAngle(prop_angles[i]);
1643 }
1644
1645 module DemoHingeAngle(ang1,ang2){
1646   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1647   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1648
1649   translate(hL)
1650     rotate([ang2,0,0])
1651     translate(-hL)
1652     translate(hC)
1653     rotate([ang1,0,0])
1654     translate(-hC) {
1655       color("red") Lid();
1656     }
1657
1658   color("blue") intersection(){
1659     Case();
1660     union(){
1661       translate([bppJ[0], -400, -200])
1662         mirror([1,0,0])
1663         cube([400, 800, 400]);
1664       translate([10, -400, -200])
1665         cube([10, 800, 400]);
1666     }
1667   }
1668 }
1669
1670 module DemoHingeAngles(){ ////toplevel
1671   angles = [ 0, 4, 8, 12 ];
1672   echo("angles",angles);
1673   for (i=[0 : len(angles)-1]) {
1674     translate(i * [0, 0, 30]) {
1675       DemoHingeAngle(0,angles[i]);
1676       translate([0, 200, 0])
1677         DemoHingeAngle(angles[i],0);
1678     }
1679   }
1680 }
1681
1682 module DemoSelectAdhocLeftRight(right=0) {
1683   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1684     mirror([1-right, 0,0])
1685     cube([400, 800, 200]);
1686 }
1687
1688 module DemoLeft(){ ////toplevel
1689   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1690   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1691 }
1692
1693 module DemoFrame(){ ////toplevel
1694   color("red") render() TestFrameCase();
1695   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1696   color("black") render() HingeScrews();
1697   %render() HingeLever();
1698 }
1699
1700 module DemoLanyardCutout(){ ////toplevel
1701   LanyardCutout(25);
1702 }
1703
1704 module DemoHingedFrame(){ ///toplevel
1705   color("red") render() TestFrameCase();
1706   translate([0,0, -2*hp_k])
1707   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1708
1709   Flip_hinge(){
1710     color("orange") render() HingeLever();
1711     color("black") render() HingeScrews();
1712   }
1713 }
1714
1715 module DemoHinge(){ ////toplevel
1716   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1717     DemoFrame();
1718     translate([0,0, -hp_k*3])
1719       DemoHingedFrame();
1720   }
1721 }
1722
1723 module DemoProfiles(){ ////toplevel
1724   LidEdgeProfile();
1725   %EdgeProfile();
1726   KeeperProfile();
1727   translate([0,0,-1]) color("black") KeeperProfile(1);
1728   translate(ly_o){
1729     rotate(-ly_theta){
1730       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1731       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1732       translate([0, ly_q_z]){
1733         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1734         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1735       }
1736     }
1737   }
1738   translate([0,0,-5]) color("white") translate(epp2i)
1739     rotate(-ly_theta)
1740     rectfromto([-15, 0],
1741                [+15, -max_case_bottom_edge_thickness]);
1742
1743   translate([0,20]) {
1744     LanyardMainChannelProfile();
1745     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1746     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1747   }
1748
1749   translate([20,0]) {
1750     LidEdgeProfile();
1751     %EdgeProfile();
1752
1753     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1754
1755     color("blue") ButtonCoverProfile();
1756     color("red") {
1757       rectfromto(bppQ, demopoint_QR);
1758       rectfromto(bppR, demopoint_QR);
1759     }
1760   }
1761
1762   translate([-20,0]) {
1763     color("black") ButtonPlanForDemo(-2, 0,1);
1764     color("red" )  ButtonPlanForDemo(-4, 1,1);
1765     color("blue")  ButtonPlanForDemo(-6, 1,0);
1766   }
1767
1768   translate([0, -30]) {
1769     %LidEdgeProfile();
1770     %EdgeProfile();
1771     color("blue") HingeLidProfile();
1772     color("red")  HingeBaseProfile();
1773     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1774   }
1775
1776   for (f=[0,1]) {
1777     translate([-30, -60 + 30*f]) {
1778       translate([0,0,-4]) EdgeProfile();
1779       %translate([0,0,-10]) HingeBaseProfile();
1780       translate([0,-2] * f * hp_k) {
1781         translate([0,0,-4]) LidEdgeProfile();
1782         %translate([0,0,-10]) %HingeLidProfile();
1783       }
1784       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1785         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1786         translate([0,0,0]) color("red") difference(){
1787           HingeLeverOuterProfile();
1788           HingeLeverInnerProfile();
1789         }
1790         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1791       }
1792     }
1793   }
1794
1795   translate([20,-30]) {
1796     %EdgeProfile();
1797     %LidEdgeProfile();
1798     //translate([0,0,1]) ThumbRecessCutProfile();
1799     translate([0,0,+1]) color("red")
1800       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1801   }
1802
1803   translate([40,-30]) {
1804     difference(){
1805       LidEdgeProfile();
1806       translate(prlp10)
1807         PropProfile(10, 1, 0);
1808     }
1809     translate(prlp10)
1810       PropProfile(15, 0);
1811   }
1812   translate([60,-30]) {
1813     PropAggregateProfile();
1814   }
1815 }
1816
1817 //EdgeProfile();
1818 //KeeperProfile();
1819 //CaseBase();
1820 //%Case();
1821 //Keeper();
1822 //LidEdgeProfile();
1823 //KeeperProfile();
1824 //DemoProfiles();
1825 //PropRecess();