#!/usr/bin/perl -w

use strict;
use Carp;
use Data::Dumper;
use Math::GSL::Vector qw/:all/;
use Math::GSL::Matrix qw/:all/;
use Math::GSL::Const;
use Math::GSL::BLAS qw/:all/;
use Math::GSL::CBLAS qw/:all/;
use Math::GSL::Machine qw/:all/;

use POSIX qw(M_PI);

BEGIN { unshift @INC, qw(.); }

use Parse;

our $xopts;
our $facesf;
our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector

sub TAU { M_PI * 2.0; }
sub MM2PT { 72.0 / 25.4; }

our $mid;

# ----- region names from plag, incl. reverse mapping -----

our %prs2region;

sub prep_region_rmap () {
  foreach my $rn (keys %region) {
    my $prs = plag_prs($rn);
    die if $prs2region{$prs};
    $prs2region{$prs} = $rn;
  }
}

our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name

sub prs2r ($) {
  # bodgery for the sea and land
  return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  $prs2region{$_[0]} // confess "@_ ?"
}
sub prs2rr ($) { $region{prs2r($_[0])} }

#----- file reader for plag output -----

sub read_faces () {
  # Sets
  #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  #  $region{NAME}{Polygon}{Pos}
  #  $region{NAME}{Special}
  #
  # also incidentally
  #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  #  $region{NAME}{Polygon}{Adjoins}
  # which should be ignored

  open P, "<", $facesf or die $!;
  while (<P>) { last if m/^\&faces$/; }
  my $rr;
  my @edges;
  my $process_rr = sub {
    my $last_ai;
    if ($rr->{Name} eq 'NZ') {
      # We combined L and NZ; now we must split them again
      # in fact, we just throw away L and L2 entirely.
      # Here, when processing NZ, we keep only vertices that
      # are part of NZ.
      @edges = grep {
	my $evxname = $_->{VxName};
	my @eregions = split / \| ?/, $evxname;
	grep { $_ eq 'NZ' } @eregions
      } @edges;
    }
    $rr->{Polygon} = [ @edges ];
    if ($rr->{Name} ne 'NZ') {
      for my $ei (0..$#edges) {
	if (!defined $last_ai) {
	  my $ai;
	  for my $ai (0..$#{ $rr->{Adj} }) {
	    next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
	    $last_ai = $ai+1;
	  }
	  confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
	}
	my $ai = ($last_ai-1+@edges) % @edges;
	$last_ai = $ai;
	my $adj = $rr->{Adj}[$ai];
	confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
		       $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
	    unless $adj->{Name} eq $edges[$ei]{Adjoins};
      
	for my $endi (0..1) {
	  $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
	}
      }
    }
    @edges = ();
    $rr = undef;
  };
  my $vxname;
  for (;;) {
    $!=0; $_=<P> // confess $!;
    last if m/^\&$/;
    if (m/^$sre$/) {
      my $new_face= $2;
      $process_rr->() if $rr;
      $rr= prs2rr($new_face);
    } elsif (m/^\s+$sre$/) {
      confess unless $rr;
      $vxname = $2;
      push @edges, { VxName => $vxname };
    } elsif (m/^\s+\^adjoins\s+$sre$/) {
      $edges[-1]{Adjoins} = prs2r($2);
    } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
      my $pos = mkvec($1,$2);
      confess unless defined $vxname;
      $edges[-1]{Pos} = $pos;
      $vxname2pos{$vxname} = $pos;
    }
  }
  $process_rr->();

  $region{$_}{Special} = 1 foreach qw(NZ L L2);
}

#----- geometry mangling -----

sub adj_ends ($) {
  my ($adj) = @_;
  map { $_->{Pos} } @{ $adj->{Ends} };
}

sub calculate_centres () {
  # Sets
  #  $region{NAME}{Centre}
  foreach my $rr (values %region) {
    next if $rr->{Special};
    my $sum = Math::GSL::Vector->new(2);
    my $wsum = 0;
    foreach my $adj (@{ $rr->{Adj} }) {
      my @ends = adj_ends($adj);
      my $w = ($ends[1] - $ends[0])->norm();
      $sum += $w * $_ foreach @ends;
      $wsum += $w;
    }
    $rr->{Centre} = $sum * (0.5 / $wsum);
  }
}

sub for_each_pos ($) {
  my ($f) = @_;
  my $call = sub {
    my ($pr,$rr,$why) = @_;
    return unless defined $$pr;
    $f->($pr,$rr,$why);
  };
  foreach my $rr (values %region) {
    $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
    foreach my $vertex (@{ $rr->{Polygon} }) {
      $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
    }
  }
}

sub prvec ($) {
  my ($v) = @_;
  confess unless $v;
  sprintf "%g,%g", $v->get(0), $v->get(1);
}

sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }

sub transform_coordinates () {
  # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
  # until it's all in PostScript points
  my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
  my $dir = $or[1] - $or[0];
  my $theta = vec2atan($dir);
  my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
  my $s = sin($rotateby);
  my $c = cos($rotateby);
  my $transform = Math::GSL::Matrix->new(2,2);
  $transform->set_row(0, [  $c, -$s ]);
  $transform->set_row(1, [  $s,  $c ]);
  print STDERR "rotate was=",prvec($dir)," theta=$theta",
      " rotateby=$rotateby s=$s c=$c\n";
  my @lims;
  foreach my $topend (qw(0 1)) {
    my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
    $lims[$topend] = mkvec($v,$v);
  }
  for_each_pos(sub {
    my ($pr, $rr, $why) = @_;
    my $y = Math::GSL::Vector->new(2);
    gsl_blas_dgemv($CblasNoTrans,
		   1.0, $transform->raw,
		   $$pr->raw,
		   0, $y->raw)
	and confess;
    #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
    gsl_blas_dcopy($y->raw, $$pr->raw)
	and confess;
    foreach my $topend (qw(0 1)) {
      foreach my $xy (qw(0 1)) {
	my $now = $y->get($xy);
	my $lim = $lims[$topend]->get($xy);
	#print STDERR "?set $topend $xy $now $lim\n";
	next if $topend ? ($now <= $lim) : ($now >= $lim);
	$lims[$topend]->set([$xy], [$now]);
	#print STDERR "set $topend $xy $now\n";
      }
    }
  });
  print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
  my $translate = -$lims[0];
  print STDERR "translate ",prvec($translate),"\n";
  my $scale = $c{GraphScale} * MM2PT;
  for_each_pos(sub {
    my ($pr) = @_;
    gsl_vector_add($$pr->raw, $translate->raw) and confess;
    gsl_vector_scale($$pr->raw, $scale) and confess;
  });
  $mid = ($lims[1] - $lims[0]) * 0.5;
}

sub adjust_nz() {
  my $poly = $region{NZ}{Polygon};
  my %occurs;
  foreach my $v (@$poly) {
    $occurs{$v->{VxName}}++
  }
  foreach my $v (@$poly) {
    $v->{NZ_Occurs} = $occurs{$v->{VxName}};
  }
  print STDERR " nz ".(scalar @$poly)."\n";
  my $occurs_m = sub {
    my ($ei) = @_;
    $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
  };
  for my $ei (0..$#$poly) {
    next if $occurs_m->($ei);
    next unless $occurs_m->($ei-1);
    next unless $occurs_m->($ei+1);
    print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
    # adjust coord outwards
  }
  for my $ei (0..$#$poly) {
    next unless $occurs_m->($ei);
    print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
    next unless $occurs_m->($ei-1);
    my $dleft = mkvec(-1000,0);
    foreach my $which (0,-1) {
      my $ej = ($ei +        $which + @$poly) % @$poly;
      my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
      my $posj = \ $poly->[$ej]{Pos};
      my $posk = \ $poly->[$ek]{Pos};
      my $dout = $$posk - $$posj;
      print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
      print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
      if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
	print STDERR " nz adj extra\n";
	$$posk = $$posj + 10 * mkvec(100,-50);
      }
      $$posj = $$posj + $dleft + $dout*10;
      $$posk = $$posk          + $dout*10;
    }
  }
}

sub psvec ($) {
  my ($pos) = @_;
  sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
}

sub face_path ($) {
  my ($rr) = @_;
  o("% $rr->{Name}\n");
  o("  newpath\n");
  my $xto = 'moveto';
  foreach my $vertex (@{ $rr->{Polygon} }) {
    my $pos = $vertex->{Pos};
    o(sprintf "    %s %s\n", psvec($pos), $xto);
    $xto = 'lineto';
  }
  o("    closepath\n");
}

sub pscolour ($;$) {
  my ($spec, $adj1) = @_;
  confess unless defined $spec;
  my @rgb = map { hex($_) / 15.0 } split //, $spec;
  $adj1 //= sub { };
  $adj1->(@rgb);
  my $r = join ' ',
      (map { sprintf "%.6f ", $_ } @rgb
      ),
	   'setrgbcolor';
  return $r;
}

sub preamble() {
  my $printeredge = 5 * MM2PT;
  my $xsz = 842;
  my $ysz = 3 * 595 - 4 * $printeredge;
  o(<<END);
%!PS-Adobe-3.0
%%BoundingBox 0 0 $xsz $ysz
%%Pages: 1
%%EndComments
%%BeginProlog
%%EndProlog
%%BeginSetup
/board {
  gsave
  40 -40 translate
END
  #o(" 0.52 dup scale\n") if $xopts =~ m/S/;
  #o("%%Box 0 0 $xsz $ysz");
  # xxx split into pages?
}

sub postamble () {
  o(<<END);
  grestore
} bind def
%%EndSetup
%%Page: 1
%%BeginPageSetup
/pgsave save def
%%EndPageSetup
board
pgsave restore
showpage
%%EOF
END
}

sub lighterpscolour ($$) {
  my ($colourname, $retain) = @_;
  pscolour($c{Colours}{$colourname},
	   sub { $_ = 1.0 - $retain * (1.0 - $_) foreach @_ })
}

sub darkerpscolour ($$) {
  my ($colourname, $retain) = @_;
  pscolour($c{Colours}{$colourname},
	   sub { $_ = $retain * $_ foreach @_ })
}

sub facepscolour ($) {
  my ($colourname) = @_;
  $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
}

sub fill_faces() {
  o("clippath ", facepscolour('land'), " fill\n");
  foreach my $rr (values %region) {
    next if $rr->{Name} =~ m/^L2?$/;
    face_path($rr);
    o(" ", facepscolour($rr->{Colour}), " eofill\n");
  }
}

our $edge_lw = 5;

sub some_edge_faces (@) {
  o("$edge_lw setlinewidth 1 setlinejoin 0 setgray\n");
  foreach my $rr (@_) {
    next if $rr->{Name} =~ m/^L2?$/;
    face_path($rr);
    o("    stroke\n");
  }
}

sub afsluitdijk() {
  my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
  my $dash = 20;
  my (@pos) = adj_ends($adj);
  my $mid = 0.5 * ($pos[0] + $pos[1]);
  my $r = 0.5 * ($pos[1] - $pos[0])->norm();
  o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
  %% Afsluitdijk
  %s %s %s 0 360 arc closepath fill
END
  some_edge_faces(()); # just sets the colour
  o(sprintf <<END, map { psvec($_) } @pos);
  newpath %s moveto %s lineto
  [ $dash $dash ] $dash 0.5 mul setdash
  stroke
  [] 0 setdash
END
  one_hs('purple', $mid);
}

sub edge_faces() {
  some_edge_faces($region{'NZ'});
  afsluitdijk();
  some_edge_faces(grep {
    $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
  } values %region);
}

our $hs_sz = 17 * MM2PT;
our $hs_lw = 3;

our $text_sz = 18;

sub token_circle ($$$$;$$) {
  my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
  $sz //= $hs_sz;
  $lw //= $hs_lw;
  o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
   %% %s
   newpath %s
     %s %f 0 360 arc closepath gsave fill grestore
     %s $lw setlinewidth stroke
END
}

sub one_hs ($$;$$) {
  my ($colour, $hspos, $sz, $lw) = @_;
  token_circle("HS - $colour",
	       $hspos,
	       darkerpscolour($colour, 0.75),
	       '0 setgray',
	      $sz,$lw);
}

our $cube_sz = 6 * MM2PT;
our $cube_gap = $cube_sz * 0.2;
our $cube_lw = ($cube_sz * 0.1);

sub label_faces() {
  my $sz = $text_sz;
  my $shadow = $sz * 0.1;
  o(<<END);
  /wordsshow {
    0 setgray 0 10 359 {
      dup  cos $shadow mul
      exch sin $shadow mul
      words pop pop
    } bind for
    1 setgray 0 0 words pop pop
  } def
END
  o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
  my %hs = map { $_ => 1 } @{ $c{HS} };
  foreach my $rr (values %region) {
    next if $rr->{Name} =~ m/^L\d?$/;
    my $words = $rr->{DisplayName};
    my $pos;
    if ($rr->{Name} eq 'NZ') {
      $pos = mkvec(90, 1280);
    } else {
      $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
    }
    if ($hs{$rr->{Name}}) {
      print STDERR "adjust hs $rr->{Name}\n";
      $pos -= mkvec(0, -$hs_sz*
		    ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
      my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
			       + $hs_sz*0.15);
      one_hs($rr->{Colour}, $hspos);
    }
    my $adjust = $c{TextAdjust}{$rr->{Name}};
    if ($adjust) {
      $pos += $sz * &mkvec(@$adjust);
    }
    my $w = $rr->{Water};
    $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
    if ($w) {
      print STDERR " water $w in $rr->{Name}\n";
      my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
      $pos -= mkvec(0, -0.5 * $down);
      my $cube_y = -($sz * @$words);
      if ($rr->{Name} eq 'Wieringermeer') {
	$pos -= mkvec(0,+$sz);
	$cube_y = 0;
	$down = 0;
      }
      o("  gsave\n");
      o("    ", psvec($pos), " translate\n");
      o("    0 ", $cube_y, " translate\n");
      o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
      water_cubes($w);
      o("  grestore\n");
    }
    o("  /words {\n");
    foreach my $word (@$words) {
      $pos += mkvec(0,-$sz);
      o("   ", psvec($pos), " moveto");
      o(<<END);
   2 copy rmoveto
   ($word) dup stringwidth pop     % word xw
     -0.5 mul 0 rmoveto             % word
     show
   0 -$sz rmoveto
END
    }
    o(<<END);
  } bind def
  wordsshow
END
  }
}

sub water_cubes_sz($){
  my ($n) = @_;
  ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
}
  
sub water_cubes($){
  my ($n) = @_;
  my $s = $cube_sz;
  for my $i (0..$n-1) {
    o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
    o("          $s  0  rlineto\n");
    o("           0 $s  rlineto\n");
    o("         -$s  0  rlineto  closepath\n");
    o("  gsave ", pscolour($c{Colours}{cube}), " fill grestore\n");
    o("  gsave ", '0 setgray ', $cube_lw,
      " setlinewidth stroke grestore \n");
  }
}

my $deck_h = 89 * MM2PT;

sub decks(){
  my $lw = $edge_lw/2;
  o("  /deck1path {\n");
  my $w = 63 * MM2PT;
  my $h = $deck_h;
  my $r =  5 * MM2PT;
  o("      ",($w/2)," 0 moveto\n");
  my @p = ([ $w, 0 ],
	   [ $w,$h ],
	   [ 0, $h ],
	   [ 0,  0 ]);
  foreach my $i (0..3) {
    o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
  }
  o("    closepath\n");
  o("  } bind def");
  o("  /deckpairpathx {\n"); # x because it leaves matrix changed
  o("    newpath         deck1path\n");
  o("    200 0 translate deck1path\n");
  o("  } bind def");
  o("  $lw setlinewidth 1 setgray\n");
  o("  gsave 407 50 translate deckpairpathx stroke grestore");
  o("  $lw setlinewidth ",pscolour($c{Colours}{dykefail}),"\n");
  o("  gsave 225 1375 translate 90 rotate deckpairpathx stroke grestore");
}

sub sea_track(){
  o("% sea level track\n");
  o("  gsave 0 660 translate\n");
  my $track = $c{SeaTrack};
  my $token_sz = $hs_sz;
  my $dy = $token_sz * 1.25;
  my $dx = $token_sz * 1.25;
  my $linecolour = darkerpscolour('cube', 0.25);
  my @pos;
  for my $i (0..$#$track) {
    $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
  }
  my $prepline = "$linecolour $hs_lw setlinewidth newpath";
  o("  $prepline\n");
  o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
  for my $pos (@pos) {
    token_circle("SL", $pos,
		 pscolour($c{Colours}{cube}),
		 $linecolour);
  }
  for my $i (0..$#pos-1) {
    my $differs = $track->[$i] != $track->[$i+1];
    o("  $prepline\n");
    o("  gsave ",
      psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
    if (#0 &&
	$i >= 1 &&
	$track->[$i] == $track->[$i-1] &&
	($i == 1 ||
	 $track->[$i] != $track->[$i-2])) {
      my $t_sz = 24;
      my $shrink = ($hs_sz * 0.75 / $deck_h);
      o("    gsave % T M $i\n");
      o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
      o("      gsave");
      o("        $shrink dup scale -90 rotate\n");
      o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
      o("         deck1path stroke\n");
      o("      grestore");
      o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
      o("      12 -22 moveto ($track->[$i]) show");
      o("    grestore\n");
    }
    if ($differs || $track->[$i]==2 && $track->[$i+2]!=2) {
      if ($differs) {
	o("  0 0 moveto",
	  " ",psvec(mkvec( $dx + $cube_sz, 0 )),
	  " rlineto stroke\n");
      }
      o("  ",($token_sz * 0.6 + $cube_gap)," ",($cube_gap + $hs_lw),
	" translate\n");
      water_cubes(2);
      my $new_n = $track->[$i+1] - 2;
      o("  ", 0.5 * (water_cubes_sz(2) - water_cubes_sz($new_n)),
	"  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
      water_cubes($new_n);
    }
    o("  grestore\n");
  }
  o("  grestore\n");
}

our $dyke_l = 25 * MM2PT;;

sub dykes(){
  my $l = $dyke_l;
  my $w = 5 * MM2PT;
  my $lw = $edge_lw * 0.50;
  my $l2 = $l/2;
  my $w2 = $w/2;
  o("  /dykepath {\n");
  o("            -$l2 -$w2 moveto\n");
  o("             $l2 -$w2 lineto\n");
  o("             $l2  $w2 lineto\n");
  o("            -$l2  $w2 lineto closepath\n");
  o("  } bind def\n");
  o("  /dyke {\n");
  o("    newpath dykepath\n");
  o("    gsave 0.50 setgray fill grestore\n");
  o("    gsave 0.00 setgray $lw setlinewidth stroke grestore\n");
  o("  } bind def\n");
  my $symbol_sz = $w * 1.50;
  my $t_sz = $symbol_sz * 1.0;
  my $t_at = sub {
    my ($ang) = @_;
    print STDERR "ANG $ang\n";
    map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
  };
  my @t0 = $t_at->((TAU) *  0.25         );
  my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
  my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
  o("  /dtriangle {\n");
  o("    newpath @t0 moveto\n");
  o("            @t1 lineto\n");
  o("            @t2 lineto closepath\n");
  o("    gsave ",pscolour($c{Colours}{dykeinit})," fill grestore\n");
  o("    gsave 0 setgray $lw setlinewidth stroke grestore\n");
  o("  } bind def\n");
  foreach my $rr (values %region) {
    next if $rr->{Special};
    next if $rr->{Name} eq 'ZZ';
    next if $rr->{Colour} eq 'high';
    foreach my $adj (@{ $rr->{Adj} }) {
      my $neigh = $adj->{Name};
      o("  % dyke $rr->{Name} --- $neigh\n");
      next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
      next if $region{$neigh}{Colour} eq 'high';
      my @ends = adj_ends($adj);
      my $dirn = $ends[1] - $ends[0];
      my $angle = vec2atan($dirn);
      $angle = $angle * 360 / TAU;
      o("  gsave\n");
      o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
      o("    $angle rotate\n");
      my $initial = $adj->{Dykes};
      for my $ys ($initial
		  ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
		  : [0]) {
	foreach my $y (@$ys) {
	  o("    gsave 0 ", $y * $w, " translate dyke ");
	  o(" grestore\n");
	}
	my $nsymbols = !!$initial + !!$adj->{Deltawerk};
	o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
	if ($adj->{Deltawerk}) {
	  one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
	  o("  $symbol_sz 0 translate % DW\n");
	}
	o(" $angle neg rotate dtriangle ") if $initial;
      }
      o("  grestore\n");
    }
  }
}

sub hs_initial_1 ($$$;$$$) {
  my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
  my $interval = $hs_sz * 1.75;
  my $demo_h = $hs_sz; #water_cubes_sz(3);
  my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
  my $demo_w = $demo_x0 + $dyke_l * 0.60;
  o("  % HS I $colour\n");
  o("  gsave\n");
  o("    550 1710 translate\n");
  o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
  if ($fn) {
    o("  gsave");
    o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
    o("        ", facepscolour($colour), " stroke grestore\n");
  }
  one_hs($colour, mkvec(0,0));
  if ($fn) {
    o("    /words {");
    o("      2 copy moveto                      ($text) show");
    o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show");
    o("    } bind def");
    o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
    o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
    $fn->();
  }
  o("  grestore\n");
}

sub hs_initial () {
  hs_initial_1('red',     0,0);
  hs_initial_1('purple',  0,1);
  hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
    o("    ",(water_cubes_sz(1))," 0 translate\n");
    o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
    water_cubes(1);
  });
  hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
    o("    newpath dykepath\n");
    o("    gsave 0.50 setgray fill grestore\n");
    o("    gsave ",pscolour($c{Colours}{dykehsadd})," fill grestore\n");
  });
}

sub play_hint () {
  my $sz = 20;
  o("  gsave 0 setgray 260 1720 translate");
  o("  /Helvetica-Bold findfont $sz scalefont setfont");
  my @t = split /\n/, $c{PlayHint};
  foreach my $i (0..$#t) {
    my $t = $t[$i];
    $t =~ s/[\\()]/\\$&/g;
    o("  0 ",(-$i * $sz)," moveto ($t) show");
  }
  o("  grestore");
}

#----- main program -----

$xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;

($facesf, @ARGV) = @ARGV or die;
parse_input_graph();
prep_region_rmap();
read_faces();
calculate_centres();
transform_coordinates();
adjust_nz();

preamble();
fill_faces();
edge_faces();
dykes();
label_faces();
decks();
sea_track();
hs_initial();
play_hint();
postamble();

print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};

# Local variables:
# cperl-indent-level: 2
# End.