fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. <deleted>
  13 //
  14 //  3. use "make" to generate the necessary files:
  15 //
  16 //     make -j8 fairphone-case.auto.scads `for f in   \
  17 //        HingeLeverPrint   \
  18 //        LidPrint          \
  19 //        OneKeeperPrint    \
  20 //        Case              \
  21 //     ; do echo fairphone-case,$f.auto.stl; done`
  22 //
  23 //  4. Print them.  Case and OneKeeperPrint should probably be
  24 //     the same colour.
  25 //
  26 //  5. Assemble the hinge.  After placing the parts in the appropirate
  27 //     relative placement:
  28 //
  29 //        Use long bit of wire to ensure holes are lined up and proper
  30 //        Cut four short bits of wire, using above as a guage
  31 //
  32 //        Push two short bits into two holes on same side
  33 //        Use long bit of wire to ensure properly in holes
  34 //        Keep that side up so they don't fall out!
  35 //
  36 //        For each of the two holes
  37 //          Use 20-30cm hunk of 2.85mm PLA
  38 //          Use gas flame to melt end until it catches fire (!)
  39 //          Remove from flame, wave to extinguish, and quickly:
  40 //          Dab end onto where hole is
  41 //          As it congeals, use sidecutters to cut off by hole
  42 //
  43 //        Repeat for two holes on other side
  44 //        When cool, file down rough edges
  45 //
  46 //  6. In use:
  47 //
  48 //      - To put the phone in, drop its RH side into the RH side of
  49 //        the case.  Then feed the keeper through the small hole.
  50 //        Feed it right through.
  51 //
  52 //      - The optional prop can be used to prop the phone up (in
  53 //        portrait orientation only right now).  See
  54 //            openscad fairphone-case,DemoPropAngles.auto.scad
  55 //
  56 // Other phones
  57 //
  58 //  It might well be possible to adapt this file for other phones.
  59 //  If you do, let me know how you get on.
  60 //
  61 //
  62 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  63 //
  64 //   Copyright (C) 2018-2022 Ian Jackson.
  65 //
  66 //    This program for generating a 3D model is free software: you can
  67 //    redistribute it and/or modify it under the terms of the GNU
  68 //    General Public License as published by the Free Software
  69 //    Foundation, either version 3 of the License, or (at your option)
  70 //    any later version.
  71 //
  72 //    This program is distributed in the hope that it will be useful,
  73 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
  74 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  75 //    GNU General Public License for more details.
  76 //
  77 //    You should have received a copy of the GNU General Public
  78 //    License along with this program.  If not, see
  79 //    <http://www.gnu.org/licenses/>.
  80 //
  81 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
  82 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
  83 //  this case will meet your needs.
  84
  85 include <utils.scad>
  86 include <funcs.scad>
  87
  88 phone = [ 75.86, 162.0 ];
  89
  90 prop_buildout_less = 3;
  91
  92 prop_angles = [ 15, 30, 45, 60 ];
  93
  94 bumper = [ 0.250, -0.025 ];
  95 // ^ One side.  Overall size is increased by twice this.
  96 // If no bumpers, is the gap around the phone.
  97
  98 enable_support = 1;
  99
 100 led_window_style = 0;
 101 // 0: no window
 102 // 1: simply an opening
 103 // 2: opening with separate cover model, for printing in clear (two colour)
 104 // 3: like 2 but one-layer window for ad-hoc multi-colour
 105
 106 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 107 initial_layer_width = 0.750; // ^ needed for mode 3 only
 108 multicolour_gap = 0.15; // each side
 109
 110 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 111 phone_rim_depth = 0.01; // includes allowance for a screen protector
 112
 113 button_cutout_depth = 9;
 114
 115 phone_edge_thick = 11.25;
 116
 117 camera_pos_tl = [  5.600,  5.750 ]; // from tl corner (as seen from back)
 118 camera_edge_rad = 9.750 + 0.700;
 119 camera_sz = 32.920 + .750 + 1.000;
 120
 121 // this is disabled, FP4 doesn't have one
 122 jack_pos = [ 13.83, 8.485 ];
 123 jack_dia = 10.64 + .5; // some jack I had lying around
 124
 125 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 126 led_pos = []; // [ 13.98, 10.00 ];
 127 led_aperture = 9;
 128 led_window_ledge = 0.75; // each side
 129
 130 noisecancelmic_pos = [ 15.08 + .720, 4.35 ];   // from rhs, from top edge
 131 noisecancelmic_dia = 4.00;
 132
 133 mainmic_pos = [ 21.0, 4.65 ];   // from lhs, from top edge
 134 mainmic_dia = 4.00;
 135
 136 lhshole_pos = [ phone[1]/2 + 0.40, 4.35 ];
 137
 138 fingerpushhole_dias = [];
 139 //fingerpushhole_dias = [ 15, 18 ]; // this is for testing
 140
 141 lanyard_half_dia = 1.15;
 142 lanyard_entry_rel_breadth = 2;
 143 lanyard_channel_len = 8;
 144 //rearspeaker_pos_bl = [ 12.64, 18.72 ];
 145 //rearspeaker_size   = [  3.76,  7.36 ];
 146
 147 bottomspeaker_size = [ 11.35, 1.90 ] + [1,1] * 0.5;
 148 bottomspeaker_pos = [ 17.55, 5.17 ]; // from rhs, from top
 149
 150 microusb_above = 1.64 - 0.25;
 151 microusb_below = 2.42;
 152 microusb_width = 12.16 + 2.0 + 1.25;
 153
 154 case_th_bottom = 2.5;
 155 case_th_lid = 3.0;
 156 case_th_side = 3.1;
 157 case_th_lip = 1.2;
 158
 159 lid_screen_gap_extra = .66;
 160
 161 case_struts_count = 6;
 162 case_struts_solid_below = 1.00;
 163 case_struts_solid_above = 0.75;
 164 case_struts_width = 0.10;
 165
 166 keeper_th_z = 0.75;
 167 keeper_th_x = 0.75;
 168 keeper_inner_width = 2.75;
 169 keeper_inner_height = 2.75;
 170 keeper_slant_slope = 2; // larger means steeper
 171
 172 keeper_gap_z_top = 0.25;
 173 keeper_gap_z_bot = 0.75;
 174 keeper_gap_x     = 0.25;
 175 keeper_gap_x_holes = 0.75;
 176 keeper_fatter = 0.45;
 177 keeper_fatter_hole = 1.20;
 178
 179 keeper_side = 0; // 0 = lhs; 1 = rhs
 180
 181 case_lip = 1.25;
 182
 183 lid_gap_x = 0.25;
 184 lid_gap_z = 0.25;
 185 lid_lip = 1.75;
 186 lid_edgepart_width = 5.0;
 187 lid_buttoncover_thick = 1.2;
 188 lid_buttoncover_reinf = 1.05;
 189
 190 foldover_gap = 0.50;
 191 foldover_lever_gap = 0.50;
 192
 193 // properties of the hinge fasteners
 194 hingescrew_shaft_dia = 1.600 + 0.45; // beading wire
 195 hingescrew_shaft_len = 10;
 196 hingescrew_fasteners_extra_thick = 0.40;
 197 // ^ amount of thread protruding if everything was completely nominal
 198 //   and we are using two nuts
 199 hingescrew_nut_access_dia = 4.72 + 0.50;
 200 // ^ washer is 4.72 dia
 201 //   also, want to get pliers or tiny spanner in to do up locknut
 202 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 203 hingescrew_nut_thick = 1.93;
 204 hingescrew_head_th = 1.38 + 0.75;
 205 hingescrew_head_dia = 3.92;
 206
 207 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 208
 209 lever_cover_th = 0.75;
 210 hingemount_th = 2.5;
 211 hingemount_wd = 4.8725;
 212
 213 $fa = 5;
 214 $fs = 0.1;
 215
 216 button_l_fudge = 4.4;
 217 buttonishleg_default_l_is_fudge = 10;
 218
 219 hinge_base_slope = 1.5; // bigger is steeper
 220
 221 strut_min_at_end = 1.5;
 222
 223 hinge_x_gap = 0.125;
 224 hinge_x_postscrew_gap = 0.75;
 225 hinge_x_arms_gap = 0.35;
 226 hinge_r_arms_gap = 0.55;
 227 hinge_over_nut_plate = -0.50; // bodge apropos slope
 228
 229 // there isn't one of these, speaker is by hinge
 230 // rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 231
 232 thumbrecess_depth = 1.3;
 233 thumbrecess_width = 16.5;
 234 thumbrecess_topcurve_r = 5.0;
 235
 236 prop_recess_under = 0.50;
 237 prop_recess_slop = 0.200; // each side
 238 prop_end_dia = 0.5;
 239 prop_main_th = 3;
 240 prop_taper_len = 6;
 241 prop_main_width = 4;
 242 prop_side_gap = 0.75; // each side
 243 prop_lidrecess_behind = 0.75;
 244 prop_caserecess_behind = 0.75;
 245 prop_caserecess_taper = 0.45; // one side only
 246 prop_prop_gap = 0.5;
 247 prop_prong_heel_slope = 0.5;
 248
 249 lid_fold_clearance_antislop = 0.5;
 250
 251 $button_leg_only = false;
 252 $suppress_forward_holes = false;
 253 $suppress_hinge = false;
 254
 255 // ---------- calculated ----------
 256
 257 phone_total_thick = phone_edge_thick;
 258
 259 phone_width =  (phone + bumper*2)[0];
 260 phone_height = (phone + bumper*2)[1];
 261
 262 inside_br = [phone_width, -phone_height];
 263
 264 prop_prong_h = prop_main_th;
 265
 266 //echo(camera_pos_tl + bumper,
 267 //     camera_pos_br + bumper);
 268
 269 // ----- could be changed -----
 270 lid_buttoncover_gap = lid_gap_x;
 271 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 272
 273 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 274
 275 //prop_nose_len = case_th_lid - prop_recess_under;
 276 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 277 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 278
 279
 280 epp0 = [0,0];
 281 epp1 = [0, -phone_edge_thick];
 282 epp2i = epp1; // conflated for FP4
 283 epp2o = epp2i;
 284 epp3 = epp2i + [10, 0];
 285 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 286 epp4 = epp5 + [-1,0] * case_th_side;
 287
 288 kppe = [0,0];
 289 kppd = kppe + [1,0] * keeper_inner_width;
 290 kppc = kppd + [0,1] * keeper_th_z;
 291 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 292 kppf = kppe - [0,1] * keeper_inner_height;
 293 kppa = [ kppb[0], kppf[1] ];
 294
 295 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 296 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 297
 298 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 299 // exact x posn not very important; must extend past end of keeper
 300
 301 lpp15 = [ lpp14[0],
 302           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 303           + lid_screen_gap_extra ];
 304 // ^ beam theory says to maximise force before contact,
 305 //   the gap below the `beam' (the lid) must be 1/3
 306 //   the thickness (ie the lid thickness) if the beam
 307 //   is solid, or 1/2 if it has a top and bottom only.
 308 //   ours is mostly solid.
 309
 310 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 311              case_th_lip);
 312
 313 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 314 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 315
 316 case_bottom_z = epp2o[1] - case_th_bottom;
 317
 318 // button profile
 319 bppM = epp4 + [0,5];
 320 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 321 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 322 bppS = [ epp1[0], bppR[1] ];
 323 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 324 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 325 bppO = [ bppN[0], bppP[1] ];
 326 bppL = lpp10 + [5,0];
 327 bppK = [ bppL[0], bppN[1] ];
 328 bppJ = [ bppN[0], bppL[1] ];
 329 bppU = [ bppJ[0], lpp12[1] ];
 330 bppV = lpp11;
 331 bppW = lpp10;
 332
 333 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 334
 335 // notification led aperture
 336
 337 nla_r0 = led_aperture/2;
 338 nla_r1 = nla_r0 + led_window_ledge;
 339 nla_r2 = nla_r1 + multicolour_gap;
 340 nla_t =
 341   led_window_style >= 3 ? initial_layer_thick :
 342   led_window_style >= 2 ? led_window_ledge : 0;
 343
 344
 345 // hinge plan
 346 hp_rn = hingescrew_nut_access_dia/2;
 347 hp_r2_min = hp_rn + lever_cover_th;
 348 hp_rs = hingescrew_shaft_dia/2;
 349 hp_r1_min = hp_rs + hingemount_th;
 350
 351 hp_r1 = max(hp_r1_min, hp_r2_min);
 352 hp_r2 = hp_r1;
 353
 354 hppU = lpp13;
 355 hppS = epp2o + [0,-1] * case_th_bottom;
 356 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 357
 358 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 359          0.5 * (hppU + hppS)[1] ];
 360 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 361 hppB = hppT + [0,-1] * hp_k;
 362
 363 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 364 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 365 hppE = [ hppE_x, hppE_y ];
 366
 367 // hinge elevation x coords
 368
 369 hex20 = max(epp2o[0],
 370             phone_cnr_rad,
 371             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 372 hex21 = hex20 + hingemount_wd;
 373 hex22 = hex21 + hinge_x_gap;
 374 hex27 = hex20 + hingescrew_shaft_len;
 375 hex24 = hex27 + hinge_x_postscrew_gap;
 376 hex23 = hex27 - (hingescrew_nut_thick*2
 377                  + hingescrew_fasteners_extra_thick);
 378 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 379
 380 //echo(hex20, hex21, hex22, hex23, hex24);
 381 ////  6, 10.8725, 10.9975, 13.74, 18.75
 382 //module chk(act,exp) {
 383 //  if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 384 //  else echo("ok", act);
 385 //}
 386 //chk(hex20, 6);
 387 //chk(hex21, 10.8725);
 388 //chk(hex22, 10.9975);
 389 //chk(hex23, 13.74);
 390 //chk(hex24, 18.75);
 391
 392 lid_fold_clearance_skew =
 393   (lpp10[1] - hppB[1]) /
 394   (lpp10[0] - hppB[0]);
 395
 396 echo("SK",lid_fold_clearance_skew);
 397
 398 // thumb recess (used to be "catch" hence cpp*
 399
 400 cppA = epp4 + [thumbrecess_depth, 0];
 401 cppB = [ cppA[0], epp1[1] ];
 402
 403 // lanyard
 404
 405 ly_r = lanyard_half_dia / 2;
 406 ly_rc = ly_r * 2;
 407
 408 ly_theta = 90;
 409 ly_o = epp2i + 3 * ly_r * [0,1];
 410
 411 max_case_bottom_edge_thickness =
 412   case_th_bottom;
 413
 414 ly_q_z = -(ly_rc + ly_r);
 415 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 416
 417 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 418
 419 // prop recess in case
 420
 421 prop_x_pos = phone_width/2;
 422
 423 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 424
 425 prc_r1 = prop_end_dia/2;
 426 prc_r3 = prc_r1 + prop_recess_slop;
 427
 428 prcp2 = [ epp4[0] + prop_buildout_less,
 429           case_bottom_z ];
 430
 431 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 432
 433 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 434           epp2i[1] - prc_r3 - prop_recess_under];
 435
 436 // prop recess in lid
 437
 438 prl_r10 = prop_end_dia/2;
 439 prl_r10o = prl_r10 + prop_recess_slop;
 440
 441 prlp10 = lpp10 + [1,1] * prl_r10o
 442   + [1,0] * prop_lidrecess_behind
 443   + [0,1] * prop_recess_under;
 444
 445 // prop
 446
 447 $prpp10 = [0,0];
 448 $prpp11 = [0, prop_taper_len];
 449
 450 $prp_r10 = prl_r10;
 451
 452 // ---------- modules ----------
 453
 454 module AdhocMultiprintFrame(phase, z0, zs) {
 455   // from z0 to z0 + zs*layer
 456   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 457   xextra = extra + -epp4[0];
 458   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 459   yextra = extra + -epp4[0];
 460   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 461   p0 = [ xrange[0], yrange[0] ];
 462   p1 = [ xrange[1], yrange[1] ];
 463   echo(p0, p1);
 464   translate([0,0, z0])
 465     mirror([0,0, zs<0 ? 1 : 0])
 466     linear_extrude(height= initial_layer_thick)
 467     difference(){
 468       rectfromto(p0 - [1,1] * initial_layer_width,
 469                  p1 + [1,1] * initial_layer_width);
 470       rectfromto(p0, p1);
 471     }
 472 }
 473
 474 module KeeperProfile(fatter=0, slant=0){
 475   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 476   polygon([use_e + [+1,-1] * fatter,
 477            kppd  + [ 0,-1] * fatter,
 478            kppc,
 479            kppb,
 480            kppa,
 481            kppf  + [+1, 0] * fatter
 482            ]);
 483 }
 484
 485 module EdgeProfile(){
 486   difference(){
 487     hull(){
 488       translate(epp3) square(case_th_bottom*2, center=true);
 489       circleat(epp2o, r=case_th_bottom);
 490       circleat(epp1, r=case_th_side);
 491       rectfromto(epp0, epp4);
 492     }
 493     polygon([ epp5 + [0,10],
 494               epp1,
 495               epp3 + [10,0] ]);
 496   }
 497 }
 498
 499 module LanyardLanyardProfile(entry=false){
 500   hull(){
 501     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 502       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 503         circle(r= lanyard_half_dia/2);
 504   }
 505 }
 506
 507 module LanyardCurveChannelProfile(){
 508   translate([0, -ly_r])
 509     LanyardLanyardProfile();
 510 }
 511
 512 module LanyardEntryChannelProfile(){
 513   LanyardLanyardProfile(true);
 514 }
 515
 516 module LanyardMainChannelProfile(){
 517   LanyardCurveChannelProfile();
 518   difference(){
 519     square(center=true, ly_r * [6, 2]);
 520     for (xs=[-1,+1])
 521       translate(ly_r * [3 * xs, -1])
 522         circle(r = ly_r);
 523   }
 524 }
 525
 526 module LanyardEntryOuterProfile(){
 527   circleat([ly_re + ly_r, 0], ly_re);
 528 }
 529
 530 module LanyardEntry(){
 531   q_z = ly_q_z;
 532   oec_y = ly_oec_y;
 533
 534   d_x = -ly_rc;
 535
 536   translate([d_x, 0, q_z]) {
 537     intersection(){
 538       rotate([90,0,0])
 539         rotate_extrude(convexity=10)
 540         rotate(90)
 541         translate([0, -q_z])
 542         LanyardCurveChannelProfile();
 543       translate([0,-10,0])
 544         cube([20,20,20]);
 545     }
 546   }
 547
 548   mirror([0,0,1])
 549     translate([0,0,-1])
 550     linear_extrude(height=20)
 551     rotate(-90)
 552     LanyardEntryChannelProfile();
 553
 554   translate([0, ly_r*2, 0])
 555     rotate([90,0,0])
 556     linear_extrude(height = ly_r*4){
 557     difference(){
 558       rectfromto([d_x, q_z], [ly_r, 0]);
 559       circleat([d_x, q_z], ly_rc);
 560     }
 561   }
 562
 563   translate([0,0,q_z]){
 564     for (my=[0,1])
 565       mirror([0,my,0]){
 566         translate([0, oec_y, 0]){
 567           difference(){
 568             translate(ly_re * [-1,0,-2])
 569               cube(ly_re * [2,1,2]);
 570             rotate_extrude(convexity=10)
 571               LanyardEntryOuterProfile();
 572           }
 573         }
 574       }
 575     difference(){
 576       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 577         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 578       for (mx=[0,1])
 579         mirror([mx,0,0])
 580           rotate([90,0,0])
 581           translate([0,0,-10])
 582           linear_extrude(height=20)
 583           LanyardEntryOuterProfile();
 584     }
 585   }
 586 }
 587
 588 module LanyardCutout(l){
 589   rotate([0,-90,0])
 590     linear_extrude(height=l)
 591     rotate(-90)
 592     LanyardMainChannelProfile();
 593
 594   for (ee=[0,1]){
 595     translate(ee * l * [-1,0])
 596       mirror([ee,0,0])
 597       LanyardEntry();
 598   }
 599 }
 600
 601 module LidEdgeProfile(){
 602   polygon([ lpp10,
 603             lpp11,
 604             lpp12,
 605             lpp13,
 606             lpp13 + [10, 0],
 607             lpp15 + [10, 0],
 608             lpp15,
 609             lpp14,
 610             ]);
 611   intersection(){
 612     circleat(lpp12, r=lp_r12);
 613     rectfromto( lpp12 + [-10,   0],
 614                 lpp12 + [+10, +10] );
 615   }
 616 }
 617
 618 module LidEdgeFoldClearanceProfile(){
 619   translate([-lid_fold_clearance_antislop, 0])
 620     polygon([ lpp10,
 621               lpp11,
 622               lpp11 + [-20,  0],
 623               lpp11 + [-20, 20],
 624               lpp11 + [+20, 20],
 625               lpp10 + [+20,  0] ]);
 626 }
 627
 628 module ButtonCoverProfile(){
 629   intersection(){
 630     polygon(concat([ bppM, bppP, bppO, bppJ ],
 631                    (enable_support && !$button_suppress_over_keeper
 632                     ? [ bppU, bppV, bppW ] : []),
 633                    [ bppL, bppK ]));
 634     hull(){
 635       EdgeProfile();
 636       LidEdgeProfile();
 637     }
 638   }
 639 }
 640
 641 module ButtonPlan(l, deep, cut){
 642   epsilon =
 643     (cut  ? 0 : lid_buttoncover_gap);
 644
 645   delta =
 646     (deep ? lid_buttoncover_overlap : 0);
 647
 648   C = [0,0]; // by definition
 649   T = [ 0, epp4[1] ];
 650   G = T + [0,10];
 651
 652   B0 = C + [0,-1] * button_cutout_depth;
 653   B1 = B0 + [0,1] * epsilon;
 654
 655   r0 = 0.5 * (T[1] - B0[1]);
 656   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 657   H = A + [0,-1] * delta;
 658
 659   D = A + [-2,0] * r0;
 660   F = D + [0,10];
 661
 662   E0 = 0.5 * (D + A);
 663   E1 = E0 + [1,0] * epsilon;
 664
 665   I0 = [ E0[0], H[1] ];
 666   I1 = [ E1[0], H[1] ];
 667
 668   hull(){
 669     for (m=[0,1]) mirror([m,0])
 670       circleat(H, r0 - epsilon);
 671   }
 672   for (m=[0,1]) mirror([m,0]) {
 673     difference(){
 674       polygon([ E1,
 675                 I1,
 676                 H,
 677                 B1,
 678                 G,
 679                 F,
 680                 D
 681                 ]);
 682       circleat(D, r0 + epsilon);
 683     }
 684   }
 685 }
 686
 687 module ButtonCoverReinf(){ ////toplevel
 688   minkowski(){
 689     rotate([90,0,0])
 690       linear_extrude(height=0.01)
 691       intersection(){
 692         ButtonCoverProfile();
 693         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 694           square([100,100]);
 695     }
 696     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 697       circle(r= lid_buttoncover_reinf);
 698       translate([-20,0]) square(40, center=true);
 699     }
 700   }
 701 }
 702
 703 module ThumbRecessCutProfile(){
 704   difference(){
 705     polygon([ cppA + [-10,0],
 706               cppB + [-10,0],
 707               cppB,
 708               cppA ]);
 709     circleat(epp1, r=case_th_side);
 710   }
 711 }
 712
 713 module Flip_rhs(yn=[0,1]) {
 714   for ($rhsflip=yn) {
 715     translate([phone_width/2, 0, 0])
 716       mirror([$rhsflip,0,0])
 717       translate([-phone_width/2, 0, 0])
 718       children();
 719   }
 720 }
 721
 722 module Flip_bot(yn=[0,1]) {
 723   for ($botflip=yn) {
 724     translate([0, -phone_height/2, 0])
 725       mirror([0, $botflip, 0])
 726       translate([0, phone_height/2, 0])
 727       children();
 728   }
 729 }
 730
 731 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 732   // sides
 733   Flip_rhs(){
 734     translate([0, -phone_cnr_rad, 0])
 735       rotate([90,0,0])
 736       linear_extrude(height = phone_height - phone_cnr_rad*2)
 737       children(0);
 738   }
 739   // corners
 740   Flip_rhs() Flip_bot() {
 741     translate([+1,-1] * phone_cnr_rad)
 742       intersection(){
 743         rotate_extrude()
 744           intersection(){
 745             mirror([1,0,0])
 746               translate([-1,0] * phone_cnr_rad)
 747               children(0);
 748             rectfromto([0,-20],[10,20]);
 749           }
 750         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 751           cube([10,10,40]);
 752       }
 753   }
 754   // top and bottom
 755   Flip_bot(){
 756     translate([ phone_width - phone_cnr_rad, 0,0 ])
 757       rotate([90,0,-90])
 758       linear_extrude(height = phone_width - phone_cnr_rad*2)
 759       children(0);
 760   }
 761   // fill
 762   translate([0,0, fill_zstart])
 763     mirror([0,0, fill_downwards])
 764     linear_extrude(height = fill_th)
 765     rectfromto([+1,-1] * phone_cnr_rad,
 766                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 767 }
 768
 769 module CaseAperture(pos, dia, $fn, topbottom=0) {
 770   theta = 180/$fn;
 771   translate([ bumper[0],
 772               -epp2i[0],
 773                0 ])
 774     rotate([0,0, 90*topbottom])
 775     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 776     rotate([-90, theta, 0])
 777     cylinder(r = dia/2 / cos(theta),
 778              h = 60);
 779 }
 780
 781 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 782   // y_ref_sign:
 783   //   +1  measured from top    of actual phone to top    of button
 784   //   -1  measured from bottom of actual phone to bottom of button
 785   //    0  y is centre of button in coordinate system
 786   $button_l= l;
 787   $button_suppress_over_keeper= suppress_over_keeper;
 788   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 789           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 790           y;
 791   //echo(eff_y);
 792   translate([0, eff_y, 0])
 793     children();
 794 }
 795
 796 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 797   $button_leg_only = true;
 798   SideButton(y, y_ref_sign, l) children();
 799 }
 800
 801 module Buttons(){
 802   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 803   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 804   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 805   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 806   Flip_rhs(0) LidButtonishLeg(38, +1) children();
 807   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 808 }
 809
 810 module Struts(x_start, z_min, th){
 811   // if th is negative, starts at z_min and works towards -ve z
 812   // and object should then be printed other way up
 813   for (i= [1 : 1 : case_struts_count]) {
 814     translate([0,
 815                0,
 816                z_min])
 817       mirror([0,0, th<0 ? 1 : 0])
 818       translate([0,
 819                  -phone_height * i / (case_struts_count+1),
 820                  case_struts_solid_below])
 821       linear_extrude(height= abs(th)
 822                      -(case_struts_solid_below+case_struts_solid_above))
 823       rectfromto([               x_start, -0.5 * case_struts_width ],
 824                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 825   }
 826 }
 827
 828 module OrdinaryRearAperture(rhs,bot, pos){
 829   Flip_rhs(rhs) Flip_bot(bot)
 830     linextr(-20, 20)
 831     mirror([0,1])
 832     translate(pos + bumper)
 833     children();
 834 }
 835
 836 module MicroUSBEtc(){
 837   Flip_bot(1){
 838     rotate([90,0,0])
 839       mirror([0,0,1])
 840       linextr(-epp2i[0], 60)
 841       translate([0.5 * phone_width, 0, 0])
 842       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 843                  [+microusb_width/2, epp0[1] + -microusb_above]);
 844   }
 845 }
 846
 847 module OrdinaryBottomEdgeApertures(){
 848   Flip_bot(1)
 849     CaseAperture(mainmic_pos, mainmic_dia, 8);
 850
 851   Flip_bot(1) Flip_rhs(1) {
 852     linextr_y_xz(-epp2i[0], 60)
 853       hull()
 854       for (x= [-1,+1]) {
 855         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 856                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 857                     0 ])
 858           rotate(360/16)
 859           circle(r = bottomspeaker_size[1], $fn = 8);
 860       }
 861   }
 862 }
 863
 864 module OrdinaryRearApertures(){
 865   // rear speaker
 866   //  OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 867   //    rectfromto(-rearspeaker_gap,
 868   //           rearspeaker_size + rearspeaker_gap);
 869 }
 870
 871 module NotInTestFrameRearApertures(){
 872   // finger hole to remove phone
 873   if (len(fingerpushhole_dias))
 874     OrdinaryRearAperture(0,0, [ fingerpushhole_dias[0] + epp2i[0],
 875                                 phone[1]/2 ])
 876     scale(fingerpushhole_dias)
 877     circle(r= 0.5 );
 878 }
 879
 880 module RearCameraAperture(){
 881   Flip_rhs(1)
 882     mirror([0, 0, 1])
 883     translate([0,0,0])
 884     hull() // there is some kind of bug if hull() is done in 2D here!
 885     linear_extrude(height = 20)
 886     mirror([0, 1, 0])
 887     translate(bumper)
 888     translate(camera_pos_tl)
 889     for (xy = [ [0,0], [0,1], [1,0] ]) {
 890       translate(
 891           camera_edge_rad * [1,1] +
 892           xy * (camera_sz - camera_edge_rad * 2)
 893                 )
 894         circle(r = camera_edge_rad);
 895     }
 896 }
 897
 898 module HingeLidProfile(){
 899   hull(){
 900     circleat(hppT, hp_r1);
 901     circleat(lpp12, lp_r12);
 902     polygon([lpp10,
 903              lpp13 + [2,0],
 904              lpp12,
 905              hppT]);
 906   }
 907 }
 908
 909 module HingeBaseProfile(){
 910   difference(){
 911     hull(){
 912       circleat(hppB, hp_r1);
 913       circleat(hppE, hp_r1);
 914       circleat(epp2o, case_th_bottom);
 915       circleat(hppB + [10,0], hp_r1);
 916     }
 917     polygon([epp5, epp1, epp3, bppL]);
 918   }
 919 }
 920
 921 module HingeLeverOuterProfile(){
 922   hull(){
 923     circleat(hppT, hp_r2);
 924     circleat(hppB, hp_r2);
 925   }
 926 }
 927
 928 module HingeLeverInnerProfile(){
 929   for (s = [-1,+1]) {
 930     c = s > 0 ? hppT : hppB;
 931     translate(c)
 932       mirror([0,0, s>0 ? 1 : 0])
 933       rotate(s<0 ? -40 : 0)
 934       hull()
 935       for (x=[-20,20])
 936         for (y=[0, s * 10])
 937           translate([x,y])
 938             circle(hp_rn);
 939   }
 940 }
 941
 942 module HingeLeverNutProfile(){
 943   for (c= [hppB, hppT]) {
 944     translate(c)
 945       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 946   }
 947 }
 948
 949 module Flip_hinge(doflip=1){
 950   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 951   translate(hinge_origin)
 952     rotate([doflip*180,0,0])
 953     translate(-hinge_origin)
 954     children();
 955 }
 956
 957 module HingePortion(x0,x1){
 958   Flip_rhs() Flip_bot(1)
 959     translate([x0,0,0])
 960     mirror([1,0,0])
 961     rotate([90,0,-90])
 962     linear_extrude(height=x1-x0)
 963     children();
 964 }
 965
 966 module ThumbRecessApply(ztop){
 967   width = thumbrecess_width;
 968   w = width + thumbrecess_topcurve_r*2 + 1;
 969   translate([phone_width/2, 0,0]){
 970     difference(){
 971       rotate([90,0,-90])
 972         linextr(-w/2, w/2)
 973         children(0);
 974       translate([0, 50, 0])
 975         rotate([90,0,0])
 976         linear_extrude(height=100){
 977         for (m=[0,1]) mirror([m,0,0]) {
 978           hull(){
 979             translate([w/2, ztop - thumbrecess_topcurve_r])
 980               circle(thumbrecess_topcurve_r);
 981             translate([w/2, -50])
 982               square(thumbrecess_topcurve_r*2, center=true);
 983           }
 984         }
 985       }
 986     }
 987   }
 988 }
 989
 990 module CaseBase(){
 991   AroundEdges(epp3[1], case_th_bottom, 1)
 992     EdgeProfile();
 993 }
 994
 995 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 996
 997 module PropProfileAssignments(gamma){
 998   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 999   x = prop_x(gamma);
1000   p = phone_height + prlp10[0] - hppB[0];
1001   b = p + x;
1002
1003   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1004   a = q + x;
1005   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1006   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1007
1008   $prp_theta = 90 - $prp_alpha;
1009   beta = 180 - $prp_alpha - gamma;
1010   psi = 90 - beta;
1011
1012   //echo("abc", a,b,c);
1013
1014   v1 = [ [ cos(psi), -sin(psi) ],    // x
1015          [ sin(psi),  cos(psi) ] ];  // y
1016
1017   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1018
1019   $prp_r1 = prc_r1;
1020   $prp_r11 = prop_main_th/2;
1021
1022   $prpp1 = $prpp7 + [1,0] *
1023     // this is approximate, but will do
1024     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1025   $prpp3 = $prpp1 +
1026     v1[0] * -$prp_r1 +
1027     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1028   $prpp12 = $prpp3 + v1[0] *
1029     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1030   $prp_r8 = prop_main_th;
1031   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1032   $prp_r5 = $prp_r8;
1033   $prpp5 = [ $prpp12[0] - $prp_r5,
1034             $prpp3[1] - prop_prong_h + $prp_r5 ];
1035   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1036          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1037   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1038   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1039
1040   children();
1041 }
1042
1043 module PropProfile(gamma, cut=0, rot=0){
1044   PropProfileAssignments(gamma){
1045
1046     //#circleat($prpp3,1);
1047     //#circleat($prpp12,1);
1048
1049     if (!cut) {
1050       hull(){
1051         translate($prpp8)
1052           intersection(){
1053             circle($prp_r8);
1054             polygon([[-20,-0], [20,20], [0,0]]);
1055           }
1056         rectfromto($prpp6, $prpp9);
1057         translate($prpp5) intersection(){
1058           circle($prp_r5);
1059           polygon([[-10,-10], [0,0], [10,0]]);
1060         }
1061         rectfromto($prpp12 + [0,-0.1], $prpp3);
1062       }
1063       hull(){
1064         circleat($prpp1, $prp_r1);
1065         rectfromto($prpp12 + [0,-0.1], $prpp3);
1066       }
1067     }
1068     // main shaft
1069     rotate([0,0, rot*-$prp_theta]){
1070       hull(){
1071         extra = cut ? prop_recess_slop : 0;
1072         rectfromto($prpp6, $prpp9);
1073         circleat($prpp11, $prp_r11 + extra);
1074         circleat($prpp10, $prp_r10 + extra);
1075       }
1076     }
1077   }
1078 }
1079
1080 module PropAggregateProfile(){
1081   for (angle = prop_angles)
1082     PropProfile(angle, 0,0);
1083 }
1084
1085 module Prop(){ ////toplevel
1086   hw = prop_main_width/2;
1087   linextr(-hw, +hw)
1088     PropAggregateProfile();
1089 }
1090
1091 module Case(){ ////toplevel
1092   difference(){
1093     union(){
1094       CaseBase();
1095
1096       // ledge (fixed keeper)
1097       Flip_rhs(1-keeper_side) intersection(){
1098         rotate([90, 0, 0])
1099           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1100           KeeperProfile(fatter=0, slant=1);
1101
1102         // outline of the whole case, to stop it protruding
1103         translate([0,0, -25])
1104           linear_extrude(height = 50)
1105           hull()
1106           Flip_bot()
1107           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1108       }
1109
1110       // hinge
1111       if (!$suppress_hinge)
1112         HingePortion(hex20, hex21) HingeBaseProfile();
1113
1114       // buildout for prop recess
1115       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1116         linextr(case_bottom_z, epp2i[1])
1117         hull() {
1118           for (dxs = [-1,+1])
1119             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1120                        -epp2o[0] ],
1121                      r = epp2o[0] - prcp2[0]);
1122         }
1123     }
1124
1125     // slot for keeper
1126     Flip_rhs(keeper_side)
1127       translate([0, -phone_cnr_rad, 0])
1128       rotate([90, 0, 0])
1129       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1130       minkowski(){
1131         KeeperProfile(fatter=keeper_fatter_hole);
1132         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1133                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1134       }
1135
1136     // front camera
1137     RearCameraAperture();
1138
1139     // struts (invisible, because they're buried in the case)
1140     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1141
1142     Buttons(){
1143       mirror([1,0,0])
1144         rotate([90,0,90]) {
1145           if (!($button_leg_only && enable_support))
1146           intersection(){
1147             translate([0,0,-10])
1148               linear_extrude(height= 20)
1149               ButtonPlan($button_l, 0,1);
1150             if ($button_leg_only)
1151               rotate([-90,90,0])
1152                 translate([phone_width/2, -400, kppe[1]])
1153                 mirror([1-abs($rhsflip - keeper_side),0,0])
1154                 cube([400, 800, 50]);
1155             if (enable_support && !$button_suppress_over_keeper)
1156               rotate([-90,90,0])
1157               translate([-400, -400, kppd[1]])
1158                 mirror([0,0,1])
1159                 cube([800,800,100]);
1160           }
1161           translate([0,0, -bppR[0]])
1162             linear_extrude(height= 20)
1163             ButtonPlan($button_l, 1,1);
1164         }
1165
1166     }
1167
1168     // apertures along top edge
1169     if (!$suppress_forward_holes) {
1170       // CaseAperture(jack_pos, jack_dia, 8);
1171       Flip_rhs(1)
1172         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1173     }
1174     CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1175
1176     OrdinaryBottomEdgeApertures();
1177
1178     OrdinaryRearApertures();
1179     NotInTestFrameRearApertures();
1180
1181     MicroUSBEtc();
1182
1183     // gaps for the lid's hinge arms
1184     if (!$suppress_hinge) {
1185       HingePortion(hex20 - hinge_x_arms_gap,
1186                    hex21 + hinge_x_arms_gap)
1187         minkowski(){
1188         HingeLidProfile();
1189         circle(r= hinge_r_arms_gap, $fn= 8);
1190       }
1191
1192       // screw holes in the hinge arms
1193       HingeScrews();
1194     }
1195
1196     // thumb recess
1197     ThumbRecessApply(epp4[1])
1198       ThumbRecessCutProfile();
1199
1200     // lanyard
1201     Flip_bot(1)
1202       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1203       rotate([0, ly_theta, 0])
1204       rotate([0,0,90])
1205       LanyardCutout(lanyard_channel_len);
1206
1207     // prop recess
1208     Flip_rhs(1)
1209       translate([prop_x_pos,0,0])
1210       mirror([0,1,0])
1211       rotate([90,0,90])
1212       linextr(-prop_recess_hw, +prop_recess_hw)
1213       hull(){
1214         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1215           circleat(prcp1 + 20*d,
1216                    prc_r3);
1217       }
1218   }
1219 }
1220
1221 module LidAdhocMultiprintFrame(phase){
1222   if (led_window_style >= 3) {
1223     AdhocMultiprintFrame(phase, lpp13[1], -1);
1224   }
1225 }
1226
1227 module LidAroundEdges(){
1228   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1229     children();
1230 }
1231
1232 module Lid(){ ////toplevel
1233   skew_centre = [0, lpp11[0], lpp11[1]];
1234   difference(){
1235     union(){
1236       intersection(){
1237         LidAroundEdges()
1238           LidEdgeProfile();
1239
1240         translate(skew_centre)
1241           multmatrix([[ 1, 0, 0, 0 ],
1242                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1243                       [ 0, 0, 1, 0 ],
1244                       [ 0, 0, 0, 1 ]])
1245           translate(-skew_centre)
1246           LidAroundEdges()
1247           LidEdgeFoldClearanceProfile();
1248       }
1249
1250       // button covers
1251       Buttons(){
1252         intersection(){
1253           rotate([90,0,90])
1254             translate([0,0,-10])
1255             linear_extrude(height= 20)
1256             ButtonPlan($button_l, 1,0);
1257           union(){
1258             rotate([90,0,0])
1259               translate([0,0,-100])
1260               linear_extrude(height= 200)
1261               ButtonCoverProfile();
1262             hull()
1263               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1264                                  - lid_buttoncover_reinf))
1265                 translate([0,y,0])
1266                   ButtonCoverReinf();
1267           }
1268         }
1269       }
1270
1271       // hinge arms
1272       HingePortion(hex20, hex21) {
1273         LidEdgeProfile();
1274         HingeLidProfile();
1275       }
1276     }
1277     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1278
1279     // screw holes in the hinge arms
1280     HingeScrews();
1281
1282     // prop recess
1283     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1284       mirror([0,1,0])
1285       rotate([90,0,90])
1286       linextr(-prop_recess_hw, +prop_recess_hw)
1287       hull()
1288       for (pa = prop_angles)
1289         PropProfile(pa, 1,1);
1290
1291     // notification led aperture
1292     if (led_window_style)
1293       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1294         translate([0,0,-10])
1295           cylinder(r=nla_r0, h=20);
1296         if (led_window_style >= 2)
1297           translate([0,0, -nla_t])
1298             cylinder(r=nla_r2, height=20);
1299       }
1300
1301     }
1302
1303   LidAdhocMultiprintFrame(1);
1304 }
1305
1306 module HingeLever(){ ////toplevel
1307   difference() {
1308     // outer body, positive
1309     HingePortion(hex22, hex22 + phone_width/2)
1310       HingeLeverOuterProfile();
1311
1312     // space for the screws
1313 //    HingePortion(hex26, hex24)
1314 //      HingeLeverInnerProfile();
1315
1316     // recesses for the nuts
1317 //    HingePortion(hex23, hex26+1)
1318 //      HingeLeverNutProfile();
1319
1320     // bores for the screws
1321     HingeScrews();
1322
1323     // space for the charging cable and speaker and micc apertures
1324     hull() {
1325       for (x = [-1,+1]) {
1326         multmatrix([[ 1,0,
1327
1328                      x
1329                      * ( (hex24 + hinge_over_nut_plate) -
1330                          (phone_width/2 - microusb_width/2)
1331                         )
1332                      / ( (epp0[1] - microusb_above)
1333                          -
1334                          (hppB[1] - hp_r2) ),
1335
1336                      x * (epp0[1] - microusb_above)
1337
1338                       ],
1339                     [ 0,1,0, 0 ],
1340                     [ 0,0,1, 0 ]]) {
1341           union(){
1342             MicroUSBEtc();
1343             Flip_hinge() MicroUSBEtc();
1344           }
1345         }
1346       }
1347     }
1348   }
1349 }
1350
1351 module LidWindow(){ ////toplevel
1352   translate([led_pos[0], -led_pos[1], lpp13[1]])
1353     mirror([0,0,1])
1354     cylinder(r= nla_r1, h=nla_t);
1355   LidAdhocMultiprintFrame(0);
1356 }
1357
1358 module LidWindowPrint(){ ////toplevel
1359   rotate([0,180,0])
1360     LidWindow();
1361 }
1362
1363 module DemoLidWindowSelect(){
1364   translate([led_pos[0], led_pos[1], -100]) {
1365     translate([0, -30, 0]) cube([400, 400, 200]);
1366   }
1367 }
1368
1369 module DemoLidWindow(){ ////toplevel
1370   %Lid();
1371   LidWindow();
1372   translate([0,40,0]){
1373     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1374     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1375   }
1376 }
1377
1378 module HingeLeverPrint(){ ////toplevel
1379   rotate([-90,0,0])
1380     translate([-phone_width/2, phone_height, 0])
1381     HingeLever();
1382 }
1383
1384 module TestSelectLength(){
1385   translate([-30, -200, -20])
1386     cube([30 + 15, 250, 40]);
1387 }
1388
1389 module TestLength(){ ////toplevel
1390   intersection(){
1391     Case();
1392     TestSelectLength();
1393   }
1394 }
1395
1396 module TestLengthRight(){ ////toplevel
1397   intersection(){
1398     Case();
1399     Flip_rhs(1)
1400       TestSelectLength();
1401   }
1402 }
1403
1404 module TestSelectWidth(){
1405   translate([-30, -(phone_height - 25), -20])
1406     mirror([0, 1, 0])
1407     cube([200, 50, 40]);
1408 }
1409
1410 module TestWidth(){ ////toplevel
1411   intersection(){
1412     Case();
1413     TestSelectWidth();
1414   }
1415 }
1416
1417 module TestLidWidthPrint(){ ////toplevel
1418   rotate([0,180.0]) intersection(){
1419     Lid();
1420     TestSelectWidth();
1421   }
1422 }
1423
1424 module TestSelectRearAperture(){
1425   minkowski(){
1426     union() children();
1427     translate([20, 0,0])
1428       cube([42, 2, 1], center=true);
1429   }
1430 }
1431
1432 module TestSelectCamera(){
1433   minkowski(){
1434     TestSelectRearAperture()
1435       RearCameraAperture();
1436     cube([0.1, 50, 0.1]);
1437   }
1438 }
1439
1440 module TestSelectOrdinaryRearApertures(){
1441   TestSelectRearAperture()
1442     OrdinaryRearApertures();
1443 }
1444
1445 module TestCamera(){ ////toplevel
1446   intersection(){
1447     Case();
1448     TestSelectCamera();
1449   }
1450 }
1451
1452 module TestLidByCamera(){ ////toplevel
1453   intersection(){
1454     Lid();
1455     TestSelectCamera();
1456   }
1457 }
1458
1459 module TestLidByCameraPrint(){ ////toplevel
1460   rotate([180,0,0]) TestLidByCamera();
1461 }
1462
1463 module DemoByCamera(){ ////toplevel
1464   color("blue") TestLidByCamera();
1465   color("red")  TestCamera();
1466 }
1467
1468 module OneKeeper(){ ////toplevel
1469   translate([0, -phone_cnr_rad, 0])
1470     rotate([90, 0, 0])
1471     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1472     KeeperProfile(fatter=keeper_fatter);
1473 }
1474
1475 module OneKeeperPrint(){ ////toplevel
1476   rotate([0,180,0])
1477     OneKeeper();
1478 }
1479
1480 module LidPrint(){ ////toplevel
1481   rotate([0,180,0])
1482     Lid();
1483 }
1484
1485 module TestSelectFrame(){
1486   include = [1,-1] * (epp2i[0] + 4);
1487
1488   difference(){
1489     cube(1000, center=true);
1490     translate([0,0, -100])
1491       linear_extrude(height=200)
1492       rectfromto(include,  inside_br - include);
1493   }
1494
1495   for (i= [1,2]) {
1496     translate([ 0, -phone[1] * i/3, 0 ])
1497       cube(center=true, [1000, 4, 100]);
1498   }
1499 }
1500
1501 module TestSelectLidFrame(){
1502   TestSelectFrame();
1503   if (len(led_pos))
1504     translate([led_pos[0], -led_pos[1], -50])
1505     cylinder(r= nla_r2+3, h=100);
1506 }
1507
1508 module TestFrameCase(){ ////toplevel
1509   intersection(){
1510     Case();
1511     union(){
1512       TestSelectFrame();
1513       TestSelectCamera();
1514       TestSelectOrdinaryRearApertures();
1515     }
1516   }
1517 }
1518
1519 module TestSelectTopApertures(){
1520   translate([-100, -35, -100])
1521     cube([400, 100, 200]);
1522   LidAdhocMultiprintFrame(0);
1523   LidAdhocMultiprintFrame(1);
1524 }
1525
1526 module TestTopApertures(){ ////toplevel
1527   intersection(){
1528     Case();
1529     TestSelectFrame();
1530     TestSelectTopApertures();
1531   }
1532 }
1533
1534 module TestLidTopAperturesPrint(){ ////toplevel
1535   rotate([0,180,0]) intersection(){
1536     Lid();
1537     TestSelectLidFrame();
1538     TestSelectTopApertures();
1539   }
1540 }
1541
1542 module TestLidWindowTopAperturesPrint(){ ////toplevel
1543   rotate([0,180,0]) intersection(){
1544     LidWindow();
1545     TestSelectTopApertures();
1546   }
1547 }
1548
1549 module TestFrameLidPrint(){ ////toplevel
1550   rotate([0,180,0]) intersection(){
1551     Lid();
1552     TestSelectLidFrame();
1553   }
1554 }
1555
1556 module ButtonPlanForDemo(z, deep, cut){
1557   translate([0,0,z])
1558     ButtonPlan(8, deep, cut);
1559 }
1560
1561 module HingeScrews(){
1562   Flip_rhs() Flip_bot(1){
1563     for (c= [ hppT, hppB ])
1564       translate([ hex20,
1565                   -c[0],
1566                   c[1] ]){
1567         rotate([0,90,0])
1568           translate([0,0,-.2])
1569           cylinder( r= hingescrew_shaft_dia/2,
1570                     h = hingescrew_shaft_len+0.2 );
1571         rotate([0,-90,0])
1572           translate([0,0,+.1])
1573           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1574       }
1575   }
1576 }
1577
1578 module DemoPropAngleSelect(c){
1579   color(c) difference(){
1580     union(){ children(); }
1581     translate([ prop_x_pos, -400, -200 ])
1582       cube([ 400,800,400 ]);
1583   }
1584 }
1585
1586 module DemoPropAngle(ang){
1587   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1588   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1589
1590   translate(hL)
1591     rotate([ang/2,0,0])
1592     translate(-hL)
1593     translate(hC)
1594     rotate([ang/2,0,0])
1595     translate(-hC) {
1596       DemoPropAngleSelect("red") Case();
1597
1598       color("orange")
1599         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1600         PropProfileAssignments(ang) {
1601           echo($prpp1);
1602           rotate([-$prp_theta, 0, 0])
1603           translate([0, $prpp1[0], -$prpp1[1]])
1604           rotate([90,0,-90])
1605           Prop();
1606         }
1607     }
1608
1609   translate([0,0, -hp_k*2])
1610     DemoPropAngleSelect("blue")
1611     Lid();
1612 }
1613
1614 module DemoPropAngles(){ ////toplevel
1615   for (i=[0 : len(prop_angles)-1])
1616     translate(i * [0, -100, 100])
1617     DemoPropAngle(prop_angles[i]);
1618 }
1619
1620 module DemoHingeAngle(ang1,ang2){
1621   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1622   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1623
1624   translate(hL)
1625     rotate([ang2,0,0])
1626     translate(-hL)
1627     translate(hC)
1628     rotate([ang1,0,0])
1629     translate(-hC) {
1630       color("red") Lid();
1631     }
1632
1633   color("blue") intersection(){
1634     Case();
1635     union(){
1636       translate([bppJ[0], -400, -200])
1637         mirror([1,0,0])
1638         cube([400, 800, 400]);
1639       translate([10, -400, -200])
1640         cube([10, 800, 400]);
1641     }
1642   }
1643 }
1644
1645 module DemoHingeAngles(){ ////toplevel
1646   angles = [ 0, 4, 8, 12 ];
1647   echo("angles",angles);
1648   for (i=[0 : len(angles)-1]) {
1649     translate(i * [0, 0, 30]) {
1650       DemoHingeAngle(0,angles[i]);
1651       translate([0, 200, 0])
1652         DemoHingeAngle(angles[i],0);
1653     }
1654   }
1655 }
1656
1657 module DemoSelectAdhocLeftRight(right=0) {
1658   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1659     mirror([1-right, 0,0])
1660     cube([400, 800, 200]);
1661 }
1662
1663 module DemoLeft(){ ////toplevel
1664   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1665   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1666 }
1667
1668 module DemoFrame(){ ////toplevel
1669   color("red") render() TestFrameCase();
1670   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1671   color("black") render() HingeScrews();
1672   %render() HingeLever();
1673 }
1674
1675 module DemoLanyardCutout(){ ////toplevel
1676   LanyardCutout(25);
1677 }
1678
1679 module DemoHingedFrame(){ ///toplevel
1680   color("red") render() TestFrameCase();
1681   translate([0,0, -2*hp_k])
1682   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1683
1684   Flip_hinge(){
1685     color("orange") render() HingeLever();
1686     color("black") render() HingeScrews();
1687   }
1688 }
1689
1690 module DemoHinge(){ ////toplevel
1691   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1692     DemoFrame();
1693     translate([0,0, -hp_k*3])
1694       DemoHingedFrame();
1695   }
1696 }
1697
1698 module DemoProfiles(){ ////toplevel
1699   LidEdgeProfile();
1700   %EdgeProfile();
1701   KeeperProfile();
1702   translate([0,0,-1]) color("black") KeeperProfile(1);
1703   translate(ly_o){
1704     rotate(-ly_theta){
1705       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1706       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1707       translate([0, ly_q_z]){
1708         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1709         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1710       }
1711     }
1712   }
1713   translate([0,0,-5]) color("white") translate(epp2i)
1714     rotate(-ly_theta)
1715     rectfromto([-15, 0],
1716                [+15, -max_case_bottom_edge_thickness]);
1717
1718   translate([0,20]) {
1719     LanyardMainChannelProfile();
1720     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1721     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1722   }
1723
1724   translate([20,0]) {
1725     LidEdgeProfile();
1726     %EdgeProfile();
1727
1728     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1729
1730     color("blue") ButtonCoverProfile();
1731     color("red") {
1732       rectfromto(bppQ, demopoint_QR);
1733       rectfromto(bppR, demopoint_QR);
1734     }
1735   }
1736
1737   translate([-20,0]) {
1738     color("black") ButtonPlanForDemo(-2, 0,1);
1739     color("red" )  ButtonPlanForDemo(-4, 1,1);
1740     color("blue")  ButtonPlanForDemo(-6, 1,0);
1741   }
1742
1743   translate([0, -30]) {
1744     %LidEdgeProfile();
1745     %EdgeProfile();
1746     color("blue") HingeLidProfile();
1747     color("red")  HingeBaseProfile();
1748     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1749   }
1750
1751   for (f=[0,1]) {
1752     translate([-30, -60 + 30*f]) {
1753       translate([0,0,-4]) EdgeProfile();
1754       %translate([0,0,-10]) HingeBaseProfile();
1755       translate([0,-2] * f * hp_k) {
1756         translate([0,0,-4]) LidEdgeProfile();
1757         %translate([0,0,-10]) %HingeLidProfile();
1758       }
1759       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1760         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1761         translate([0,0,0]) color("red") difference(){
1762           HingeLeverOuterProfile();
1763           HingeLeverInnerProfile();
1764         }
1765         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1766       }
1767     }
1768   }
1769
1770   translate([20,-30]) {
1771     %EdgeProfile();
1772     %LidEdgeProfile();
1773     //translate([0,0,1]) ThumbRecessCutProfile();
1774     translate([0,0,+1]) color("red")
1775       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1776   }
1777
1778   translate([40,-30]) {
1779     difference(){
1780       LidEdgeProfile();
1781       translate(prlp10)
1782         PropProfile(10, 1, 0);
1783     }
1784     translate(prlp10)
1785       PropProfile(15, 0);
1786   }
1787   translate([60,-30]) {
1788     PropAggregateProfile();
1789   }
1790 }
1791
1792 //EdgeProfile();
1793 //KeeperProfile();
1794 //CaseBase();
1795 //%Case();
1796 //Keeper();
1797 //LidEdgeProfile();
1798 //KeeperProfile();
1799 //DemoProfiles();
1800 //PropRecess();