update-xfonts-traditional

   1 #!/usr/bin/perl -w
   2 use strict;
   3 use POSIX;
   4 use IO::File;
   5 use Getopt::Long;
   6 use File::Glob qw(:glob);
   7 use Data::Dumper;
   8 use IO::Pipe;
   9
  10 our $prefix="/usr/local";
  11 our $package='xfonts-traditional';
  12 our $sharedir="$prefix/share/$package";
  13 our @fontparentdirs=qw(/usr/share/fonts/X11 /usr/local/share/fonts/X11);
  14 our $donefile="$package.done";
  15 our $logfile="$package.log";
  16 our $fontprefix="trad--";
  17 our @rulespath;
  18 our $mode;
  19 our %foundrymap;
  20 our $verbose=0;
  21 our $reportfh;
  22
  23 sub reportloaded {
  24     return unless $verbose;
  25     print $reportfh @_,"\n" or die $!;
  26 }
  27
  28 sub loadrules ($) {
  29     my ($key) = @_;
  30     our %cache;
  31     my $fc=$cache{$key};
  32     return $fc if $fc;
  33     foreach my $path (@rulespath) {
  34         my $script="$path/$key.rules";
  35         $!=0; $@=''; my $f = do $script;
  36         if (defined $f) {
  37             reportloaded("rules: loaded ",$script);
  38             $cache{$key}=$f;
  39             return $f;
  40         }
  41         die "$! $? $script" unless $! == &ENOENT;
  42     }
  43     return $cache{$key}=undef;
  44 }
  45
  46 sub processbdf ($$$$) {
  47     my ($inbdf,$outbdf,$logfile,$what) = @_;
  48     my $state='idle';
  49     my ($foundry,$font);
  50     my ($w,$h,$xo,$yo,$y,$bitmap,$glyph);
  51     my $modified=0;
  52     while (<$inbdf>) {
  53         if ($state eq 'bitmap' && $y==$h) {
  54             $glyph = uc $glyph;
  55             $glyph =~ s/\;$//;
  56             local ($_) = $glyph;
  57             my $key= sprintf "%s,%d,%d,%d,%d", $foundry,$w,$h,$xo,$yo;
  58             my $rules= loadrules($key);
  59             return (0,'no rules') if !$rules;
  60             $rules->();
  61             $modified += ($_ ne $glyph);
  62             print $outbdf $_,"\n" or die $!
  63                 foreach split /\;/, $_; # /;
  64             $state='idle';
  65         }
  66         if ($state eq 'bitmap') {
  67             m/^([0-9a-fA-F]+)\s+$/ or die $y;
  68             length($1) == (($w+7 >> 3) << 1) or die "$1 $w";
  69             $glyph .= "$1;";
  70             $y++;
  71             next;
  72         }
  73         if ($state eq 'idle' && m/^FOUNDRY\s+/) {
  74             die if defined $foundry;
  75             return (0,'foundry syntax') unless m/^FOUNDRY\s+\"(\w+)\"\s+/;
  76             $foundry = $foundrymap{lc $1};
  77             return (0,'no foundry') unless defined $foundry;
  78             $_ = "FOUNDRY \"$foundry\"\n";
  79         }
  80         if ($state eq 'idle' && m/^FONT\s+/) {
  81             die if defined $font;
  82             return (0,'simple font name') unless m/^(FONT\s+)\-(\w+)\-/;
  83             $font = $foundrymap{lc $2};
  84             return (0,'no foundry') unless defined $font;
  85             $_ = "FONT -$font-$'";
  86         }
  87         if ($state eq 'idle' && m/^STARTCHAR\s/) {
  88             die unless defined $foundry;
  89             die unless defined $font;
  90             return (0,'foundry != font') unless $foundry eq $font;
  91             $state='startchar';
  92             $w=undef;
  93         }
  94         if ($state eq 'startchar') {
  95             if (m/^BBX\s+(\+?\d+)\s+(\+?\d+)\s+([-+]?\d+)\s+([-+]?\d+)\s+$/) {
  96                 ($w,$h,$xo,$yo) = ($1,$2,$3,$4);
  97             }
  98             if (m/^BITMAP\s+$/) {
  99                 die unless defined $w;
 100                 $y=0;
 101                 $glyph='';
 102                 $state='bitmap';
 103             }
 104         }
 105         print $outbdf $_ or die $!;
 106     }
 107     die $! if $inbdf->error;
 108     die $! if $outbdf->error or !$outbdf->flush;
 109     die unless $state eq 'idle';
 110     if ($modified) {
 111         printf $logfile "%s: %d glyphs changed\n", $what, $modified
 112             or die $!;
 113     } else {
 114         printf $logfile "%s: unchanged - no rules matched\n", $what
 115             or die $!;
 116     }
 117     return $modified;
 118 }
 119
 120 our (@options)=(
 121     'R|rules-include=s@' => \@rulespath,
 122     'share-dir=s' => \$sharedir,
 123     'verbose|v+' => \$verbose,
 124     );
 125
 126 sub define_mode ($$) {
 127     my ($optname,$f) = @_;
 128     push @options, $optname, sub {
 129         die "only one mode may be specified\n" if defined $mode;
 130         $mode=$f;
 131     };
 132 }
 133
 134 sub loadfoundries () {
 135     foreach my $path (@rulespath) {
 136         my $p = "$path/foundries";
 137         my $f = new IO::File $p;
 138         if (!$f) {
 139             die "$p $!" unless $!==&ENOENT;
 140             print $reportfh "foundries: none in $p\n" or die $! if $verbose;
 141             next;
 142         }
 143         while (<$f>) {
 144             s/^\s*//; s/\s+$//;
 145             next if m/^\#/;
 146             m/^(\w+)\s+(\w+)$/ or die;
 147             my $k = lc $1;
 148             next if exists $foundrymap{$k};
 149             $foundrymap{$k}=$2;
 150         }
 151         $f->error and die $!;
 152         reportloaded('foundries: loaded ',$p);
 153     }
 154     die "no foundry maps\n" unless %foundrymap;
 155 }
 156
 157 sub processpcfgz ($$$$) {
 158     my ($inpcfgz,$outpcfgz,$logfile,$what) = @_;
 159
 160     my $current = new IO::File $inpcfgz, '<' or die "$inpcfgz $!";
 161     my ($usread,$uswrite);
 162     my ($reader,$writer);
 163     my @children;
 164     foreach my $proc (['zcat'], ['pcf2bdf'], [],
 165                       ['bdftopcf'],['',qw(gzip -1)]) {
 166         my $isfinal = (@$proc && $proc->[0] eq '');
 167         if (!$isfinal) {
 168             $reader = new IO::Handle or die $!;
 169             $writer = new IO::Handle or die $!;
 170             new IO::Pipe($reader,$writer) or die $!;
 171         } else {
 172             shift @$proc;
 173             $reader = undef;
 174             $writer = new IO::File $outpcfgz, '>' or die "$outpcfgz $!";
 175         }
 176         if (@$proc) {
 177             my $exe = $proc->[0];
 178             my $child = fork;  defined $child or die $!;
 179             if (!$child) {
 180                 open STDIN, '<&', $current or die $!;
 181                 open STDOUT, '>&', $writer or die $!;
 182                 if (!$isfinal) {
 183                     close $reader or die $!;
 184                 }
 185                 close $usread or die $! if $usread;
 186                 close $uswrite or die $! if $uswrite;
 187                 exec $exe @$proc or die "$exe $!";
 188             }
 189             push @children, [ $child, $exe, defined $usread ];
 190             close $current or die $!;
 191             close $writer or die $!;
 192             $current = $reader;
 193         } else {
 194             $usread = $current;
 195             $uswrite = $writer;
 196             $current = $reader;
 197         }
 198     }
 199     my $r = processbdf($usread,$uswrite,$logfile,$what);
 200     my $none = $r !~ m/^\d/;
 201     if ($none) {
 202         flush $uswrite or die $!;
 203     } else {
 204         close $uswrite or die $!;
 205     }
 206     close $usread or die $!;
 207     foreach my $chinfo (@children) {
 208         my ($child,$exe,$isoutput)=@$chinfo;
 209         my $sigok = 0;
 210         if ($none) {
 211             if ($isoutput) {
 212                 $sigok = 9;
 213                 kill 9, $child or die "$child $!";
 214             } else {
 215                 $sigok = 13;
 216             }
 217         }
 218         $!=0; waitpid($child, 0) == $child or die "$child $!";
 219         !$? or ($?&~128)==$sigok or die "$exe [$child] $sigok $?";
 220     }
 221     return $r;
 222 }
 223
 224 sub processfontdir ($) {
 225     my ($fontdir) = @_;
 226     if (!opendir FD, $fontdir) {
 227         die "$fontdir $!" unless $!==&ENOENT;
 228         return;
 229     }
 230     my $olddone = do "$fontdir/$donefile";
 231     if (!$olddone) {
 232         die "$fontdir $! $@ " unless $!==&ENOENT;
 233         $olddone = { };
 234     }
 235     my $newdone = { };
 236     my $log = new IO::File "$fontdir/$logfile", "w"
 237         or die "$fontdir/$logfile $!";
 238     my %outfiles; # bitmask: 1 /*exists*/ | 2 /*wanted*/
 239     my $changed;
 240     my $updated=0;
 241
 242     print $reportfh "processing $fontdir...\n" or die $!;
 243     flush $reportfh or die $!;
 244     while (my $dent = scalar readdir FD) {
 245         if ($dent =~ m/^\Q$fontprefix\E.*\.new$/) {
 246             unlink "$fontdir/$dent" or $!==&ENOENT or die "$fontdir $dent $!";
 247             next;
 248         }
 249         next unless $dent =~ m/^[^.\/].*\.pcf\.gz$/;
 250         if ($dent =~ m/^\Q$fontprefix/) {
 251             $outfiles{$dent} |= 1;
 252             next;
 253         }
 254         if (!stat "$fontdir/$dent") {
 255             die "$fontdir $dent $!" unless $!==&ENOENT;
 256             next;
 257         }
 258         die "$fontdir $dent" unless -f _;
 259         my $stats = join ' ', ((stat _)[1,7,9,10]);
 260         my $tdone = $olddone->{$dent};
 261         my $outdent = $fontprefix.$dent;
 262         if (defined $tdone && $tdone eq $stats) {
 263             $outfiles{$outdent} |= 2;
 264             $newdone->{$dent} = $stats;
 265             next;
 266         }
 267
 268         my $r = processpcfgz("$fontdir/$dent",
 269                              "$fontdir/$outdent.new",
 270                              $log, $dent);
 271         if ($r !~ m/^\d/) {
 272             printf $log "%s: unchanged - %s\n", $dent, $r;
 273             unlink "$fontdir/$outdent.new" or die "$fontdir $outdent $!";
 274         } else {
 275             rename "$fontdir/$outdent.new", "$fontdir/$outdent"
 276                 or die "$fontdir $outdent $!";
 277             $updated++;
 278             $outfiles{$outdent} |= 3;
 279             $changed = 1;
 280         }
 281         $newdone->{$dent} = $stats;
 282     }
 283     my $affected=0;
 284     foreach my $olddent (keys %outfiles) {
 285         my $state = $outfiles{$olddent};
 286         if ($state & 2) {
 287             $affected++ if $state & 1;
 288             next;
 289         }
 290         unlink "$fontdir/$olddent" or die "$fontdir $olddent $!";
 291         $changed = 1;
 292     }
 293     if (!%$newdone) {
 294         unlink "$fontdir/$logfile" or die "$fontdir $!";
 295         unlink "$fontdir/$donefile" or $!==&ENOENT or die "$fontdir $!";
 296     } elsif ($changed) {
 297         $!=0; $?=0; system 'mkfontdir',$fontdir;
 298         die "$fontdir $? $!" if $? or $!;
 299         my $newdoneh = new IO::File "$fontdir/$donefile.new", 'w'
 300             or die "$fontdir $!";
 301         print $newdoneh Dumper($newdone) or die "$fontdir $!";
 302         close $newdoneh or die "$fontdir $!";
 303         rename "$fontdir/$donefile.new","$fontdir/$donefile"
 304             or die "$fontdir $!";
 305     }
 306     printf " processed %s: %d pcfs, %d affected, %d updated.\n",
 307         $fontdir, (scalar keys %$newdone), $affected, $updated;
 308 }
 309
 310 our $stdin = new IO::File '<&STDIN' or die $!;
 311 our $stdout = new IO::File '>&STDOUT' or die $!;
 312 our $stderr = new IO::File '>&STDERR' or die $!;
 313 $reportfh = $stdout;
 314
 315 define_mode('bdf-filter', sub {
 316     die "no arguments allowed with --bdf-filter\n" if @ARGV;
 317     $reportfh = $stderr;
 318     loadfoundries();
 319     my $r = processbdf($stdin,$stdout,$reportfh,'stdin');
 320     if ($r !~ m/^\d/) {
 321         print STDERR "stdin not processed: $r\n";
 322         exit 2;
 323     }
 324 });
 325
 326 define_mode('process-pcf', sub {
 327     die "need source and destination pcf.gz\n" if @ARGV!=2;
 328     loadfoundries();
 329     my $r = processpcfgz($ARGV[0],$ARGV[1],$reportfh,"pcf");
 330     if ($r !~ m/^\d/) {
 331         print STDERR "pcf not processed: $r\n";
 332         exit 2;
 333     }
 334 });
 335
 336 define_mode('process-fontdir', sub {
 337     die "need font dir(s)\n" unless @ARGV;
 338     loadfoundries();
 339     foreach my $d (@ARGV) {
 340         processfontdir($d);
 341     }
 342 });
 343
 344 Getopt::Long::Configure(qw(bundling));
 345 GetOptions(@options) or exit 127;
 346
 347 push @rulespath, "$sharedir/rules";
 348
 349 die "need a mode\n" unless $mode;
 350
 351 $mode->();
 352
 353 #   70  zcat /usr/share/fonts/X11/misc/6x13.pcf.gz |pcf2bdf >in.bdf
 354 #   71  ./utility <in.bdf >out.bdf
 355 #   83  bdftopcf out.bdf >out.pcf
 356 #   84  gzip out.pcf
 357 #   85  cp out.pcf.gz /usr/share/fonts/X11/misc/
 358 # really mkfontdir /usr/share/fonts/X11/misc/
 359 # xset fp rehash
 360 # xfontsel