fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 4.35 ];   // from rhs, from top edge
 166 noisecancelmic_dia = 4.00;
 167
 168 mainmic_pos = [ 21.0, 4.35 ];   // from lhs, from top edge
 169 mainmic_dia = 4.00;
 170
 171 lhshole_pos = [ phone[1]/2, 4.35 ];
 172
 173 // fingerpushhole_dias = []; xxx what was this
 174 fingerpushhole_dias = [ 15, 18 ];
 175
 176 lanyard_half_dia = 1.15;
 177 lanyard_entry_rel_breadth = 2;
 178 lanyard_channel_len = 8;
 179 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 180 rearspeaker_size   = [  3.76,  7.36 ];
 181
 182 bottomspeaker_size = [ 11.35, 1.40 ] + [1,1] * 0.5;
 183 bottomspeaker_pos = [ 19.45, 4.82 ];
 184
 185 microusb_above = 1.64 - 0.25;
 186 microusb_below = 2.42;
 187 microusb_width = 12.16 + 2.0 + 1.25;
 188
 189 case_th_bottom = 2.5;
 190 case_th_lid = 3.0;
 191 case_th_side = 2.3;
 192 case_th_lip = 1.2;
 193
 194 lid_screen_gap_extra = .66;
 195
 196 case_struts_count = 6;
 197 case_struts_solid_below = 1.00;
 198 case_struts_solid_above = 0.75;
 199 case_struts_width = 0.10;
 200
 201 keeper_th_z = 0.75;
 202 keeper_th_x = 0.75;
 203 keeper_inner_width = 2.75;
 204 keeper_inner_height = 2.75;
 205 keeper_slant_slope = 2; // larger means steeper
 206
 207 keeper_gap_z_top = 0.25;
 208 keeper_gap_z_bot = 0.75;
 209 keeper_gap_x     = 0.25;
 210 keeper_gap_x_holes = 0.75;
 211
 212 keeper_side = 0; // 0 = lhs; 1 = rhs
 213
 214 case_lip = 1.25;
 215
 216 lid_gap_x = 0.25;
 217 lid_gap_z = 0.25;
 218 lid_lip = 1.75;
 219 lid_edgepart_width = 5.0;
 220 lid_buttoncover_thick = 1.3;
 221 lid_buttoncover_reinf = 0.65;
 222
 223 foldover_gap = 0.50;
 224 foldover_lever_gap = 0.50;
 225
 226 // xxx replace hinge screw with nail plan
 227
 228 // properties of the hinge fasteners
 229 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 230 hingescrew_shaft_len = 12;
 231 hingescrew_fasteners_extra_thick = 0.40;
 232 // ^ amount of thread protruding if everything was completely nominal
 233 //   and we are using two nuts
 234 hingescrew_nut_access_dia = 4.72 + 0.50;
 235 // ^ washer is 4.72 dia
 236 //   also, want to get pliers or tiny spanner in to do up locknut
 237 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 238 hingescrew_nut_thick = 1.93;
 239 hingescrew_head_th = 1.38 + 0.75;
 240 hingescrew_head_dia = 3.92;
 241
 242 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 243
 244 lever_cover_th = 0.75;
 245 hingemount_th = 2.5;
 246 hingemount_wd = 4.8725;
 247
 248 $fa = 5;
 249 $fs = 0.1;
 250
 251 button_l_fudge = 4.4;
 252 buttonishleg_default_l_is_fudge = 10;
 253
 254 hinge_base_slope = 1.5; // bigger is steeper
 255
 256 strut_min_at_end = 1.5;
 257
 258 hinge_x_gap = 0.125;
 259 hinge_x_postscrew_gap = 0.75;
 260 hinge_x_arms_gap = 0.35;
 261 hinge_r_arms_gap = 0.55;
 262 hinge_over_nut_plate = 1.0;
 263
 264 // xxx there isn't one of these, speaker is by hinge
 265 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 266
 267 thumbrecess_depth = 1.3;
 268 thumbrecess_width = 16.5;
 269 thumbrecess_topcurve_r = 5.0;
 270
 271 prop_recess_under = 0.50;
 272 prop_recess_slop = 0.200; // each side
 273 prop_end_dia = 0.5;
 274 prop_main_th = 3;
 275 prop_taper_len = 6;
 276 prop_main_width = 4;
 277 prop_side_gap = 0.75; // each side
 278 prop_lidrecess_behind = 0.75;
 279 prop_caserecess_behind = 0.75;
 280 prop_caserecess_taper = 0.45; // one side only
 281 prop_prop_gap = 0.5;
 282 prop_prong_heel_slope = 0.5;
 283
 284 lid_fold_clearance_antislop = 0.5;
 285
 286 $button_leg_only = false;
 287 $suppress_forward_holes = false;
 288
 289 // ---------- calculated ----------
 290
 291 phone_total_thick = phone_edge_thick;
 292
 293 phone_width =  (phone + bumper*2)[0];
 294 phone_height = (phone + bumper*2)[1];
 295
 296 inside_br = [phone_width, -phone_height];
 297
 298 prop_prong_h = prop_main_th;
 299
 300 //echo(camera_pos_tl + bumper,
 301 //     camera_pos_br + bumper);
 302
 303 // ----- could be changed -----
 304 lid_buttoncover_gap = lid_gap_x;
 305 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 306
 307 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 308
 309 //prop_nose_len = case_th_lid - prop_recess_under;
 310 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 311 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 312
 313
 314 //lid_lip_overlap_width xxx bad name = ;
 315 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 316
 317 epp0 = [0,0];
 318 epp1 = [0, -phone_edge_thick];
 319 epp2i = epp1; // conflated for FP4
 320 epp2o = epp2i;
 321 epp3 = epp2i + [10, 0];
 322 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 323 epp4 = epp5 + [-1,0] * case_th_side;
 324
 325 kppe = [0,0];
 326 kppd = kppe + [1,0] * keeper_inner_width;
 327 kppc = kppd + [0,1] * keeper_th_z;
 328 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 329 kppf = kppe - [0,1] * keeper_inner_height;
 330 kppa = [ kppb[0], kppf[1] ];
 331
 332 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 333 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 334
 335 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 336 // exact x posn not very important; must extend past end of keeper
 337
 338 lpp15 = [ lpp14[0],
 339           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 340           + lid_screen_gap_extra ];
 341 // ^ beam theory says to maximise force before contact,
 342 //   the gap below the `beam' (the lid) must be 1/3
 343 //   the thickness (ie the lid thickness) if the beam
 344 //   is solid, or 1/2 if it has a top and bottom only.
 345 //   ours is mostly solid.
 346
 347 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 348              case_th_lip);
 349
 350 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 351 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 352
 353 case_bottom_z = epp2o[1] - case_th_bottom;
 354
 355 // button profile
 356 bppM = epp4 + [0,5];
 357 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 358 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 359 bppS = [ epp1[0], bppR[1] ];
 360 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 361 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 362 bppO = [ bppN[0], bppP[1] ];
 363 bppL = lpp10 + [5,0];
 364 bppK = [ bppL[0], bppN[1] ];
 365 bppJ = [ bppN[0], bppL[1] ];
 366 bppU = [ bppJ[0], lpp12[1] ];
 367 bppV = lpp11;
 368 bppW = lpp10;
 369
 370 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 371
 372 // notification led aperture
 373
 374 nla_r0 = led_aperture/2;
 375 nla_r1 = nla_r0 + led_window_ledge;
 376 nla_r2 = nla_r1 + multicolour_gap;
 377 nla_t =
 378   led_window_style >= 3 ? initial_layer_thick :
 379   led_window_style >= 2 ? led_window_ledge : 0;
 380
 381
 382 // hinge plan
 383 hp_rn = hingescrew_nut_access_dia/2;
 384 hp_r2_min = hp_rn + lever_cover_th;
 385 hp_rs = hingescrew_shaft_dia/2;
 386 hp_r1_min = hp_rs + hingemount_th;
 387
 388 hp_r1 = max(hp_r1_min, hp_r2_min);
 389 hp_r2 = hp_r1;
 390
 391 hppU = lpp13;
 392 hppS = epp2o + [0,-1] * case_th_bottom;
 393 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 394
 395 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 396          0.5 * (hppU + hppS)[1] ];
 397 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 398 hppB = hppT + [0,-1] * hp_k;
 399
 400 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 401 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 402 hppE = [ hppE_x, hppE_y ];
 403
 404 // hinge elevation x coords
 405
 406 hex20 = max(epp2o[0],
 407             phone_cnr_rad,
 408             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 409 hex21 = hex20 + hingemount_wd;
 410 hex22 = hex21 + hinge_x_gap;
 411 hex27 = hex20 + hingescrew_shaft_len;
 412 hex24 = hex27 + hinge_x_postscrew_gap;
 413 hex23 = hex27 - (hingescrew_nut_thick*2
 414                  + hingescrew_fasteners_extra_thick);
 415 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 416
 417 echo(hex20, hex21, hex22, hex23, hex24);
 418 //  6, 10.8725, 10.9975, 13.74, 18.75
 419 module chk(act,exp) {
 420   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 421   else echo("ok", act);
 422 }
 423 chk(hex20, 6);
 424 chk(hex21, 10.8725);
 425 chk(hex22, 10.9975);
 426 chk(hex23, 13.74);
 427 chk(hex24, 18.75);
 428
 429 lid_fold_clearance_skew =
 430   (lpp10[1] - hppB[1]) /
 431   (lpp10[0] - hppB[0]);
 432
 433 echo("SK",lid_fold_clearance_skew);
 434
 435 // thumb recess (used to be "catch" hence cpp*
 436
 437 cppA = epp4 + [thumbrecess_depth, 0];
 438 cppB = [ cppA[0], epp1[1] ];
 439
 440 // lanyard
 441
 442 ly_r = lanyard_half_dia / 2;
 443 ly_rc = ly_r * 2;
 444
 445 ly_theta = 90;
 446 ly_o = epp2i + 3 * ly_r * [0,1];
 447
 448 max_case_bottom_edge_thickness =
 449   case_th_bottom;
 450
 451 ly_q_z = -(ly_rc + ly_r);
 452 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 453
 454 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 455
 456 // prop recess in case
 457
 458 prop_x_pos = phone_width/2;
 459
 460 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 461
 462 prc_r1 = prop_end_dia/2;
 463 prc_r3 = prc_r1 + prop_recess_slop;
 464
 465 prcp2 = [ epp4[0] + prop_buildout_less,
 466           case_bottom_z ];
 467
 468 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 469
 470 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 471           epp2i[1] - prc_r3 - prop_recess_under];
 472
 473 // prop recess in lid
 474
 475 prl_r10 = prop_end_dia/2;
 476 prl_r10o = prl_r10 + prop_recess_slop;
 477
 478 prlp10 = lpp10 + [1,1] * prl_r10o
 479   + [1,0] * prop_lidrecess_behind
 480   + [0,1] * prop_recess_under;
 481
 482 // prop
 483
 484 $prpp10 = [0,0];
 485 $prpp11 = [0, prop_taper_len];
 486
 487 $prp_r10 = prl_r10;
 488
 489 // ---------- modules ----------
 490
 491 module AdhocMultiprintFrame(phase, z0, zs) {
 492   // from z0 to z0 + zs*layer
 493   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 494   xextra = extra + -epp4[0];
 495   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 496   yextra = extra + -epp4[0];
 497   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 498   p0 = [ xrange[0], yrange[0] ];
 499   p1 = [ xrange[1], yrange[1] ];
 500   echo(p0, p1);
 501   translate([0,0, z0])
 502     mirror([0,0, zs<0 ? 1 : 0])
 503     linear_extrude(height= initial_layer_thick)
 504     difference(){
 505       rectfromto(p0 - [1,1] * initial_layer_width,
 506                  p1 + [1,1] * initial_layer_width);
 507       rectfromto(p0, p1);
 508     }
 509 }
 510
 511 module KeeperProfile(slant=0){
 512   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 513   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 514 }
 515
 516 module EdgeProfile(){
 517   difference(){
 518     hull(){
 519       translate(epp3) square(case_th_bottom*2, center=true);
 520       circleat(epp2o, r=case_th_bottom);
 521       circleat(epp1, r=case_th_side);
 522       rectfromto(epp0, epp4);
 523     }
 524     polygon([ epp5 + [0,10],
 525               epp1,
 526               epp3 + [10,0] ]);
 527   }
 528 }
 529
 530 module LanyardLanyardProfile(entry=false){
 531   hull(){
 532     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 533       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 534         circle(r= lanyard_half_dia/2);
 535   }
 536 }
 537
 538 module LanyardCurveChannelProfile(){
 539   translate([0, -ly_r])
 540     LanyardLanyardProfile();
 541 }
 542
 543 module LanyardEntryChannelProfile(){
 544   LanyardLanyardProfile(true);
 545 }
 546
 547 module LanyardMainChannelProfile(){
 548   LanyardCurveChannelProfile();
 549   difference(){
 550     square(center=true, ly_r * [6, 2]);
 551     for (xs=[-1,+1])
 552       translate(ly_r * [3 * xs, -1])
 553         circle(r = ly_r);
 554   }
 555 }
 556
 557 module LanyardEntryOuterProfile(){
 558   circleat([ly_re + ly_r, 0], ly_re);
 559 }
 560
 561 module LanyardEntry(){
 562   q_z = ly_q_z;
 563   oec_y = ly_oec_y;
 564
 565   d_x = -ly_rc;
 566
 567   translate([d_x, 0, q_z]) {
 568     intersection(){
 569       rotate([90,0,0])
 570         rotate_extrude(convexity=10)
 571         rotate(90)
 572         translate([0, -q_z])
 573         LanyardCurveChannelProfile();
 574       translate([0,-10,0])
 575         cube([20,20,20]);
 576     }
 577   }
 578
 579   mirror([0,0,1])
 580     translate([0,0,-1])
 581     linear_extrude(height=20)
 582     rotate(-90)
 583     LanyardEntryChannelProfile();
 584
 585   translate([0, ly_r*2, 0])
 586     rotate([90,0,0])
 587     linear_extrude(height = ly_r*4){
 588     difference(){
 589       rectfromto([d_x, q_z], [ly_r, 0]);
 590       circleat([d_x, q_z], ly_rc);
 591     }
 592   }
 593
 594   translate([0,0,q_z]){
 595     for (my=[0,1])
 596       mirror([0,my,0]){
 597         translate([0, oec_y, 0]){
 598           difference(){
 599             translate(ly_re * [-1,0,-2])
 600               cube(ly_re * [2,1,2]);
 601             rotate_extrude(convexity=10)
 602               LanyardEntryOuterProfile();
 603           }
 604         }
 605       }
 606     difference(){
 607       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 608         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 609       for (mx=[0,1])
 610         mirror([mx,0,0])
 611           rotate([90,0,0])
 612           translate([0,0,-10])
 613           linear_extrude(height=20)
 614           LanyardEntryOuterProfile();
 615     }
 616   }
 617 }
 618
 619 module LanyardCutout(l){
 620   rotate([0,-90,0])
 621     linear_extrude(height=l)
 622     rotate(-90)
 623     LanyardMainChannelProfile();
 624
 625   for (ee=[0,1]){
 626     translate(ee * l * [-1,0])
 627       mirror([ee,0,0])
 628       LanyardEntry();
 629   }
 630 }
 631
 632 module LidEdgeProfile(){
 633   polygon([ lpp10,
 634             lpp11,
 635             lpp12,
 636             lpp13,
 637             lpp13 + [10, 0],
 638             lpp15 + [10, 0],
 639             lpp15,
 640             lpp14,
 641             ]);
 642   intersection(){
 643     circleat(lpp12, r=lp_r12);
 644     rectfromto( lpp12 + [-10,   0],
 645                 lpp12 + [+10, +10] );
 646   }
 647 }
 648
 649 module LidEdgeFoldClearanceProfile(){
 650   translate([-lid_fold_clearance_antislop, 0])
 651     polygon([ lpp10,
 652               lpp11,
 653               lpp11 + [-20,  0],
 654               lpp11 + [-20, 20],
 655               lpp11 + [+20, 20],
 656               lpp10 + [+20,  0] ]);
 657 }
 658
 659 module ButtonCoverProfile(){
 660   intersection(){
 661     polygon(concat([ bppM, bppP, bppO, bppJ ],
 662                    (enable_support && !$button_suppress_over_keeper
 663                     ? [ bppU, bppV, bppW ] : []),
 664                    [ bppL, bppK ]));
 665     hull(){
 666       EdgeProfile();
 667       LidEdgeProfile();
 668     }
 669   }
 670 }
 671
 672 module ButtonPlan(l, deep, cut){
 673   epsilon =
 674     (cut  ? 0 : lid_buttoncover_gap);
 675
 676   delta =
 677     (deep ? lid_buttoncover_overlap : 0);
 678
 679   C = [0,0]; // by definition
 680   T = [ 0, epp4[1] ];
 681   G = T + [0,10];
 682
 683   B0 = C + [0,-1] * button_cutout_depth;
 684   B1 = B0 + [0,1] * epsilon;
 685
 686   r0 = 0.5 * (T[1] - B0[1]);
 687   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 688   H = A + [0,-1] * delta;
 689
 690   D = A + [-2,0] * r0;
 691   F = D + [0,10];
 692
 693   E0 = 0.5 * (D + A);
 694   E1 = E0 + [1,0] * epsilon;
 695
 696   I0 = [ E0[0], H[1] ];
 697   I1 = [ E1[0], H[1] ];
 698
 699   hull(){
 700     for (m=[0,1]) mirror([m,0])
 701       circleat(H, r0 - epsilon);
 702   }
 703   for (m=[0,1]) mirror([m,0]) {
 704     difference(){
 705       polygon([ E1,
 706                 I1,
 707                 H,
 708                 B1,
 709                 G,
 710                 F,
 711                 D
 712                 ]);
 713       circleat(D, r0 + epsilon);
 714     }
 715   }
 716 }
 717
 718 module ButtonCoverReinf(){ ////toplevel
 719   minkowski(){
 720     rotate([90,0,0])
 721       linear_extrude(height=0.01)
 722       intersection(){
 723         ButtonCoverProfile();
 724         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 725           square([100,100]);
 726     }
 727     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 728       circle(r= lid_buttoncover_reinf);
 729       translate([-20,0]) square(40, center=true);
 730     }
 731   }
 732 }
 733
 734 module ThumbRecessCutProfile(){
 735   difference(){
 736     polygon([ cppA + [-10,0],
 737               cppB + [-10,0],
 738               cppB,
 739               cppA ]);
 740     circleat(epp1, r=case_th_side);
 741   }
 742 }
 743
 744 module Flip_rhs(yn=[0,1]) {
 745   for ($rhsflip=yn) {
 746     translate([phone_width/2, 0, 0])
 747       mirror([$rhsflip,0,0])
 748       translate([-phone_width/2, 0, 0])
 749       children();
 750   }
 751 }
 752
 753 module Flip_bot(yn=[0,1]) {
 754   for ($botflip=yn) {
 755     translate([0, -phone_height/2, 0])
 756       mirror([0, $botflip, 0])
 757       translate([0, phone_height/2, 0])
 758       children();
 759   }
 760 }
 761
 762 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 763   // sides
 764   Flip_rhs(){
 765     translate([0, -phone_cnr_rad, 0])
 766       rotate([90,0,0])
 767       linear_extrude(height = phone_height - phone_cnr_rad*2)
 768       children(0);
 769   }
 770   // corners
 771   Flip_rhs() Flip_bot() {
 772     translate([+1,-1] * phone_cnr_rad)
 773       intersection(){
 774         rotate_extrude()
 775           intersection(){
 776             mirror([1,0,0])
 777               translate([-1,0] * phone_cnr_rad)
 778               children(0);
 779             rectfromto([0,-20],[10,20]);
 780           }
 781         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 782           cube([10,10,40]);
 783       }
 784   }
 785   // top and bottom
 786   Flip_bot(){
 787     translate([ phone_width - phone_cnr_rad, 0,0 ])
 788       rotate([90,0,-90])
 789       linear_extrude(height = phone_width - phone_cnr_rad*2)
 790       children(0);
 791   }
 792   // fill
 793   translate([0,0, fill_zstart])
 794     mirror([0,0, fill_downwards])
 795     linear_extrude(height = fill_th)
 796     rectfromto([+1,-1] * phone_cnr_rad,
 797                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 798 }
 799
 800 module CaseAperture(pos, dia, $fn, topbottom=0) {
 801   theta = 180/$fn;
 802   translate([ bumper[0],
 803               -epp2i[0],
 804                0 ])
 805     rotate([0,0, 90*topbottom])
 806     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 807     rotate([-90, theta, 0])
 808     cylinder(r = dia/2 / cos(theta),
 809              h = 60);
 810 }
 811
 812 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 813   // y_ref_sign:
 814   //   +1  measured from top    of actual phone to top    of button
 815   //   -1  measured from bottom of actual phone to bottom of button
 816   //    0  y is centre of button in coordinate system
 817   $button_l= l;
 818   $button_suppress_over_keeper= suppress_over_keeper;
 819   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 820           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 821           y;
 822   //echo(eff_y);
 823   translate([0, eff_y, 0])
 824     children();
 825 }
 826
 827 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 828   $button_leg_only = true;
 829   SideButton(y, y_ref_sign, l) children();
 830 }
 831
 832 module Buttons(){
 833   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 834   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 835   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 836   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 837   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 838   // xxx need hole for whatever that hole is on lhs
 839 }
 840
 841 module Struts(x_start, z_min, th){
 842   // if th is negative, starts at z_min and works towards -ve z
 843   // and object should then be printed other way up
 844   for (i= [1 : 1 : case_struts_count]) {
 845     translate([0,
 846                0,
 847                z_min])
 848       mirror([0,0, th<0 ? 1 : 0])
 849       translate([0,
 850                  -phone_height * i / (case_struts_count+1),
 851                  case_struts_solid_below])
 852       linear_extrude(height= abs(th)
 853                      -(case_struts_solid_below+case_struts_solid_above))
 854       rectfromto([               x_start, -0.5 * case_struts_width ],
 855                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 856   }
 857 }
 858
 859 module OrdinaryRearAperture(rhs,bot, pos){
 860   Flip_rhs(rhs) Flip_bot(bot)
 861     linextr(-20, 20)
 862     mirror([0,1])
 863     translate(pos + bumper)
 864     children();
 865 }
 866
 867 module MicroUSBEtc(){
 868   Flip_bot(1){
 869     rotate([90,0,0])
 870       mirror([0,0,1])
 871       linextr(-epp2i[0], 60)
 872       translate([0.5 * phone_width, 0, 0])
 873       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 874                  [+microusb_width/2, epp0[1] + -microusb_above]);
 875   }
 876 }
 877
 878 module OrdinaryBottomEdgeApertures(){
 879   Flip_bot(1)
 880     CaseAperture(mainmic_pos, mainmic_dia, 8);
 881
 882   Flip_bot(1) Flip_rhs(1) {
 883     linextr_y_xz(-epp2i[0], 60)
 884       hull()
 885       for (x= [-1,+1]) {
 886         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 887                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 888                     0 ])
 889           rotate(360/16)
 890           circle(r = bottomspeaker_size[1], $fn = 8);
 891       }
 892   }
 893 }
 894
 895 module OrdinaryRearApertures(){
 896   // rear speaker
 897   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 898     rectfromto(-rearspeaker_gap,
 899                rearspeaker_size + rearspeaker_gap);
 900
 901   // finger hole to remove phone
 902   if (len(fingerpushhole_dias))
 903     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 904                                 phone[1]/2 ])
 905     scale(fingerpushhole_dias)
 906     circle(r= 0.5 );
 907 }
 908
 909 module RearCameraAperture(){
 910   Flip_rhs(1)
 911     mirror([0, 0, 1])
 912     linear_extrude(height = 20)
 913     mirror([0, 1, 0])
 914     translate(bumper)
 915     rectfromto(camera_pos_tl, camera_pos_br);
 916 }
 917
 918 module HingeLidProfile(){
 919   hull(){
 920     circleat(hppT, hp_r1);
 921     circleat(lpp12, lp_r12);
 922     polygon([lpp10,
 923              lpp13 + [2,0],
 924              lpp12,
 925              hppT]);
 926   }
 927 }
 928
 929 module HingeBaseProfile(){
 930   difference(){
 931     hull(){
 932       circleat(hppB, hp_r1);
 933       circleat(hppE, hp_r1);
 934       circleat(epp2o, case_th_bottom);
 935       circleat(hppB + [10,0], hp_r1);
 936     }
 937     polygon([epp5, epp1, epp3, bppL]);
 938   }
 939 }
 940
 941 module HingeLeverOuterProfile(){
 942   hull(){
 943     circleat(hppT, hp_r2);
 944     circleat(hppB, hp_r2);
 945   }
 946 }
 947
 948 module HingeLeverInnerProfile(){
 949   for (s = [-1,+1]) {
 950     c = s > 0 ? hppT : hppB;
 951     translate(c)
 952       mirror([0,0, s>0 ? 1 : 0])
 953       rotate(s<0 ? -40 : 0)
 954       hull()
 955       for (x=[-20,20])
 956         for (y=[0, s * 10])
 957           translate([x,y])
 958             circle(hp_rn);
 959   }
 960 }
 961
 962 module HingeLeverNutProfile(){
 963   for (c= [hppB, hppT]) {
 964     translate(c)
 965       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 966   }
 967 }
 968
 969 module Flip_hinge(doflip=1){
 970   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 971   translate(hinge_origin)
 972     rotate([doflip*180,0,0])
 973     translate(-hinge_origin)
 974     children();
 975 }
 976
 977 module HingePortion(x0,x1){
 978   Flip_rhs() Flip_bot(1)
 979     translate([x0,0,0])
 980     mirror([1,0,0])
 981     rotate([90,0,-90])
 982     linear_extrude(height=x1-x0)
 983     children();
 984 }
 985
 986 module ThumbRecessApply(ztop){
 987   width = thumbrecess_width;
 988   w = width + thumbrecess_topcurve_r*2 + 1;
 989   translate([phone_width/2, 0,0]){
 990     difference(){
 991       rotate([90,0,-90])
 992         linextr(-w/2, w/2)
 993         children(0);
 994       translate([0, 50, 0])
 995         rotate([90,0,0])
 996         linear_extrude(height=100){
 997         for (m=[0,1]) mirror([m,0,0]) {
 998           hull(){
 999             translate([w/2, ztop - thumbrecess_topcurve_r])
1000               circle(thumbrecess_topcurve_r);
1001             translate([w/2, -50])
1002               square(thumbrecess_topcurve_r*2, center=true);
1003           }
1004         }
1005       }
1006     }
1007   }
1008 }
1009
1010 module CaseBase(){
1011   AroundEdges(epp3[1], case_th_bottom, 1)
1012     EdgeProfile();
1013 }
1014
1015 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1016
1017 module PropProfileAssignments(gamma){
1018   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1019   x = prop_x(gamma);
1020   p = phone_height + prlp10[0] - hppB[0];
1021   b = p + x;
1022
1023   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1024   a = q + x;
1025   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1026   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1027
1028   $prp_theta = 90 - $prp_alpha;
1029   beta = 180 - $prp_alpha - gamma;
1030   psi = 90 - beta;
1031
1032   //echo("abc", a,b,c);
1033
1034   v1 = [ [ cos(psi), -sin(psi) ],    // x
1035          [ sin(psi),  cos(psi) ] ];  // y
1036
1037   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1038
1039   $prp_r1 = prc_r1;
1040   $prp_r11 = prop_main_th/2;
1041
1042   $prpp1 = $prpp7 + [1,0] *
1043     // this is approximate, but will do
1044     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1045   $prpp3 = $prpp1 +
1046     v1[0] * -$prp_r1 +
1047     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1048   $prpp12 = $prpp3 + v1[0] *
1049     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1050   $prp_r8 = prop_main_th;
1051   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1052   $prp_r5 = $prp_r8;
1053   $prpp5 = [ $prpp12[0] - $prp_r5,
1054             $prpp3[1] - prop_prong_h + $prp_r5 ];
1055   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1056          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1057   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1058   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1059
1060   children();
1061 }
1062
1063 module PropProfile(gamma, cut=0, rot=0){
1064   PropProfileAssignments(gamma){
1065
1066     //#circleat($prpp3,1);
1067     //#circleat($prpp12,1);
1068
1069     if (!cut) {
1070       hull(){
1071         translate($prpp8)
1072           intersection(){
1073             circle($prp_r8);
1074             polygon([[-20,-0], [20,20], [0,0]]);
1075           }
1076         rectfromto($prpp6, $prpp9);
1077         translate($prpp5) intersection(){
1078           circle($prp_r5);
1079           polygon([[-10,-10], [0,0], [10,0]]);
1080         }
1081         rectfromto($prpp12 + [0,-0.1], $prpp3);
1082       }
1083       hull(){
1084         circleat($prpp1, $prp_r1);
1085         rectfromto($prpp12 + [0,-0.1], $prpp3);
1086       }
1087     }
1088     // main shaft
1089     rotate([0,0, rot*-$prp_theta]){
1090       hull(){
1091         extra = cut ? prop_recess_slop : 0;
1092         rectfromto($prpp6, $prpp9);
1093         circleat($prpp11, $prp_r11 + extra);
1094         circleat($prpp10, $prp_r10 + extra);
1095       }
1096     }
1097   }
1098 }
1099
1100 module PropAggregateProfile(){
1101   for (angle = prop_angles)
1102     PropProfile(angle, 0,0);
1103 }
1104
1105 module Prop(){ ////toplevel
1106   hw = prop_main_width/2;
1107   linextr(-hw, +hw)
1108     PropAggregateProfile();
1109 }
1110
1111 module Case(){ ////toplevel
1112   difference(){
1113     union(){
1114       CaseBase();
1115
1116       // ledge (fixed keeper)
1117       Flip_rhs(1-keeper_side) intersection(){
1118         rotate([90, 0, 0])
1119           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1120           KeeperProfile(1);
1121
1122         // outline of the whole case, to stop it protruding
1123         translate([0,0, -25])
1124           linear_extrude(height = 50)
1125           hull()
1126           Flip_bot()
1127           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1128       }
1129
1130       // hinge
1131       HingePortion(hex20, hex21) HingeBaseProfile();
1132
1133       // buildout for prop recess
1134       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1135         linextr(case_bottom_z, epp2i[1])
1136         hull() {
1137           for (dxs = [-1,+1])
1138             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1139                        -epp2o[0] ],
1140                      r = epp2o[0] - prcp2[0]);
1141         }
1142     }
1143
1144     // slot for keeper
1145     Flip_rhs(keeper_side)
1146       translate([0, -phone_cnr_rad, 0])
1147       rotate([90, 0, 0])
1148       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1149       minkowski(){
1150         KeeperProfile();
1151         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1152                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1153       }
1154
1155     // front camera
1156     RearCameraAperture();
1157
1158     // struts (invisible, because they're buried in the case)
1159     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1160
1161     Buttons(){
1162       mirror([1,0,0])
1163         rotate([90,0,90]) {
1164           if (!($button_leg_only && enable_support))
1165           intersection(){
1166             translate([0,0,-10])
1167               linear_extrude(height= 20)
1168               ButtonPlan($button_l, 0,1);
1169             if ($button_leg_only)
1170               rotate([-90,90,0])
1171                 translate([phone_width/2, -400, kppe[1]])
1172                 mirror([1-abs($rhsflip - keeper_side),0,0])
1173                 cube([400, 800, 50]);
1174             if (enable_support && !$button_suppress_over_keeper)
1175               rotate([-90,90,0])
1176               translate([-400, -400, kppd[1]])
1177                 mirror([0,0,1])
1178                 cube([800,800,100]);
1179           }
1180           translate([0,0, -bppR[0]])
1181             linear_extrude(height= 20)
1182             ButtonPlan($button_l, 1,1);
1183         }
1184
1185     }
1186
1187     // apertures along top edge
1188     if (!$suppress_forward_holes) {
1189       // CaseAperture(jack_pos, jack_dia, 8);
1190       Flip_rhs(1)
1191         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1192       CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1193     }
1194
1195     OrdinaryBottomEdgeApertures();
1196
1197     OrdinaryRearApertures();
1198
1199     MicroUSBEtc();
1200
1201     // gaps for the lid's hinge arms
1202     HingePortion(hex20 - hinge_x_arms_gap,
1203                  hex21 + hinge_x_arms_gap)
1204       minkowski(){
1205         HingeLidProfile();
1206         circle(r= hinge_r_arms_gap, $fn= 8);
1207       }
1208
1209     // screw holes in the hinge arms
1210     HingeScrews();
1211
1212     // thumb recess
1213     ThumbRecessApply(epp4[1])
1214       ThumbRecessCutProfile();
1215
1216     // lanyard
1217     Flip_bot(1)
1218       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1219       rotate([0, ly_theta, 0])
1220       rotate([0,0,90])
1221       LanyardCutout(lanyard_channel_len);
1222
1223     // prop recess
1224     Flip_rhs(1)
1225       translate([prop_x_pos,0,0])
1226       mirror([0,1,0])
1227       rotate([90,0,90])
1228       linextr(-prop_recess_hw, +prop_recess_hw)
1229       hull(){
1230         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1231           circleat(prcp1 + 20*d,
1232                    prc_r3);
1233       }
1234   }
1235 }
1236
1237 module LidAdhocMultiprintFrame(phase){
1238   if (led_window_style >= 3) {
1239     AdhocMultiprintFrame(phase, lpp13[1], -1);
1240   }
1241 }
1242
1243 module LidAroundEdges(){
1244   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1245     children();
1246 }
1247
1248 module Lid(){ ////toplevel
1249   skew_centre = [0, lpp11[0], lpp11[1]];
1250   difference(){
1251     union(){
1252       intersection(){
1253         LidAroundEdges()
1254           LidEdgeProfile();
1255
1256         translate(skew_centre)
1257           multmatrix([[ 1, 0, 0, 0 ],
1258                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1259                       [ 0, 0, 1, 0 ],
1260                       [ 0, 0, 0, 1 ]])
1261           translate(-skew_centre)
1262           LidAroundEdges()
1263           LidEdgeFoldClearanceProfile();
1264       }
1265
1266       // button covers
1267       Buttons(){
1268         intersection(){
1269           rotate([90,0,90])
1270             translate([0,0,-10])
1271             linear_extrude(height= 20)
1272             ButtonPlan($button_l, 1,0);
1273           union(){
1274             rotate([90,0,0])
1275               translate([0,0,-100])
1276               linear_extrude(height= 200)
1277               ButtonCoverProfile();
1278             hull()
1279               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1280                                  - lid_buttoncover_reinf))
1281                 translate([0,y,0])
1282                   ButtonCoverReinf();
1283           }
1284         }
1285       }
1286
1287       // hinge arms
1288       HingePortion(hex20, hex21) {
1289         LidEdgeProfile();
1290         HingeLidProfile();
1291       }
1292     }
1293     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1294
1295     // screw holes in the hinge arms
1296     HingeScrews();
1297
1298     // prop recess
1299     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1300       mirror([0,1,0])
1301       rotate([90,0,90])
1302       linextr(-prop_recess_hw, +prop_recess_hw)
1303       hull()
1304       for (pa = prop_angles)
1305         PropProfile(pa, 1,1);
1306
1307     // notification led aperture
1308     if (led_window_style)
1309       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1310         translate([0,0,-10])
1311           cylinder(r=nla_r0, h=20);
1312         if (led_window_style >= 2)
1313           translate([0,0, -nla_t])
1314             cylinder(r=nla_r2, height=20);
1315       }
1316
1317     }
1318
1319   LidAdhocMultiprintFrame(1);
1320 }
1321
1322 module HingeLever(){ ////toplevel
1323   difference() {
1324     // outer body, positive
1325     HingePortion(hex22, hex22 + phone_width/2)
1326       HingeLeverOuterProfile();
1327
1328     // space for the screws
1329     HingePortion(hex26, hex24)
1330       HingeLeverInnerProfile();
1331
1332     // recesses for the nuts
1333     HingePortion(hex23, hex26+1)
1334       HingeLeverNutProfile();
1335
1336     // bores for the screws
1337     HingeScrews();
1338
1339     // space for the charging cable and speaker and micc apertures
1340     hull() {
1341       for (x = [-1,+1]) {
1342         multmatrix([[ 1,0,
1343
1344                      x
1345                      * ( (hex24 + hinge_over_nut_plate) -
1346                          (phone_width/2 - microusb_width/2)
1347                         )
1348                      / ( (epp0[1] - microusb_above)
1349                          -
1350                          (hppB[1] - hp_r2) ),
1351
1352                      x * (epp0[1] - microusb_above)
1353
1354                       ],
1355                     [ 0,1,0, 0 ],
1356                     [ 0,0,1, 0 ]]) {
1357           union(){
1358             MicroUSBEtc();
1359             Flip_hinge() MicroUSBEtc();
1360           }
1361         }
1362       }
1363     }
1364   }
1365 }
1366
1367 module LidWindow(){ ////toplevel
1368   translate([led_pos[0], -led_pos[1], lpp13[1]])
1369     mirror([0,0,1])
1370     cylinder(r= nla_r1, h=nla_t);
1371   LidAdhocMultiprintFrame(0);
1372 }
1373
1374 module LidWindowPrint(){ ////toplevel
1375   rotate([0,180,0])
1376     LidWindow();
1377 }
1378
1379 module DemoLidWindowSelect(){
1380   translate([led_pos[0], led_pos[1], -100]) {
1381     translate([0, -30, 0]) cube([400, 400, 200]);
1382   }
1383 }
1384
1385 module DemoLidWindow(){ ////toplevel
1386   %Lid();
1387   LidWindow();
1388   translate([0,40,0]){
1389     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1390     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1391   }
1392 }
1393
1394 module HingeLeverPrint(){ ////toplevel
1395   rotate([-90,0,0])
1396     translate([-phone_width/2, phone_height, 0])
1397     HingeLever();
1398 }
1399
1400 module TestSelectLength(){
1401   translate([-30, -200, -20])
1402     cube([30 + 15, 250, 40]);
1403 }
1404
1405 module TestLength(){ ////toplevel
1406   intersection(){
1407     Case();
1408     TestSelectLength();
1409   }
1410 }
1411
1412 module TestLengthRight(){ ////toplevel
1413   intersection(){
1414     Case();
1415     Flip_rhs(1)
1416       TestSelectLength();
1417   }
1418 }
1419
1420 module TestSelectWidth(){
1421   translate([-30, -(phone_height - 25), -20])
1422     mirror([0, 1, 0])
1423     cube([200, 50, 40]);
1424 }
1425
1426 module TestWidth(){ ////toplevel
1427   intersection(){
1428     Case();
1429     TestSelectWidth();
1430   }
1431 }
1432
1433 module TestLidWidthPrint(){ ////toplevel
1434   rotate([0,180.0]) intersection(){
1435     Lid();
1436     TestSelectWidth();
1437   }
1438 }
1439
1440 module TestSelectRearAperture(){
1441   minkowski(){
1442     union() children();
1443     translate([20, 0,0])
1444       cube([42, 2, 1], center=true);
1445   }
1446 }
1447
1448 module TestSelectCamera(){
1449   minkowski(){
1450     TestSelectRearAperture()
1451       RearCameraAperture();
1452     cube([0.1, 50, 0.1]);
1453   }
1454 }
1455
1456 module TestSelectOrdinaryRearApertures(){
1457   TestSelectRearAperture()
1458     OrdinaryRearApertures();
1459 }
1460
1461 module TestCamera(){ ////toplevel
1462   intersection(){
1463     Case();
1464     TestSelectCamera();
1465   }
1466 }
1467
1468 module TestLidByCamera(){ ////toplevel
1469   intersection(){
1470     Lid();
1471     TestSelectCamera();
1472   }
1473 }
1474
1475 module TestLidByCameraPrint(){ ////toplevel
1476   rotate([180,0,0]) TestLidByCamera();
1477 }
1478
1479 module DemoByCamera(){ ////toplevel
1480   color("blue") TestLidByCamera();
1481   color("red")  TestCamera();
1482 }
1483
1484 module OneKeeper(){ ////toplevel
1485   translate([0, -phone_cnr_rad, 0])
1486     rotate([90, 0, 0])
1487     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1488     KeeperProfile();
1489 }
1490
1491 module OneKeeperPrint(){ ////toplevel
1492   rotate([0,180,0])
1493     OneKeeper();
1494 }
1495
1496 module LidPrint(){ ////toplevel
1497   rotate([0,180,0])
1498     Lid();
1499 }
1500
1501 module TestSelectFrame(){
1502   include = [1,-1] * (epp2i[0] + 4);
1503
1504   difference(){
1505     cube(1000, center=true);
1506     translate([0,0, -100])
1507       linear_extrude(height=200)
1508       rectfromto(include,  inside_br - include);
1509   }
1510 }
1511
1512 module TestSelectLidFrame(){
1513   TestSelectFrame();
1514   translate([led_pos[0], -led_pos[1], -50])
1515     cylinder(r= nla_r2+3, h=100);
1516 }
1517
1518 module TestFrameCase(){ ////toplevel
1519   intersection(){
1520     Case();
1521     union(){
1522       TestSelectFrame();
1523       TestSelectCamera();
1524       TestSelectOrdinaryRearApertures();
1525     }
1526   }
1527 }
1528
1529 module TestSelectTopApertures(){
1530   translate([-100, -35, -100])
1531     cube([400, 100, 200]);
1532   LidAdhocMultiprintFrame(0);
1533   LidAdhocMultiprintFrame(1);
1534 }
1535
1536 module TestTopApertures(){ ////toplevel
1537   intersection(){
1538     Case();
1539     TestSelectFrame();
1540     TestSelectTopApertures();
1541   }
1542 }
1543
1544 module TestLidTopAperturesPrint(){ ////toplevel
1545   rotate([0,180,0]) intersection(){
1546     Lid();
1547     TestSelectLidFrame();
1548     TestSelectTopApertures();
1549   }
1550 }
1551
1552 module TestLidWindowTopAperturesPrint(){ ////toplevel
1553   rotate([0,180,0]) intersection(){
1554     LidWindow();
1555     TestSelectTopApertures();
1556   }
1557 }
1558
1559 module TestFrameLidPrint(){ ////toplevel
1560   rotate([0,180,0]) intersection(){
1561     Lid();
1562     TestSelectLidFrame();
1563   }
1564 }
1565
1566 module ButtonPlanForDemo(z, deep, cut){
1567   translate([0,0,z])
1568     ButtonPlan(8, deep, cut);
1569 }
1570
1571 module HingeScrews(){
1572   Flip_rhs() Flip_bot(1){
1573     for (c= [ hppT, hppB ])
1574       translate([ hex20,
1575                   -c[0],
1576                   c[1] ]){
1577         rotate([0,90,0])
1578           translate([0,0,-.2])
1579           cylinder( r= hingescrew_shaft_dia/2,
1580                     h = hingescrew_shaft_len+0.2 );
1581         rotate([0,-90,0])
1582           translate([0,0,+.1])
1583           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1584       }
1585   }
1586 }
1587
1588 module DemoPropAngleSelect(c){
1589   color(c) difference(){
1590     union(){ children(); }
1591     translate([ prop_x_pos, -400, -200 ])
1592       cube([ 400,800,400 ]);
1593   }
1594 }
1595
1596 module DemoPropAngle(ang){
1597   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1598   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1599
1600   translate(hL)
1601     rotate([ang/2,0,0])
1602     translate(-hL)
1603     translate(hC)
1604     rotate([ang/2,0,0])
1605     translate(-hC) {
1606       DemoPropAngleSelect("red") Case();
1607
1608       color("orange")
1609         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1610         PropProfileAssignments(ang) {
1611           echo($prpp1);
1612           rotate([-$prp_theta, 0, 0])
1613           translate([0, $prpp1[0], -$prpp1[1]])
1614           rotate([90,0,-90])
1615           Prop();
1616         }
1617     }
1618
1619   translate([0,0, -hp_k*2])
1620     DemoPropAngleSelect("blue")
1621     Lid();
1622 }
1623
1624 module DemoPropAngles(){ ////toplevel
1625   for (i=[0 : len(prop_angles)-1])
1626     translate(i * [0, -100, 100])
1627     DemoPropAngle(prop_angles[i]);
1628 }
1629
1630 module DemoHingeAngle(ang1,ang2){
1631   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1632   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1633
1634   translate(hL)
1635     rotate([ang2,0,0])
1636     translate(-hL)
1637     translate(hC)
1638     rotate([ang1,0,0])
1639     translate(-hC) {
1640       color("red") Lid();
1641     }
1642
1643   color("blue") intersection(){
1644     Case();
1645     union(){
1646       translate([bppJ[0], -400, -200])
1647         mirror([1,0,0])
1648         cube([400, 800, 400]);
1649       translate([10, -400, -200])
1650         cube([10, 800, 400]);
1651     }
1652   }
1653 }
1654
1655 module DemoHingeAngles(){ ////toplevel
1656   angles = [ 0, 4, 8, 12 ];
1657   echo("angles",angles);
1658   for (i=[0 : len(angles)-1]) {
1659     translate(i * [0, 0, 30]) {
1660       DemoHingeAngle(0,angles[i]);
1661       translate([0, 200, 0])
1662         DemoHingeAngle(angles[i],0);
1663     }
1664   }
1665 }
1666
1667 module DemoSelectAdhocLeftRight(right=0) {
1668   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1669     mirror([1-right, 0,0])
1670     cube([400, 800, 200]);
1671 }
1672
1673 module DemoLeft(){ ////toplevel
1674   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1675   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1676 }
1677
1678 module DemoFrame(){ ////toplevel
1679   color("red") render() TestFrameCase();
1680   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1681   color("black") render() HingeScrews();
1682   %render() HingeLever();
1683 }
1684
1685 module DemoLanyardCutout(){ ////toplevel
1686   LanyardCutout(25);
1687 }
1688
1689 module DemoHingedFrame(){ ///toplevel
1690   color("red") render() TestFrameCase();
1691   translate([0,0, -2*hp_k])
1692   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1693
1694   Flip_hinge(){
1695     color("orange") render() HingeLever();
1696     color("black") render() HingeScrews();
1697   }
1698 }
1699
1700 module DemoHinge(){ ////toplevel
1701   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1702     DemoFrame();
1703     translate([0,0, -hp_k*3])
1704       DemoHingedFrame();
1705   }
1706 }
1707
1708 module DemoProfiles(){ ////toplevel
1709   LidEdgeProfile();
1710   %EdgeProfile();
1711   KeeperProfile();
1712   translate([0,0,-1]) color("black") KeeperProfile(1);
1713   translate(ly_o){
1714     rotate(-ly_theta){
1715       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1716       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1717       translate([0, ly_q_z]){
1718         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1719         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1720       }
1721     }
1722   }
1723   translate([0,0,-5]) color("white") translate(epp2i)
1724     rotate(-ly_theta)
1725     rectfromto([-15, 0],
1726                [+15, -max_case_bottom_edge_thickness]);
1727
1728   translate([0,20]) {
1729     LanyardMainChannelProfile();
1730     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1731     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1732   }
1733
1734   translate([20,0]) {
1735     LidEdgeProfile();
1736     %EdgeProfile();
1737
1738     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1739
1740     color("blue") ButtonCoverProfile();
1741     color("red") {
1742       rectfromto(bppQ, demopoint_QR);
1743       rectfromto(bppR, demopoint_QR);
1744     }
1745   }
1746
1747   translate([-20,0]) {
1748     color("black") ButtonPlanForDemo(-2, 0,1);
1749     color("red" )  ButtonPlanForDemo(-4, 1,1);
1750     color("blue")  ButtonPlanForDemo(-6, 1,0);
1751   }
1752
1753   translate([0, -30]) {
1754     %LidEdgeProfile();
1755     %EdgeProfile();
1756     color("blue") HingeLidProfile();
1757     color("red")  HingeBaseProfile();
1758     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1759   }
1760
1761   for (f=[0,1]) {
1762     translate([-30, -60 + 30*f]) {
1763       translate([0,0,-4]) EdgeProfile();
1764       %translate([0,0,-10]) HingeBaseProfile();
1765       translate([0,-2] * f * hp_k) {
1766         translate([0,0,-4]) LidEdgeProfile();
1767         %translate([0,0,-10]) %HingeLidProfile();
1768       }
1769       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1770         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1771         translate([0,0,0]) color("red") difference(){
1772           HingeLeverOuterProfile();
1773           HingeLeverInnerProfile();
1774         }
1775         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1776       }
1777     }
1778   }
1779
1780   translate([20,-30]) {
1781     %EdgeProfile();
1782     %LidEdgeProfile();
1783     //translate([0,0,1]) ThumbRecessCutProfile();
1784     translate([0,0,+1]) color("red")
1785       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1786   }
1787
1788   translate([40,-30]) {
1789     difference(){
1790       LidEdgeProfile();
1791       translate(prlp10)
1792         PropProfile(10, 1, 0);
1793     }
1794     translate(prlp10)
1795       PropProfile(15, 0);
1796   }
1797   translate([60,-30]) {
1798     PropAggregateProfile();
1799   }
1800 }
1801
1802 //EdgeProfile();
1803 //KeeperProfile();
1804 //CaseBase();
1805 //%Case();
1806 //Keeper();
1807 //LidEdgeProfile();
1808 //KeeperProfile();
1809 //DemoProfiles();
1810 //PropRecess();