fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 168.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 7.37 /* xxx? */ ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 // fingerpushhole_dias = []; xxx what was this
 169 fingerpushhole_dias = [ 15, 18 ];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 1.64 - 0.25;
 178 microusb_below = 2.42;
 179 microusb_width = 12.16 + 2.0 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 // xxx there isn't one of these, speaker is by hinge
 254 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 255
 256 thumbrecess_depth = 1.3;
 257 thumbrecess_width = 16.5;
 258 thumbrecess_topcurve_r = 5.0;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 lid_fold_clearance_antislop = 0.5;
 274
 275 $button_leg_only = false;
 276 $suppress_forward_holes = false;
 277
 278 // ---------- calculated ----------
 279
 280 phone_total_thick = phone_edge_thick;
 281
 282 phone_width =  (phone + bumper*2)[0];
 283 phone_height = (phone + bumper*2)[1];
 284
 285 inside_br = [phone_width, -phone_height];
 286
 287 prop_prong_h = prop_main_th;
 288
 289 //echo(camera_pos_tl + bumper,
 290 //     camera_pos_br + bumper);
 291
 292 // ----- could be changed -----
 293 lid_buttoncover_gap = lid_gap_x;
 294 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 295
 296 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 297
 298 //prop_nose_len = case_th_lid - prop_recess_under;
 299 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 300 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 301
 302
 303 //lid_lip_overlap_width xxx bad name = ;
 304 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 305
 306 epp0 = [0,0];
 307 epp1 = [0, -phone_edge_thick];
 308 epp2i = epp1; // conflated for FP4
 309 epp2o = epp2i;
 310 epp3 = epp2i + [10, 0];
 311 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 312 epp4 = epp5 + [-1,0] * case_th_side;
 313
 314 kppe = [0,0];
 315 kppd = kppe + [1,0] * keeper_inner_width;
 316 kppc = kppd + [0,1] * keeper_th_z;
 317 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 318 kppf = kppe - [0,1] * keeper_inner_height;
 319 kppa = [ kppb[0], kppf[1] ];
 320
 321 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 322 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 323
 324 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 325 // exact x posn not very important; must extend past end of keeper
 326
 327 lpp15 = [ lpp14[0],
 328           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 329           + lid_screen_gap_extra ];
 330 // ^ beam theory says to maximise force before contact,
 331 //   the gap below the `beam' (the lid) must be 1/3
 332 //   the thickness (ie the lid thickness) if the beam
 333 //   is solid, or 1/2 if it has a top and bottom only.
 334 //   ours is mostly solid.
 335
 336 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 337              case_th_lip);
 338
 339 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 340 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 341
 342 case_bottom_z = epp2o[1] - case_th_bottom;
 343
 344 // button profile
 345 bppM = epp4 + [0,5];
 346 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 347 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 348 bppS = [ epp1[0], bppR[1] ];
 349 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 350 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 351 bppO = [ bppN[0], bppP[1] ];
 352 bppL = lpp10 + [5,0];
 353 bppK = [ bppL[0], bppN[1] ];
 354 bppJ = [ bppN[0], bppL[1] ];
 355 bppU = [ bppJ[0], lpp12[1] ];
 356 bppV = lpp11;
 357 bppW = lpp10;
 358
 359 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 360
 361 // notification led aperture
 362
 363 nla_r0 = led_aperture/2;
 364 nla_r1 = nla_r0 + led_window_ledge;
 365 nla_r2 = nla_r1 + multicolour_gap;
 366 nla_t =
 367   led_window_style >= 3 ? initial_layer_thick :
 368   led_window_style >= 2 ? led_window_ledge : 0;
 369
 370
 371 // hinge plan
 372 hp_rn = hingescrew_nut_access_dia/2;
 373 hp_r2_min = hp_rn + lever_cover_th;
 374 hp_rs = hingescrew_shaft_dia/2;
 375 hp_r1_min = hp_rs + hingemount_th;
 376
 377 hp_r1 = max(hp_r1_min, hp_r2_min);
 378 hp_r2 = hp_r1;
 379
 380 hppU = lpp13;
 381 hppS = epp2o + [0,-1] * case_th_bottom;
 382 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 383
 384 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 385          0.5 * (hppU + hppS)[1] ];
 386 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 387 hppB = hppT + [0,-1] * hp_k;
 388
 389 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 390 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 391 hppE = [ hppE_x, hppE_y ];
 392
 393 // hinge elevation x coords
 394
 395 hex20 = max(epp2o[0],
 396             phone_cnr_rad,
 397             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 398 hex21 = hex20 + hingemount_wd;
 399 hex22 = hex21 + hinge_x_gap;
 400 hex27 = hex20 + hingescrew_shaft_len;
 401 hex24 = hex27 + hinge_x_postscrew_gap;
 402 hex23 = hex27 - (hingescrew_nut_thick*2
 403                  + hingescrew_fasteners_extra_thick);
 404 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 405
 406 echo(hex20, hex21, hex22, hex23, hex24);
 407 //  6, 10.8725, 10.9975, 13.74, 18.75
 408 module chk(act,exp) {
 409   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 410   else echo("ok", act);
 411 }
 412 chk(hex20, 6);
 413 chk(hex21, 10.8725);
 414 chk(hex22, 10.9975);
 415 chk(hex23, 13.74);
 416 chk(hex24, 18.75);
 417
 418 lid_fold_clearance_skew =
 419   (lpp10[1] - hppB[1]) /
 420   (lpp10[0] - hppB[0]);
 421
 422 echo("SK",lid_fold_clearance_skew);
 423
 424 // thumb recess (used to be "catch" hence cpp*
 425
 426 cppA = epp4 + [thumbrecess_depth, 0];
 427 cppB = [ cppA[0], epp1[1] ];
 428
 429 // lanyard
 430
 431 ly_r = lanyard_half_dia / 2;
 432 ly_rc = ly_r * 2;
 433
 434 ly_theta = 90;
 435 ly_o = epp2i + 3 * ly_r * [0,1];
 436
 437 max_case_bottom_edge_thickness =
 438   case_th_bottom;
 439
 440 ly_q_z = -(ly_rc + ly_r);
 441 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 442
 443 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 444
 445 // prop recess in case
 446
 447 prop_x_pos = phone_width/2;
 448
 449 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 450
 451 prc_r1 = prop_end_dia/2;
 452 prc_r3 = prc_r1 + prop_recess_slop;
 453
 454 prcp2 = [ epp4[0] + prop_buildout_less,
 455           case_bottom_z ];
 456
 457 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 458
 459 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 460           epp2i[1] - prc_r3 - prop_recess_under];
 461
 462 // prop recess in lid
 463
 464 prl_r10 = prop_end_dia/2;
 465 prl_r10o = prl_r10 + prop_recess_slop;
 466
 467 prlp10 = lpp10 + [1,1] * prl_r10o
 468   + [1,0] * prop_lidrecess_behind
 469   + [0,1] * prop_recess_under;
 470
 471 // prop
 472
 473 $prpp10 = [0,0];
 474 $prpp11 = [0, prop_taper_len];
 475
 476 $prp_r10 = prl_r10;
 477
 478 // ---------- modules ----------
 479
 480 module AdhocMultiprintFrame(phase, z0, zs) {
 481   // from z0 to z0 + zs*layer
 482   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 483   xextra = extra + -epp4[0];
 484   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 485   yextra = extra + -epp4[0];
 486   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 487   p0 = [ xrange[0], yrange[0] ];
 488   p1 = [ xrange[1], yrange[1] ];
 489   echo(p0, p1);
 490   translate([0,0, z0])
 491     mirror([0,0, zs<0 ? 1 : 0])
 492     linear_extrude(height= initial_layer_thick)
 493     difference(){
 494       rectfromto(p0 - [1,1] * initial_layer_width,
 495                  p1 + [1,1] * initial_layer_width);
 496       rectfromto(p0, p1);
 497     }
 498 }
 499
 500 module KeeperProfile(slant=0){
 501   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 502   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 503 }
 504
 505 module EdgeProfile(){
 506   difference(){
 507     hull(){
 508       translate(epp3) square(case_th_bottom*2, center=true);
 509       circleat(epp2o, r=case_th_bottom);
 510       circleat(epp1, r=case_th_side);
 511       rectfromto(epp0, epp4);
 512     }
 513     polygon([ epp5 + [0,10],
 514               epp1,
 515               epp3 + [10,0] ]);
 516   }
 517 }
 518
 519 module LanyardLanyardProfile(entry=false){
 520   hull(){
 521     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 522       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 523         circle(r= lanyard_half_dia/2);
 524   }
 525 }
 526
 527 module LanyardCurveChannelProfile(){
 528   translate([0, -ly_r])
 529     LanyardLanyardProfile();
 530 }
 531
 532 module LanyardEntryChannelProfile(){
 533   LanyardLanyardProfile(true);
 534 }
 535
 536 module LanyardMainChannelProfile(){
 537   LanyardCurveChannelProfile();
 538   difference(){
 539     square(center=true, ly_r * [6, 2]);
 540     for (xs=[-1,+1])
 541       translate(ly_r * [3 * xs, -1])
 542         circle(r = ly_r);
 543   }
 544 }
 545
 546 module LanyardEntryOuterProfile(){
 547   circleat([ly_re + ly_r, 0], ly_re);
 548 }
 549
 550 module LanyardEntry(){
 551   q_z = ly_q_z;
 552   oec_y = ly_oec_y;
 553
 554   d_x = -ly_rc;
 555
 556   translate([d_x, 0, q_z]) {
 557     intersection(){
 558       rotate([90,0,0])
 559         rotate_extrude(convexity=10)
 560         rotate(90)
 561         translate([0, -q_z])
 562         LanyardCurveChannelProfile();
 563       translate([0,-10,0])
 564         cube([20,20,20]);
 565     }
 566   }
 567
 568   mirror([0,0,1])
 569     translate([0,0,-1])
 570     linear_extrude(height=20)
 571     rotate(-90)
 572     LanyardEntryChannelProfile();
 573
 574   translate([0, ly_r*2, 0])
 575     rotate([90,0,0])
 576     linear_extrude(height = ly_r*4){
 577     difference(){
 578       rectfromto([d_x, q_z], [ly_r, 0]);
 579       circleat([d_x, q_z], ly_rc);
 580     }
 581   }
 582
 583   translate([0,0,q_z]){
 584     for (my=[0,1])
 585       mirror([0,my,0]){
 586         translate([0, oec_y, 0]){
 587           difference(){
 588             translate(ly_re * [-1,0,-2])
 589               cube(ly_re * [2,1,2]);
 590             rotate_extrude(convexity=10)
 591               LanyardEntryOuterProfile();
 592           }
 593         }
 594       }
 595     difference(){
 596       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 597         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 598       for (mx=[0,1])
 599         mirror([mx,0,0])
 600           rotate([90,0,0])
 601           translate([0,0,-10])
 602           linear_extrude(height=20)
 603           LanyardEntryOuterProfile();
 604     }
 605   }
 606 }
 607
 608 module LanyardCutout(l){
 609   rotate([0,-90,0])
 610     linear_extrude(height=l)
 611     rotate(-90)
 612     LanyardMainChannelProfile();
 613
 614   for (ee=[0,1]){
 615     translate(ee * l * [-1,0])
 616       mirror([ee,0,0])
 617       LanyardEntry();
 618   }
 619 }
 620
 621 module LidEdgeProfile(){
 622   polygon([ lpp10,
 623             lpp11,
 624             lpp12,
 625             lpp13,
 626             lpp13 + [10, 0],
 627             lpp15 + [10, 0],
 628             lpp15,
 629             lpp14,
 630             ]);
 631   intersection(){
 632     circleat(lpp12, r=lp_r12);
 633     rectfromto( lpp12 + [-10,   0],
 634                 lpp12 + [+10, +10] );
 635   }
 636 }
 637
 638 module LidEdgeFoldClearanceProfile(){
 639   translate([-lid_fold_clearance_antislop, 0])
 640     polygon([ lpp10,
 641               lpp11,
 642               lpp11 + [-20,  0],
 643               lpp11 + [-20, 20],
 644               lpp11 + [+20, 20],
 645               lpp10 + [+20,  0] ]);
 646 }
 647
 648 module ButtonCoverProfile(){
 649   intersection(){
 650     polygon(concat([ bppM, bppP, bppO, bppJ ],
 651                    (enable_support && !$button_suppress_over_keeper
 652                     ? [ bppU, bppV, bppW ] : []),
 653                    [ bppL, bppK ]));
 654     hull(){
 655       EdgeProfile();
 656       LidEdgeProfile();
 657     }
 658   }
 659 }
 660
 661 module ButtonPlan(l, deep, cut){
 662   epsilon =
 663     (cut  ? 0 : lid_buttoncover_gap);
 664
 665   delta =
 666     (deep ? lid_buttoncover_overlap : 0);
 667
 668   C = [0,0]; // by definition
 669   T = [ 0, epp4[1] ];
 670   G = T + [0,10];
 671
 672   B0 = C + [0,-1] * button_cutout_depth;
 673   B1 = B0 + [0,1] * epsilon;
 674
 675   r0 = 0.5 * (T[1] - B0[1]);
 676   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 677   H = A + [0,-1] * delta;
 678
 679   D = A + [-2,0] * r0;
 680   F = D + [0,10];
 681
 682   E0 = 0.5 * (D + A);
 683   E1 = E0 + [1,0] * epsilon;
 684
 685   I0 = [ E0[0], H[1] ];
 686   I1 = [ E1[0], H[1] ];
 687
 688   hull(){
 689     for (m=[0,1]) mirror([m,0])
 690       circleat(H, r0 - epsilon);
 691   }
 692   for (m=[0,1]) mirror([m,0]) {
 693     difference(){
 694       polygon([ E1,
 695                 I1,
 696                 H,
 697                 B1,
 698                 G,
 699                 F,
 700                 D
 701                 ]);
 702       circleat(D, r0 + epsilon);
 703     }
 704   }
 705 }
 706
 707 module ButtonCoverReinf(){ ////toplevel
 708   minkowski(){
 709     rotate([90,0,0])
 710       linear_extrude(height=0.01)
 711       intersection(){
 712         ButtonCoverProfile();
 713         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 714           square([100,100]);
 715     }
 716     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 717       circle(r= lid_buttoncover_reinf);
 718       translate([-20,0]) square(40, center=true);
 719     }
 720   }
 721 }
 722
 723 module ThumbRecessCutProfile(){
 724   difference(){
 725     polygon([ cppA + [-10,0],
 726               cppB + [-10,0],
 727               cppB,
 728               cppA ]);
 729     circleat(epp1, r=case_th_side);
 730   }
 731 }
 732
 733 module Flip_rhs(yn=[0,1]) {
 734   for ($rhsflip=yn) {
 735     translate([phone_width/2, 0, 0])
 736       mirror([$rhsflip,0,0])
 737       translate([-phone_width/2, 0, 0])
 738       children();
 739   }
 740 }
 741
 742 module Flip_bot(yn=[0,1]) {
 743   for ($botflip=yn) {
 744     translate([0, -phone_height/2, 0])
 745       mirror([0, $botflip, 0])
 746       translate([0, phone_height/2, 0])
 747       children();
 748   }
 749 }
 750
 751 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 752   // sides
 753   Flip_rhs(){
 754     translate([0, -phone_cnr_rad, 0])
 755       rotate([90,0,0])
 756       linear_extrude(height = phone_height - phone_cnr_rad*2)
 757       children(0);
 758   }
 759   // corners
 760   Flip_rhs() Flip_bot() {
 761     translate([+1,-1] * phone_cnr_rad)
 762       intersection(){
 763         rotate_extrude()
 764           intersection(){
 765             mirror([1,0,0])
 766               translate([-1,0] * phone_cnr_rad)
 767               children(0);
 768             rectfromto([0,-20],[10,20]);
 769           }
 770         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 771           cube([10,10,40]);
 772       }
 773   }
 774   // top and bottom
 775   Flip_bot(){
 776     translate([ phone_width - phone_cnr_rad, 0,0 ])
 777       rotate([90,0,-90])
 778       linear_extrude(height = phone_width - phone_cnr_rad*2)
 779       children(0);
 780   }
 781   // fill
 782   translate([0,0, fill_zstart])
 783     mirror([0,0, fill_downwards])
 784     linear_extrude(height = fill_th)
 785     rectfromto([+1,-1] * phone_cnr_rad,
 786                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 787 }
 788
 789 module CaseAperture(pos, dia, $fn) {
 790   theta = 180/$fn;
 791   translate([ pos[0] + bumper[0],
 792               -epp2i[0],
 793               -pos[1] ])
 794     rotate([-90, theta, 0])
 795     cylinder(r = dia/2 / cos(theta),
 796              h = 60);
 797 }
 798
 799 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 800   // y_ref_sign:
 801   //   +1  measured from top    of actual phone to top    of button
 802   //   -1  measured from bottom of actual phone to bottom of button
 803   //    0  y is centre of button in coordinate system
 804   $button_l= l;
 805   $button_suppress_over_keeper= suppress_over_keeper;
 806   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 807           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 808           y;
 809   //echo(eff_y);
 810   translate([0, eff_y, 0])
 811     children();
 812 }
 813
 814 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 815   $button_leg_only = true;
 816   SideButton(y, y_ref_sign, l) children();
 817 }
 818
 819 module Buttons(){
 820   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 821   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 822   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 823   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 824 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 825 }
 826
 827 module Struts(x_start, z_min, th){
 828   // if th is negative, starts at z_min and works towards -ve z
 829   // and object should then be printed other way up
 830   for (i= [1 : 1 : case_struts_count]) {
 831     translate([0,
 832                0,
 833                z_min])
 834       mirror([0,0, th<0 ? 1 : 0])
 835       translate([0,
 836                  -phone_height * i / (case_struts_count+1),
 837                  case_struts_solid_below])
 838       linear_extrude(height= abs(th)
 839                      -(case_struts_solid_below+case_struts_solid_above))
 840       rectfromto([               x_start, -0.5 * case_struts_width ],
 841                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 842   }
 843 }
 844
 845 module OrdinaryRearAperture(rhs,bot, pos){
 846   Flip_rhs(rhs) Flip_bot(bot)
 847     linextr(-20, 20)
 848     mirror([0,1])
 849     translate(pos + bumper)
 850     children();
 851 }
 852
 853 module MicroUSB(){
 854   Flip_bot(1){
 855     rotate([90,0,0])
 856       mirror([0,0,1])
 857       linextr(-epp2i[0], 60)
 858       translate([0.5 * phone_width, 0, 0])
 859       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 860                  [+microusb_width/2, epp0[1] + -microusb_above]);
 861   }
 862 }
 863
 864 module OrdinaryRearApertures(){
 865   // rear speaker
 866   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 867     rectfromto(-rearspeaker_gap,
 868                rearspeaker_size + rearspeaker_gap);
 869
 870   // finger hole to remove phone
 871   if (len(fingerpushhole_dias))
 872     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 873                                 phone[1]/2 ])
 874     scale(fingerpushhole_dias)
 875     circle(r= 0.5 );
 876 }
 877
 878 module RearCameraAperture(){
 879   Flip_rhs(1)
 880     mirror([0, 0, 1])
 881     linear_extrude(height = 20)
 882     mirror([0, 1, 0])
 883     translate(bumper)
 884     rectfromto(camera_pos_tl, camera_pos_br);
 885 }
 886
 887 module HingeLidProfile(){
 888   hull(){
 889     circleat(hppT, hp_r1);
 890     circleat(lpp12, lp_r12);
 891     polygon([lpp10,
 892              lpp13 + [2,0],
 893              lpp12,
 894              hppT]);
 895   }
 896 }
 897
 898 module HingeBaseProfile(){
 899   difference(){
 900     hull(){
 901       circleat(hppB, hp_r1);
 902       circleat(hppE, hp_r1);
 903       circleat(epp2o, case_th_bottom);
 904       circleat(hppB + [10,0], hp_r1);
 905     }
 906     polygon([epp5, epp1, epp3, bppL]);
 907   }
 908 }
 909
 910 module HingeLeverOuterProfile(){
 911   hull(){
 912     circleat(hppT, hp_r2);
 913     circleat(hppB, hp_r2);
 914   }
 915 }
 916
 917 module HingeLeverInnerProfile(){
 918   for (s = [-1,+1]) {
 919     c = s > 0 ? hppT : hppB;
 920     translate(c)
 921       mirror([0,0,s>0])
 922       rotate(s<0 ? -40 : 0)
 923       hull()
 924       for (x=[-20,20])
 925         for (y=[0, s * 10])
 926           translate([x,y])
 927             circle(hp_rn);
 928   }
 929 }
 930
 931 module HingeLeverNutProfile(){
 932   for (c= [hppB, hppT]) {
 933     translate(c)
 934       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 935   }
 936 }
 937
 938 module Flip_hinge(doflip=1){
 939   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 940   translate(hinge_origin)
 941     rotate([doflip*180,0,0])
 942     translate(-hinge_origin)
 943     children();
 944 }
 945
 946 module HingePortion(x0,x1){
 947   Flip_rhs() Flip_bot(1)
 948     translate([x0,0,0])
 949     mirror([1,0,0])
 950     rotate([90,0,-90])
 951     linear_extrude(height=x1-x0)
 952     children();
 953 }
 954
 955 module ThumbRecessApply(ztop){
 956   width = thumbrecess_width;
 957   w = width + thumbrecess_topcurve_r*2 + 1;
 958   translate([phone_width/2, 0,0]){
 959     difference(){
 960       rotate([90,0,-90])
 961         linextr(-w/2, w/2)
 962         children(0);
 963       translate([0, 50, 0])
 964         rotate([90,0,0])
 965         linear_extrude(height=100){
 966         for (m=[0,1]) mirror([m,0,0]) {
 967           hull(){
 968             translate([w/2, ztop - thumbrecess_topcurve_r])
 969               circle(thumbrecess_topcurve_r);
 970             translate([w/2, -50])
 971               square(thumbrecess_topcurve_r*2, center=true);
 972           }
 973         }
 974       }
 975     }
 976   }
 977 }
 978
 979 module CaseBase(){
 980   AroundEdges(epp3[1], case_th_bottom, 1)
 981     EdgeProfile();
 982 }
 983
 984 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 985
 986 module PropProfileAssignments(gamma){
 987   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 988   x = prop_x(gamma);
 989   p = phone_height + prlp10[0] - hppB[0];
 990   b = p + x;
 991
 992   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 993   a = q + x;
 994   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 995   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 996
 997   $prp_theta = 90 - $prp_alpha;
 998   beta = 180 - $prp_alpha - gamma;
 999   psi = 90 - beta;
1000
1001   //echo("abc", a,b,c);
1002
1003   v1 = [ [ cos(psi), -sin(psi) ],    // x
1004          [ sin(psi),  cos(psi) ] ];  // y
1005
1006   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1007
1008   $prp_r1 = prc_r1;
1009   $prp_r11 = prop_main_th/2;
1010
1011   $prpp1 = $prpp7 + [1,0] *
1012     // this is approximate, but will do
1013     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1014   $prpp3 = $prpp1 +
1015     v1[0] * -$prp_r1 +
1016     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1017   $prpp12 = $prpp3 + v1[0] *
1018     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1019   $prp_r8 = prop_main_th;
1020   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1021   $prp_r5 = $prp_r8;
1022   $prpp5 = [ $prpp12[0] - $prp_r5,
1023             $prpp3[1] - prop_prong_h + $prp_r5 ];
1024   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1025          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1026   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1027   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1028
1029   children();
1030 }
1031
1032 module PropProfile(gamma, cut=0, rot=0){
1033   PropProfileAssignments(gamma){
1034
1035     //#circleat($prpp3,1);
1036     //#circleat($prpp12,1);
1037
1038     if (!cut) {
1039       hull(){
1040         translate($prpp8)
1041           intersection(){
1042             circle($prp_r8);
1043             polygon([[-20,-0], [20,20], [0,0]]);
1044           }
1045         rectfromto($prpp6, $prpp9);
1046         translate($prpp5) intersection(){
1047           circle($prp_r5);
1048           polygon([[-10,-10], [0,0], [10,0]]);
1049         }
1050         rectfromto($prpp12 + [0,-0.1], $prpp3);
1051       }
1052       hull(){
1053         circleat($prpp1, $prp_r1);
1054         rectfromto($prpp12 + [0,-0.1], $prpp3);
1055       }
1056     }
1057     // main shaft
1058     rotate([0,0, rot*-$prp_theta]){
1059       hull(){
1060         extra = cut ? prop_recess_slop : 0;
1061         rectfromto($prpp6, $prpp9);
1062         circleat($prpp11, $prp_r11 + extra);
1063         circleat($prpp10, $prp_r10 + extra);
1064       }
1065     }
1066   }
1067 }
1068
1069 module PropAggregateProfile(){
1070   for (angle = prop_angles)
1071     PropProfile(angle, 0,0);
1072 }
1073
1074 module Prop(){ ////toplevel
1075   hw = prop_main_width/2;
1076   linextr(-hw, +hw)
1077     PropAggregateProfile();
1078 }
1079
1080 module Case(){ ////toplevel
1081   difference(){
1082     union(){
1083       CaseBase();
1084
1085       // ledge (fixed keeper)
1086       Flip_rhs(1-keeper_side) intersection(){
1087         rotate([90, 0, 0])
1088           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1089           KeeperProfile(1);
1090
1091         // outline of the whole case, to stop it protruding
1092         translate([0,0, -25])
1093           linear_extrude(height = 50)
1094           hull()
1095           Flip_bot()
1096           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1097       }
1098
1099       // hinge
1100       HingePortion(hex20, hex21) HingeBaseProfile();
1101
1102       // buildout for prop recess
1103       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1104         linextr(case_bottom_z, epp2i[1])
1105         hull() {
1106           for (dxs = [-1,+1])
1107             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1108                        -epp2o[0] ],
1109                      r = epp2o[0] - prcp2[0]);
1110         }
1111     }
1112
1113     // slot for keeper
1114     Flip_rhs(keeper_side)
1115       translate([0, -phone_cnr_rad, 0])
1116       rotate([90, 0, 0])
1117       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1118       minkowski(){
1119         KeeperProfile();
1120         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1121                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1122       }
1123
1124     // front camera
1125     RearCameraAperture();
1126
1127     // struts (invisible, because they're buried in the case)
1128     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1129
1130     Buttons(){
1131       mirror([1,0,0])
1132         rotate([90,0,90]) {
1133           if (!($button_leg_only && enable_support))
1134           intersection(){
1135             translate([0,0,-10])
1136               linear_extrude(height= 20)
1137               ButtonPlan($button_l, 0,1);
1138             if ($button_leg_only)
1139               rotate([-90,90,0])
1140                 translate([phone_width/2, -400, kppe[1]])
1141                 mirror([1-abs($rhsflip - keeper_side),0,0])
1142                 cube([400, 800, 50]);
1143             if (enable_support && !$button_suppress_over_keeper)
1144               rotate([-90,90,0])
1145               translate([-400, -400, kppd[1]])
1146                 mirror([0,0,1])
1147                 cube([800,800,100]);
1148           }
1149           translate([0,0, -bppR[0]])
1150             linear_extrude(height= 20)
1151             ButtonPlan($button_l, 1,1);
1152         }
1153
1154     }
1155
1156     // apertures along top edge
1157     if (!$suppress_forward_holes) {
1158       // CaseAperture(jack_pos, jack_dia, 8);
1159       Flip_rhs(1)
1160         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1161     }
1162
1163     OrdinaryRearApertures();
1164
1165     MicroUSB();
1166
1167     // gaps for the lid's hinge arms
1168     HingePortion(hex20 - hinge_x_arms_gap,
1169                  hex21 + hinge_x_arms_gap)
1170       minkowski(){
1171         HingeLidProfile();
1172         circle(r= hinge_r_arms_gap, $fn= 8);
1173       }
1174
1175     // screw holes in the hinge arms
1176     HingeScrews();
1177
1178     // thumb recess
1179     ThumbRecessApply(epp4[1])
1180       ThumbRecessCutProfile();
1181
1182     // lanyard
1183     Flip_bot(1)
1184       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1185       rotate([0, ly_theta, 0])
1186       rotate([0,0,90])
1187       LanyardCutout(lanyard_channel_len);
1188
1189     // prop recess
1190     Flip_rhs(1)
1191       translate([prop_x_pos,0,0])
1192       mirror([0,1,0])
1193       rotate([90,0,90])
1194       linextr(-prop_recess_hw, +prop_recess_hw)
1195       hull(){
1196         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1197           circleat(prcp1 + 20*d,
1198                    prc_r3);
1199       }
1200   }
1201 }
1202
1203 module LidAdhocMultiprintFrame(phase){
1204   if (led_window_style >= 3) {
1205     AdhocMultiprintFrame(phase, lpp13[1], -1);
1206   }
1207 }
1208
1209 module LidAroundEdges(){
1210   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1211     children();
1212 }
1213
1214 module Lid(){ ////toplevel
1215   skew_centre = [0, lpp11[0], lpp11[1]];
1216   difference(){
1217     union(){
1218       intersection(){
1219         LidAroundEdges()
1220           LidEdgeProfile();
1221
1222         translate(skew_centre)
1223           multmatrix([[ 1, 0, 0, 0 ],
1224                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1225                       [ 0, 0, 1, 0 ],
1226                       [ 0, 0, 0, 1 ]])
1227           translate(-skew_centre)
1228           LidAroundEdges()
1229           LidEdgeFoldClearanceProfile();
1230       }
1231
1232       // button covers
1233       Buttons(){
1234         intersection(){
1235           rotate([90,0,90])
1236             translate([0,0,-10])
1237             linear_extrude(height= 20)
1238             ButtonPlan($button_l, 1,0);
1239           union(){
1240             rotate([90,0,0])
1241               translate([0,0,-100])
1242               linear_extrude(height= 200)
1243               ButtonCoverProfile();
1244             hull()
1245               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1246                                  - lid_buttoncover_reinf))
1247                 translate([0,y,0])
1248                   ButtonCoverReinf();
1249           }
1250         }
1251       }
1252
1253       // hinge arms
1254       HingePortion(hex20, hex21) {
1255         LidEdgeProfile();
1256         HingeLidProfile();
1257       }
1258     }
1259     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1260
1261     // screw holes in the hinge arms
1262     HingeScrews();
1263
1264     // prop recess
1265     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1266       mirror([0,1,0])
1267       rotate([90,0,90])
1268       linextr(-prop_recess_hw, +prop_recess_hw)
1269       hull()
1270       for (pa = prop_angles)
1271         PropProfile(pa, 1,1);
1272
1273     // notification led aperture
1274     if (led_window_style)
1275       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1276         translate([0,0,-10])
1277           cylinder(r=nla_r0, h=20);
1278         if (led_window_style >= 2)
1279           translate([0,0, -nla_t])
1280             cylinder(r=nla_r2, height=20);
1281       }
1282
1283     }
1284
1285   LidAdhocMultiprintFrame(1);
1286 }
1287
1288 module HingeLever(){ ////toplevel
1289   difference() {
1290     // outer body, positive
1291     HingePortion(hex22, hex22 + phone_width/2)
1292       HingeLeverOuterProfile();
1293
1294     // space for the screws
1295     HingePortion(hex26, hex24)
1296       HingeLeverInnerProfile();
1297
1298     // recesses for the nuts
1299     HingePortion(hex23, hex26+1)
1300       HingeLeverNutProfile();
1301
1302     // bores for the screws
1303     HingeScrews();
1304
1305     // space for the charging cable
1306     MicroUSB();
1307     Flip_hinge() MicroUSB();
1308   }
1309 }
1310
1311 module LidWindow(){ ////toplevel
1312   translate([led_pos[0], -led_pos[1], lpp13[1]])
1313     mirror([0,0,1])
1314     cylinder(r= nla_r1, h=nla_t);
1315   LidAdhocMultiprintFrame(0);
1316 }
1317
1318 module LidWindowPrint(){ ////toplevel
1319   rotate([0,180,0])
1320     LidWindow();
1321 }
1322
1323 module DemoLidWindowSelect(){
1324   translate([led_pos[0], led_pos[1], -100]) {
1325     translate([0, -30, 0]) cube([400, 400, 200]);
1326   }
1327 }
1328
1329 module DemoLidWindow(){ ////toplevel
1330   %Lid();
1331   LidWindow();
1332   translate([0,40,0]){
1333     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1334     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1335   }
1336 }
1337
1338 module HingeLeverPrint(){ ////toplevel
1339   rotate([-90,0,0])
1340     translate([-phone_width/2, phone_height, 0])
1341     HingeLever();
1342 }
1343
1344 module TestSelectLength(){
1345   translate([-30, -200, -20])
1346     cube([30 + 15, 250, 40]);
1347 }
1348
1349 module TestLength(){ ////toplevel
1350   intersection(){
1351     Case();
1352     TestSelectLength();
1353   }
1354 }
1355
1356 module TestLengthRight(){ ////toplevel
1357   intersection(){
1358     Case();
1359     Flip_rhs(1)
1360       TestSelectLength();
1361   }
1362 }
1363
1364 module TestSelectWidth(){
1365   translate([-30, -(phone_height - 25), -20])
1366     mirror([0, 1, 0])
1367     cube([200, 50, 40]);
1368 }
1369
1370 module TestWidth(){ ////toplevel
1371   intersection(){
1372     Case();
1373     TestSelectWidth();
1374   }
1375 }
1376
1377 module TestLidWidthPrint(){ ////toplevel
1378   rotate([0,180.0]) intersection(){
1379     Lid();
1380     TestSelectWidth();
1381   }
1382 }
1383
1384 module TestSelectRearAperture(){
1385   minkowski(){
1386     union() children();
1387     translate([20, 0,0])
1388       cube([42, 2, 1], center=true);
1389   }
1390 }
1391
1392 module TestSelectCamera(){
1393   minkowski(){
1394     TestSelectRearAperture()
1395       RearCameraAperture();
1396     cube([0.1, 50, 0.1]);
1397   }
1398 }
1399
1400 module TestSelectOrdinaryRearApertures(){
1401   TestSelectRearAperture()
1402     OrdinaryRearApertures();
1403 }
1404
1405 module TestCamera(){ ////toplevel
1406   intersection(){
1407     Case();
1408     TestSelectCamera();
1409   }
1410 }
1411
1412 module TestLidByCamera(){ ////toplevel
1413   intersection(){
1414     Lid();
1415     TestSelectCamera();
1416   }
1417 }
1418
1419 module TestLidByCameraPrint(){ ////toplevel
1420   rotate([180,0,0]) TestLidByCamera();
1421 }
1422
1423 module DemoByCamera(){ ////toplevel
1424   color("blue") TestLidByCamera();
1425   color("red")  TestCamera();
1426 }
1427
1428 module OneKeeper(){ ////toplevel
1429   translate([0, -phone_cnr_rad, 0])
1430     rotate([90, 0, 0])
1431     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1432     KeeperProfile();
1433 }
1434
1435 module OneKeeperPrint(){ ////toplevel
1436   rotate([0,180,0])
1437     OneKeeper();
1438 }
1439
1440 module LidPrint(){ ////toplevel
1441   rotate([0,180,0])
1442     Lid();
1443 }
1444
1445 module TestSelectFrame(){
1446   include = [1,-1] * (epp2i[0] + 4);
1447
1448   difference(){
1449     cube(1000, center=true);
1450     translate([0,0, -100])
1451       linear_extrude(height=200)
1452       rectfromto(include,  inside_br - include);
1453   }
1454 }
1455
1456 module TestSelectLidFrame(){
1457   TestSelectFrame();
1458   translate([led_pos[0], -led_pos[1], -50])
1459     cylinder(r= nla_r2+3, h=100);
1460 }
1461
1462 module TestFrameCase(){ ////toplevel
1463   intersection(){
1464     Case();
1465     union(){
1466       TestSelectFrame();
1467       TestSelectCamera();
1468       TestSelectOrdinaryRearApertures();
1469     }
1470   }
1471 }
1472
1473 module TestSelectTopApertures(){
1474   translate([-100, -35, -100])
1475     cube([400, 100, 200]);
1476   LidAdhocMultiprintFrame(0);
1477   LidAdhocMultiprintFrame(1);
1478 }
1479
1480 module TestTopApertures(){ ////toplevel
1481   intersection(){
1482     Case();
1483     TestSelectFrame();
1484     TestSelectTopApertures();
1485   }
1486 }
1487
1488 module TestLidTopAperturesPrint(){ ////toplevel
1489   rotate([0,180,0]) intersection(){
1490     Lid();
1491     TestSelectLidFrame();
1492     TestSelectTopApertures();
1493   }
1494 }
1495
1496 module TestLidWindowTopAperturesPrint(){ ////toplevel
1497   rotate([0,180,0]) intersection(){
1498     LidWindow();
1499     TestSelectTopApertures();
1500   }
1501 }
1502
1503 module TestFrameLidPrint(){ ////toplevel
1504   rotate([0,180,0]) intersection(){
1505     Lid();
1506     TestSelectLidFrame();
1507   }
1508 }
1509
1510 module ButtonPlanForDemo(z, deep, cut){
1511   translate([0,0,z])
1512     ButtonPlan(8, deep, cut);
1513 }
1514
1515 module HingeScrews(){
1516   Flip_rhs() Flip_bot(1){
1517     for (c= [ hppT, hppB ])
1518       translate([ hex20,
1519                   -c[0],
1520                   c[1] ]){
1521         rotate([0,90,0])
1522           translate([0,0,-.2])
1523           cylinder( r= hingescrew_shaft_dia/2,
1524                     h = hingescrew_shaft_len+0.2 );
1525         rotate([0,-90,0])
1526           translate([0,0,+.1])
1527           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1528       }
1529   }
1530 }
1531
1532 module DemoPropAngleSelect(c){
1533   color(c) difference(){
1534     union(){ children(); }
1535     translate([ prop_x_pos, -400, -200 ])
1536       cube([ 400,800,400 ]);
1537   }
1538 }
1539
1540 module DemoPropAngle(ang){
1541   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1542   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1543
1544   translate(hL)
1545     rotate([ang/2,0,0])
1546     translate(-hL)
1547     translate(hC)
1548     rotate([ang/2,0,0])
1549     translate(-hC) {
1550       DemoPropAngleSelect("red") Case();
1551
1552       color("orange")
1553         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1554         PropProfileAssignments(ang) {
1555           echo($prpp1);
1556           rotate([-$prp_theta, 0, 0])
1557           translate([0, $prpp1[0], -$prpp1[1]])
1558           rotate([90,0,-90])
1559           Prop();
1560         }
1561     }
1562
1563   translate([0,0, -hp_k*2])
1564     DemoPropAngleSelect("blue")
1565     Lid();
1566 }
1567
1568 module DemoPropAngles(){ ////toplevel
1569   for (i=[0 : len(prop_angles)-1])
1570     translate(i * [0, -100, 100])
1571     DemoPropAngle(prop_angles[i]);
1572 }
1573
1574 module DemoHingeAngle(ang1,ang2){
1575   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1576   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1577
1578   translate(hL)
1579     rotate([ang2,0,0])
1580     translate(-hL)
1581     translate(hC)
1582     rotate([ang1,0,0])
1583     translate(-hC) {
1584       color("red") Lid();
1585     }
1586
1587   color("blue") intersection(){
1588     Case();
1589     union(){
1590       translate([bppJ[0], -400, -200])
1591         mirror([1,0,0])
1592         cube([400, 800, 400]);
1593       translate([10, -400, -200])
1594         cube([10, 800, 400]);
1595     }
1596   }
1597 }
1598
1599 module DemoHingeAngles(){ ////toplevel
1600   angles = [ 0, 4, 8, 12 ];
1601   echo("angles",angles);
1602   for (i=[0 : len(angles)-1]) {
1603     translate(i * [0, 0, 30]) {
1604       DemoHingeAngle(0,angles[i]);
1605       translate([0, 200, 0])
1606         DemoHingeAngle(angles[i],0);
1607     }
1608   }
1609 }
1610
1611 module DemoSelectAdhocLeftRight(right=0) {
1612   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1613     mirror([1-right, 0,0])
1614     cube([400, 800, 200]);
1615 }
1616
1617 module DemoLeft(){ ////toplevel
1618   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1619   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1620 }
1621
1622 module DemoFrame(){ ////toplevel
1623   color("red") render() TestFrameCase();
1624   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1625   color("black") render() HingeScrews();
1626   %render() HingeLever();
1627 }
1628
1629 module DemoLanyardCutout(){ ////toplevel
1630   LanyardCutout(25);
1631 }
1632
1633 module DemoHingedFrame(){ ///toplevel
1634   color("red") TestFrameCase();
1635   translate([0,0, -2*hp_k])
1636   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1637
1638   Flip_hinge(){
1639     color("orange") HingeLever();
1640     color("black") HingeScrews();
1641   }
1642 }
1643
1644 module DemoHinge(){ ////toplevel
1645   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1646     DemoFrame();
1647     translate([0,0, -hp_k*3])
1648       DemoHingedFrame();
1649   }
1650 }
1651
1652 module DemoProfiles(){ ////toplevel
1653   LidEdgeProfile();
1654   %EdgeProfile();
1655   KeeperProfile();
1656   translate([0,0,-1]) color("black") KeeperProfile(1);
1657   translate(ly_o){
1658     rotate(-ly_theta){
1659       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1660       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1661       translate([0, ly_q_z]){
1662         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1663         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1664       }
1665     }
1666   }
1667   translate([0,0,-5]) color("white") translate(epp2i)
1668     rotate(-ly_theta)
1669     rectfromto([-15, 0],
1670                [+15, -max_case_bottom_edge_thickness]);
1671
1672   translate([0,20]) {
1673     LanyardMainChannelProfile();
1674     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1675     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1676   }
1677
1678   translate([20,0]) {
1679     LidEdgeProfile();
1680     %EdgeProfile();
1681
1682     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1683
1684     color("blue") ButtonCoverProfile();
1685     color("red") {
1686       rectfromto(bppQ, demopoint_QR);
1687       rectfromto(bppR, demopoint_QR);
1688     }
1689   }
1690
1691   translate([-20,0]) {
1692     color("black") ButtonPlanForDemo(-2, 0,1);
1693     color("red" )  ButtonPlanForDemo(-4, 1,1);
1694     color("blue")  ButtonPlanForDemo(-6, 1,0);
1695   }
1696
1697   translate([0, -30]) {
1698     %LidEdgeProfile();
1699     %EdgeProfile();
1700     color("blue") HingeLidProfile();
1701     color("red")  HingeBaseProfile();
1702     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1703   }
1704
1705   for (f=[0,1]) {
1706     translate([-30, -60 + 30*f]) {
1707       translate([0,0,-4]) EdgeProfile();
1708       %translate([0,0,-10]) HingeBaseProfile();
1709       translate([0,-2] * f * hp_k) {
1710         translate([0,0,-4]) LidEdgeProfile();
1711         %translate([0,0,-10]) %HingeLidProfile();
1712       }
1713       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1714         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1715         translate([0,0,0]) color("red") difference(){
1716           HingeLeverOuterProfile();
1717           HingeLeverInnerProfile();
1718         }
1719         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1720       }
1721     }
1722   }
1723
1724   translate([20,-30]) {
1725     %EdgeProfile();
1726     %LidEdgeProfile();
1727     //translate([0,0,1]) ThumbRecessCutProfile();
1728     translate([0,0,+1]) color("red")
1729       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1730   }
1731
1732   translate([40,-30]) {
1733     difference(){
1734       LidEdgeProfile();
1735       translate(prlp10)
1736         PropProfile(10, 1, 0);
1737     }
1738     translate(prlp10)
1739       PropProfile(15, 0);
1740   }
1741   translate([60,-30]) {
1742     PropAggregateProfile();
1743   }
1744 }
1745
1746 //EdgeProfile();
1747 //KeeperProfile();
1748 //CaseBase();
1749 //%Case();
1750 //Keeper();
1751 //LidEdgeProfile();
1752 //KeeperProfile();
1753 //DemoProfiles();
1754 //PropRecess();