Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34 use Dpkg::Control::Hash;
  35 use Debian::Dgit::ExitStatus;
  36 use Debian::Dgit::I18n;
  37
  38 BEGIN {
  39     use Exporter   ();
  40     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  41
  42     $VERSION     = 1.00;
  43     @ISA         = qw(Exporter);
  44     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  45                       dep14_version_mangle
  46                       debiantags debiantag_old debiantag_new
  47                       debiantag_maintview
  48                       upstreamversion
  49                       stripepoch source_file_leafname is_orig_file_of_p_v
  50                       server_branch server_ref
  51                       stat_exists link_ltarget rename_link_xf
  52                       hashfile
  53                       fail failmsg ensuredir must_getcwd executable_on_path
  54                       waitstatusmsg failedcmd_waitstatus
  55                       failedcmd_report_cmd failedcmd
  56                       runcmd shell_cmd cmdoutput cmdoutput_errok
  57                       git_rev_parse git_cat_file
  58                       git_get_ref git_get_symref git_for_each_ref
  59                       git_for_each_tag_referring is_fast_fwd
  60                       git_check_unmodified
  61                       git_reflog_action_msg  git_update_ref_cmd
  62                       make_commit_text
  63                       reflog_cache_insert reflog_cache_lookup
  64                       $package_re $component_re $deliberately_re
  65                       $distro_re $versiontag_re $series_filename_re
  66                       $orig_f_comp_re $orig_f_sig_re $orig_f_tail_re
  67                       $extra_orig_namepart_re
  68                       $git_null_obj
  69                       $branchprefix
  70                       $ffq_refprefix $gdrlast_refprefix
  71                       initdebug enabledebug enabledebuglevel
  72                       printdebug debugcmd
  73                       $printdebug_when_debuglevel $debugcmd_when_debuglevel
  74                       $debugprefix *debuglevel *DEBUG
  75                       shellquote printcmd messagequote
  76                       $negate_harmful_gitattrs
  77                       changedir git_slurp_config_src
  78                       gdr_ffq_prev_branchinfo
  79                       parsecontrolfh parsecontrol parsechangelog
  80                       getfield parsechangelog_loop
  81                       playtree_setup);
  82     # implicitly uses $main::us
  83     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  84                      playground => [qw(record_maindir $maindir $local_git_cfg
  85                                        $maindir_gitdir $maindir_gitcommon
  86                                        fresh_playground
  87                                        ensure_a_playground)]);
  88     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  89                      @{ $EXPORT_TAGS{playground} } );
  90 }
  91
  92 our @EXPORT_OK;
  93
  94 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  95 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  96 our $deliberately_re = "(?:TEST-)?$package_re";
  97 our $distro_re = $component_re;
  98 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  99 our $branchprefix = 'dgit';
 100 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
 101 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
 102 our $orig_f_comp_re = qr{orig(?:-$extra_orig_namepart_re)?};
 103 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
 104 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
 105 our $git_null_obj = '0' x 40;
 106 our $ffq_refprefix = 'ffq-prev';
 107 our $gdrlast_refprefix = 'debrebase-last';
 108 our $printdebug_when_debuglevel = 1;
 109 our $debugcmd_when_debuglevel = 1;
 110
 111 # these three all go together, only valid after record_maindir
 112 our $maindir;
 113 our $maindir_gitdir;
 114 our $maindir_gitcommon;
 115
 116 # policy hook exit status bits
 117 # see dgit-repos-server head comment for documentation
 118 # 1 is reserved in case something fails with `exit 1' and to spot
 119 # dynamic loader, runtime, etc., failures, which report 127 or 255
 120 sub NOFFCHECK () { return 0x2; }
 121 sub FRESHREPO () { return 0x4; }
 122 sub NOCOMMITCHECK () { return 0x8; }
 123
 124 our $debugprefix;
 125 our $debuglevel = 0;
 126
 127 our $negate_harmful_gitattrs =
 128     "-text -eol -crlf -ident -filter -working-tree-encoding";
 129     # ^ when updating this, alter the regexp in dgit:is_gitattrs_setup
 130
 131 our $forkcheck_mainprocess;
 132
 133 sub forkcheck_setup () {
 134     $forkcheck_mainprocess = $$;
 135 }
 136
 137 sub forkcheck_mainprocess () {
 138     # You must have called forkcheck_setup or setup_sigwarn already
 139     getppid != $forkcheck_mainprocess;
 140 }
 141
 142 sub setup_sigwarn () {
 143     forkcheck_setup();
 144     $SIG{__WARN__} = sub {
 145         confess $_[0] if forkcheck_mainprocess;
 146     };
 147 }
 148
 149 sub initdebug ($) {
 150     ($debugprefix) = @_;
 151     open DEBUG, ">/dev/null" or confess $!;
 152 }
 153
 154 sub enabledebug () {
 155     open DEBUG, ">&STDERR" or confess $!;
 156     DEBUG->autoflush(1);
 157     $debuglevel ||= 1;
 158 }
 159
 160 sub enabledebuglevel ($) {
 161     my ($newlevel) = @_; # may be undef (eg from env var)
 162     confess if $debuglevel;
 163     $newlevel //= 0;
 164     $newlevel += 0;
 165     return unless $newlevel;
 166     $debuglevel = $newlevel;
 167     enabledebug();
 168 }
 169
 170 sub printdebug {
 171     # Prints a prefix, and @_, to DEBUG.  @_ should normally contain
 172     # a trailing \n.
 173
 174     # With no (or only empty) arguments just prints the prefix and
 175     # leaves the caller to do more with DEBUG.  The caller should make
 176     # sure then to call printdebug with something ending in "\n" to
 177     # get the prefix right in subsequent calls.
 178
 179     return unless $debuglevel >= $printdebug_when_debuglevel;
 180     our $printdebug_noprefix;
 181     print DEBUG $debugprefix unless $printdebug_noprefix;
 182     pop @_ while @_ and !length $_[-1];
 183     return unless @_;
 184     print DEBUG @_ or confess $!;
 185     $printdebug_noprefix = $_[-1] !~ m{\n$};
 186 }
 187
 188 sub messagequote ($) {
 189     local ($_) = @_;
 190     s{\\}{\\\\}g;
 191     s{\n}{\\n}g;
 192     s{\x08}{\\b}g;
 193     s{\t}{\\t}g;
 194     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 195     $_;
 196 }
 197
 198 sub shellquote {
 199     my @out;
 200     local $_;
 201     defined or confess __ 'internal error' foreach @_;
 202     foreach my $a (@_) {
 203         $_ = $a;
 204         if (!length || m{[^-=_./:0-9a-z]}i) {
 205             s{['\\]}{'\\$&'}g;
 206             push @out, "'$_'";
 207         } else {
 208             push @out, $_;
 209         }
 210     }
 211     return join ' ', @out;
 212 }
 213
 214 sub printcmd {
 215     my $fh = shift @_;
 216     my $intro = shift @_;
 217     print $fh $intro," " or confess $!;
 218     print $fh shellquote @_ or confess $!;
 219     print $fh "\n" or confess $!;
 220 }
 221
 222 sub debugcmd {
 223     my $extraprefix = shift @_;
 224     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_)
 225         if $debuglevel >= $debugcmd_when_debuglevel;
 226 }
 227
 228 sub dep14_version_mangle ($) {
 229     my ($v) = @_;
 230     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 231     $v =~ y/~:/_%/;
 232     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 233     return $v;
 234 }
 235
 236 sub debiantag_old ($$) {
 237     my ($v,$distro) = @_;
 238     return "$distro/". dep14_version_mangle $v;
 239 }
 240
 241 sub debiantag_new ($$) {
 242     my ($v,$distro) = @_;
 243     return "archive/$distro/".dep14_version_mangle $v;
 244 }
 245
 246 sub debiantag_maintview ($$) {
 247     my ($v,$distro) = @_;
 248     return "$distro/".dep14_version_mangle $v;
 249 }
 250
 251 sub debiantags ($$) {
 252     my ($version,$distro) = @_;
 253     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 254 }
 255
 256 sub stripepoch ($) {
 257     my ($vsn) = @_;
 258     $vsn =~ s/^\d+\://;
 259     return $vsn;
 260 }
 261
 262 sub upstreamversion ($) {
 263     my ($vsn) = @_;
 264     $vsn =~ s/-[^-]+$//;
 265     return $vsn;
 266 }
 267
 268 sub source_file_leafname ($$$) {
 269     my ($package,$vsn,$sfx) = @_;
 270     return "${package}_".(stripepoch $vsn).$sfx
 271 }
 272
 273 sub is_orig_file_of_p_v ($$$) {
 274     my ($f, $package, $upstreamvsn) = @_;
 275     my $base = source_file_leafname $package, $upstreamvsn, '';
 276     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
 277     return 1;
 278 }
 279
 280 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 281 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 282
 283 sub stat_exists ($) {
 284     my ($f) = @_;
 285     return 1 if stat $f;
 286     return 0 if $!==&ENOENT;
 287     confess "stat $f: $!";
 288 }
 289
 290 sub _us () {
 291     $::us // ($0 =~ m#[^/]*$#, $&);
 292 }
 293
 294 sub failmsg {
 295     my $s = f_ "error: %s\n", "@_";
 296     $s =~ s/\n\n$/\n/g;
 297     my $prefix = _us().": ";
 298     $s =~ s/^/$prefix/gm;
 299     return "\n".$s;
 300 }
 301
 302 sub fail {
 303     die failmsg @_;
 304 }
 305
 306 sub ensuredir ($) {
 307     my ($dir) = @_; # does not create parents
 308     return if mkdir $dir;
 309     return if $! == EEXIST;
 310     confess "mkdir $dir: $!";
 311 }
 312
 313 sub must_getcwd () {
 314     my $d = getcwd();
 315     defined $d or fail f_ "getcwd failed: %s\n", $!;
 316     return $d;
 317 }
 318
 319 sub executable_on_path ($) {
 320     my ($program) = @_;
 321     return 1 if $program =~ m{/};
 322     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 323     foreach my $pe (@path) {
 324         my $here = "$pe/$program";
 325         return $here if stat_exists $here && -x _;
 326     }
 327     return undef;
 328 }
 329
 330 our @signames = split / /, $Config{sig_name};
 331
 332 sub waitstatusmsg () {
 333     if (!$?) {
 334         return __ "terminated, reporting successful completion";
 335     } elsif (!($? & 255)) {
 336         return f_ "failed with error exit status %s", WEXITSTATUS($?);
 337     } elsif (WIFSIGNALED($?)) {
 338         my $signum=WTERMSIG($?);
 339         return f_ "died due to fatal signal %s",
 340             ($signames[$signum] // "number $signum").
 341             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 342     } else {
 343         return f_ "failed with unknown wait status %s", $?;
 344     }
 345 }
 346
 347 sub failedcmd_report_cmd {
 348     my $intro = shift @_;
 349     $intro //= __ "failed command";
 350     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or confess $!; };
 351 }
 352
 353 sub failedcmd_waitstatus {
 354     if ($? < 0) {
 355         return f_ "failed to fork/exec: %s", $!;
 356     } elsif ($?) {
 357         return f_ "subprocess %s", waitstatusmsg();
 358     } else {
 359         return __ "subprocess produced invalid output";
 360     }
 361 }
 362
 363 sub failedcmd {
 364     # Expects $!,$? as set by close - see below.
 365     # To use with system(), set $?=-1 first.
 366     #
 367     # Actual behaviour of perl operations:
 368     #   success              $!==0       $?==0       close of piped open
 369     #   program failed       $!==0       $? >0       close of piped open
 370     #   syscall failure      $! >0       $?=-1       close of piped open
 371     #   failure              $! >0       unchanged   close of something else
 372     #   success              trashed     $?==0       system
 373     #   program failed       trashed     $? >0       system
 374     #   syscall failure      $! >0       unchanged   system
 375     failedcmd_report_cmd undef, @_;
 376     fail failedcmd_waitstatus();
 377 }
 378
 379 sub runcmd {
 380     debugcmd "+",@_;
 381     $!=0; $?=-1;
 382     failedcmd @_ if system @_;
 383 }
 384
 385 sub shell_cmd {
 386     my ($first_shell, @cmd) = @_;
 387     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 388 }
 389
 390 sub cmdoutput_errok {
 391     confess Dumper(\@_)." ?" if grep { !defined } @_;
 392     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 393     debugcmd "|",@_;
 394     open P, "-|", @_ or confess "$_[0] $!";
 395     my $d;
 396     $!=0; $?=0;
 397     { local $/ = undef; $d = <P>; }
 398     confess $! if P->error;
 399     if (!close P) { printdebug "=>!$?\n"; return undef; }
 400     chomp $d;
 401     if ($debuglevel > 0) {
 402         $d =~ m/^.*/;
 403         my $dd = $&;
 404         my $more = (length $' ? '...' : ''); #');
 405         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 406         printdebug "=> \`$dd'",$more,"\n";
 407     }
 408     return $d;
 409 }
 410
 411 sub cmdoutput {
 412     my $d = cmdoutput_errok @_;
 413     defined $d or failedcmd @_;
 414     return $d;
 415 }
 416
 417 sub link_ltarget ($$) {
 418     my ($old,$new) = @_;
 419     lstat $old or return undef;
 420     if (-l _) {
 421         $old = cmdoutput qw(realpath  --), $old;
 422     }
 423     my $r = link $old, $new;
 424     $r = symlink $old, $new if !$r && $!==EXDEV;
 425     $r or fail "(sym)link $old $new: $!\n";
 426 }
 427
 428 sub rename_link_xf ($$$) {
 429     # renames/moves or links/copies $src to $dst,
 430     # even if $dst is on a different fs
 431     # (May use the filename "$dst.tmp".);
 432     # On success, returns true.
 433     # On failure, returns false and sets
 434     #    $@ to a reason message
 435     #    $! to an errno value, or -1 if not known
 436     # having possibly printed something about mv to stderr.
 437     my ($keeporig,$src,$dst) = @_;
 438     if ($keeporig
 439         ? link   $src, $dst
 440         : rename $src, $dst) {
 441         return 1;
 442     } elsif ($! != EXDEV) {
 443         $@ = "$!";
 444         return 0;
 445     }
 446     $!=0; $?=0;
 447     my @cmd = ($keeporig ? qw(cp) : qw(mv));
 448     push @cmd, (qw(--), $src, "$dst.tmp");
 449     debugcmd '+',@cmd;
 450     if (system @cmd) {
 451         failedcmd_report_cmd undef, @cmd;
 452         $@ = failedcmd_waitstatus();
 453         $! = -1;
 454         return 0;
 455     }
 456     if (rename "$dst.tmp", $dst) {
 457         return 1;
 458     } else {
 459         $@ = f_ "finally install file after mv: %S", $!;
 460         return 0;
 461     }
 462 }
 463
 464 sub hashfile ($) {
 465     my ($fn) = @_;
 466     my $h = Digest::SHA->new(256);
 467     $h->addfile($fn);
 468     return $h->hexdigest();
 469 }
 470
 471 sub git_rev_parse ($) {
 472     return cmdoutput qw(git rev-parse), "$_[0]~0";
 473 }
 474
 475 sub git_cat_file ($;$) {
 476     my ($objname, $etype) = @_;
 477     # => ($type, $data) or ('missing', undef)
 478     # in scalar context, just the data
 479     # if $etype defined, dies unless type is $etype or in @$etype
 480     our ($gcf_pid, $gcf_i, $gcf_o);
 481     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 482     my $chk = sub {
 483         my ($gtype, $data) = @_;
 484         if ($etype) {
 485             $etype = [$etype] unless ref $etype;
 486             confess "$objname expected @$etype but is $gtype"
 487                 unless grep { $gtype eq $_ } @$etype;
 488         }
 489         return ($gtype, $data);
 490     };
 491     if (!$gcf_pid) {
 492         my @cmd = qw(git cat-file --batch);
 493         debugcmd "GCF|", @cmd;
 494         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or confess $!;
 495     }
 496     printdebug "GCF>| $objname\n";
 497     print $gcf_i $objname, "\n" or confess $!;
 498     my $x = <$gcf_o>;
 499     printdebug "GCF<| ", $x;
 500     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 501     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or confess "$objname ?";
 502     my $data;
 503     (read $gcf_o, $data, $size) == $size or confess "$objname $!";
 504     $x = <$gcf_o>;
 505     $x eq "\n" or confess "$objname ($_) $!";
 506     return $chk->($type, $data);
 507 }
 508
 509 sub git_get_symref (;$) {
 510     my ($symref) = @_;  $symref //= 'HEAD';
 511     # => undef if not a symref, otherwise refs/...
 512     my @cmd = (qw(git symbolic-ref -q HEAD));
 513     my $branch = cmdoutput_errok @cmd;
 514     if (!defined $branch) {
 515         $?==256 or failedcmd @cmd;
 516     } else {
 517         chomp $branch;
 518     }
 519     return $branch;
 520 }
 521
 522 sub git_for_each_ref ($$;$) {
 523     my ($pattern,$func,$gitdir) = @_;
 524     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 525     # $reftail is RHS of ref after refs/[^/]+/
 526     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 527     # $pattern may be an array ref to mean multiple patterns
 528     $pattern = [ $pattern ] unless ref $pattern;
 529     my @cmd = (qw(git for-each-ref), @$pattern);
 530     if (defined $gitdir) {
 531         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 532     }
 533     open GFER, "-|", @cmd or confess $!;
 534     debugcmd "|", @cmd;
 535     while (<GFER>) {
 536         chomp or confess "$_ ?";
 537         printdebug "|> ", $_, "\n";
 538         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or confess "$_ ?";
 539         $func->($1,$2,$3,$4);
 540     }
 541     $!=0; $?=0; close GFER or confess "$pattern $? $!";
 542 }
 543
 544 sub git_get_ref ($) {
 545     # => '' if no such ref
 546     my ($refname) = @_;
 547     local $_ = $refname;
 548     s{^refs/}{[r]efs/} or confess "$refname $_ ?";
 549     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 550 }
 551
 552 sub git_for_each_tag_referring ($$) {
 553     my ($objreferring, $func) = @_;
 554     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 555     printdebug "git_for_each_tag_referring ",
 556         ($objreferring // 'UNDEF'),"\n";
 557     git_for_each_ref('refs/tags', sub {
 558         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 559         return unless $objtype eq 'tag';
 560         my $refobjid = git_rev_parse $tagobjid;
 561         return unless
 562             !defined $objreferring # caller wants them all
 563             or $tagobjid eq $objreferring
 564             or $refobjid eq $objreferring;
 565         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 566     });
 567 }
 568
 569 sub git_check_unmodified () {
 570     foreach my $cached (qw(0 1)) {
 571         my @cmd = qw(git diff --quiet);
 572         push @cmd, qw(--cached) if $cached;
 573         push @cmd, qw(HEAD);
 574         debugcmd "+",@cmd;
 575         $!=0; $?=-1; system @cmd;
 576         return if !$?;
 577         if ($?==256) {
 578             fail
 579                 $cached
 580                 ? __ "git index contains changes (does not match HEAD)"
 581                 : __ "working tree is dirty (does not match HEAD)";
 582         } else {
 583             failedcmd @cmd;
 584         }
 585     }
 586 }
 587
 588 sub is_fast_fwd ($$) {
 589     my ($ancestor,$child) = @_;
 590     my @cmd = (qw(git merge-base), $ancestor, $child);
 591     my $mb = cmdoutput_errok @cmd;
 592     if (defined $mb) {
 593         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 594     } else {
 595         $?==256 or failedcmd @cmd;
 596         return 0;
 597     }
 598 }
 599
 600 sub git_reflog_action_msg ($) {
 601     my ($msg) = @_;
 602     my $rla = $ENV{GIT_REFLOG_ACTION};
 603     $msg = "$rla: $msg" if length $rla;
 604     return $msg;
 605 }
 606
 607 sub git_update_ref_cmd {
 608     # returns  qw(git update-ref), qw(-m), @_
 609     # except that message may be modified to honour GIT_REFLOG_ACTION
 610     my $msg = shift @_;
 611     $msg = git_reflog_action_msg $msg;
 612     return qw(git update-ref -m), $msg, @_;
 613 }
 614
 615 sub changedir ($) {
 616     my ($newdir) = @_;
 617     printdebug "CD $newdir\n";
 618     chdir $newdir or confess "chdir: $newdir: $!";
 619 }
 620
 621 sub git_slurp_config_src ($) {
 622     my ($src) = @_;
 623     # returns $r such that $r->{KEY}[] = VALUE
 624     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 625     debugcmd "|",@cmd;
 626
 627     local ($debuglevel) = $debuglevel-2;
 628     local $/="\0";
 629
 630     my $r = { };
 631     open GITS, "-|", @cmd or confess $!;
 632     while (<GITS>) {
 633         chomp or confess;
 634         printdebug "=> ", (messagequote $_), "\n";
 635         m/\n/ or confess "$_ ?";
 636         push @{ $r->{$`} }, $'; #';
 637     }
 638     $!=0; $?=0;
 639     close GITS
 640         or ($!==0 && $?==256)
 641         or failedcmd @cmd;
 642     return $r;
 643 }
 644
 645 sub gdr_ffq_prev_branchinfo ($) {
 646     my ($symref) = @_;
 647     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 648     # 'status' may be
 649     #    branch         message is undef
 650     #    weird-symref   } no $symref,
 651     #    notbranch      }  no $ffq_prev
 652     return ('detached', __ 'detached HEAD') unless defined $symref;
 653     return ('weird-symref', __ 'HEAD symref is not to refs/')
 654         unless $symref =~ m{^refs/};
 655     my $ffq_prev = "refs/$ffq_refprefix/$'";
 656     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 657     printdebug "ffq_prev_branchinfo branch current $symref\n";
 658     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 659 }
 660
 661 sub parsecontrolfh ($$;$) {
 662     my ($fh, $desc, $allowsigned) = @_;
 663     our $dpkgcontrolhash_noissigned;
 664     my $c;
 665     for (;;) {
 666         my %opts = ('name' => $desc);
 667         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 668         $c = Dpkg::Control::Hash->new(%opts);
 669         $c->parse($fh,$desc) or fail f_ "parsing of %s failed", $desc;
 670         last if $allowsigned;
 671         last if $dpkgcontrolhash_noissigned;
 672         my $issigned= $c->get_option('is_pgp_signed');
 673         if (!defined $issigned) {
 674             $dpkgcontrolhash_noissigned= 1;
 675             seek $fh, 0,0 or confess "seek $desc: $!";
 676         } elsif ($issigned) {
 677             fail f_
 678                 "control file %s is (already) PGP-signed. ".
 679                 " Note that dgit push needs to modify the .dsc and then".
 680                 " do the signature itself",
 681                 $desc;
 682         } else {
 683             last;
 684         }
 685     }
 686     return $c;
 687 }
 688
 689 sub parsecontrol {
 690     my ($file, $desc, $allowsigned) = @_;
 691     my $fh = new IO::Handle;
 692     open $fh, '<', $file or fail f_ "open %s (%s): %s", $file, $desc, $!;
 693     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 694     $fh->error and confess $!;
 695     close $fh;
 696     return $c;
 697 }
 698
 699 sub parsechangelog {
 700     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 701     my $p = new IO::Handle;
 702     my @cmd = (qw(dpkg-parsechangelog), @_);
 703     open $p, '-|', @cmd or confess $!;
 704     $c->parse($p);
 705     $?=0; $!=0; close $p or failedcmd @cmd;
 706     return $c;
 707 }
 708
 709 sub getfield ($$) {
 710     my ($dctrl,$field) = @_;
 711     my $v = $dctrl->{$field};
 712     return $v if defined $v;
 713     fail f_ "missing field %s in %s", $field, $dctrl->get_option('name');
 714 }
 715
 716 sub parsechangelog_loop ($$$) {
 717     my ($clogcmd, $descbase, $fn) = @_;
 718     # @$clogcmd is qw(dpkg-parsechangelog ...some...options...)
 719     # calls $fn->($thisstanza, $desc);
 720     debugcmd "|",@$clogcmd;
 721     open CLOGS, "-|", @$clogcmd or confess $!;
 722     for (;;) {
 723         my $stanzatext = do { local $/=""; <CLOGS>; };
 724         printdebug "clogp stanza ".Dumper($stanzatext) if $debuglevel>1;
 725         last if !defined $stanzatext;
 726
 727         my $desc = "$descbase, entry no.$.";
 728         open my $stanzafh, "<", \$stanzatext or confess;
 729         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
 730
 731         $fn->($thisstanza, $desc);
 732     }
 733     confess $! if CLOGS->error;
 734     close CLOGS or $?==SIGPIPE or failedcmd @$clogcmd;
 735 }
 736
 737 sub make_commit_text ($) {
 738     my ($text) = @_;
 739     my ($out, $in);
 740     my @cmd = (qw(git hash-object -w -t commit --stdin));
 741     debugcmd "|",@cmd;
 742     print Dumper($text) if $debuglevel > 1;
 743     my $child = open2($out, $in, @cmd) or confess $!;
 744     my $h;
 745     eval {
 746         print $in $text or confess $!;
 747         close $in or confess $!;
 748         $h = <$out>;
 749         $h =~ m/^\w+$/ or confess;
 750         $h = $&;
 751         printdebug "=> $h\n";
 752     };
 753     close $out;
 754     waitpid $child, 0 == $child or confess "$child $!";
 755     $? and failedcmd @cmd;
 756     return $h;
 757 }
 758
 759 sub reflog_cache_insert ($$$) {
 760     my ($ref, $cachekey, $value) = @_;
 761     # you must call this in $maindir
 762     # you must have called record_maindir
 763
 764     # When we no longer need to support squeeze, use --create-reflog
 765     # instead of this:
 766     my $parent = $ref; $parent =~ s{/[^/]+$}{};
 767     ensuredir "$maindir_gitcommon/logs/$parent";
 768     my $makelogfh = new IO::File "$maindir_gitcommon/logs/$ref", '>>'
 769       or confess $!;
 770
 771     my $oldcache = git_get_ref $ref;
 772
 773     if ($oldcache eq $value) {
 774         my $tree = cmdoutput qw(git rev-parse), "$value:";
 775         # git update-ref doesn't always update, in this case.  *sigh*
 776         my $authline = (ucfirst _us()).
 777             ' <'._us().'@example.com> 1000000000 +0000';
 778         my $dummy = make_commit_text <<ENDU.(__ <<END);
 779 tree $tree
 780 parent $value
 781 author $authline
 782 committer $authline
 783
 784 ENDU
 785 Dummy commit - do not use
 786 END
 787         runcmd qw(git update-ref -m), _us()." - dummy", $ref, $dummy;
 788     }
 789     runcmd qw(git update-ref -m), $cachekey, $ref, $value;
 790 }
 791
 792 sub reflog_cache_lookup ($$) {
 793     my ($ref, $cachekey) = @_;
 794     # you may call this in $maindir or in a playtree
 795     # you must have called record_maindir
 796     my @cmd = (qw(git log -g), '--pretty=format:%H %gs', $ref);
 797     debugcmd "|(probably)",@cmd;
 798     my $child = open GC, "-|";  defined $child or confess $!;
 799     if (!$child) {
 800         chdir $maindir or confess $!;
 801         if (!stat "$maindir_gitcommon/logs/$ref") {
 802             $! == ENOENT or confess $!;
 803             printdebug ">(no reflog)\n";
 804             finish 0;
 805         }
 806         exec @cmd; die f_ "exec %s: %s\n", $cmd[0], $!;
 807     }
 808     while (<GC>) {
 809         chomp;
 810         printdebug ">| ", $_, "\n" if $debuglevel > 1;
 811         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $cachekey;
 812         close GC;
 813         return $1;
 814     }
 815     confess $! if GC->error;
 816     failedcmd unless close GC;
 817     return undef;
 818 }
 819
 820 # ========== playground handling ==========
 821
 822 # terminology:
 823 #
 824 #   $maindir      user's git working tree
 825 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 826 #   playtree      git working tree sharing object store with the user's
 827 #                 inside playground, or identical to it
 828 #
 829 # other globals
 830 #
 831 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 832 #
 833 # expected calling pattern
 834 #
 835 #  firstly
 836 #
 837 #    [record_maindir]
 838 #      must be run in directory containing .git
 839 #      assigns to $maindir if not already set
 840 #      also calls git_slurp_config_src to record git config
 841 #        in $local_git_cfg, unless it's already set
 842 #
 843 #    fresh_playground SUBDIR_PATH_COMPONENTS
 844 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 845 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 846 #      calls record_maindir
 847 #      sets up a new playground (destroying any old one)
 848 #      returns playground pathname
 849 #      caller may call multiple times with different subdir paths
 850 #       createing different playgrounds
 851 #
 852 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 853 #      like fresh_playground except:
 854 #      merely ensures the directory exists; does not delete an existing one
 855 #
 856 #  then can use
 857 #
 858 #    changedir playground
 859 #    changedir $maindir
 860 #
 861 #    playtree_setup $local_git_cfg
 862 #            # ^ call in some (perhaps trivial) subdir of playground
 863 #
 864 #    rmtree playground
 865
 866 # ----- maindir -----
 867
 868 our $local_git_cfg;
 869
 870 sub record_maindir () {
 871     if (!defined $maindir) {
 872         $maindir = must_getcwd();
 873         if (!stat "$maindir/.git") {
 874             fail f_ "cannot stat %s/.git: %s", $maindir, $!;
 875         }
 876         if (-d _) {
 877             # we fall back to this in case we have a pre-worktree
 878             # git, which may not know git rev-parse --git-common-dir
 879             $maindir_gitdir    = "$maindir/.git";
 880             $maindir_gitcommon = "$maindir/.git";
 881         } else {
 882             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 883             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 884         }
 885     }
 886     $local_git_cfg //= git_slurp_config_src 'local';
 887 }
 888
 889 # ----- playgrounds -----
 890
 891 sub ensure_a_playground_parent ($) {
 892     my ($spc) = @_;
 893     record_maindir();
 894     $spc = "$maindir_gitdir/$spc";
 895     my $parent = dirname $spc;
 896     mkdir $parent or $!==EEXIST or fail f_
 897         "failed to mkdir playground parent %s: %s", $parent, $!;
 898     return $spc;
 899 }
 900
 901 sub ensure_a_playground ($) {
 902     my ($spc) = @_;
 903     $spc = ensure_a_playground_parent $spc;
 904     mkdir $spc or $!==EEXIST or fail f_
 905         "failed to mkdir a playground %s: %s", $spc, $!;
 906     return $spc;
 907 }
 908
 909 sub fresh_playground ($) {
 910     my ($spc) = @_;
 911     $spc = ensure_a_playground_parent $spc;
 912     rmtree $spc;
 913     mkdir $spc or fail f_
 914         "failed to mkdir the playground %s: %s", $spc, $!;
 915     return $spc;
 916 }
 917
 918 # ----- playtrees -----
 919
 920 sub playtree_setup (;$) {
 921     my ($t_local_git_cfg) = @_;
 922     $t_local_git_cfg //= $local_git_cfg;
 923     # for use in the playtree
 924     # $maindir must be set, eg by calling record_maindir or fresh_playground
 925     runcmd qw(git init -q);
 926     runcmd qw(git config gc.auto 0);
 927     foreach my $copy (qw(user.email user.name user.useConfigOnly
 928                          core.sharedRepository
 929                          core.compression core.looseCompression
 930                          core.bigFileThreshold core.fsyncObjectFiles)) {
 931         my $v = $t_local_git_cfg->{$copy};
 932         next unless $v;
 933         runcmd qw(git config), $copy, $_ foreach @$v;
 934     }
 935     # this is confusing: we have
 936     #   .                   playtree, not a worktree, has .git/, our cwd
 937     #   $maindir            might be a worktree so
 938     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 939     #   $maindir_gitcommon  the shared stuff, including .objects
 940     rmtree('.git/objects');
 941     symlink "$maindir_gitcommon/objects",'.git/objects' or confess $!;
 942     ensuredir '.git/info';
 943     open GA, "> .git/info/attributes" or confess $!;
 944     print GA "* $negate_harmful_gitattrs\n" or confess $!;
 945     close GA or confess $!;
 946 }
 947
 948 1;