git-daemon/git-daemon.pl

   1 #!/usr/bin/perl
   2 #
   3 # A git daemon with an added userv security boundary.
   4 #
   5 # This was written by Tony Finch <dot@dotat.at>
   6 # You may do anything with it, at your own risk.
   7 # http://creativecommons.org/publicdomain/zero/1.0/
   8
   9 use strict;
  10 use warnings;
  11
  12 use POSIX;
  13 use Socket;
  14 use Sys::Syslog;
  15
  16 sub ntoa {
  17     my $sockaddr = shift;
  18     return ('[?.?.?.?]:?') unless defined $sockaddr;
  19     my ($port,$addr) = sockaddr_in $sockaddr;
  20     $addr = inet_ntoa $addr;
  21     return ("[$addr]:$port",$addr,$port);
  22 }
  23 our ($client,$client_addr,$client_port) = ::ntoa(getpeername(STDIN));
  24 our ($server,$server_addr,$server_port) = ::ntoa(getsockname(STDIN));
  25 our ($service,$path,$host,$uri,$user);
  26
  27 openlog 'userv-git-daemon', 'pid', 'daemon';
  28 sub fail { syslog 'err', "$client @_"; exit }
  29
  30 sub xread {
  31     my $length = shift;
  32     my $buffer = "";
  33     local $SIG{ALRM} = sub { fail "timeout" };
  34     alarm 30;
  35     while ($length > length $buffer) {
  36         my $ret = sysread STDIN, $buffer, $length, length $buffer;
  37         fail "short read: expected $length bytes, got " . length $buffer
  38                             if defined $ret and $ret == 0;
  39         fail "read: $!" if not defined $ret and $! != EINTR and $! != EAGAIN;
  40     }
  41     alarm 0;
  42     return $buffer;
  43 }
  44
  45 my $len_hex = xread 4;
  46 fail "non-hex packet length" unless $len_hex =~ m{^[0-9a-fA-F]{4}$};
  47 my $line = xread hex $len_hex;
  48 if ($line !~ m{^(git-[a-z-]+) /*([!-~]+)\0host=([!-~]+)\0$}) {
  49     $line =~ s|[^ -~]+| |g;
  50     fail "could not parse \"$line\""
  51 }
  52 ($service,$path,$host) = ($1,$2,$3);
  53 $_ = $uri = "git://$host/$path";
  54 for my $cf (@ARGV) { do $cf }
  55
  56 fail "no user configured for $uri" unless defined $user;
  57 syslog 'info', "$client $service $uri";
  58
  59 my @opts = map "-D$_=${$main::{$_}}",
  60         grep defined ${$main::{$_}} && /^[a-z]+$/,
  61              sort keys %main::;
  62
  63 my @cmd = ('userv', @opts, $user, $service);
  64 no warnings; # suppress errors to stderr
  65 exec @cmd or fail "exec @cmd: $!";
  66
  67 # end