git-daemon/git-daemon

   1 #!/usr/bin/perl
   2 #
   3 # A git daemon with an added userv security boundary.
   4 #
   5 # This was written by Tony Finch <dot@dotat.at>
   6 # You may do anything with it, at your own risk.
   7 # http://creativecommons.org/publicdomain/zero/1.0/
   8
   9 use strict;
  10 use warnings;
  11
  12 use POSIX;
  13 use Socket;
  14 use Sys::Syslog;
  15
  16 sub ntoa {
  17     my $sockaddr = shift;
  18     return ('(local)') unless defined $sockaddr;
  19     my ($port,$addr) = sockaddr_in $sockaddr;
  20     $addr = inet_ntoa $addr;
  21     return ("[$addr]:$port",$addr,$port);
  22 }
  23 our ($client,$client_addr,$client_port) = ntoa getpeername STDIN;
  24 our ($server,$server_addr,$server_port) = ntoa getsockname STDIN;
  25 our ($service,$path,$host,$user);
  26
  27 openlog 'userv-git-daemon', 'pid', 'daemon';
  28 sub fail { syslog 'err', "$client @_"; exit }
  29
  30 $SIG{ALRM} = sub { fail "timeout" };
  31 alarm 30;
  32
  33 sub xread {
  34     my $length = shift;
  35     my $buffer = "";
  36     while ($length > length $buffer) {
  37         my $ret = sysread STDIN, $buffer, $length, length $buffer;
  38         fail "Expected $length bytes, got ".length $buffer
  39                             if defined $ret and $ret == 0;
  40         fail "read: $!" if not defined $ret and $! != EINTR and $! != EAGAIN;
  41     }
  42     return $buffer;
  43 }
  44 my $hex_len = xread 4;
  45 fail "Bad hex in packet length" unless $hex_len =~ m|^[0-9a-fA-F]{4}$|;
  46 my $line = xread -4 + hex $hex_len;
  47 unless (($service,$path,$host) = $line =~
  48         m|^(git-[a-z-]+) /*([!-~]+)\0host=([!-~]+)\0$|) {
  49     $line =~ s|[^ -~]+| |g;
  50     fail "Could not parse \"$line\""
  51 }
  52 our $uri = $_ = "git://$host/$path";
  53 for my $cf (@ARGV) { do $cf }
  54
  55 fail "No user for $uri" unless defined $user;
  56 syslog 'notice', "$client $service $uri";
  57
  58 my @opts = map "-D$_=${$::{$_}}",
  59         grep defined ${$::{$_}} && /^[a-z_]+$/, keys %::;
  60
  61 my @cmd = ('userv', @opts, $user, $service);
  62 no warnings; # suppress errors to stderr
  63 exec @cmd or fail "exec userv: $!";
  64
  65 # end