fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 7.37 /* xxx? */ ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 // fingerpushhole_dias = []; xxx what was this
 169 fingerpushhole_dias = [ 15, 18 ];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 8;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 1.64 - 0.25;
 178 microusb_below = 2.42;
 179 microusb_width = 12.16 + 2.0 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // xxx replace hinge screw with nail plan
 219
 220 // properties of the hinge fasteners
 221 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 222 hingescrew_shaft_len = 12;
 223 hingescrew_fasteners_extra_thick = 0.40;
 224 // ^ amount of thread protruding if everything was completely nominal
 225 //   and we are using two nuts
 226 hingescrew_nut_access_dia = 4.72 + 0.50;
 227 // ^ washer is 4.72 dia
 228 //   also, want to get pliers or tiny spanner in to do up locknut
 229 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 230 hingescrew_nut_thick = 1.93;
 231 hingescrew_head_th = 1.38 + 0.75;
 232 hingescrew_head_dia = 3.92;
 233
 234 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 235
 236 lever_cover_th = 0.75;
 237 hingemount_th = 2.5;
 238 hingemount_wd = 4.8725;
 239
 240 $fa = 5;
 241 $fs = 0.1;
 242
 243 button_l_fudge = 4.4;
 244 buttonishleg_default_l_is_fudge = 10;
 245
 246 hinge_base_slope = 1.5; // bigger is steeper
 247
 248 strut_min_at_end = 1.5;
 249
 250 hinge_x_gap = 0.125;
 251 hinge_x_postscrew_gap = 0.75;
 252 hinge_x_arms_gap = 0.35;
 253 hinge_r_arms_gap = 0.55;
 254
 255 // xxx there isn't one of these, speaker is by hinge
 256 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 257
 258 thumbrecess_depth = 1.3;
 259 thumbrecess_width = 16.5;
 260 thumbrecess_topcurve_r = 5.0;
 261
 262 prop_recess_under = 0.50;
 263 prop_recess_slop = 0.200; // each side
 264 prop_end_dia = 0.5;
 265 prop_main_th = 3;
 266 prop_taper_len = 6;
 267 prop_main_width = 4;
 268 prop_side_gap = 0.75; // each side
 269 prop_lidrecess_behind = 0.75;
 270 prop_caserecess_behind = 0.75;
 271 prop_caserecess_taper = 0.45; // one side only
 272 prop_prop_gap = 0.5;
 273 prop_prong_heel_slope = 0.5;
 274
 275 lid_fold_clearance_antislop = 0.5;
 276
 277 $button_leg_only = false;
 278 $suppress_forward_holes = false;
 279
 280 // ---------- calculated ----------
 281
 282 phone_total_thick = phone_edge_thick;
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 299
 300 //prop_nose_len = case_th_lid - prop_recess_under;
 301 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 302 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 303
 304
 305 //lid_lip_overlap_width xxx bad name = ;
 306 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 307
 308 epp0 = [0,0];
 309 epp1 = [0, -phone_edge_thick];
 310 epp2i = epp1; // conflated for FP4
 311 epp2o = epp2i;
 312 epp3 = epp2i + [10, 0];
 313 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 314 epp4 = epp5 + [-1,0] * case_th_side;
 315
 316 kppe = [0,0];
 317 kppd = kppe + [1,0] * keeper_inner_width;
 318 kppc = kppd + [0,1] * keeper_th_z;
 319 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 320 kppf = kppe - [0,1] * keeper_inner_height;
 321 kppa = [ kppb[0], kppf[1] ];
 322
 323 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 324 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 325
 326 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 327 // exact x posn not very important; must extend past end of keeper
 328
 329 lpp15 = [ lpp14[0],
 330           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 331           + lid_screen_gap_extra ];
 332 // ^ beam theory says to maximise force before contact,
 333 //   the gap below the `beam' (the lid) must be 1/3
 334 //   the thickness (ie the lid thickness) if the beam
 335 //   is solid, or 1/2 if it has a top and bottom only.
 336 //   ours is mostly solid.
 337
 338 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 339              case_th_lip);
 340
 341 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 342 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 343
 344 case_bottom_z = epp2o[1] - case_th_bottom;
 345
 346 // button profile
 347 bppM = epp4 + [0,5];
 348 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 349 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 350 bppS = [ epp1[0], bppR[1] ];
 351 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 352 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 353 bppO = [ bppN[0], bppP[1] ];
 354 bppL = lpp10 + [5,0];
 355 bppK = [ bppL[0], bppN[1] ];
 356 bppJ = [ bppN[0], bppL[1] ];
 357 bppU = [ bppJ[0], lpp12[1] ];
 358 bppV = lpp11;
 359 bppW = lpp10;
 360
 361 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 362
 363 // notification led aperture
 364
 365 nla_r0 = led_aperture/2;
 366 nla_r1 = nla_r0 + led_window_ledge;
 367 nla_r2 = nla_r1 + multicolour_gap;
 368 nla_t =
 369   led_window_style >= 3 ? initial_layer_thick :
 370   led_window_style >= 2 ? led_window_ledge : 0;
 371
 372
 373 // hinge plan
 374 hp_rn = hingescrew_nut_access_dia/2;
 375 hp_r2_min = hp_rn + lever_cover_th;
 376 hp_rs = hingescrew_shaft_dia/2;
 377 hp_r1_min = hp_rs + hingemount_th;
 378
 379 hp_r1 = max(hp_r1_min, hp_r2_min);
 380 hp_r2 = hp_r1;
 381
 382 hppU = lpp13;
 383 hppS = epp2o + [0,-1] * case_th_bottom;
 384 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 385
 386 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 387          0.5 * (hppU + hppS)[1] ];
 388 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 389 hppB = hppT + [0,-1] * hp_k;
 390
 391 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 392 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 393 hppE = [ hppE_x, hppE_y ];
 394
 395 // hinge elevation x coords
 396
 397 hex20 = max(epp2o[0],
 398             phone_cnr_rad,
 399             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 400 hex21 = hex20 + hingemount_wd;
 401 hex22 = hex21 + hinge_x_gap;
 402 hex27 = hex20 + hingescrew_shaft_len;
 403 hex24 = hex27 + hinge_x_postscrew_gap;
 404 hex23 = hex27 - (hingescrew_nut_thick*2
 405                  + hingescrew_fasteners_extra_thick);
 406 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 407
 408 echo(hex20, hex21, hex22, hex23, hex24);
 409 //  6, 10.8725, 10.9975, 13.74, 18.75
 410 module chk(act,exp) {
 411   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 412   else echo("ok", act);
 413 }
 414 chk(hex20, 6);
 415 chk(hex21, 10.8725);
 416 chk(hex22, 10.9975);
 417 chk(hex23, 13.74);
 418 chk(hex24, 18.75);
 419
 420 lid_fold_clearance_skew =
 421   (lpp10[1] - hppB[1]) /
 422   (lpp10[0] - hppB[0]);
 423
 424 echo("SK",lid_fold_clearance_skew);
 425
 426 // thumb recess (used to be "catch" hence cpp*
 427
 428 cppA = epp4 + [thumbrecess_depth, 0];
 429 cppB = [ cppA[0], epp1[1] ];
 430
 431 // lanyard
 432
 433 ly_r = lanyard_half_dia / 2;
 434 ly_rc = ly_r * 2;
 435
 436 ly_theta = 90;
 437 ly_o = epp2i + 3 * ly_r * [0,1];
 438
 439 max_case_bottom_edge_thickness =
 440   case_th_bottom;
 441
 442 ly_q_z = -(ly_rc + ly_r);
 443 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 444
 445 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 446
 447 // prop recess in case
 448
 449 prop_x_pos = phone_width/2;
 450
 451 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 452
 453 prc_r1 = prop_end_dia/2;
 454 prc_r3 = prc_r1 + prop_recess_slop;
 455
 456 prcp2 = [ epp4[0] + prop_buildout_less,
 457           case_bottom_z ];
 458
 459 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 460
 461 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 462           epp2i[1] - prc_r3 - prop_recess_under];
 463
 464 // prop recess in lid
 465
 466 prl_r10 = prop_end_dia/2;
 467 prl_r10o = prl_r10 + prop_recess_slop;
 468
 469 prlp10 = lpp10 + [1,1] * prl_r10o
 470   + [1,0] * prop_lidrecess_behind
 471   + [0,1] * prop_recess_under;
 472
 473 // prop
 474
 475 $prpp10 = [0,0];
 476 $prpp11 = [0, prop_taper_len];
 477
 478 $prp_r10 = prl_r10;
 479
 480 // ---------- modules ----------
 481
 482 module AdhocMultiprintFrame(phase, z0, zs) {
 483   // from z0 to z0 + zs*layer
 484   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 485   xextra = extra + -epp4[0];
 486   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 487   yextra = extra + -epp4[0];
 488   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 489   p0 = [ xrange[0], yrange[0] ];
 490   p1 = [ xrange[1], yrange[1] ];
 491   echo(p0, p1);
 492   translate([0,0, z0])
 493     mirror([0,0, zs<0 ? 1 : 0])
 494     linear_extrude(height= initial_layer_thick)
 495     difference(){
 496       rectfromto(p0 - [1,1] * initial_layer_width,
 497                  p1 + [1,1] * initial_layer_width);
 498       rectfromto(p0, p1);
 499     }
 500 }
 501
 502 module KeeperProfile(slant=0){
 503   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 504   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 505 }
 506
 507 module EdgeProfile(){
 508   difference(){
 509     hull(){
 510       translate(epp3) square(case_th_bottom*2, center=true);
 511       circleat(epp2o, r=case_th_bottom);
 512       circleat(epp1, r=case_th_side);
 513       rectfromto(epp0, epp4);
 514     }
 515     polygon([ epp5 + [0,10],
 516               epp1,
 517               epp3 + [10,0] ]);
 518   }
 519 }
 520
 521 module LanyardLanyardProfile(entry=false){
 522   hull(){
 523     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 524       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 525         circle(r= lanyard_half_dia/2);
 526   }
 527 }
 528
 529 module LanyardCurveChannelProfile(){
 530   translate([0, -ly_r])
 531     LanyardLanyardProfile();
 532 }
 533
 534 module LanyardEntryChannelProfile(){
 535   LanyardLanyardProfile(true);
 536 }
 537
 538 module LanyardMainChannelProfile(){
 539   LanyardCurveChannelProfile();
 540   difference(){
 541     square(center=true, ly_r * [6, 2]);
 542     for (xs=[-1,+1])
 543       translate(ly_r * [3 * xs, -1])
 544         circle(r = ly_r);
 545   }
 546 }
 547
 548 module LanyardEntryOuterProfile(){
 549   circleat([ly_re + ly_r, 0], ly_re);
 550 }
 551
 552 module LanyardEntry(){
 553   q_z = ly_q_z;
 554   oec_y = ly_oec_y;
 555
 556   d_x = -ly_rc;
 557
 558   translate([d_x, 0, q_z]) {
 559     intersection(){
 560       rotate([90,0,0])
 561         rotate_extrude(convexity=10)
 562         rotate(90)
 563         translate([0, -q_z])
 564         LanyardCurveChannelProfile();
 565       translate([0,-10,0])
 566         cube([20,20,20]);
 567     }
 568   }
 569
 570   mirror([0,0,1])
 571     translate([0,0,-1])
 572     linear_extrude(height=20)
 573     rotate(-90)
 574     LanyardEntryChannelProfile();
 575
 576   translate([0, ly_r*2, 0])
 577     rotate([90,0,0])
 578     linear_extrude(height = ly_r*4){
 579     difference(){
 580       rectfromto([d_x, q_z], [ly_r, 0]);
 581       circleat([d_x, q_z], ly_rc);
 582     }
 583   }
 584
 585   translate([0,0,q_z]){
 586     for (my=[0,1])
 587       mirror([0,my,0]){
 588         translate([0, oec_y, 0]){
 589           difference(){
 590             translate(ly_re * [-1,0,-2])
 591               cube(ly_re * [2,1,2]);
 592             rotate_extrude(convexity=10)
 593               LanyardEntryOuterProfile();
 594           }
 595         }
 596       }
 597     difference(){
 598       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 599         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 600       for (mx=[0,1])
 601         mirror([mx,0,0])
 602           rotate([90,0,0])
 603           translate([0,0,-10])
 604           linear_extrude(height=20)
 605           LanyardEntryOuterProfile();
 606     }
 607   }
 608 }
 609
 610 module LanyardCutout(l){
 611   rotate([0,-90,0])
 612     linear_extrude(height=l)
 613     rotate(-90)
 614     LanyardMainChannelProfile();
 615
 616   for (ee=[0,1]){
 617     translate(ee * l * [-1,0])
 618       mirror([ee,0,0])
 619       LanyardEntry();
 620   }
 621 }
 622
 623 module LidEdgeProfile(){
 624   polygon([ lpp10,
 625             lpp11,
 626             lpp12,
 627             lpp13,
 628             lpp13 + [10, 0],
 629             lpp15 + [10, 0],
 630             lpp15,
 631             lpp14,
 632             ]);
 633   intersection(){
 634     circleat(lpp12, r=lp_r12);
 635     rectfromto( lpp12 + [-10,   0],
 636                 lpp12 + [+10, +10] );
 637   }
 638 }
 639
 640 module LidEdgeFoldClearanceProfile(){
 641   translate([-lid_fold_clearance_antislop, 0])
 642     polygon([ lpp10,
 643               lpp11,
 644               lpp11 + [-20,  0],
 645               lpp11 + [-20, 20],
 646               lpp11 + [+20, 20],
 647               lpp10 + [+20,  0] ]);
 648 }
 649
 650 module ButtonCoverProfile(){
 651   intersection(){
 652     polygon(concat([ bppM, bppP, bppO, bppJ ],
 653                    (enable_support && !$button_suppress_over_keeper
 654                     ? [ bppU, bppV, bppW ] : []),
 655                    [ bppL, bppK ]));
 656     hull(){
 657       EdgeProfile();
 658       LidEdgeProfile();
 659     }
 660   }
 661 }
 662
 663 module ButtonPlan(l, deep, cut){
 664   epsilon =
 665     (cut  ? 0 : lid_buttoncover_gap);
 666
 667   delta =
 668     (deep ? lid_buttoncover_overlap : 0);
 669
 670   C = [0,0]; // by definition
 671   T = [ 0, epp4[1] ];
 672   G = T + [0,10];
 673
 674   B0 = C + [0,-1] * button_cutout_depth;
 675   B1 = B0 + [0,1] * epsilon;
 676
 677   r0 = 0.5 * (T[1] - B0[1]);
 678   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 679   H = A + [0,-1] * delta;
 680
 681   D = A + [-2,0] * r0;
 682   F = D + [0,10];
 683
 684   E0 = 0.5 * (D + A);
 685   E1 = E0 + [1,0] * epsilon;
 686
 687   I0 = [ E0[0], H[1] ];
 688   I1 = [ E1[0], H[1] ];
 689
 690   hull(){
 691     for (m=[0,1]) mirror([m,0])
 692       circleat(H, r0 - epsilon);
 693   }
 694   for (m=[0,1]) mirror([m,0]) {
 695     difference(){
 696       polygon([ E1,
 697                 I1,
 698                 H,
 699                 B1,
 700                 G,
 701                 F,
 702                 D
 703                 ]);
 704       circleat(D, r0 + epsilon);
 705     }
 706   }
 707 }
 708
 709 module ButtonCoverReinf(){ ////toplevel
 710   minkowski(){
 711     rotate([90,0,0])
 712       linear_extrude(height=0.01)
 713       intersection(){
 714         ButtonCoverProfile();
 715         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 716           square([100,100]);
 717     }
 718     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 719       circle(r= lid_buttoncover_reinf);
 720       translate([-20,0]) square(40, center=true);
 721     }
 722   }
 723 }
 724
 725 module ThumbRecessCutProfile(){
 726   difference(){
 727     polygon([ cppA + [-10,0],
 728               cppB + [-10,0],
 729               cppB,
 730               cppA ]);
 731     circleat(epp1, r=case_th_side);
 732   }
 733 }
 734
 735 module Flip_rhs(yn=[0,1]) {
 736   for ($rhsflip=yn) {
 737     translate([phone_width/2, 0, 0])
 738       mirror([$rhsflip,0,0])
 739       translate([-phone_width/2, 0, 0])
 740       children();
 741   }
 742 }
 743
 744 module Flip_bot(yn=[0,1]) {
 745   for ($botflip=yn) {
 746     translate([0, -phone_height/2, 0])
 747       mirror([0, $botflip, 0])
 748       translate([0, phone_height/2, 0])
 749       children();
 750   }
 751 }
 752
 753 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 754   // sides
 755   Flip_rhs(){
 756     translate([0, -phone_cnr_rad, 0])
 757       rotate([90,0,0])
 758       linear_extrude(height = phone_height - phone_cnr_rad*2)
 759       children(0);
 760   }
 761   // corners
 762   Flip_rhs() Flip_bot() {
 763     translate([+1,-1] * phone_cnr_rad)
 764       intersection(){
 765         rotate_extrude()
 766           intersection(){
 767             mirror([1,0,0])
 768               translate([-1,0] * phone_cnr_rad)
 769               children(0);
 770             rectfromto([0,-20],[10,20]);
 771           }
 772         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 773           cube([10,10,40]);
 774       }
 775   }
 776   // top and bottom
 777   Flip_bot(){
 778     translate([ phone_width - phone_cnr_rad, 0,0 ])
 779       rotate([90,0,-90])
 780       linear_extrude(height = phone_width - phone_cnr_rad*2)
 781       children(0);
 782   }
 783   // fill
 784   translate([0,0, fill_zstart])
 785     mirror([0,0, fill_downwards])
 786     linear_extrude(height = fill_th)
 787     rectfromto([+1,-1] * phone_cnr_rad,
 788                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 789 }
 790
 791 module CaseAperture(pos, dia, $fn) {
 792   theta = 180/$fn;
 793   translate([ bumper[0],
 794               -epp2i[0],
 795                0 ])
 796     translate([ pos[0], 0, -pos[1] ])
 797     rotate([-90, theta, 0])
 798     cylinder(r = dia/2 / cos(theta),
 799              h = 60);
 800 }
 801
 802 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 803   // y_ref_sign:
 804   //   +1  measured from top    of actual phone to top    of button
 805   //   -1  measured from bottom of actual phone to bottom of button
 806   //    0  y is centre of button in coordinate system
 807   $button_l= l;
 808   $button_suppress_over_keeper= suppress_over_keeper;
 809   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 810           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 811           y;
 812   //echo(eff_y);
 813   translate([0, eff_y, 0])
 814     children();
 815 }
 816
 817 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 818   $button_leg_only = true;
 819   SideButton(y, y_ref_sign, l) children();
 820 }
 821
 822 module Buttons(){
 823   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 824   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 825   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 826   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 827   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 828   // xxx need hole for whatever that hole is on lhs
 829 }
 830
 831 module Struts(x_start, z_min, th){
 832   // if th is negative, starts at z_min and works towards -ve z
 833   // and object should then be printed other way up
 834   for (i= [1 : 1 : case_struts_count]) {
 835     translate([0,
 836                0,
 837                z_min])
 838       mirror([0,0, th<0 ? 1 : 0])
 839       translate([0,
 840                  -phone_height * i / (case_struts_count+1),
 841                  case_struts_solid_below])
 842       linear_extrude(height= abs(th)
 843                      -(case_struts_solid_below+case_struts_solid_above))
 844       rectfromto([               x_start, -0.5 * case_struts_width ],
 845                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 846   }
 847 }
 848
 849 module OrdinaryRearAperture(rhs,bot, pos){
 850   Flip_rhs(rhs) Flip_bot(bot)
 851     linextr(-20, 20)
 852     mirror([0,1])
 853     translate(pos + bumper)
 854     children();
 855 }
 856
 857 module MicroUSB(){
 858   Flip_bot(1){
 859     rotate([90,0,0])
 860       mirror([0,0,1])
 861       linextr(-epp2i[0], 60)
 862       translate([0.5 * phone_width, 0, 0])
 863       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 864                  [+microusb_width/2, epp0[1] + -microusb_above]);
 865   }
 866 }
 867
 868 module OrdinaryRearApertures(){
 869   // rear speaker
 870   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 871     rectfromto(-rearspeaker_gap,
 872                rearspeaker_size + rearspeaker_gap);
 873
 874   // finger hole to remove phone
 875   if (len(fingerpushhole_dias))
 876     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 877                                 phone[1]/2 ])
 878     scale(fingerpushhole_dias)
 879     circle(r= 0.5 );
 880 }
 881
 882 module RearCameraAperture(){
 883   Flip_rhs(1)
 884     mirror([0, 0, 1])
 885     linear_extrude(height = 20)
 886     mirror([0, 1, 0])
 887     translate(bumper)
 888     rectfromto(camera_pos_tl, camera_pos_br);
 889 }
 890
 891 module HingeLidProfile(){
 892   hull(){
 893     circleat(hppT, hp_r1);
 894     circleat(lpp12, lp_r12);
 895     polygon([lpp10,
 896              lpp13 + [2,0],
 897              lpp12,
 898              hppT]);
 899   }
 900 }
 901
 902 module HingeBaseProfile(){
 903   difference(){
 904     hull(){
 905       circleat(hppB, hp_r1);
 906       circleat(hppE, hp_r1);
 907       circleat(epp2o, case_th_bottom);
 908       circleat(hppB + [10,0], hp_r1);
 909     }
 910     polygon([epp5, epp1, epp3, bppL]);
 911   }
 912 }
 913
 914 module HingeLeverOuterProfile(){
 915   hull(){
 916     circleat(hppT, hp_r2);
 917     circleat(hppB, hp_r2);
 918   }
 919 }
 920
 921 module HingeLeverInnerProfile(){
 922   for (s = [-1,+1]) {
 923     c = s > 0 ? hppT : hppB;
 924     translate(c)
 925       mirror([0,0,s>0])
 926       rotate(s<0 ? -40 : 0)
 927       hull()
 928       for (x=[-20,20])
 929         for (y=[0, s * 10])
 930           translate([x,y])
 931             circle(hp_rn);
 932   }
 933 }
 934
 935 module HingeLeverNutProfile(){
 936   for (c= [hppB, hppT]) {
 937     translate(c)
 938       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 939   }
 940 }
 941
 942 module Flip_hinge(doflip=1){
 943   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 944   translate(hinge_origin)
 945     rotate([doflip*180,0,0])
 946     translate(-hinge_origin)
 947     children();
 948 }
 949
 950 module HingePortion(x0,x1){
 951   Flip_rhs() Flip_bot(1)
 952     translate([x0,0,0])
 953     mirror([1,0,0])
 954     rotate([90,0,-90])
 955     linear_extrude(height=x1-x0)
 956     children();
 957 }
 958
 959 module ThumbRecessApply(ztop){
 960   width = thumbrecess_width;
 961   w = width + thumbrecess_topcurve_r*2 + 1;
 962   translate([phone_width/2, 0,0]){
 963     difference(){
 964       rotate([90,0,-90])
 965         linextr(-w/2, w/2)
 966         children(0);
 967       translate([0, 50, 0])
 968         rotate([90,0,0])
 969         linear_extrude(height=100){
 970         for (m=[0,1]) mirror([m,0,0]) {
 971           hull(){
 972             translate([w/2, ztop - thumbrecess_topcurve_r])
 973               circle(thumbrecess_topcurve_r);
 974             translate([w/2, -50])
 975               square(thumbrecess_topcurve_r*2, center=true);
 976           }
 977         }
 978       }
 979     }
 980   }
 981 }
 982
 983 module CaseBase(){
 984   AroundEdges(epp3[1], case_th_bottom, 1)
 985     EdgeProfile();
 986 }
 987
 988 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 989
 990 module PropProfileAssignments(gamma){
 991   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 992   x = prop_x(gamma);
 993   p = phone_height + prlp10[0] - hppB[0];
 994   b = p + x;
 995
 996   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 997   a = q + x;
 998   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 999   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1000
1001   $prp_theta = 90 - $prp_alpha;
1002   beta = 180 - $prp_alpha - gamma;
1003   psi = 90 - beta;
1004
1005   //echo("abc", a,b,c);
1006
1007   v1 = [ [ cos(psi), -sin(psi) ],    // x
1008          [ sin(psi),  cos(psi) ] ];  // y
1009
1010   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1011
1012   $prp_r1 = prc_r1;
1013   $prp_r11 = prop_main_th/2;
1014
1015   $prpp1 = $prpp7 + [1,0] *
1016     // this is approximate, but will do
1017     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1018   $prpp3 = $prpp1 +
1019     v1[0] * -$prp_r1 +
1020     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1021   $prpp12 = $prpp3 + v1[0] *
1022     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1023   $prp_r8 = prop_main_th;
1024   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1025   $prp_r5 = $prp_r8;
1026   $prpp5 = [ $prpp12[0] - $prp_r5,
1027             $prpp3[1] - prop_prong_h + $prp_r5 ];
1028   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1029          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1030   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1031   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1032
1033   children();
1034 }
1035
1036 module PropProfile(gamma, cut=0, rot=0){
1037   PropProfileAssignments(gamma){
1038
1039     //#circleat($prpp3,1);
1040     //#circleat($prpp12,1);
1041
1042     if (!cut) {
1043       hull(){
1044         translate($prpp8)
1045           intersection(){
1046             circle($prp_r8);
1047             polygon([[-20,-0], [20,20], [0,0]]);
1048           }
1049         rectfromto($prpp6, $prpp9);
1050         translate($prpp5) intersection(){
1051           circle($prp_r5);
1052           polygon([[-10,-10], [0,0], [10,0]]);
1053         }
1054         rectfromto($prpp12 + [0,-0.1], $prpp3);
1055       }
1056       hull(){
1057         circleat($prpp1, $prp_r1);
1058         rectfromto($prpp12 + [0,-0.1], $prpp3);
1059       }
1060     }
1061     // main shaft
1062     rotate([0,0, rot*-$prp_theta]){
1063       hull(){
1064         extra = cut ? prop_recess_slop : 0;
1065         rectfromto($prpp6, $prpp9);
1066         circleat($prpp11, $prp_r11 + extra);
1067         circleat($prpp10, $prp_r10 + extra);
1068       }
1069     }
1070   }
1071 }
1072
1073 module PropAggregateProfile(){
1074   for (angle = prop_angles)
1075     PropProfile(angle, 0,0);
1076 }
1077
1078 module Prop(){ ////toplevel
1079   hw = prop_main_width/2;
1080   linextr(-hw, +hw)
1081     PropAggregateProfile();
1082 }
1083
1084 module Case(){ ////toplevel
1085   difference(){
1086     union(){
1087       CaseBase();
1088
1089       // ledge (fixed keeper)
1090       Flip_rhs(1-keeper_side) intersection(){
1091         rotate([90, 0, 0])
1092           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1093           KeeperProfile(1);
1094
1095         // outline of the whole case, to stop it protruding
1096         translate([0,0, -25])
1097           linear_extrude(height = 50)
1098           hull()
1099           Flip_bot()
1100           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1101       }
1102
1103       // hinge
1104       HingePortion(hex20, hex21) HingeBaseProfile();
1105
1106       // buildout for prop recess
1107       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1108         linextr(case_bottom_z, epp2i[1])
1109         hull() {
1110           for (dxs = [-1,+1])
1111             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1112                        -epp2o[0] ],
1113                      r = epp2o[0] - prcp2[0]);
1114         }
1115     }
1116
1117     // slot for keeper
1118     Flip_rhs(keeper_side)
1119       translate([0, -phone_cnr_rad, 0])
1120       rotate([90, 0, 0])
1121       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1122       minkowski(){
1123         KeeperProfile();
1124         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1125                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1126       }
1127
1128     // front camera
1129     RearCameraAperture();
1130
1131     // struts (invisible, because they're buried in the case)
1132     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1133
1134     Buttons(){
1135       mirror([1,0,0])
1136         rotate([90,0,90]) {
1137           if (!($button_leg_only && enable_support))
1138           intersection(){
1139             translate([0,0,-10])
1140               linear_extrude(height= 20)
1141               ButtonPlan($button_l, 0,1);
1142             if ($button_leg_only)
1143               rotate([-90,90,0])
1144                 translate([phone_width/2, -400, kppe[1]])
1145                 mirror([1-abs($rhsflip - keeper_side),0,0])
1146                 cube([400, 800, 50]);
1147             if (enable_support && !$button_suppress_over_keeper)
1148               rotate([-90,90,0])
1149               translate([-400, -400, kppd[1]])
1150                 mirror([0,0,1])
1151                 cube([800,800,100]);
1152           }
1153           translate([0,0, -bppR[0]])
1154             linear_extrude(height= 20)
1155             ButtonPlan($button_l, 1,1);
1156         }
1157
1158     }
1159
1160     // apertures along top edge
1161     if (!$suppress_forward_holes) {
1162       // CaseAperture(jack_pos, jack_dia, 8);
1163       Flip_rhs(1)
1164         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1165     }
1166
1167     OrdinaryRearApertures();
1168
1169     MicroUSB();
1170
1171     // gaps for the lid's hinge arms
1172     HingePortion(hex20 - hinge_x_arms_gap,
1173                  hex21 + hinge_x_arms_gap)
1174       minkowski(){
1175         HingeLidProfile();
1176         circle(r= hinge_r_arms_gap, $fn= 8);
1177       }
1178
1179     // screw holes in the hinge arms
1180     HingeScrews();
1181
1182     // thumb recess
1183     ThumbRecessApply(epp4[1])
1184       ThumbRecessCutProfile();
1185
1186     // lanyard
1187     Flip_bot(1)
1188       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1189       rotate([0, ly_theta, 0])
1190       rotate([0,0,90])
1191       LanyardCutout(lanyard_channel_len);
1192
1193     // prop recess
1194     Flip_rhs(1)
1195       translate([prop_x_pos,0,0])
1196       mirror([0,1,0])
1197       rotate([90,0,90])
1198       linextr(-prop_recess_hw, +prop_recess_hw)
1199       hull(){
1200         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1201           circleat(prcp1 + 20*d,
1202                    prc_r3);
1203       }
1204   }
1205 }
1206
1207 module LidAdhocMultiprintFrame(phase){
1208   if (led_window_style >= 3) {
1209     AdhocMultiprintFrame(phase, lpp13[1], -1);
1210   }
1211 }
1212
1213 module LidAroundEdges(){
1214   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1215     children();
1216 }
1217
1218 module Lid(){ ////toplevel
1219   skew_centre = [0, lpp11[0], lpp11[1]];
1220   difference(){
1221     union(){
1222       intersection(){
1223         LidAroundEdges()
1224           LidEdgeProfile();
1225
1226         translate(skew_centre)
1227           multmatrix([[ 1, 0, 0, 0 ],
1228                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1229                       [ 0, 0, 1, 0 ],
1230                       [ 0, 0, 0, 1 ]])
1231           translate(-skew_centre)
1232           LidAroundEdges()
1233           LidEdgeFoldClearanceProfile();
1234       }
1235
1236       // button covers
1237       Buttons(){
1238         intersection(){
1239           rotate([90,0,90])
1240             translate([0,0,-10])
1241             linear_extrude(height= 20)
1242             ButtonPlan($button_l, 1,0);
1243           union(){
1244             rotate([90,0,0])
1245               translate([0,0,-100])
1246               linear_extrude(height= 200)
1247               ButtonCoverProfile();
1248             hull()
1249               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1250                                  - lid_buttoncover_reinf))
1251                 translate([0,y,0])
1252                   ButtonCoverReinf();
1253           }
1254         }
1255       }
1256
1257       // hinge arms
1258       HingePortion(hex20, hex21) {
1259         LidEdgeProfile();
1260         HingeLidProfile();
1261       }
1262     }
1263     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1264
1265     // screw holes in the hinge arms
1266     HingeScrews();
1267
1268     // prop recess
1269     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1270       mirror([0,1,0])
1271       rotate([90,0,90])
1272       linextr(-prop_recess_hw, +prop_recess_hw)
1273       hull()
1274       for (pa = prop_angles)
1275         PropProfile(pa, 1,1);
1276
1277     // notification led aperture
1278     if (led_window_style)
1279       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1280         translate([0,0,-10])
1281           cylinder(r=nla_r0, h=20);
1282         if (led_window_style >= 2)
1283           translate([0,0, -nla_t])
1284             cylinder(r=nla_r2, height=20);
1285       }
1286
1287     }
1288
1289   LidAdhocMultiprintFrame(1);
1290 }
1291
1292 module HingeLever(){ ////toplevel
1293   difference() {
1294     // outer body, positive
1295     HingePortion(hex22, hex22 + phone_width/2)
1296       HingeLeverOuterProfile();
1297
1298     // space for the screws
1299     HingePortion(hex26, hex24)
1300       HingeLeverInnerProfile();
1301
1302     // recesses for the nuts
1303     HingePortion(hex23, hex26+1)
1304       HingeLeverNutProfile();
1305
1306     // bores for the screws
1307     HingeScrews();
1308
1309     // space for the charging cable
1310     MicroUSB();
1311     Flip_hinge() MicroUSB();
1312   }
1313 }
1314
1315 module LidWindow(){ ////toplevel
1316   translate([led_pos[0], -led_pos[1], lpp13[1]])
1317     mirror([0,0,1])
1318     cylinder(r= nla_r1, h=nla_t);
1319   LidAdhocMultiprintFrame(0);
1320 }
1321
1322 module LidWindowPrint(){ ////toplevel
1323   rotate([0,180,0])
1324     LidWindow();
1325 }
1326
1327 module DemoLidWindowSelect(){
1328   translate([led_pos[0], led_pos[1], -100]) {
1329     translate([0, -30, 0]) cube([400, 400, 200]);
1330   }
1331 }
1332
1333 module DemoLidWindow(){ ////toplevel
1334   %Lid();
1335   LidWindow();
1336   translate([0,40,0]){
1337     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1338     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1339   }
1340 }
1341
1342 module HingeLeverPrint(){ ////toplevel
1343   rotate([-90,0,0])
1344     translate([-phone_width/2, phone_height, 0])
1345     HingeLever();
1346 }
1347
1348 module TestSelectLength(){
1349   translate([-30, -200, -20])
1350     cube([30 + 15, 250, 40]);
1351 }
1352
1353 module TestLength(){ ////toplevel
1354   intersection(){
1355     Case();
1356     TestSelectLength();
1357   }
1358 }
1359
1360 module TestLengthRight(){ ////toplevel
1361   intersection(){
1362     Case();
1363     Flip_rhs(1)
1364       TestSelectLength();
1365   }
1366 }
1367
1368 module TestSelectWidth(){
1369   translate([-30, -(phone_height - 25), -20])
1370     mirror([0, 1, 0])
1371     cube([200, 50, 40]);
1372 }
1373
1374 module TestWidth(){ ////toplevel
1375   intersection(){
1376     Case();
1377     TestSelectWidth();
1378   }
1379 }
1380
1381 module TestLidWidthPrint(){ ////toplevel
1382   rotate([0,180.0]) intersection(){
1383     Lid();
1384     TestSelectWidth();
1385   }
1386 }
1387
1388 module TestSelectRearAperture(){
1389   minkowski(){
1390     union() children();
1391     translate([20, 0,0])
1392       cube([42, 2, 1], center=true);
1393   }
1394 }
1395
1396 module TestSelectCamera(){
1397   minkowski(){
1398     TestSelectRearAperture()
1399       RearCameraAperture();
1400     cube([0.1, 50, 0.1]);
1401   }
1402 }
1403
1404 module TestSelectOrdinaryRearApertures(){
1405   TestSelectRearAperture()
1406     OrdinaryRearApertures();
1407 }
1408
1409 module TestCamera(){ ////toplevel
1410   intersection(){
1411     Case();
1412     TestSelectCamera();
1413   }
1414 }
1415
1416 module TestLidByCamera(){ ////toplevel
1417   intersection(){
1418     Lid();
1419     TestSelectCamera();
1420   }
1421 }
1422
1423 module TestLidByCameraPrint(){ ////toplevel
1424   rotate([180,0,0]) TestLidByCamera();
1425 }
1426
1427 module DemoByCamera(){ ////toplevel
1428   color("blue") TestLidByCamera();
1429   color("red")  TestCamera();
1430 }
1431
1432 module OneKeeper(){ ////toplevel
1433   translate([0, -phone_cnr_rad, 0])
1434     rotate([90, 0, 0])
1435     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1436     KeeperProfile();
1437 }
1438
1439 module OneKeeperPrint(){ ////toplevel
1440   rotate([0,180,0])
1441     OneKeeper();
1442 }
1443
1444 module LidPrint(){ ////toplevel
1445   rotate([0,180,0])
1446     Lid();
1447 }
1448
1449 module TestSelectFrame(){
1450   include = [1,-1] * (epp2i[0] + 4);
1451
1452   difference(){
1453     cube(1000, center=true);
1454     translate([0,0, -100])
1455       linear_extrude(height=200)
1456       rectfromto(include,  inside_br - include);
1457   }
1458 }
1459
1460 module TestSelectLidFrame(){
1461   TestSelectFrame();
1462   translate([led_pos[0], -led_pos[1], -50])
1463     cylinder(r= nla_r2+3, h=100);
1464 }
1465
1466 module TestFrameCase(){ ////toplevel
1467   intersection(){
1468     Case();
1469     union(){
1470       TestSelectFrame();
1471       TestSelectCamera();
1472       TestSelectOrdinaryRearApertures();
1473     }
1474   }
1475 }
1476
1477 module TestSelectTopApertures(){
1478   translate([-100, -35, -100])
1479     cube([400, 100, 200]);
1480   LidAdhocMultiprintFrame(0);
1481   LidAdhocMultiprintFrame(1);
1482 }
1483
1484 module TestTopApertures(){ ////toplevel
1485   intersection(){
1486     Case();
1487     TestSelectFrame();
1488     TestSelectTopApertures();
1489   }
1490 }
1491
1492 module TestLidTopAperturesPrint(){ ////toplevel
1493   rotate([0,180,0]) intersection(){
1494     Lid();
1495     TestSelectLidFrame();
1496     TestSelectTopApertures();
1497   }
1498 }
1499
1500 module TestLidWindowTopAperturesPrint(){ ////toplevel
1501   rotate([0,180,0]) intersection(){
1502     LidWindow();
1503     TestSelectTopApertures();
1504   }
1505 }
1506
1507 module TestFrameLidPrint(){ ////toplevel
1508   rotate([0,180,0]) intersection(){
1509     Lid();
1510     TestSelectLidFrame();
1511   }
1512 }
1513
1514 module ButtonPlanForDemo(z, deep, cut){
1515   translate([0,0,z])
1516     ButtonPlan(8, deep, cut);
1517 }
1518
1519 module HingeScrews(){
1520   Flip_rhs() Flip_bot(1){
1521     for (c= [ hppT, hppB ])
1522       translate([ hex20,
1523                   -c[0],
1524                   c[1] ]){
1525         rotate([0,90,0])
1526           translate([0,0,-.2])
1527           cylinder( r= hingescrew_shaft_dia/2,
1528                     h = hingescrew_shaft_len+0.2 );
1529         rotate([0,-90,0])
1530           translate([0,0,+.1])
1531           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1532       }
1533   }
1534 }
1535
1536 module DemoPropAngleSelect(c){
1537   color(c) difference(){
1538     union(){ children(); }
1539     translate([ prop_x_pos, -400, -200 ])
1540       cube([ 400,800,400 ]);
1541   }
1542 }
1543
1544 module DemoPropAngle(ang){
1545   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1546   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1547
1548   translate(hL)
1549     rotate([ang/2,0,0])
1550     translate(-hL)
1551     translate(hC)
1552     rotate([ang/2,0,0])
1553     translate(-hC) {
1554       DemoPropAngleSelect("red") Case();
1555
1556       color("orange")
1557         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1558         PropProfileAssignments(ang) {
1559           echo($prpp1);
1560           rotate([-$prp_theta, 0, 0])
1561           translate([0, $prpp1[0], -$prpp1[1]])
1562           rotate([90,0,-90])
1563           Prop();
1564         }
1565     }
1566
1567   translate([0,0, -hp_k*2])
1568     DemoPropAngleSelect("blue")
1569     Lid();
1570 }
1571
1572 module DemoPropAngles(){ ////toplevel
1573   for (i=[0 : len(prop_angles)-1])
1574     translate(i * [0, -100, 100])
1575     DemoPropAngle(prop_angles[i]);
1576 }
1577
1578 module DemoHingeAngle(ang1,ang2){
1579   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1580   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1581
1582   translate(hL)
1583     rotate([ang2,0,0])
1584     translate(-hL)
1585     translate(hC)
1586     rotate([ang1,0,0])
1587     translate(-hC) {
1588       color("red") Lid();
1589     }
1590
1591   color("blue") intersection(){
1592     Case();
1593     union(){
1594       translate([bppJ[0], -400, -200])
1595         mirror([1,0,0])
1596         cube([400, 800, 400]);
1597       translate([10, -400, -200])
1598         cube([10, 800, 400]);
1599     }
1600   }
1601 }
1602
1603 module DemoHingeAngles(){ ////toplevel
1604   angles = [ 0, 4, 8, 12 ];
1605   echo("angles",angles);
1606   for (i=[0 : len(angles)-1]) {
1607     translate(i * [0, 0, 30]) {
1608       DemoHingeAngle(0,angles[i]);
1609       translate([0, 200, 0])
1610         DemoHingeAngle(angles[i],0);
1611     }
1612   }
1613 }
1614
1615 module DemoSelectAdhocLeftRight(right=0) {
1616   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1617     mirror([1-right, 0,0])
1618     cube([400, 800, 200]);
1619 }
1620
1621 module DemoLeft(){ ////toplevel
1622   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1623   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1624 }
1625
1626 module DemoFrame(){ ////toplevel
1627   color("red") render() TestFrameCase();
1628   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1629   color("black") render() HingeScrews();
1630   %render() HingeLever();
1631 }
1632
1633 module DemoLanyardCutout(){ ////toplevel
1634   LanyardCutout(25);
1635 }
1636
1637 module DemoHingedFrame(){ ///toplevel
1638   color("red") TestFrameCase();
1639   translate([0,0, -2*hp_k])
1640   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1641
1642   Flip_hinge(){
1643     color("orange") HingeLever();
1644     color("black") HingeScrews();
1645   }
1646 }
1647
1648 module DemoHinge(){ ////toplevel
1649   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1650     DemoFrame();
1651     translate([0,0, -hp_k*3])
1652       DemoHingedFrame();
1653   }
1654 }
1655
1656 module DemoProfiles(){ ////toplevel
1657   LidEdgeProfile();
1658   %EdgeProfile();
1659   KeeperProfile();
1660   translate([0,0,-1]) color("black") KeeperProfile(1);
1661   translate(ly_o){
1662     rotate(-ly_theta){
1663       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1664       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1665       translate([0, ly_q_z]){
1666         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1667         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1668       }
1669     }
1670   }
1671   translate([0,0,-5]) color("white") translate(epp2i)
1672     rotate(-ly_theta)
1673     rectfromto([-15, 0],
1674                [+15, -max_case_bottom_edge_thickness]);
1675
1676   translate([0,20]) {
1677     LanyardMainChannelProfile();
1678     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1679     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1680   }
1681
1682   translate([20,0]) {
1683     LidEdgeProfile();
1684     %EdgeProfile();
1685
1686     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1687
1688     color("blue") ButtonCoverProfile();
1689     color("red") {
1690       rectfromto(bppQ, demopoint_QR);
1691       rectfromto(bppR, demopoint_QR);
1692     }
1693   }
1694
1695   translate([-20,0]) {
1696     color("black") ButtonPlanForDemo(-2, 0,1);
1697     color("red" )  ButtonPlanForDemo(-4, 1,1);
1698     color("blue")  ButtonPlanForDemo(-6, 1,0);
1699   }
1700
1701   translate([0, -30]) {
1702     %LidEdgeProfile();
1703     %EdgeProfile();
1704     color("blue") HingeLidProfile();
1705     color("red")  HingeBaseProfile();
1706     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1707   }
1708
1709   for (f=[0,1]) {
1710     translate([-30, -60 + 30*f]) {
1711       translate([0,0,-4]) EdgeProfile();
1712       %translate([0,0,-10]) HingeBaseProfile();
1713       translate([0,-2] * f * hp_k) {
1714         translate([0,0,-4]) LidEdgeProfile();
1715         %translate([0,0,-10]) %HingeLidProfile();
1716       }
1717       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1718         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1719         translate([0,0,0]) color("red") difference(){
1720           HingeLeverOuterProfile();
1721           HingeLeverInnerProfile();
1722         }
1723         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1724       }
1725     }
1726   }
1727
1728   translate([20,-30]) {
1729     %EdgeProfile();
1730     %LidEdgeProfile();
1731     //translate([0,0,1]) ThumbRecessCutProfile();
1732     translate([0,0,+1]) color("red")
1733       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1734   }
1735
1736   translate([40,-30]) {
1737     difference(){
1738       LidEdgeProfile();
1739       translate(prlp10)
1740         PropProfile(10, 1, 0);
1741     }
1742     translate(prlp10)
1743       PropProfile(15, 0);
1744   }
1745   translate([60,-30]) {
1746     PropAggregateProfile();
1747   }
1748 }
1749
1750 //EdgeProfile();
1751 //KeeperProfile();
1752 //CaseBase();
1753 //%Case();
1754 //Keeper();
1755 //LidEdgeProfile();
1756 //KeeperProfile();
1757 //DemoProfiles();
1758 //PropRecess();