#!/usr/bin/perl -w

use strict;
use IO::File;
use Data::Dumper;
use POSIX;

use vars qw($quis
	    $mode $doall
	    $etcfile $where
	    $debug $needglue $localonly $verbosity);

$quis= $0; $quis =~ s,.*/,,;

$mode= '';
$doall= 0;
$etcfile= "/etc/bind/chiark-conf-gen.zones";
$where= '<built-in>';
$debug= 0;
$needglue= 2;
$localonly= 0;
$verbosity= 1;

use vars qw($dig_owner $dig_type $dig_rdata);

while (@ARGV && $ARGV[0] =~ m/^\-/) {
    $_= shift @ARGV;
    if (s/^\-\-//) {
	last if m/^$/;
	if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
	elsif (m/^all$/) { $doall=1; }
	elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
	elsif (m/^glueless$/) { $needglue--; }
	elsif (m/^localonly$/) { $localonly=1; }
	elsif (m/^quiet$/) { $verbosity=0; }
	elsif (m/^verbose$/) { $verbosity=2; }
	else { usageerr("unknown option --$_"); }
    } else {
	s/^\-//;
	last if m/^$/;
	while (m/^./) {
	    if (s/^[ynf]//) { $mode=$&; }
	    elsif (s/^A//) { $doall=1; }
	    elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
	    elsif (s/^D//) { $debug++; }
	    elsif (s/^g//) { $needglue--; }
	    elsif (s/^l//) { $localonly=1; }
	    elsif (s/^q//) { $verbosity=0; }
	    elsif (s/^v//) { $verbosity=2; }
	    else { usageerr("unknown option -$&"); }
	}
    }
}

sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }

usageerr("-g may be specified at most twice") if $needglue<0;
usageerr("-D may be specified at most twice") if $debug>2;
usageerr("must specify either -f|-y|-n or zones (and not both)")
    if !!$mode == !!@ARGV;

sub usageerr ($) {
    die
"$_[0]
usage: named-conf-regen [-rvq] -f|-y|-n|<zone>...\n".
"operation modes:\n".
" -f --force   install without checking\n".
" -y --yes     check and install\n".
" -n --no      check only\n".
"additional options:\n".
" -q --quiet   no output for OK zones\n".
" -v --verbose extra verbose\n";
}

cfg_fail("config filename $etcfile should not be directory")
    if $etcfile =~ m,/$,;

use vars qw($default_dir);
$default_dir= $etcfile =~ m,^.*/, ? $& : './';

use vars qw($slave_dir $slave_prefix $slave_suffix);
$slave_dir= 'slave';
$slave_prefix= '';
$slave_suffix= '';

use vars qw(@self_ns @self_soa @self_addr);
@self_ns= @self_soa= @self_addr= ();

use vars qw(%zone_cfg @zone_cfg_list);
%zone_cfg= ();
@zone_cfg_list= ();

use vars qw($output $default_output %output_contents);
$output= '';
$default_output= '';
%output_contents= ();

use vars qw($check $install);
$check= $mode !~ m/^f/;
$install= $mode =~ m/^[yf]/;

read_config($etcfile);
debug_dump('@zone_cfg_list %zone_cfg');
process_zones($mode ? @zone_cfg_list : @ARGV);
debug_dump('%output_contents');
output_files() if $install;

exit 0;

#-------------------- configuration reading

sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }

sub read_config ($) {
    my ($if) = @_;
    my ($fh,$z,@self,$before, $mod,$dir,$prefix,$suffix,$lprefix,$lsuffix);
    local ($_);

    $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
    $before= '';
    for (;;) {
	if (!defined($_= <$fh>)) {
	    cfg_fail("read config file $if:\n $!") if $fh->error();
	    last;
	}
	chomp; s/\s+$//;
	if (m/\\$/) { $before.= $_; next; }
	$_= $before.$_;
	$before= '';
	s/^\s+//;
	$where= "$if:$.";
	next if m/^\#/;
	last if m/^end$/;
	next unless m/\S/;
	if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
	    @self= split /\s+/, $2;
	    @self_ns= @self if $1 ne '-soa';
	    @self_soa= @self if $1 ne '-ns';
	} elsif (m/^self\-addr\s+([0-9. \t]+)/) {
	    @self_addr= split /\s+/, $1;
	} elsif (m/^primary\-dir([*?]?)\s+(\S+)((?:\s+(\S+))?:\s+(\S+))?$/) {
	    ($mod, $dir, $prefix, $suffix) = ($1,qualify($2),$3,$4);
	    $suffix= '_db' if !defined $suffix;
	    $prefix= '' if !defined $prefix;
	    opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
	    $lprefix= length $prefix; $lsuffix= length $suffix;
	    while (defined($_= readdir D)) {
		next if m/^\./ && !$lprefix;
		next unless length > $lprefix+$lsuffix;
		next unless substr($_,0,$lprefix) eq $prefix;
		next unless substr($_,length($_)-$lsuffix) eq $suffix;
		$z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
		zone_conf($z,'primary','p',$mod,"$dir/$_");
	    }
	    closedir D or cfg_fail("close primary-dir $dir:\n $!");
	} elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
	    zone_conf($2,'primary','p',$1,qualify($3));
	} elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
	    zone_conf($2,'published','s',$1,'',$3);
	} elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
	    zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
	} elsif (m/^slave\-dir\s+(\S+)((?:\s+(\S+))?:\s+(\S+))?$/) {
	    ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
	} elsif (m/^output\s+bind8\+(\S+)$/) {
	    cfg_fail("default output may not apply to only some zones")
		if @zone_cfg_list && length $default_output;
	    set_output(qualify($1));
	} elsif (m/^include\s+(\S+)$/) {
	    read_config($1);
	} else {
	    cfg_fail("unknown configuration directive".
		     " or incorrect syntax or arguments");
	}
    }
    $fh->close or cfg_fail("close config file $if:\n $!");
}

sub qualify ($) {
    my ($i) = @_;
    $i= "$default_dir$i" unless $i =~ m,^/,;
    return $i;
}

sub zone_conf ($$$$$@) {
    my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
    my ($sfx,$aref);
    $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
	unless length $file;
    if (!length $output) {
	$default_output= qualify('chiark-conf-gen.bind8')
	    unless length $default_output;
	set_output($default_output);
    }
    cfg_fail("redefined zone $zone") if exists $zone_cfg{$zone};
    $zone_cfg{$zone}{'file'}= $file;
    $zone_cfg{$zone}{'style_p'}= $style.$mod;
    $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
    $zone_cfg{$zone}{'servers'}= [ @servers ];
    foreach $sfx (qw(soa ns addr)) {
	{ no strict 'refs'; $aref= [ @{ "self_$sfx" } ]; }
	@$aref or cfg_fail("failed to specify self-$sfx before zone");
	$zone_cfg{$zone}{"self_$sfx"}= $aref;
    }
    $zone_cfg{$zone}{'output'}= $output;
    push @zone_cfg_list, $zone;
}

sub set_output($) {
    my ($newout) = @_;
    $output= $newout;
    $output_contents{$output}= '';
}


#-------------------- checking

use vars qw($zone $cfg $warnings);
$warnings= 0;

sub progress ($) {
    return if !$verbosity;
    print "$_[0]\n";
}

sub verbose ($) {
    return if $verbosity<2;
    print "    $_[0]\n";
}

sub process_zones (@) {
    my (@zones) = @_;
    local ($zone,$cfg);

    foreach $zone (@zones) {
	$cfg= $zone_cfg{$zone} || {
	    'style_p' => 'foreign',
	    's' => 'f',
	    'servers' => [ ],
	    };
	progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
	if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
	    eval {
		if ($localonly && $cfg->{'s'} =~ m/f/) {
		    zone_warning("foreign zone specified with -l");
		} elsif ($cfg->{'s'} =~ m/\*/ ||
			 ($localonly && $cfg->{'s'} !~ m/p/)) {
		    zone_check_local();
		} else {
		    zone_check_full();
		}
	    };
	    zone_warning("checks failed: $@") if length $@;
	}
	zone_output() if $install;
    }
    print STDERR "$quis: $warnings warnings\n" or die $!
	if $warnings;
}

sub zone_warning ($) {
    my ($w) = @_;
    $w =~ s/\n$//;
    $w =~ s,\n, // ,g;
    print STDERR "$zone: warning: $w\n" or die $!;
    $warnings++;
}

sub zone_warnmore ($) {
    print STDERR "$zone:  $_[0]\n" or die $!;
}

use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
use vars qw(%soas);  # $soa{"$origin $serial"} = [ $whosaidandwhy ]
use vars qw(%addr_is_ok %warned_glueless %warned_mynameaddr);
use vars qw($delg_to_us);
use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
use vars qw(@to_check_soa); # ($addr,$whyask, ...)

sub zone_check_full () {
    zone_reset();
    zone_investigate();
    zone_consistency();
    zone_servers_ok();
}

sub zone_reset() {
    %delgs= %auths= %glue= %soas=
	%warned_glueless= %warned_mynameaddr=
	    %addr_is_ok= ();
    $delg_to_us= 0;
    @to_check= @to_check_soa= ();
}

sub zone_investigate() {
    my ($super_zone, @super_nsnames,
	$super_ns, @super_ns_addrs, $s, $wa, $is_auth,
	%nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);

    $super_zone= $zone;
    for (;;) {
	debug_trace("zone $zone superzone $super_zone");
	$super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
	($rcode,@super_nsnames)= lookup($super_zone,'ns-','06');
	last if !$rcode;
    }
    for $super_ns (@super_nsnames) {
	$super_ns= lc $super_ns;
	($rcode,@super_ns_addrs)= lookup($super_ns,'a','0');
	foreach $addr (@super_ns_addrs) {
	    push @to_check,
	         $addr,
		 "$super_ns, server for $super_zone",
		 0, 0;
	}
    }
    for (;;) {
	# We do these in order so that we always do NS RRset checks on
	# nameservers that came from other NS RRsets first; otherwise
	# we might set nsrrset_checked due to a glueless_ok check,
	# and then not check for gluefulness later.
	debug_dump('@to_check @to_check_soa');
	if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
	    push @to_check_soa, $addr, $wa if $is_auth;
	    next if $nsrrset_checked{$addr}++;
	    zone_check_nsrrset($addr, "[$addr] $wa",
			       $is_auth, $glueless_ok);
	} elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
	    next if $soa_checked{$addr}++;
	    zone_check_soa($addr,"[$addr] $wa","[$addr] NS");
	} else {
	    last;
	}
    }
}

sub zone_check_nsrrset ($$$$) {
    my ($uaddr,$ww, $is_auth, $glueless_ok) = @_;
    my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn);
    verbose("checking delegation by $ww");
    dig(sub {
	if ($dig_type eq 'ns' && $dig_owner eq $zone) {
	    $s2g{lc $dig_rdata} = [ ];
	} elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
	    $wwn= "in glue from $ww";
	    push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
	    zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
	    push @{ $s2g{$dig_owner} }, $dig_rdata;
	}
    },
	     $zone,'ns',$uaddr);
    if (!%s2g) { zone_warning("unable to find NS RRset at $ww"); return; }
    elsif (keys %s2g == 1) { zone_warning("only one nameserver at $ww"); }
    @s= sort keys %s2g;
    foreach $s (@s) {
	@glue= @{ $s2g{$s} };
	if (!@glue) {
	    zone_warning("glueless NS $s,".
			 ($needglue<=1 ? " (eg)" : "").
			 " from $ww")
		unless $glueless_ok || !$needglue ||
		       ($needglue<=1 && $warned_glueless{$s}++);
	    next;
	}
	$glue= join ' ', sort @glue;
	push @{ $glue{$s}{$glue} }, $ww;
    }
    $s= join ' ', @s;
    $delgs_or_auths= $is_auth ? \%auths : \%delgs;
    push @{ $delgs_or_auths->{$s} }, $ww;
}

sub zone_server_addr ($$$$$) {
    my ($addr,$name,$ww,$wwq,$is_soa) = @_;
    $addr_is_ok{$addr}= "$name ($wwq)"
	if $is_soa || $cfg->{'s'} =~ m/u/;
    zone_warning("configured as stealth but we [$addr]".
		 " are published ($name $wwq)")
	if $cfg->{'s'} =~ m/u/ && grep { $_ eq $addr } @self_addr;

    my ($name_is_self, $addr_is_self);
    $name_is_self= grep { $_ eq $name }
        @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
    $addr_is_self= grep { $_ eq $addr }
        @{ $cfg->{'self_addr'} };
    if ($name_is_self && !$addr_is_self) {
	zone_warning("our name $name with wrong address [$addr], (eg) $ww")
	    unless $warned_mynameaddr{$name}{$addr}++;
    } elsif (!$name_is_self && $addr_is_self) {
	zone_warning(($is_soa ? "SOA ORIGIN maps to" : "allegedly served by").
		     " us [$addr] with wrong name $name, (eg) $ww")
	    unless $warned_mynameaddr{$name}{$addr}++;
    }
    $delg_to_us=1 if $name_is_self;
}

sub zone_check_soa ($$$) {
    my ($uaddr,$ww,$wwq) = @_;
    my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$wwn);
    verbose("checking service at $wwq");
    $lame= 'dead or lame';
    dig(sub {
	if ($dig_type eq 'flags:') {
	    $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
	} elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
	    die "several SOAs ? $ww" if defined $origin;
	    $got= $dig_rdata;
	    $got =~ m/^(\S+) \d+/ or die "$got ?";
	    $origin= $1;
	}
    },
	     $zone,'soa',$uaddr);
    $lame= 'broken' if !$lame && !defined $origin;
    if ($lame) { zone_warning("$lame server $ww"); return; }
    push @{ $soas{$got} }, $ww;
    ($rcode,@soa_addrs)= lookup($origin,'a','0');
    foreach $soa_addr (@soa_addrs) {
	$wwn= "SOA ORIGIN from $ww";
	zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
	push @to_check, $soa_addr, "$origin, $wwn";
    }
}

sub zone_consistency() {
    my ($d, $org_ser, $origin, $a, $h, $self_soa);
    zone_consistency_set('delegations',\%delgs);
    foreach $d (keys %delgs) { delete $auths{$d}; }
    zone_consistency_set('zone nameserver rrset',\%auths);
    foreach $h (keys %glue) {
	zone_consistency_set("glue for $h", $glue{$h});
    }
    zone_consistency_set("SOA ORIGIN and SERIAL",\%soas);
    $self_soa= $cfg->{'self_soa'};
    if ($cfg->{'s'} =~ m/p/) {
	foreach $org_ser (keys %soas) {
	    $org_ser =~ m/^(\S+) \d+$/ or die "$org_ser ?";
	    $origin= $1;
	    next if grep { $_ eq $origin } @$self_soa;
	    zone_warning("SOA ORIGIN $origin is not our name (@$self_soa),".
			 " eg from ".($soas{$org_ser}[0]));
	}
    }
}

sub zone_servers_ok () {
    my ($showok);
    if (%addr_is_ok) {
	$showok= 0;
	foreach $a (@{ $cfg->{'servers'} }) {
	    next if exists $addr_is_ok{$a};
	    zone_warning("we slave from $a"); $showok=1;
	}
	if ($showok) {
	    foreach $a (keys %addr_is_ok) {
		zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
	    }
	}
    }
    if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
	zone_warnmore("we are supposedly published secondary,".
		      " but not listed as a nameserver");
    }
}

sub zone_consistency_set ($%) {
    my ($msg,$set) = @_;
    my ($d,$o);
    if (keys(%$set) > 1) {
	zone_warning("inconsistent $msg:");
	foreach $d (keys %$set) {
	    foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
	}
    }
}

sub zone_check_local () {
    zone_reset();
    zone_servers_simplefind();
    zone_servers_ok();
}

sub zone_servers_simplefind () {
    my ($rcode,@nsnames,$ns,@soas,$origin);

    ($rcode,@nsnames)= lookup($zone,'ns-','0');
    foreach $ns (@nsnames) { zone_server_simple($ns,'NS',0); }

    ($rcode,@soas)= lookup($zone,'soa','0');
    die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
    $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
    zone_server_simple(domain_canon($1),'SOA',1);
}

sub zone_server_simple ($$$) {
    my ($name,$ww,$is_soa) = @_;
    my ($rcode,@addrs,$addr);
    ($rcode,@addrs)= lookup($name,'a','0');
    foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
}

#-------------------- outputting

sub zone_output () {
    $output_contents{$$cfg{'output'}}.=
	sprintf(<<'END',
zone "%s" {
    type %s;
    file "%s";
};
END
		$zone,
		$$cfg{'s'} =~ m/p/ ? 'master' : 'slave',
		$$cfg{'file'});
}

sub output_files () {
    my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
    
    foreach $ofn (keys %output_contents) {
	$fn= $ofn; $mfn= "output file $fn";
	for (;;) {
	    if (!lstat $fn) {
		$! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
		$maxmode= 0666;
		last;
	    } elsif (-f _) {
		$maxmode= (stat _)[2];
		last;
	    } elsif (-l _) {
		defined($l= readlink $fn)
		    or die "$quis: readlink $mfn:\n $!\n";
		$dir= $fn =~ m,^.*/, ? $& : './';
		$fn= "$dir$l" unless $l =~ m,^/,;
		$mfn= "output file $fn (symlink target of $ofn)";
	    } else {
		die "$quis: output file $mfn exists but is not a file".
		    " (or symlink to one)";
	    }
	}
	unlink "$fn.new" or $! == &ENOENT or
	    die "$quis: cannot clear out old .new version of $mfn:\n $!";
	$h= new IO::File "$fn.new",'w',$maxmode
	    or die("$quis: create .new version of $mfn:\n $!");
	print $h
	    "# generated by $quis, do not edit\n",
	    $output_contents{$ofn}
	    or die "$quis: write data to .new version of $mfn:\n $!";
        $h->close
	    or die "$quis: close .new version of $mfn:\n $!";
	push @to_install, $fn,$mfn;
    }

    while (($fn,$mfn, @to_install) = @to_install) {
	rename "$fn.new",$fn
	    or die "$quis: install new version of $mfn:\n $!";
    }
}

#-------------------- general utilities

sub debug_dump ($) {
    my ($vn);
    return unless $debug>1;
    local $Data::Dumper::Terse=1;
    foreach $vn (split /\s+/, $_[0]) {
	print "$vn := ", eval "Dumper(\\$vn)";
    }
}

sub debug_trace ($) {
    return unless $debug;
    print "D $_[0]\n";
}

sub lookup ($$$) {
    my ($domain,$type,$okrcodes) = @_;
    my ($c,$h,@result);
    debug_trace("lookup ==> (->$okrcodes) $domain $type");
    $h= new IO::Handle;

    defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
    if (!$c) {
	exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
	     '-',"$domain.";
	die "$quis: exec adnshost:\n $!\n";
    }
    @result= $h->getlines();
    $h->error and die "$quis: read from adnshost:\n $!\n";
    chomp @result;
    $!=0; $h->close;
    die "$quis: lookup -t$type $domain $okrcodes failed $? $! @result\n"
	if $! or $?>6 or index($okrcodes,$?)<0;
    debug_trace("lookup <== $? @result");
    return ($?,@result);
}


sub dig (&$$$) {
    my ($eachrr, $qowner,$qtype,$qaddr) = @_;
    # also pseudo-rr with type `flags:'
    my ($h,$inmid,$irdata,$c);
    local ($_);

    debug_trace("dig ==> \@$qaddr $qowner $qtype");

    $h= new IO::Handle;
    defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
    if (!$c) {
	open STDERR, ">&STDOUT" or die $!;
	exec ('dig',
	      '+nodef','+nosea','+nodebug','+norecurse',
	      "\@$qaddr",'-t',$qtype,$qowner);
	die "$quis: exec dig:\n $!\n";
    }
    $inmid='';
    for (;;) {
	if (!defined($_= $h->getline())) {
	    $h->error() and die "$quis: read from dig:\n $!\n";
	    last;
	}
	chomp;
	if (length $inmid) {
	    s/^\s+/ / or die "$inmid // $_ ?";
	    s/\;.*$//;
	    $_= $inmid.$_;
	    $inmid='';
	    s/$/ \(/ unless s/\s*\)\s*$//;
	}
	if (s/\s*\(\s*$//) { $inmid= $_; next; }
	if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
	    $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
	    debug_trace("dig  f: $dig_rdata");
	    &$eachrr;
	} elsif (m/^\;/) {
	} elsif (!m/\S/) {
	} elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
	    $dig_owner=domain_canon($1); $dig_type=lc $2; $irdata=$3;
	    if ($dig_type eq 'a') {
		$irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
		$dig_rdata= $&;
	    } elsif ($dig_type eq 'ns') {
		$irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
		$dig_rdata= domain_canon($irdata);
	    } elsif ($dig_type eq 'soa') {
		$irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
		    or die "bad SOA $irdata ?";
		$dig_rdata= domain_canon($1).' '.$2;
	    } else {
		debug_trace("ignoring uknown RR type $dig_type");
		next;
	    }
	    debug_trace("dig  $dig_owner $dig_type $dig_rdata");
	    &$eachrr;
	} else {
	    debug_trace("ignoring unknown dig output $_");
	}
    }
    $h->close;
    debug_trace("dig <== gave $?");
}

sub domain_canon ($) {
    local ($_) = @_;
    s/(.)\.$/$1/;
    die "domain $_ ?" unless m/^[0-9a-z]/i;
    return lc $_;
}