Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10 use Config;
  11
  12 BEGIN {
  13     use Exporter   ();
  14     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  15
  16     $VERSION     = 1.00;
  17     @ISA         = qw(Exporter);
  18     @EXPORT      = qw(debiantag server_branch server_ref
  19                       stat_exists fail ensuredir waitstatusmsg failedcmd
  20                       cmdoutput cmdoutput_errok
  21                       git_rev_parse git_get_ref git_for_each_ref
  22                       git_for_each_tag_referring is_fast_fwd
  23                       $package_re $component_re $deliberately_re
  24                       $branchprefix
  25                       initdebug enabledebug enabledebuglevel
  26                       printdebug debugcmd
  27                       $debugprefix *debuglevel *DEBUG
  28                       shellquote printcmd messagequote);
  29     # implicitly uses $main::us
  30     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  31     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  32 }
  33
  34 our @EXPORT_OK;
  35
  36 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  37 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  38 our $deliberately_re = "(?:TEST-)?$package_re";
  39 our $branchprefix = 'dgit';
  40
  41 # policy hook exit status bits
  42 # see dgit-repos-server head comment for documentation
  43 # 1 is reserved in case something fails with `exit 1' and to spot
  44 # dynamic loader, runtime, etc., failures, which report 127 or 255
  45 sub NOFFCHECK () { return 0x2; }
  46 sub FRESHREPO () { return 0x4; }
  47
  48 our $debugprefix;
  49 our $debuglevel = 0;
  50
  51 sub initdebug ($) {
  52     ($debugprefix) = @_;
  53     open DEBUG, ">/dev/null" or die $!;
  54 }
  55
  56 sub enabledebug () {
  57     open DEBUG, ">&STDERR" or die $!;
  58     DEBUG->autoflush(1);
  59     $debuglevel ||= 1;
  60 }
  61
  62 sub enabledebuglevel ($) {
  63     my ($newlevel) = @_; # may be undef (eg from env var)
  64     die if $debuglevel;
  65     $newlevel //= 0;
  66     $newlevel += 0;
  67     return unless $newlevel;
  68     $debuglevel = $newlevel;
  69     enabledebug();
  70 }
  71
  72 sub printdebug {
  73     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  74 }
  75
  76 sub messagequote ($) {
  77     local ($_) = @_;
  78     s{\\}{\\\\}g;
  79     s{\n}{\\n}g;
  80     s{\x08}{\\b}g;
  81     s{\t}{\\t}g;
  82     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  83     $_;
  84 }
  85
  86 sub shellquote {
  87     my @out;
  88     local $_;
  89     foreach my $a (@_) {
  90         $_ = $a;
  91         if (!length || m{[^-=_./0-9a-z]}i) {
  92             s{['\\]}{'\\$&'}g;
  93             push @out, "'$_'";
  94         } else {
  95             push @out, $_;
  96         }
  97     }
  98     return join ' ', @out;
  99 }
 100
 101 sub printcmd {
 102     my $fh = shift @_;
 103     my $intro = shift @_;
 104     print $fh $intro," " or die $!;
 105     print $fh shellquote @_ or die $!;
 106     print $fh "\n" or die $!;
 107 }
 108
 109 sub debugcmd {
 110     my $extraprefix = shift @_;
 111     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 112 }
 113
 114 sub debiantag ($$) {
 115     my ($v,$distro) = @_;
 116     $v =~ y/~:/_%/;
 117     return "$distro/$v";
 118 }
 119
 120 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 121 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 122
 123 sub stat_exists ($) {
 124     my ($f) = @_;
 125     return 1 if stat $f;
 126     return 0 if $!==&ENOENT;
 127     die "stat $f: $!";
 128 }
 129
 130 sub _us () {
 131     $::us // ($0 =~ m#[^/]*$#, $&);
 132 }
 133
 134 sub fail {
 135     my $s = "@_\n";
 136     my $prefix = _us().": ";
 137     $s =~ s/^/$prefix/gm;
 138     die $s;
 139 }
 140
 141 sub ensuredir ($) {
 142     my ($dir) = @_; # does not create parents
 143     return if mkdir $dir;
 144     return if $! == EEXIST;
 145     die "mkdir $dir: $!";
 146 }
 147
 148 our @signames = split / /, $Config{sig_name};
 149
 150 sub waitstatusmsg () {
 151     if (!$?) {
 152         return "terminated, reporting successful completion";
 153     } elsif (!($? & 255)) {
 154         return "failed with error exit status ".WEXITSTATUS($?);
 155     } elsif (WIFSIGNALED($?)) {
 156         my $signum=WTERMSIG($?);
 157         return "died due to fatal signal ".
 158             ($signames[$signum] // "number $signum").
 159             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 160     } else {
 161         return "failed with unknown wait status ".$?;
 162     }
 163 }
 164
 165 sub failedcmd {
 166     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 167     if ($!) {
 168         fail "failed to fork/exec: $!";
 169     } elsif ($?) {
 170         fail "subprocess ".waitstatusmsg();
 171     } else {
 172         fail "subprocess produced invalid output";
 173     }
 174 }
 175
 176 sub cmdoutput_errok {
 177     die Dumper(\@_)." ?" if grep { !defined } @_;
 178     debugcmd "|",@_;
 179     open P, "-|", @_ or die $!;
 180     my $d;
 181     $!=0; $?=0;
 182     { local $/ = undef; $d = <P>; }
 183     die $! if P->error;
 184     if (!close P) { printdebug "=>!$?\n"; return undef; }
 185     chomp $d;
 186     if ($debuglevel > 0) {
 187         $d =~ m/^.*/;
 188         my $dd = $&;
 189         my $more = (length $' ? '...' : ''); #');
 190         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 191         printdebug "=> \`$dd'",$more,"\n";
 192     }
 193     return $d;
 194 }
 195
 196 sub cmdoutput {
 197     my $d = cmdoutput_errok @_;
 198     defined $d or failedcmd @_;
 199     return $d;
 200 }
 201
 202 sub git_rev_parse ($) {
 203     return cmdoutput qw(git rev-parse), "$_[0]~0";
 204 }
 205
 206 sub git_for_each_ref ($$;$) {
 207     my ($pattern,$func,$gitdir) = @_;
 208     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 209     # $reftail is RHS of ref after refs/[^/]+/
 210     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 211     my @cmd = (qw(git for-each-ref), $pattern);
 212     if (defined $gitdir) {
 213         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 214     }
 215     open GFER, "-|", @cmd or die $!;
 216     debugcmd "|", @cmd;
 217     while (<GFER>) {
 218         chomp or die "$_ ?";
 219         printdebug "|> ", $_, "\n";
 220         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 221         $func->($1,$2,$3,$4);
 222     }
 223     $!=0; $?=0; close GFER or die "$pattern $? $!";
 224 }
 225
 226 sub git_get_ref ($) {
 227     # => '' if no such ref
 228     my ($refname) = @_;
 229     local $_ = $refname;
 230     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 231     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 232 }
 233
 234 sub git_for_each_tag_referring ($$) {
 235     my ($objreferring, $func) = @_;
 236     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 237     printdebug "git_for_each_tag_referring ",
 238         ($objreferring // 'UNDEF'),"\n";
 239     git_for_each_ref('refs/tags', sub {
 240         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 241         return unless $objtype eq 'tag';
 242         my $refobjid = git_rev_parse $tagobjid;
 243         return unless
 244             !defined $objreferring # caller wants them all
 245             or $tagobjid eq $objreferring
 246             or $refobjid eq $objreferring;
 247         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 248     });
 249 }
 250
 251 sub is_fast_fwd ($$) {
 252     my ($ancestor,$child) = @_;
 253     my @cmd = (qw(git merge-base), $ancestor, $child);
 254     my $mb = cmdoutput_errok @cmd;
 255     if (defined $mb) {
 256         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 257     } else {
 258         $?==256 or failedcmd @cmd;
 259         return 0;
 260     }
 261 }
 262
 263 1;