chiark / gitweb /
Do not ignore errors from readdir.
[userv.git] / configure.in
1 #  userv - configure.in
2 #
3 #  Copyright (C)1996-1997,1999-2000,2003 Ian Jackson
4 #   
5 #  This is free software; you can redistribute it and/or modify it
6 #  under the terms of the GNU General Public License as published by
7 #  the Free Software Foundation; either version 2 of the License, or
8 #  (at your option) any later version.
9
10 #  This program is distributed in the hope that it will be useful, but
11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13 #  General Public License for more details.
14
15 #  You should have received a copy of the GNU General Public License
16 #  along with userv; if not, write to the Free Software
17 #  Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
18
19 AC_INIT(language.i4)
20 AC_CONFIG_HEADER(config.h)
21
22 AC_PREFIX_DEFAULT(/usr/local)
23
24 crdir="`pwd`"
25 AC_SUBST(DEBUGDEFS)
26 AC_SUBST(DEBUGLIBS)
27 DEBUGDEFS=''
28 DEBUGLIBS=''
29 AC_ARG_ENABLE(debug,
30 [  --enable-debug          build debugging version],
31 [
32  if test "x$enable_debug" = xyes; then
33   DEBUGDEFS="-DDEBUG -DVARDIR='\"$crdir/vd\"' -DSYSTEMCONFIGDIR='\"$crdir/slash-etc\"' -DSERVICEUSERDIR='\"$crdir/tilde\"'"
34   DEBUGLIBS=-lefence
35   echo will build debugging version
36  elif test "x$enable_debug" != xno; then
37   AC_MSG_ERROR(--enable-debug does not allow any arguments except 'yes' and 'no')
38  fi
39 ])
40
41 AC_PROG_CC
42 AC_PROG_CPP
43 AC_PROG_INSTALL
44 AC_CHECK_PROGS(MD5SUM_SIMPLE, md5sum md5 gmd5sum)
45
46 CFLAGS="$CFLAGS -D_GNU_SOURCE"
47
48 AC_CHECK_LIB(socket,socket)
49 AC_CHECK_FUNCS(setenv strsignal vsnprintf)
50
51 AC_CACHE_CHECK(for EPROTO,userv_cv_hdr_eproto,
52  AC_EGREP_CPP(yes,
53 [
54 #include <errno.h>
55 #ifdef EPROTO
56  yes
57 #endif
58 ],userv_cv_hdr_eproto=yes,userv_cv_hdr_eproto=no))
59 if test $userv_cv_hdr_eproto = yes
60 then
61         AC_DEFINE(HAVE_EPROTO)
62 fi
63
64 AC_CACHE_CHECK(for LOG_AUTHPRIV,userv_cv_hdr_logauthpriv,
65  AC_EGREP_CPP(yes,
66 [
67 #include <syslog.h>
68 #ifdef LOG_AUTHPRIV
69  yes
70 #endif
71 ],userv_cv_hdr_logauthpriv=yes,userv_cv_hdr_logauthpriv=no))
72 if test $userv_cv_hdr_logauthpriv = yes
73 then
74         AC_DEFINE(HAVE_LOG_AUTHPRIV)
75 fi
76
77 AC_CACHE_CHECK(for WCOREDUMP,userv_cv_hdr_wcoredump,
78  AC_EGREP_CPP(yes,
79 [
80 #include <sys/types.h>
81 #include <sys/wait.h>
82 #ifdef WCOREDUMP
83  yes
84 #endif
85 ],userv_cv_hdr_wcoredump=yes,userv_cv_hdr_wcoredump=no))
86 if test $userv_cv_hdr_wcoredump = yes
87 then
88         AC_DEFINE(HAVE_WCOREDUMP)
89 fi
90
91 AC_SUBST(OPTIMISE)
92 if test "${GCC-no}" = yes; then
93  OPTIMISE=-O2
94 else
95  OPTIMISE=-O
96 fi
97
98 dnl DPKG_CACHED_TRY_COMPILE(<description>,<cachevar>,<include>,<program>,<ifyes>,<ifno>)
99 define(DPKG_CACHED_TRY_COMPILE,[
100  AC_MSG_CHECKING($1)
101  AC_CACHE_VAL($2,[
102   AC_TRY_COMPILE([$3],[$4],[$2=yes],[$2=no])
103  ])
104  if test "x$$2" = xyes; then
105   true
106   $5
107  else
108   true
109   $6
110  fi
111 ])
112
113 DPKG_CACHED_TRY_COMPILE(your C compiler,dpkg_cv_c_works,
114  [#include <string.h>], [strcmp("a","b")],
115  AC_MSG_RESULT(works),
116  AC_MSG_RESULT(broken)
117  AC_MSG_ERROR(C compiler is broken))
118
119 DPKG_CACHED_TRY_COMPILE(__attribute__((,,)),dpkg_cv_c_attribute_supported,,
120  [extern int testfunction(int x) __attribute__((,,))],
121  AC_MSG_RESULT(yes)
122  AC_DEFINE(HAVE_GNUC25_ATTRIB)
123   DPKG_CACHED_TRY_COMPILE(__attribute__((noreturn)),dpkg_cv_c_attribute_noreturn,,
124    [extern int testfunction(int x) __attribute__((noreturn))],
125    AC_MSG_RESULT(yes)
126    AC_DEFINE(HAVE_GNUC25_NORETURN),
127    AC_MSG_RESULT(no))
128   DPKG_CACHED_TRY_COMPILE(__attribute__((unused)),dpkg_cv_c_attribute_unused,,
129    [extern int testfunction(int x) __attribute__((unused))],
130    AC_MSG_RESULT(yes)
131    AC_DEFINE(HAVE_GNUC25_UNUSED),
132    AC_MSG_RESULT(no))
133   DPKG_CACHED_TRY_COMPILE(__attribute__((format...)),dpkg_cv_attribute_format,,
134    [extern int testfunction(char *y, ...) __attribute__((format(printf,1,2)))],
135    AC_MSG_RESULT(yes)
136    AC_DEFINE(HAVE_GNUC25_PRINTFFORMAT),
137    AC_MSG_RESULT(no)),
138  AC_MSG_RESULT(no))
139
140 AC_SUBST(CWARNS)
141 CWARNS=""
142
143 dnl DPKG_C_GCC_TRY_WARNS(<warnings>,<cachevar>)
144 define(DPKG_C_GCC_TRY_WARNS,[
145  AC_MSG_CHECKING([GCC warning flag(s) $1])
146  if test "${GCC-no}" = yes
147  then
148   AC_CACHE_VAL($2,[
149    oldcflags="${CFLAGS-}"
150    CFLAGS="${CFLAGS-} ${CWARNS} $1 -Werror"
151    AC_TRY_COMPILE([
152 #include <string.h>
153 #include <stdio.h>
154 ],[
155     strcmp("a","b"); fprintf(stdout,"test ok\n");
156 ], [$2=yes], [$2=no])
157    CFLAGS="${oldcflags}"])
158   if test "x$$2" = xyes; then
159    CWARNS="${CWARNS} $1"
160    AC_MSG_RESULT(ok)
161   else
162    $2=''
163    AC_MSG_RESULT(no)
164   fi
165  else
166   AC_MSG_RESULT(no, not using GCC)
167  fi
168 ])
169
170 DPKG_C_GCC_TRY_WARNS(-Wall -Wno-implicit, dpkg_cv_c_gcc_warn_all)
171 DPKG_C_GCC_TRY_WARNS(-Wwrite-strings, dpkg_cv_c_gcc_warn_writestrings)
172 DPKG_C_GCC_TRY_WARNS(-Wpointer-arith, dpkg_cv_c_gcc_warn_pointerarith)
173 DPKG_C_GCC_TRY_WARNS(-Wimplicit -Wnested-externs, dpkg_cv_c_gcc_warn_implicit)
174
175 if test "${GCC-no}" = yes; then
176  CWARNS="${CWARNS} -Wmissing-prototypes -Wstrict-prototypes"
177 fi
178 [CFLAGS="`echo $CFLAGS $CWARNS | sed -e 's/-O[0-9]*/$(OPTIMISE)/'`"]
179
180 AC_SUBST(VERSION)
181 VERSION="`sed -n '/^userv (.*)/!d; s/^userv (//; s/).*//; p; q' debian/changelog`"
182 echo will build version $VERSION
183
184 AC_OUTPUT(Makefile)