configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(nlopt, 2.0.1, stevenj@alum.mit.edu)
   3 AC_CONFIG_SRCDIR(api/nlopt.h)
   4 SHARED_VERSION_INFO="3:1:3" # CURRENT:REVISION:AGE
   5
   6 AM_INIT_AUTOMAKE(1.7)
   7 AM_CONFIG_HEADER(config.h)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_MAINTAINER_MODE
  10 AC_SUBST(SHARED_VERSION_INFO)
  11 AC_DISABLE_SHARED dnl shared libraries are a PITA, disable by default
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AC_PROG_CC_STDC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 NLOPT_SUFFIX=""
  23 AC_ARG_WITH(cxx,
  24         [AC_HELP_STRING([--with-cxx], [include C++-based routines])],
  25         with_cxx=$withval,with_cxx=no)
  26 AM_CONDITIONAL(WITH_CXX, test "x$with_cxx" = xyes)
  27 AC_PROG_CXX
  28 if test "x$with_cxx" = xyes; then
  29    AC_DEFINE([WITH_CXX], 1, [Define if compiled including C++-based routines])
  30    NLOPT_SUFFIX="_cxx"
  31    CC=$CXX
  32    CFLAGS=$CXXFLAGS
  33 fi
  34 AC_SUBST(NLOPT_SUFFIX)
  35
  36 AC_ARG_WITH(mthreads,
  37         [AC_HELP_STRING([--with-mthreads], [use -mthreads compiler flag])],
  38         with_mthrads=$withval,with_mthreads=no)
  39 if test "x$with_mthreads" = xyes; then
  40    CFLAGS="$CFLAGS -mthreads"
  41    CXXFLAGS="$CXXFLAGS -mthreads"
  42 fi
  43
  44 dnl Checks for typedefs, structures, and compiler characteristics.
  45 AC_HEADER_STDC
  46 AC_HEADER_TIME
  47 AC_CHECK_HEADERS([unistd.h getopt.h stdint.h])
  48 AC_C_CONST
  49 AC_C_INLINE
  50 AX_C_THREADLOCAL
  51
  52 dnl find 32-bit unsigned integer type for random-number generator
  53 AC_CHECK_SIZEOF(unsigned int)
  54 AC_CHECK_SIZEOF(unsigned long)
  55 AC_CHECK_TYPES(uint32_t, [], [], [$ac_includes_default
  56 #ifdef HAVE_STDINT_H
  57 #  include <stdint.h>
  58 #endif])
  59
  60 dnl Checks for libraries and functions
  61 AC_CHECK_LIB(m, sin)
  62 AC_CHECK_FUNCS([BSDgettimeofday gettimeofday time qsort_r getpid])
  63
  64 AC_MSG_CHECKING([for gettid syscall])
  65 AC_TRY_LINK([#include <unistd.h>
  66 #include <sys/syscall.h>
  67 ], [syscall(SYS_gettid);], [ok=yes], [ok=no])
  68 if test "$ok" = "yes"; then
  69         AC_DEFINE(HAVE_GETTID_SYSCALL,1,[Define if syscall(SYS_gettid) available.])
  70 fi
  71 AC_MSG_RESULT(${ok})
  72
  73 AC_MSG_CHECKING([for isnan])
  74 AC_TRY_LINK([#include <math.h>
  75 ], [if (!isnan(3.14159)) isnan(2.7183);], ok=yes, ok=no)
  76 if test "$ok" = "yes"; then
  77         AC_DEFINE(HAVE_ISNAN,1,[Define if the isnan() function/macro is available.])
  78 fi
  79 AC_MSG_RESULT(${ok})
  80
  81 AC_MSG_CHECKING([for isinf])
  82 AC_TRY_LINK([#include <math.h>
  83 ], [if (!isinf(3.14159)) isinf(2.7183);], ok=yes, ok=no)
  84 if test "$ok" = "yes"; then
  85         AC_DEFINE(HAVE_ISINF,1,[Define if the isinf() function/macro is available.])
  86 fi
  87 AC_MSG_RESULT(${ok})
  88
  89 dnl -----------------------------------------------------------------------
  90
  91 if test "x$with_cxx" = xyes; then
  92   test -r $srcdir/lbfgs/ap.cpp && test -r $srcdir/lbfgs/ap.h && test -r $srcdir/lbfgs/l-bfgs-b.cpp && test -r $srcdir/lbfgs/l-bfgs-b.h && have_lbfgs=yes
  93 fi
  94 AM_CONDITIONAL(WITH_NOCEDAL, test -n "$have_lbfgs")
  95 if test -n "$have_lbfgs"; then
  96    AC_DEFINE(WITH_NOCEDAL, [1], [Define if we have the non-free Nocedal LBFGS code])
  97 fi
  98
  99 dnl -----------------------------------------------------------------------
 100 dnl SWIG wrappers
 101
 102 AC_ARG_WITH(guile,
 103         [AC_HELP_STRING([--without-guile], [don't compile Guile plugin])],
 104         with_guile=$withval,with_guile=yes)
 105 AC_ARG_WITH(python,
 106         [AC_HELP_STRING([--without-python], [don't compile Python plugin])],
 107         with_python=$withval,with_python=yes)
 108
 109 if test "$enable_shared" = no; then
 110    AC_MSG_WARN([Python and Guile wrappers require --enable-shared; disabling])
 111    GUILE_CONFIG=unknown
 112    have_python=no
 113 else
 114
 115 if test "x$with_guile" = xno; then
 116    GUILE_CONFIG=unknown
 117 else
 118
 119 dnl Guile:
 120 AC_CHECK_PROG(GUILE_CONFIG, guile-config, guile-config, unknown)
 121 if test "x$GUILE_CONFIG" = "xunknown"; then
 122    AC_MSG_WARN([can't find guile-config, disabling Guile wrapper])
 123 else
 124    save_CPPFLAGS=$CPPFLAGS
 125    save_LIBS=$LIBS
 126    GUILE_CPPFLAGS=`$GUILE_CONFIG compile`
 127    GUILE_LIBS=`$GUILE_CONFIG link`
 128    CPPFLAGS="$CPPFLAGS $GUILE_CPPFLAGS"
 129    LIBS="$GUILE_LIBS $LIBS"
 130    AC_MSG_CHECKING([if linking to guile works])
 131    AC_TRY_LINK_FUNC(scm_is_vector, [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 132         AC_MSG_WARN(guile-config is broken, disabling Guile wrapper)
 133         GUILE_CONFIG="unknown"])
 134    CPPFLAGS=$save_CPPFLAGS
 135    LIBS=$save_LIBS
 136 fi
 137 AC_CHECK_PROG(GUILE, guile, guile, unknown)
 138 if test "x$GUILE" = xunknown; then
 139    AC_MSG_WARN([can't find guile, disabling Guile wrapper])
 140    GUILE_CONFIG=unknown
 141 else
 142    AC_MSG_CHECKING([for Guile site installation directory])
 143    GUILE_SITEDIR=`guile -c '(display (%site-dir))'`
 144    AC_MSG_RESULT([$GUILE_SITEDIR])
 145 fi
 146
 147 fi # with_guile
 148
 149 if test "x$with_python" = xno; then
 150   have_python=no
 151 else
 152
 153 dnl Python:
 154 AM_PATH_PYTHON([],[have_python=yes],[have_python=no])
 155 if test $have_python = yes; then
 156   pdir=`dirname $pythondir | sed 's,/lib/,/include/,'`
 157   pdir=`eval echo $pdir`
 158   AC_MSG_CHECKING([for Python include directory])
 159   for PYTHON_INCLUDE_DIR in "$pdir" /usr/include/python$PYTHON_VERSION /usr/local/include/python$PYTHON_VERSION unknown; do
 160     test -d "$PYTHON_INCLUDE_DIR" && break
 161   done
 162   AC_MSG_RESULT([$PYTHON_INCLUDE_DIR])
 163   if test "x$PYTHON_INCLUDE_DIR" = xunknown; then
 164      AC_MSG_WARN([disabling Python wrappers])
 165      have_python=no
 166   else
 167      save_CPPFLAGS=$CPPFLAGS
 168      CPPFLAGS="$CPPFLAGS -I$PYTHON_INCLUDE_DIR"
 169      AC_CHECK_HEADER([numpy/arrayobject.h],[],[
 170           AC_MSG_WARN([disabling Python wrappers])
 171           have_python=no],[#include <Python.h>])
 172      CPPFLAGS=$save_CPPFLAGS
 173   fi
 174 fi
 175
 176 fi # with_python
 177
 178 fi # if enable_shared
 179
 180 AC_SUBST(GUILE_SITEDIR)
 181 AC_SUBST(GUILE_CPPFLAGS)
 182 AC_SUBST(GUILE_LIBS)
 183 AC_SUBST(PYTHON_INCLUDE_DIR)
 184 AM_CONDITIONAL(WITH_GUILE, test x"$GUILE_CONFIG" != "xunknown")
 185 AM_CONDITIONAL(WITH_PYTHON, test x"$have_python" = "xyes")
 186
 187 dnl -----------------------------------------------------------------------
 188 dnl Compiling Octave plug-in
 189
 190 AC_ARG_VAR(OCT_INSTALL_DIR, [where to install GNU Octave .oct plug-ins])
 191 AC_ARG_VAR(M_INSTALL_DIR, [where to install GNU Octave .m plug-ins])
 192 AC_ARG_VAR(MKOCTFILE, [name of mkoctfile program to compile Octave plug-ins])
 193
 194 AC_ARG_WITH(octave,
 195         [AC_HELP_STRING([--without-octave], [don't compile Octave plugin])],
 196         with_octave=$withval,with_octave=yes)
 197
 198 AC_CHECK_PROGS(MKOCTFILE, mkoctfile, echo)
 199
 200 if test x"$with_octave" = xno; then
 201         OCT_INSTALL_DIR=""
 202 elif test "$MKOCTFILE" = "echo"; then
 203         AC_MSG_WARN([can't find mkoctfile: won't be able to compile GNU Octave plugin])
 204         OCT_INSTALL_DIR=""
 205 elif test x"$OCT_INSTALL_DIR" = "x"; then
 206         # try to find installation directory
 207         AC_CHECK_PROGS(OCTAVE, octave, echo)
 208         AC_CHECK_PROGS(OCTAVE_CONFIG, octave-config, echo)
 209
 210         AC_MSG_CHECKING(where octave plugins go)
 211         OCT_INSTALL_DIR=`octave-config --oct-site-dir 2> /dev/null | grep '/'`
 212         if test -z "$OCT_INSTALL_DIR"; then
 213                 OCT_INSTALL_DIR=`octave-config --print OCTFILEDIR 2> /dev/null | grep '/'`
 214         fi
 215         if test -z "$OCT_INSTALL_DIR"; then
 216                 OCT_INSTALL_DIR=`echo "path" | $OCTAVE -q 2> /dev/null | grep "/oct/" | head -1`
 217         fi
 218         if test -z "$OCT_INSTALL_DIR"; then
 219                 OCT_INSTALL_DIR=`echo "DEFAULT_LOADPATH" | $OCTAVE -q 2> /dev/null | tr ':' '\n' | grep "site/oct" | head -1`
 220         fi
 221         if test -n "$OCT_INSTALL_DIR"; then
 222                 AC_MSG_RESULT($OCT_INSTALL_DIR)
 223         else
 224                 AC_MSG_RESULT(unknown)
 225                 AC_MSG_WARN([can't find where to install octave plugins: won't be able to compile octave plugin])
 226         fi
 227
 228         AC_MSG_CHECKING(where octave scripts go)
 229         M_INSTALL_DIR=`octave-config --m-site-dir 2> /dev/null | grep '/'`
 230         if test -z "$M_INSTALL_DIR"; then
 231                 M_INSTALL_DIR=`octave-config --print FCNFILEDIR 2> /dev/null | grep '/'`
 232         fi
 233         if test -z "$M_INSTALL_DIR"; then
 234                 M_INSTALL_DIR=`echo "path" | $OCTAVE -q 2> /dev/null | grep "/m" | head -1`
 235         fi
 236         if test -z "$M_INSTALL_DIR"; then
 237                 M_INSTALL_DIR=`echo "DEFAULT_LOADPATH" | $OCTAVE -q 2> /dev/null | tr ':' '\n' | grep "site/m" | head -1`
 238         fi
 239         if test -n "$M_INSTALL_DIR"; then
 240                 AC_MSG_RESULT($M_INSTALL_DIR)
 241         else
 242                 AC_MSG_RESULT(unknown)
 243                 AC_MSG_WARN([can't find where to install octave scripts: won't be able to install octave plugin])
 244                 OCT_INSTALL_DIR=""
 245         fi
 246 fi
 247
 248 if test x"$OCT_INSTALL_DIR" != "x"; then
 249 if test "$enable_shared" = no; then
 250      AC_MSG_CHECKING([whether mkoctfile can link with static objects])
 251      rm -f conftest*
 252      echo 'void foo(void) {};' > conftestfoo.c
 253      $CC -c conftestfoo.c >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD
 254      cat > conftest.cc <<EOF
 255 #include <octave/oct.h>
 256 extern "C" void foo(void);
 257 DEFUN_DLD(foobar, args, nargout, "foo bar") { foo(); }
 258 EOF
 259      if $MKOCTFILE conftest.cc conftestfoo.o >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 260         AC_MSG_RESULT(yes)
 261      else
 262         AC_MSG_RESULT(no)
 263         AC_MSG_WARN([mkoctfile requires --enable-shared; won't compile Octave plugin])
 264         OCT_INSTALL_DIR=""
 265      fi
 266 fi
 267 fi
 268
 269 AM_CONDITIONAL(WITH_OCTAVE, test x"$OCT_INSTALL_DIR" != "x")
 270 AC_SUBST(OCT_INSTALL_DIR)
 271 AC_SUBST(M_INSTALL_DIR)
 272 AC_SUBST(MKOCTFILE)
 273
 274 dnl -----------------------------------------------------------------------
 275 dnl Compiling Matlab plug-in
 276
 277 AC_ARG_WITH(matlab,
 278         [AC_HELP_STRING([--without-matlab], [don't compile Matlab plugin])],
 279         with_matlab=$withval,with_matlab=yes)
 280
 281 AC_ARG_VAR(MEX_INSTALL_DIR, [where to install Matlab .mex plug-ins])
 282 AC_ARG_VAR(MEX, [name of mex program to compile Matlab plug-ins])
 283 AC_CHECK_PROGS(MEX, mex, echo)
 284 if test x"$with_matlab" = xno; then
 285      MEX_INSTALL_DIR=""
 286 elif test "$MEX" = "echo"; then
 287      AC_MSG_WARN([can't find mex: won't be able to compile Matlab plugin])
 288      MEX_INSTALL_DIR=""
 289 else
 290      AC_MSG_CHECKING([for extension of compiled mex files])
 291      rm -f conftest*
 292      cat > conftest.c <<EOF
 293 #include <mex.h>
 294 void mexFunction(int nlhs, mxArray *plhs[[]],
 295                  int nrhs, const mxArray *prhs[[]]) { }
 296 EOF
 297      if $MEX conftest.c >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 298         MEXSUFF=`ls conftest.m* | head -1 | cut -d'.' -f2`
 299         AC_MSG_RESULT($MEXSUFF)
 300         AC_CHECK_PROGS(MATLAB, matlab, echo)
 301      else
 302         AC_MSG_WARN([$MEX failed to compile a simple file; won't compile Matlab plugin])
 303         MEX_INSTALL_DIR=""
 304         MATLAB=echo
 305      fi
 306
 307      if test x"$MATLAB" != xecho; then
 308      if test "$enable_shared" = no; then
 309      AC_MSG_CHECKING([whether mex can link with static objects])
 310      rm -f conftest*
 311      echo 'void foo(void) {};' > conftestfoo.c
 312      $CC -c conftestfoo.c >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD
 313      cat > conftest.c <<EOF
 314 #include <mex.h>
 315 extern void foo(void);
 316 void mexFunction(int nlhs, mxArray *plhs[[]],
 317                  int nrhs, const mxArray *prhs[[]]) { foo(); }
 318 EOF
 319      if $MEX conftest.c conftestfoo.o >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 320         AC_MSG_RESULT(yes)
 321      else
 322         AC_MSG_RESULT(no)
 323         AC_MSG_WARN([mex requires --enable-shared; won't compile Matlab plugin])
 324         MEX_INSTALL_DIR=""
 325         MATLAB=echo
 326      fi
 327      fi
 328      fi
 329
 330      if test x"$MATLAB" != xecho; then
 331        # try to find installation directory
 332        if test x"$MEX_INSTALL_DIR" = "x"; then
 333           AC_MSG_CHECKING(for MATLAB mex installation dir)
 334           MEX_INSTALL_DIR=`matlab -nodisplay -nodesktop -nojvm -r 'path;quit' | grep toolbox/local |sed 's,^[[^/]]*,,g' |sort |head -1`
 335           AC_MSG_RESULT($MEX_INSTALL_DIR)
 336           if test x`basename "$MEX_INSTALL_DIR"` != xlocal; then
 337              MEX_INSTALL_DIR=""
 338           fi
 339           if test x"$MEX_INSTALL_DIR" = "x"; then
 340             AC_MSG_WARN([can't find reasonable Matlab installation directory; Matlab plugins will not be compiled unless you manually specify MEX_INSTALL_DIR])
 341           fi
 342        fi
 343      else
 344         MEX_INSTALL_DIR=""
 345      fi
 346 fi
 347 AM_CONDITIONAL(WITH_MATLAB, test x"$MEX_INSTALL_DIR" != "x")
 348 AC_SUBST(MEX_INSTALL_DIR)
 349 AC_SUBST(MEX)
 350 AC_SUBST(MEXSUFF)
 351
 352 dnl -----------------------------------------------------------------------
 353 dnl Check for broken Solaris HUGE_VAL macro under gcc 3.4.x and similar
 354
 355 AC_MSG_CHECKING([for working HUGE_VAL])
 356 AC_TRY_COMPILE([#include <math.h>], [double x = -HUGE_VAL;],
 357 [AC_MSG_RESULT([ok])],
 358 [AC_TRY_COMPILE([#include <math.h>
 359 #ifdef __GNUC__
 360 #undef HUGE_VAL
 361 #define HUGE_VAL __builtin_huge_val()
 362 #endif], [double x = -HUGE_VAL;],
 363 [AC_MSG_RESULT([__builtin_huge_val()])
 364 AC_DEFINE(REPLACEMENT_HUGE_VAL,[__builtin_huge_val()],
 365           [replacement for broken HUGE_VAL macro, if needed])],
 366 [AC_MSG_RESULT([unknown])
 367 AC_MSG_ERROR([broken HUGE_VAL macro with this compiler, unknown workaround])])])
 368
 369 dnl -----------------------------------------------------------------------
 370 dnl Debugging
 371
 372 AC_ARG_ENABLE(debug, [AC_HELP_STRING([--enable-debug],[compile with extra runtime checks for debugging])], ok=$enableval, ok=no)
 373 if test "$ok" = "yes"; then
 374         AC_DEFINE(DEBUG,1,[Define to enable extra debugging code.])
 375 fi
 376
 377 dnl override CFLAGS selection when debugging
 378 if test "${enable_debug}" = "yes"; then
 379         CFLAGS="-g"
 380         CXXFLAGS="-g"
 381         FFLAGS="-g"
 382 fi
 383
 384 dnl add gcc warnings, in debug/maintainer mode only
 385 if test "$enable_debug" = yes || test "$USE_MAINTAINER_MODE" = yes; then
 386 if test $ac_cv_prog_gcc = yes; then
 387    if test "$ac_test_CFLAGS" != "set"; then
 388       CFLAGS="$CFLAGS -Wall -W -Wcast-qual -Wpointer-arith -Wcast-align -pedantic -Wshadow -Wbad-function-cast -Wwrite-strings -Wstrict-prototypes -Wredundant-decls -Wnested-externs -Wundef -Wconversion -Wmissing-prototypes -Wmissing-declarations"
 389    fi
 390    if test "$ac_test_CXXFLAGS" != "set"; then
 391       CXXFLAGS="$CXXFLAGS -Wall -W -Wcast-qual -Wpointer-arith -Wcast-align -pedantic -Wshadow -Wwrite-strings -Wredundant-decls -Wundef -Wconversion"
 392    fi
 393    if test "x$with_cxx" = xyes; then
 394       CFLAGS=$CXXFLAGS
 395    fi
 396 fi
 397 fi
 398
 399 vers=`echo ${VERSION}.0.0 | cut -d. -f1`
 400 AC_DEFINE_UNQUOTED(MAJOR_VERSION, $vers, [Major version number.])
 401 vers=`echo ${VERSION}.0.0 | cut -d. -f2`
 402 AC_DEFINE_UNQUOTED(MINOR_VERSION, $vers, [Minor version number.])
 403 vers=`echo ${VERSION}.0.0 | cut -d. -f3`
 404 AC_DEFINE_UNQUOTED(BUGFIX_VERSION, $vers, [Bugfix version number.])
 405
 406 dnl -----------------------------------------------------------------------
 407
 408 AC_CONFIG_FILES([
 409    Makefile
 410    nlopt.pc
 411    api/Makefile
 412    util/Makefile
 413    octave/Makefile
 414    direct/Makefile
 415    cdirect/Makefile
 416    stogo/Makefile
 417    praxis/Makefile
 418    lbfgs/Makefile
 419    luksan/Makefile
 420    crs/Makefile
 421    mlsl/Makefile
 422    mma/Makefile
 423    cobyla/Makefile
 424    newuoa/Makefile
 425    neldermead/Makefile
 426    auglag/Makefile
 427    bobyqa/Makefile
 428    isres/Makefile
 429    test/Makefile
 430    swig/Makefile
 431    swig/nlopt.scm
 432 ])
 433
 434 AC_OUTPUT