configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(nlopt, 2.0, stevenj@alum.mit.edu)
   3 AC_CONFIG_SRCDIR(api/nlopt.h)
   4 SHARED_VERSION_INFO="3:0:3" # CURRENT:REVISION:AGE
   5
   6 AM_INIT_AUTOMAKE(1.7)
   7 AM_CONFIG_HEADER(config.h)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_MAINTAINER_MODE
  10 AC_SUBST(SHARED_VERSION_INFO)
  11 AC_DISABLE_SHARED dnl shared libraries are a PITA, disable by default
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AC_PROG_CC_STDC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 NLOPT_SUFFIX=""
  23 AC_ARG_WITH(cxx,
  24         [AC_HELP_STRING([--with-cxx], [include C++-based routines])],
  25         with_cxx=$withval,with_cxx=no)
  26 AM_CONDITIONAL(WITH_CXX, test "x$with_cxx" = xyes)
  27 AC_PROG_CXX
  28 if test "x$with_cxx" = xyes; then
  29    AC_DEFINE([WITH_CXX], 1, [Define if compiled including C++-based routines])
  30    NLOPT_SUFFIX="_cxx"
  31    CC=$CXX
  32    CFLAGS=$CXXFLAGS
  33 fi
  34 AC_SUBST(NLOPT_SUFFIX)
  35
  36 dnl Checks for typedefs, structures, and compiler characteristics.
  37 AC_HEADER_STDC
  38 AC_HEADER_TIME
  39 AC_CHECK_HEADERS([unistd.h getopt.h stdint.h])
  40 AC_C_CONST
  41 AC_C_INLINE
  42 AX_C_THREADLOCAL
  43
  44 dnl find 32-bit unsigned integer type for random-number generator
  45 AC_CHECK_SIZEOF(unsigned int)
  46 AC_CHECK_SIZEOF(unsigned long)
  47 AC_CHECK_TYPES(uint32_t, [], [], [$ac_includes_default
  48 #ifdef HAVE_STDINT_H
  49 #  include <stdint.h>
  50 #endif])
  51
  52 dnl Checks for libraries and functions
  53 AC_CHECK_LIB(m, sin)
  54 AC_CHECK_FUNCS([BSDgettimeofday gettimeofday time qsort_r getpid])
  55
  56 AC_MSG_CHECKING([for gettid syscall])
  57 AC_TRY_LINK([#include <unistd.h>
  58 #include <sys/syscall.h>
  59 ], [syscall(SYS_gettid);], [ok=yes], [ok=no])
  60 if test "$ok" = "yes"; then
  61         AC_DEFINE(HAVE_GETTID_SYSCALL,1,[Define if syscall(SYS_gettid) available.])
  62 fi
  63 AC_MSG_RESULT(${ok})
  64
  65 AC_MSG_CHECKING([for isnan])
  66 AC_TRY_LINK([#include <math.h>
  67 ], [if (!isnan(3.14159)) isnan(2.7183);], ok=yes, ok=no)
  68 if test "$ok" = "yes"; then
  69         AC_DEFINE(HAVE_ISNAN,1,[Define if the isnan() function/macro is available.])
  70 fi
  71 AC_MSG_RESULT(${ok})
  72
  73 AC_MSG_CHECKING([for isinf])
  74 AC_TRY_LINK([#include <math.h>
  75 ], [if (!isinf(3.14159)) isinf(2.7183);], ok=yes, ok=no)
  76 if test "$ok" = "yes"; then
  77         AC_DEFINE(HAVE_ISINF,1,[Define if the isinf() function/macro is available.])
  78 fi
  79 AC_MSG_RESULT(${ok})
  80
  81 dnl -----------------------------------------------------------------------
  82
  83 if test "x$with_cxx" = xyes; then
  84   test -r $srcdir/lbfgs/ap.cpp && test -r $srcdir/lbfgs/ap.h && test -r $srcdir/lbfgs/l-bfgs-b.cpp && test -r $srcdir/lbfgs/l-bfgs-b.h && have_lbfgs=yes
  85 fi
  86 AM_CONDITIONAL(WITH_NOCEDAL, test -n "$have_lbfgs")
  87 if test -n "$have_lbfgs"; then
  88    AC_DEFINE(WITH_NOCEDAL, [1], [Define if we have the non-free Nocedal LBFGS code])
  89 fi
  90
  91 dnl -----------------------------------------------------------------------
  92 dnl SWIG wrappers
  93
  94 if test "$enable_shared" = no; then
  95    AC_MSG_WARN([Python and Guile wrappers require --enable-shared; disabling])
  96 else
  97
  98 dnl Guile:
  99 AC_CHECK_PROG(GUILE_CONFIG, guile-config, guile-config, unknown)
 100 if test "x$GUILE_CONFIG" = "xunknown"; then
 101    AC_MSG_WARN([can't find guile-config, disabling Guile wrapper])
 102 else
 103    save_CPPFLAGS=$CPPFLAGS
 104    save_LIBS=$LIBS
 105    GUILE_CPPFLAGS=`$GUILE_CONFIG compile`
 106    GUILE_LIBS=`$GUILE_CONFIG link`
 107    CPPFLAGS="$CPPFLAGS $GUILE_CPPFLAGS"
 108    LIBS="$GUILE_LIBS $LIBS"
 109    AC_MSG_CHECKING([if linking to guile works])
 110    AC_TRY_LINK_FUNC(scm_is_vector, [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 111         AC_MSG_WARN(guile-config is broken, disabling Guile wrapper)
 112         GUILE_CONFIG="unknown"])
 113    CPPFLAGS=$save_CPPFLAGS
 114    LIBS=$save_LIBS
 115 fi
 116 AC_CHECK_PROG(GUILE, guile, guile, unknown)
 117 if test "x$GUILE" = xunknown; then
 118    AC_MSG_WARN([can't find guile, disabling Guile wrapper])
 119    GUILE_CONFIG=unknown
 120 else
 121    AC_MSG_CHECKING([for Guile site installation directory])
 122    GUILE_SITEDIR=`guile -c '(display (%site-dir))'`
 123    AC_MSG_RESULT([$GUILE_SITEDIR])
 124 fi
 125 AC_SUBST(GUILE_SITEDIR)
 126 AC_SUBST(GUILE_CPPFLAGS)
 127 AC_SUBST(GUILE_LIBS)
 128 AM_CONDITIONAL(WITH_GUILE, test x"$GUILE_CONFIG" != "xunknown")
 129
 130 dnl Python:
 131 AM_PATH_PYTHON([],[have_python=yes],[have_python=no])
 132 if test $have_python = yes; then
 133   pdir=`dirname $pythondir | sed 's,/lib/,/include/,'`
 134   pdir=`eval echo $pdir`
 135   AC_MSG_CHECKING([for Python include directory])
 136   for PYTHON_INCLUDE_DIR in "$pdir" /usr/include/python$PYTHON_VERSION /usr/local/include/python$PYTHON_VERSION unknown; do
 137     test -d "$PYTHON_INCLUDE_DIR" && break
 138   done
 139   AC_MSG_RESULT([$PYTHON_INCLUDE_DIR])
 140   if test "x$PYTHON_INCLUDE_DIR" = xunknown; then
 141      AC_MSG_WARN([disabling Python wrappers])
 142      have_python=no
 143   fi
 144   AC_SUBST(PYTHON_INCLUDE_DIR)
 145 fi
 146 AM_CONDITIONAL(WITH_PYTHON, test x"$have_python" = "xyes")
 147
 148 fi
 149
 150 dnl -----------------------------------------------------------------------
 151 dnl Compiling Octave plug-in
 152
 153 AC_ARG_VAR(OCT_INSTALL_DIR, [where to install GNU Octave .oct plug-ins])
 154 AC_ARG_VAR(M_INSTALL_DIR, [where to install GNU Octave .m plug-ins])
 155 AC_ARG_VAR(MKOCTFILE, [name of mkoctfile program to compile Octave plug-ins])
 156
 157 AC_ARG_WITH(octave,
 158         [AC_HELP_STRING([--without-octave], [don't compile Octave plugin])],
 159         with_octave=$withval,with_octave=yes)
 160
 161 AC_CHECK_PROGS(MKOCTFILE, mkoctfile, echo)
 162
 163 if test x"$with_octave" = xno; then
 164         OCT_INSTALL_DIR=""
 165 elif test "$MKOCTFILE" = "echo"; then
 166         AC_MSG_WARN([can't find mkoctfile: won't be able to compile GNU Octave plugin])
 167         OCT_INSTALL_DIR=""
 168 elif test x"$OCT_INSTALL_DIR" = "x"; then
 169         # try to find installation directory
 170         AC_CHECK_PROGS(OCTAVE, octave, echo)
 171         AC_CHECK_PROGS(OCTAVE_CONFIG, octave-config, echo)
 172
 173         AC_MSG_CHECKING(where octave plugins go)
 174         OCT_INSTALL_DIR=`octave-config --oct-site-dir 2> /dev/null | grep '/'`
 175         if test -z "$OCT_INSTALL_DIR"; then
 176                 OCT_INSTALL_DIR=`octave-config --print OCTFILEDIR 2> /dev/null | grep '/'`
 177         fi
 178         if test -z "$OCT_INSTALL_DIR"; then
 179                 OCT_INSTALL_DIR=`echo "path" | $OCTAVE -q 2> /dev/null | grep "/oct/" | head -1`
 180         fi
 181         if test -z "$OCT_INSTALL_DIR"; then
 182                 OCT_INSTALL_DIR=`echo "DEFAULT_LOADPATH" | $OCTAVE -q 2> /dev/null | tr ':' '\n' | grep "site/oct" | head -1`
 183         fi
 184         if test -n "$OCT_INSTALL_DIR"; then
 185                 AC_MSG_RESULT($OCT_INSTALL_DIR)
 186         else
 187                 AC_MSG_RESULT(unknown)
 188                 AC_MSG_WARN([can't find where to install octave plugins: won't be able to compile octave plugin])
 189         fi
 190
 191         AC_MSG_CHECKING(where octave scripts go)
 192         M_INSTALL_DIR=`octave-config --m-site-dir 2> /dev/null | grep '/'`
 193         if test -z "$M_INSTALL_DIR"; then
 194                 M_INSTALL_DIR=`octave-config --print FCNFILEDIR 2> /dev/null | grep '/'`
 195         fi
 196         if test -z "$M_INSTALL_DIR"; then
 197                 M_INSTALL_DIR=`echo "path" | $OCTAVE -q 2> /dev/null | grep "/m" | head -1`
 198         fi
 199         if test -z "$M_INSTALL_DIR"; then
 200                 M_INSTALL_DIR=`echo "DEFAULT_LOADPATH" | $OCTAVE -q 2> /dev/null | tr ':' '\n' | grep "site/m" | head -1`
 201         fi
 202         if test -n "$M_INSTALL_DIR"; then
 203                 AC_MSG_RESULT($M_INSTALL_DIR)
 204         else
 205                 AC_MSG_RESULT(unknown)
 206                 AC_MSG_WARN([can't find where to install octave scripts: won't be able to install octave plugin])
 207                 OCT_INSTALL_DIR=""
 208         fi
 209 fi
 210
 211 if test x"$OCT_INSTALL_DIR" != "x"; then
 212 if test "$enable_shared" = no; then
 213      AC_MSG_CHECKING([whether mkoctfile can link with static objects])
 214      rm -f conftest*
 215      echo 'void foo(void) {};' > conftestfoo.c
 216      $CC -c conftestfoo.c >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD
 217      cat > conftest.cc <<EOF
 218 #include <octave/oct.h>
 219 extern "C" void foo(void);
 220 DEFUN_DLD(foobar, args, nargout, "foo bar") { foo(); }
 221 EOF
 222      if $MKOCTFILE conftest.cc conftestfoo.o >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 223         AC_MSG_RESULT(yes)
 224      else
 225         AC_MSG_RESULT(no)
 226         AC_MSG_WARN([mkoctfile requires --enable-shared; won't compile Octave plugin])
 227         OCT_INSTALL_DIR=""
 228      fi
 229 fi
 230 fi
 231
 232 AM_CONDITIONAL(WITH_OCTAVE, test x"$OCT_INSTALL_DIR" != "x")
 233 AC_SUBST(OCT_INSTALL_DIR)
 234 AC_SUBST(M_INSTALL_DIR)
 235 AC_SUBST(MKOCTFILE)
 236
 237 dnl -----------------------------------------------------------------------
 238 dnl Compiling Matlab plug-in
 239
 240 AC_ARG_WITH(matlab,
 241         [AC_HELP_STRING([--without-matlab], [don't compile Matlab plugin])],
 242         with_matlab=$withval,with_matlab=yes)
 243
 244 AC_ARG_VAR(MEX_INSTALL_DIR, [where to install Matlab .mex plug-ins])
 245 AC_ARG_VAR(MEX, [name of mex program to compile Matlab plug-ins])
 246 AC_CHECK_PROGS(MEX, mex, echo)
 247 if test x"$with_matlab" = xno; then
 248      MEX_INSTALL_DIR=""
 249 elif test "$MEX" = "echo"; then
 250      AC_MSG_WARN([can't find mex: won't be able to compile Matlab plugin])
 251      MEX_INSTALL_DIR=""
 252 else
 253      AC_MSG_CHECKING([for extension of compiled mex files])
 254      rm -f conftest*
 255      cat > conftest.c <<EOF
 256 #include <mex.h>
 257 void mexFunction(int nlhs, mxArray *plhs[[]],
 258                  int nrhs, const mxArray *prhs[[]]) { }
 259 EOF
 260      if $MEX conftest.c >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 261         MEXSUFF=`ls conftest.m* | head -1 | cut -d'.' -f2`
 262         AC_MSG_RESULT($MEXSUFF)
 263         AC_CHECK_PROGS(MATLAB, matlab, echo)
 264      else
 265         AC_MSG_WARN([$MEX failed to compile a simple file; won't compile Matlab plugin])
 266         MEX_INSTALL_DIR=""
 267         MATLAB=echo
 268      fi
 269
 270      if test x"$MATLAB" != xecho; then
 271      if test "$enable_shared" = no; then
 272      AC_MSG_CHECKING([whether mex can link with static objects])
 273      rm -f conftest*
 274      echo 'void foo(void) {};' > conftestfoo.c
 275      $CC -c conftestfoo.c >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD
 276      cat > conftest.c <<EOF
 277 #include <mex.h>
 278 extern void foo(void);
 279 void mexFunction(int nlhs, mxArray *plhs[[]],
 280                  int nrhs, const mxArray *prhs[[]]) { foo(); }
 281 EOF
 282      if $MEX conftest.c conftestfoo.o >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 283         AC_MSG_RESULT(yes)
 284      else
 285         AC_MSG_RESULT(no)
 286         AC_MSG_WARN([mex requires --enable-shared; won't compile Matlab plugin])
 287         MEX_INSTALL_DIR=""
 288         MATLAB=echo
 289      fi
 290      fi
 291      fi
 292
 293      if test x"$MATLAB" != xecho; then
 294        # try to find installation directory
 295        if test x"$MEX_INSTALL_DIR" = "x"; then
 296           AC_MSG_CHECKING(for MATLAB mex installation dir)
 297           MEX_INSTALL_DIR=`matlab -nodisplay -nodesktop -nojvm -r 'path;quit' | grep toolbox/local |sed 's,^[[^/]]*,,g' |sort |head -1`
 298           AC_MSG_RESULT($MEX_INSTALL_DIR)
 299           if test x`basename "$MEX_INSTALL_DIR"` != xlocal; then
 300              MEX_INSTALL_DIR=""
 301           fi
 302           if test x"$MEX_INSTALL_DIR" = "x"; then
 303             AC_MSG_WARN([can't find reasonable Matlab installation directory; Matlab plugins will not be compiled unless you manually specify MEX_INSTALL_DIR])
 304           fi
 305        fi
 306      else
 307         MEX_INSTALL_DIR=""
 308      fi
 309 fi
 310 AM_CONDITIONAL(WITH_MATLAB, test x"$MEX_INSTALL_DIR" != "x")
 311 AC_SUBST(MEX_INSTALL_DIR)
 312 AC_SUBST(MEX)
 313 AC_SUBST(MEXSUFF)
 314
 315 dnl -----------------------------------------------------------------------
 316 dnl Check for broken Solaris HUGE_VAL macro under gcc 3.4.x and similar
 317
 318 AC_MSG_CHECKING([for working HUGE_VAL])
 319 AC_TRY_COMPILE([#include <math.h>], [double x = -HUGE_VAL;],
 320 [AC_MSG_RESULT([ok])],
 321 [AC_TRY_COMPILE([#include <math.h>
 322 #ifdef __GNUC__
 323 #undef HUGE_VAL
 324 #define HUGE_VAL __builtin_huge_val()
 325 #endif], [double x = -HUGE_VAL;],
 326 [AC_MSG_RESULT([__builtin_huge_val()])
 327 AC_DEFINE(REPLACEMENT_HUGE_VAL,[__builtin_huge_val()],
 328           [replacement for broken HUGE_VAL macro, if needed])],
 329 [AC_MSG_RESULT([unknown])
 330 AC_MSG_ERROR([broken HUGE_VAL macro with this compiler, unknown workaround])])])
 331
 332 dnl -----------------------------------------------------------------------
 333 dnl Debugging
 334
 335 AC_ARG_ENABLE(debug, [AC_HELP_STRING([--enable-debug],[compile with extra runtime checks for debugging])], ok=$enableval, ok=no)
 336 if test "$ok" = "yes"; then
 337         AC_DEFINE(DEBUG,1,[Define to enable extra debugging code.])
 338 fi
 339
 340 dnl override CFLAGS selection when debugging
 341 if test "${enable_debug}" = "yes"; then
 342         CFLAGS="-g"
 343         CXXFLAGS="-g"
 344         FFLAGS="-g"
 345 fi
 346
 347 dnl add gcc warnings, in debug/maintainer mode only
 348 if test "$enable_debug" = yes || test "$USE_MAINTAINER_MODE" = yes; then
 349 if test $ac_cv_prog_gcc = yes; then
 350    if test "$ac_test_CFLAGS" != "set"; then
 351       CFLAGS="$CFLAGS -Wall -W -Wcast-qual -Wpointer-arith -Wcast-align -pedantic -Wshadow -Wbad-function-cast -Wwrite-strings -Wstrict-prototypes -Wredundant-decls -Wnested-externs -Wundef -Wconversion -Wmissing-prototypes -Wmissing-declarations"
 352    fi
 353    if test "$ac_test_CXXFLAGS" != "set"; then
 354       CXXFLAGS="$CXXFLAGS -Wall -W -Wcast-qual -Wpointer-arith -Wcast-align -pedantic -Wshadow -Wwrite-strings -Wredundant-decls -Wundef -Wconversion"
 355    fi
 356    if test "x$with_cxx" = xyes; then
 357       CFLAGS=$CXXFLAGS
 358    fi
 359 fi
 360 fi
 361
 362 vers=`echo ${VERSION}.0.0 | cut -d. -f1`
 363 AC_DEFINE_UNQUOTED(MAJOR_VERSION, $vers, [Major version number.])
 364 vers=`echo ${VERSION}.0.0 | cut -d. -f2`
 365 AC_DEFINE_UNQUOTED(MINOR_VERSION, $vers, [Minor version number.])
 366 vers=`echo ${VERSION}.0.0 | cut -d. -f3`
 367 AC_DEFINE_UNQUOTED(BUGFIX_VERSION, $vers, [Bugfix version number.])
 368
 369 dnl -----------------------------------------------------------------------
 370
 371 AC_CONFIG_FILES([
 372    Makefile
 373    nlopt.pc
 374    api/Makefile
 375    util/Makefile
 376    octave/Makefile
 377    direct/Makefile
 378    cdirect/Makefile
 379    stogo/Makefile
 380    praxis/Makefile
 381    lbfgs/Makefile
 382    luksan/Makefile
 383    crs/Makefile
 384    mlsl/Makefile
 385    mma/Makefile
 386    cobyla/Makefile
 387    newuoa/Makefile
 388    neldermead/Makefile
 389    auglag/Makefile
 390    bobyqa/Makefile
 391    isres/Makefile
 392    test/Makefile
 393    swig/Makefile
 394    swig/nlopt.scm
 395 ])
 396
 397 AC_OUTPUT