#!/usr/bin/perl
# usage: tb-create <patch-spec>

use warnings;
use strict;

use Getopt::Long;
use Topbloke;

Getopt::Long::Configure(qw(bundling));

die "bad usage\n" unless @ARGV==1;

our $spec = parse_patch_spec($ARGV[0]);
our $current = current_branch();

die "cannot make patch starting at base of another;".
    " check out a real branch or patch\n" if $current->{Kind} eq 'base';

die "strange branch ref $current->{Kind} $current->{Ref},\n".
    " making new patch with this as dep is unwise\n"
    unless ($current->{Kind} eq 'foreign' ||
	    $current->{Kind} eq 'tip');

sub fillin ($$$) {
    my ($key, $newval, $what) = @_;
    return if defined $spec->{$key};
    $spec->{$key} = $newval;
}

if (!defined $spec->{Email} || !defined $spec->{Domain}) {
    my $eaddr = run_git_1line(qw(config user.email));
    $eaddr =~ m/^(.*)\@/ or die "$eaddr ?";
    fillin('Email',$1,'email domain');
    fillin('Domain',$','email domain'); #');
}

if (!defined $spec->{Date}) {
    $spec->{Date} = `LC_TIME=C date -u +%Y-%m-%dT%H%M%SZ`;
    chomp $spec->{Date} or die $!;
}

defined $spec->{Nick} or die "no patch nickname specified\n";

length($spec->{Date})==18 or die "partial date specified, not supported\n";

chdir_toplevel();

check_no_unwanted_metadata('HEAD')
    if $current->{Kind} ne 'tip';

run_git_check_nooutput("cannot create new patch with staged file(s)",
		       qw(diff --cached --name-only HEAD --));

run_git_check_nooutput("cannot create new patch with".
		       " modified metadata file(s)",
		       qw(diff --name-only HEAD -- .topbloke));

# For the metadata files in .topbloke, we hope that the user
# doesn't modify them.  If they do then they get to keep all the pieces.
#
# For .topbloke/msg, if it's modified by the user (ie, if working
# version differs from HEAD) we keep that and stage it.

my $newpatch = "$spec->{Email}\@$spec->{Domain}/$spec->{Date}/$spec->{Nick}";

$newpatch = run_git_1line(qw(check-ref-format --print), $newpatch);

my $author = run_git_1line(qw(var GIT_AUTHOR_IDENT));
$author =~ s/ \d+ [-+]\d+$// or die $!;

my $subjprefix = git_config('topbloke.subjectprefix', '');

printf "creating %s\n", $newpatch;

setup_config();

#----- subroutines for setup

sub create_and_switch ($) {
    my ($branchref) = @_;
    run_git(qw(update-ref -m), "tb-create base", $branchref, 'HEAD');
    run_git(qw(symbolic-ref HEAD), $branchref);
}

sub stage_meta ($) {
    my ($file) = @_;
    run_git(qw(add), ".topbloke/$file");
}

sub meta_and_stage ($$) {
    my ($file, $contents) = @_;
    wf_contents(".topbloke/$file", $contents);
    stage_meta($file);
}

#----- create the base branch

if (lstat '.topbloke') {
    -d _ or die;
} else {
    mkdir('.topbloke') or die "create .topbloke: $!\n";
}

my $baseref = "refs/topbloke-bases/$newpatch";
create_and_switch($baseref);

run_git(qw(update-ref -m), "tb-create base $newpatch", $baseref, 'HEAD');
run_git(qw(symbolic-ref HEAD), $baseref);

meta_and_stage('msg', "# not applicable\n");
meta_and_stage('deps', "# not applicable\n");
meta_and_stage('flags', '');

if ($current->{Kind} eq 'foreign') {
    meta_and_stage('included', $current->{DepSpec}."\n");
    meta_and_stage('pflags', '');
}

run_git(qw(commit -q -m), "tb-create base $newpatch");

#----- create the tip branch

my $tipref = "refs/topbloke-tips/$newpatch";
create_and_switch($tipref);

my $nm = wf_start('.topbloke/msg');
wf($nm, "From: $author\n");
foreach my $h (qw(To CC BCC)) {
    my $estatus;
    run_git(\$estatus, sub { wf($nm, "$h: $_") or die $!; },
	    qw(config), "topbloke.".lc $h);
    die "$h $estatus" unless $estatus==0 || $estatus==256;
}
wf($nm, <<END) or die $!;
Subject: [${subjprefix}PATCH] $spec->{Nick}

<patch description>

Signed-off-by: $author
END
wf_done($nm);
stage_meta('msg');

meta_and_stage('deps', "$current->{DepSpec}\n");
# we inherit empty flags from the base branch

flagsfile_add_flag('included',$newpatch);
stage_meta('included');

run_git(qw(commit -q -m), "tb-create tip $spec->{Nick}\n$newpatch\n");
