scripts/named-conf

   1 #!/usr/bin/perl -w
   2 # This is chiark-named-conf, which is Copyright 2002 Ian Jackson.
   3 #
   4 # chiark-named-conf and its manpage are free software; you can
   5 # redistribute it and/or modify them under the terms of the GNU
   6 # General Public License as published by the Free Software Foundation;
   7 # either version 3, or (at your option) any later version.
   8 #
   9 # chiark-named-conf and its manpage are distributed in the hope that
  10 # it will be useful, but WITHOUT ANY WARRANTY; without even the
  11 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  12 # PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with this program; if not, consult the Free Software Foundation's
  16 # website at www.fsf.org, or the GNU Project website at www.gnu.org.
  17
  18 use strict;
  19 use IO::File;
  20 use Data::Dumper;
  21 use POSIX;
  22 use Fcntl qw(:DEFAULT :flock);
  23
  24 # bastard Perl wants me to do this now !
  25 sub loarg();
  26 sub soarg();
  27 sub usageerr ($);
  28 sub cfg_fail ($);
  29 sub read_config ($);
  30 sub qualify ($);
  31 sub bad_modifiers ($);
  32 sub zone_conf ($$$$$@);
  33 sub set_output($);
  34 sub progress ($$);
  35 sub verbose ($);
  36 sub process_zones (@);
  37 sub zone_warning ($$);
  38 sub zone_warnmore ($);
  39 sub zone_check_full ();
  40 sub zone_reset();
  41 sub zone_investigate();
  42 sub zone_check_nsrrset ($$$$);
  43 sub zone_ns_name ($$);
  44 sub zone_server_queue ($$$$$);
  45 sub zone_server_addr ($$$$$);
  46 sub zone_check_soa ($$$$);
  47 sub zone_consistency();
  48 sub zone_servers_ok ();
  49 sub zone_consistency_set ($%);
  50 sub zone_check_local ();
  51 sub zone_servers_simplefind ();
  52 sub zone_server_simple ($$$);
  53 sub zone_style ($$);
  54 sub mail_zone_before ();
  55 sub mail_zone_after ();
  56 sub pmail ($);
  57 sub ptime ($);
  58 sub mail_zone_mail ();
  59 sub zone_output ();
  60 sub output_files ();
  61 sub debug_dump ($);
  62 sub debug_trace ($);
  63 sub has_suffix_of ($$);
  64 sub lookup ($$$$);
  65 sub dig (&$$$);
  66 sub domain_canon ($$);
  67
  68 use vars qw($quis $stdout_fh $stderr_fh
  69             $mode $doall $domail
  70             $etcfile $where
  71             $debug $needglue $localonly $repeat $verbosity
  72             $admin $mail_state_dir $mail_max_warnfreq
  73             $progress_fh $warn_fh $modifiers
  74             %group2modcmd %group2used);
  75
  76 $|=1;
  77 $quis= $0; $quis =~ s,.*/,,;
  78
  79 $mode= '';
  80 $doall= 0;
  81 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  82 $where= '<built-in>';
  83 $debug= 0;
  84 $needglue= 1;
  85 $localonly= 0;
  86 $verbosity= 2;
  87 $admin=''; $mail_state_dir=''; $mail_max_warnfreq= 50;
  88 $repeat= 0;
  89 $domail= '';
  90 $modifiers= '';
  91 $group2modcmd{'foreign'}= '$!*@?';
  92 $group2used{'foreign'}= 1;
  93
  94 ($progress_fh= $stdout_fh= new_from_fd IO::Handle(1,'w') and
  95  $warn_fh= $stderr_fh = new_from_fd IO::Handle(2,'w'))
  96     or die "$quis: setup standard filehandles: $!\n";
  97
  98 use vars qw($dig_owner $dig_type $dig_rdata);
  99
 100 while (@ARGV && $ARGV[0] =~ m/^\-/) {
 101     $_= shift @ARGV;
 102     if (s/^\-\-//) {
 103         last if m/^$/;
 104         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; $domail=''; }
 105         elsif (m/^nothing$/) { $mode= 'x'; $domail=''; }
 106         elsif (m/^mail\-(first|middle|final|final\-test)$/) {
 107             $mode='n';
 108             $domail=$1;
 109         }
 110         elsif (m/^all$/) { $doall=1; }
 111         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
 112         elsif (m/^glueless$/) { $needglue=0; }
 113         elsif (m/^localonly$/) { $localonly=1; }
 114         elsif (m/^quiet$/) { $verbosity--; }
 115         elsif (m/^repeat$/) { $repeat=1; }
 116         elsif (m/^verbose$/) { $verbosity++; }
 117         else { usageerr("unknown option --$_"); }
 118     } else {
 119         s/^\-//;
 120         last if m/^$/;
 121         while (m/^./) {
 122             if (s/^[ynf]//) { $mode=$&; $domail=''; }
 123             elsif (s/^A//) { $doall=1; }
 124             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
 125             elsif (s/^D//) { $debug++; }
 126             elsif (s/^g//) { $needglue=0; }
 127             elsif (s/^l//) { $localonly=1; }
 128             elsif (s/^m(\w+)(\W+)$//) {
 129                 my ($g,$m) = ($1,$2);
 130                 $group2modcmd{$g}=$m;
 131                 usageerr("modifiers $m for group $g: $@") if bad_modifiers($m);
 132             }
 133             elsif (s/^q//) { $verbosity--; }
 134             elsif (s/^r//) { $repeat=1; }
 135             elsif (s/^v//) { $verbosity++; }
 136             else { usageerr("unknown option -$&"); }
 137         }
 138     }
 139 }
 140
 141 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
 142 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
 143
 144 usageerr("-q may be specified at most twice") if $verbosity<0;
 145 usageerr("-v may be specified at most once") if $verbosity>3;
 146 usageerr("-D may be specified at most twice") if $debug>2;
 147 usageerr("must specify either -f|-y|-n or zones (and not both)")
 148     if !!$mode == !!@ARGV && !$domail;
 149
 150 sub usageerr ($) {
 151     die <<END;
 152 $_[0]
 153
 154 usage: chiark-named-conf [options] -f|-y|-n|<zone>...
 155 operation modes:
 156  -f --force   install without checking
 157  -y --yes     check and install
 158  -n --no      check only (configured zones)
 159  --nothing    list zones only
 160  --mail-*     send mail about broken zones (see manpage)
 161  <zone> ...   check only (specified zones, even unconfigured ones)
 162 additional options:
 163  -A --all       report on zones marked ? (ones we know are broken)
 164  -D             debug $quis (does not help debug your DNS config)
 165  -g --glueless  do not warn about any glueless referrals (not recommended)
 166  -l --localonly full checks only on zones which we primary
 167  -q --quiet     no output for OK zones
 168  -r --repeat    repeat warnings for all sources of imperfect data
 169  -v --verbose   extra verbose info about each zone
 170  -C|--config <DIR/FILE  use FILE as default config and DIR as default dir
 171
 172 chiark-named-conf is Copyright 2002 Ian Jackson.  It is Free software, under
 173 the GNU General Public License, and you are welcome to change it and/or
 174 distribute copies under certain conditions.  There is ABSOLUTELY NO WARRANTY.
 175 END
 176 }
 177
 178 cfg_fail("config filename $etcfile should not be directory")
 179     if $etcfile =~ m,/$,;
 180
 181 use vars qw($default_dir);
 182 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
 183
 184 use vars qw($slave_dir $slave_prefix $slave_suffix);
 185 $slave_dir= 'slave';
 186 $slave_prefix= '';
 187 $slave_suffix= '';
 188
 189 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @forbid_slave
 190             @conv_glueless @indirect_glue);
 191 @self_ns= @self_soa= @self_addr= @forbid_addr= @forbid_slave= @indirect_glue= ();
 192 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
 193
 194 use vars qw(%zone_cfg @zone_cfg_list);
 195 %zone_cfg= ();
 196 @zone_cfg_list= ();
 197
 198 use vars qw($output $default_output %output_contents);
 199 $output= '';
 200 $default_output= '';
 201 %output_contents= ();
 202
 203 use vars qw($check $install);
 204 $check= $mode !~ m/^[fx]/;
 205 $install= $mode =~ m/^[yf]/;
 206
 207 read_config($etcfile);
 208 debug_dump('@zone_cfg_list %zone_cfg');
 209 process_zones(!@ARGV ? @zone_cfg_list : @ARGV);
 210 debug_dump('%output_contents');
 211 output_files() if $install;
 212
 213 $stdout_fh->close or die "$quis: write messages to stdout: $!\n";
 214 $stderr_fh->close or die "$quis: write messages to stderr: $!\n";
 215 exit 0;
 216
 217 #-------------------- configuration reading
 218
 219 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 220
 221 sub read_config ($) {
 222     my ($if) = @_;
 223     my ($fh,$z,@self,$before,$group,
 224         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 225     local ($_);
 226
 227     $fh= new IO::File $if,'r';
 228     unless ($fh) {
 229         return if $! == &ENOENT;
 230         cfg_fail("open $if:\n $!");
 231     }
 232     $before= '';
 233     for (;;) {
 234         if (!defined($_= <$fh>)) {
 235             cfg_fail("read config file $if:\n $!") if $fh->error();
 236             last;
 237         }
 238         chomp; s/\s+$//;
 239         if (s/\\$//) { $before.= $_; next; }
 240         $_= $before.$_;
 241         $before= '';
 242         s/^\s+//;
 243         $where= "$if:$.";
 244         next if m/^\#/;
 245         last if m/^end$/;
 246         next unless m/\S/;
 247         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 248             @self= split /\s+/, $2;
 249             @self_ns= @self if $1 ne '-soa';
 250             @self_soa= @self if $1 ne '-ns';
 251         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 252             @conv_glueless= split /\s+/, $1;
 253         } elsif (m/^allow\-indirect\-glue\s+(\S.*\S)/) {
 254             @indirect_glue= split /\s+/, $1;
 255         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 256             @self_addr= split /\s+/, $1;
 257         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 258             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 259         } elsif (m/^forbid\-slave(?:\s+([0-9. \t]+))?/) {
 260             @forbid_slave= defined $1 ? split /\s+/, $1 : ();
 261         } elsif (m,^
 262                  primary\-dir (\W*)
 263                  \s+ (\S+)/([^/ \t]*)
 264                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 265                   )?
 266                  $,x) {
 267             ($mod, $dir, $prefix, $suffix, $subfile) =
 268                 ($1,qualify($2),$3,$4,$5);
 269             cfg_fail("modifiers $mod for directory $dir: $@")
 270                 if bad_modifiers($mod);
 271             $suffix= '' if !defined $suffix;
 272             $subfile= '' if !defined $subfile;
 273             $suffix= '_db' if !length $suffix && !length $subfile;
 274             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 275             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 276             $lprefix= length $prefix; $lsuffix= length $suffix;
 277             while (defined($_= readdir D)) {
 278                 next if m/^\./ && !$lprefix;
 279                 next unless length > $lprefix+$lsuffix;
 280                 next unless substr($_,0,$lprefix) eq $prefix;
 281                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 282                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 283                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 284                 if (!stat $zf) {
 285                     next if length $subfile && $! == &ENOENT;
 286                     cfg_fail("cannot stat zonefile $zf:\n $!");
 287                 }
 288                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 289                 zone_conf($z,'primary','p',$mod,$zf);
 290             }
 291             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 292         } elsif (m/^primary(\W*)\s+(\S+)\s+(\S+)$/) {
 293             zone_conf($2,'primary','p',$1,qualify($3));
 294         } elsif (m/^published(\W*)\s+(\S+)\s+([0-9.\t]+)$/) {
 295             zone_conf($2,'published','s',$1,'',$3);
 296         } elsif (m/^stealth(\W*)\s+(\S+)\s+([0-9. \t]+)$/) {
 297             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 298         } elsif (m/^modifiers\s+(\W+)(?:\s+(\w+))$/) {
 299             ($mod,$group) = ($1,$2);
 300             cfg_fail("modifiers $mod for group $group: $@")
 301                 if bad_modifiers($mod);
 302             if (exists $group2modcmd{$group}) {
 303                 $mod= $group2modcmd{$group};
 304                 $group2used{$group}++;
 305             }
 306             $modifiers= $mod;
 307         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 308             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 309             $slave_prefix='' if !defined $slave_prefix;
 310             $slave_suffix='' if !defined $slave_suffix;
 311         } elsif (m/^output\s+bind8\+(\S+)$/) {
 312             cfg_fail("default output may not apply to only some zones")
 313                 if @zone_cfg_list && length $default_output;
 314             set_output(qualify($1));
 315         } elsif (m/^include\s+(\S+)$/) {
 316             read_config($1);
 317         } elsif (m/^admin\s+(\S+)$/) {
 318             $admin=$1;
 319         } elsif (m/^mail\-state\-dir\s+(\S+)$/) {
 320             $mail_state_dir= $1;
 321         } elsif (m/^mail\-max\-warnfreq\s+(\d{1,3}(?:\.\d{0,5})?)$/) {
 322             cfg_fail("mail-max-warnfreq must be <=100") if $1>100;
 323             $mail_max_warnfreq= $1;
 324         } else {
 325             cfg_fail("unknown configuration directive".
 326                      " or incorrect syntax or arguments:\n".
 327                      " \`$_'");
 328         }
 329     }
 330     foreach $group (keys %group2modcmd) {
 331         next if exists $group2used{$group};
 332         cfg_fail("command line specifies modifier group $group".
 333                  " but missing in configuration file");
 334     }
 335     $fh->close or cfg_fail("close config file $if:\n $!");
 336 }
 337
 338 sub qualify ($) {
 339     my ($i) = @_;
 340     $i= "$default_dir$i" unless $i =~ m,^/,;
 341     return $i;
 342 }
 343
 344 sub bad_modifiers ($) {
 345     local ($_) = @_;
 346     if (!eval {
 347         die "bad modifier $&" if m/[^!*\$\@~?]/;
 348         die "repeated modifier $1" if m/(.).*\1/;
 349         1;
 350     }) {
 351         $@ =~ s/\n//;
 352         return 1;
 353     }
 354     return 0;
 355 }
 356
 357 sub zone_conf_settings ($$) {
 358     my ($cfg,$zone) = @_;
 359     my ($sfx,$aref);
 360     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr forbid_slave
 361                      conv_glueless indirect_glue)) {
 362         { no strict 'refs'; $aref= [ @$sfx ]; }
 363         @$aref or cfg_fail("failed to specify $sfx before zone")
 364             if $sfx =~ m/^self/;
 365         $cfg->{$sfx}= $aref;
 366     }
 367     foreach $sfx (qw(self_soa self_ns)) {
 368         map { s/\*$/$zone/ } @{ $zone_cfg{$zone}{$sfx} };
 369     }
 370 }
 371
 372 sub zone_conf ($$$$$@) {
 373     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 374     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 375         unless length $file;
 376     if (!length $output) {
 377         $default_output= qualify('chiark-conf-gen.bind8')
 378             unless length $default_output;
 379         set_output($default_output);
 380     }
 381     cfg_fail("redefined zone $zone\n".
 382              " earlier definition $zone_cfg{$zone}{'where'}")
 383         if exists $zone_cfg{$zone};
 384     $zone_cfg{$zone}{'where'}= $where;
 385     $zone_cfg{$zone}{'file'}= $file;
 386     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 387     $zone_cfg{$zone}{'s'}= "$sabbr $mod $modifiers";
 388     # p)rimary s)econdary u)npub f)oreign
 389     # followed by modifiers, first per-zone, then default
 390     $zone_cfg{$zone}{'servers'}= [ @servers ];
 391     if ($domail) {
 392         length $admin && length $mail_state_dir or
 393             cfg_fail("mailing but failed to specify admin".
 394                      " or mail-state-dir before zone");
 395         $zone_cfg{$zone}{'admin'}= $admin;
 396         $zone_cfg{$zone}{'maildir'}= qualify($mail_state_dir);
 397         $zone_cfg{$zone}{'mailmwarn'}= $mail_max_warnfreq;
 398     }
 399     zone_conf_settings($zone_cfg{$zone}, $zone);
 400     $zone_cfg{$zone}{'output'}= $output;
 401     push @zone_cfg_list, $zone;
 402 }
 403
 404 sub set_output($) {
 405     my ($newout) = @_;
 406     $output= $newout;
 407     $output_contents{$output}= '';
 408 }
 409
 410 #-------------------- checking
 411
 412 use vars qw($zone $cfg $warnings %zone_warnings);
 413 $warnings= 0;
 414
 415 sub progress ($$) {
 416     my ($minv,$m) = @_;
 417     return if $verbosity < $minv;
 418     print $progress_fh "$m\n" or die "$quis: $zone: write log: $!\n";
 419 }
 420
 421 sub verbose ($) { progress(3, '    ' . $_[0]); }
 422
 423 sub process_zones (@) {
 424     my (@zones) = @_;
 425     local ($zone,$cfg);
 426
 427     foreach $zone (@zones) {
 428         $cfg= $zone_cfg{$zone} || {
 429             'style_p' => 'foreign',
 430             's' => "f $group2modcmd{'foreign'}",
 431             'servers' => [ ],
 432             };
 433         zone_conf_settings($cfg, $zone);
 434
 435         mail_zone_before() or next
 436             if $domail;
 437         zone_reset();
 438         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
 439         if ($check && ($doall || !zone_style('?',0))) {
 440             eval {
 441                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 442                     zone_warning("foreign zone specified with -l",'');
 443                 } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
 444                     zone_check_local();
 445                 } else {
 446                     zone_check_full();
 447                 }
 448             };
 449             zone_warning("checks failed: $@",'') if length $@;
 450         }
 451         $output_contents{$$cfg{'output'}} .= zone_output()
 452             if $install;
 453
 454         mail_zone_after() if $domail;
 455     }
 456     if ($domail) {
 457     } elsif ($warnings) {
 458         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 459                        " %d zone(s) checked ok.\n",
 460                        $quis,
 461                        $warnings,
 462                        scalar(keys %zone_warnings),
 463                        scalar(@zones - keys %zone_warnings));
 464     } else {
 465         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
 466     }
 467 }
 468
 469 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 470 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 471 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 472 use vars qw(%soas);  # $soa{"$serial $mname"} = [ $whosaidandwhy ]
 473 use vars qw(%addr_is_ok %warned);
 474 use vars qw($delg_to_us);
 475 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
 476 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
 477
 478 sub zone_warning ($$) {
 479     my ($w,$o) = @_;
 480     my ($wk);
 481
 482     return 0 if !$repeat && $warned{$w}++;
 483
 484     $w =~ s/\n$//;
 485     $w =~ s,\n, // ,g;
 486
 487     $w .= " ($o)" if length $o;
 488     print $warn_fh "$zone: warning: $w\n" or die $!;
 489     $warnings++;
 490     $zone_warnings{$zone}++;
 491     return 1;
 492 }
 493
 494 sub zone_warnmore ($) {
 495     print $warn_fh "$zone:  $_[0]\n" or die $!;
 496 }
 497
 498 sub zone_check_full () {
 499     zone_investigate();
 500     zone_consistency();
 501     zone_servers_ok();
 502 }
 503
 504 sub zone_reset() {
 505     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 506     $delg_to_us= 0;
 507     @to_check= @to_check_soa= ();
 508 }
 509
 510 sub zone_investigate() {
 511     my ($super_zone, @start_nsnames, $start_ww,
 512         $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
 513         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
 514         $rcode, $name, $is_ns);
 515
 516     if (!zone_style('*',0)) {
 517         $super_zone= $zone;
 518         for (;;) {
 519             debug_trace("zone $zone superzone $super_zone");
 520             $super_zone eq '.'
 521                 and die "no superzone ? ($super_zone)\n";
 522             $super_zone =~ s/^[^.]+\.//
 523                 or $super_zone= '.';
 524             ($rcode,@start_nsnames)=
 525                 lookup($super_zone,'ns-','06',"superzone search");
 526             last if !$rcode;
 527         }
 528         $start_ww= "server for $super_zone";
 529     } else {
 530         ($rcode,@start_nsnames)=
 531             lookup($zone,'ns-','0',"initial nameserver search");
 532         $start_ww= "nameserver for $zone";
 533     }
 534     for $start_ns (@start_nsnames) {
 535         $start_ns= lc $start_ns;
 536         ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
 537         foreach $addr (@start_ns_addrs) {
 538             push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
 539         }
 540     }
 541     for (;;) {
 542         # We do these in order so that we always do NS RRset checks on
 543         # nameservers that came from other NS RRsets first; otherwise
 544         # we might set nsrrset_checked due to a glueless_ok check,
 545         # and then not check for gluefulness later.
 546         debug_dump('@to_check @to_check_soa');
 547         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
 548             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
 549                 if defined $name_if_auth;
 550             next if $nsrrset_checked{$addr}++;
 551             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
 552         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
 553             next if $soa_checked{$addr}++;
 554             zone_check_soa($addr,$wa,$name,$is_ns);
 555         } else {
 556             last;
 557         }
 558     }
 559 }
 560
 561 sub zone_check_nsrrset ($$$$) {
 562     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
 563     my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww, $cg);
 564     my ($rcode);
 565     $ww= "[$uaddr] $wa";
 566     verbose("checking delegation by $ww");
 567     dig(sub {
 568         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 569             $s2g{lc $dig_rdata} = [ ];
 570         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 571             $wwn= "in glue from $ww";
 572             zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 573             push @{ $s2g{$dig_owner} }, $dig_rdata;
 574         }
 575     },
 576              $zone,'ns',$uaddr);
 577     if (!%s2g) {
 578         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 579         return;
 580     } elsif (keys %s2g == 1) {
 581         zone_warning("only one nameserver ". (join '', keys %s2g),
 582                      $ww);
 583     }
 584     @s= sort keys %s2g;
 585     foreach $s (@s) {
 586         zone_ns_name($s,$ww);
 587         @glue= @{ $s2g{$s} };
 588         if (!@glue) {
 589             zone_warning("glueless NS $s", $ww)
 590                 unless $glueless_ok
 591                     or zone_style('~',!$needglue)
 592                     or grep { has_suffix_of($zone,".$_"); }
 593                            @{ $cfg->{'conv_glueless'} }
 594                     or ((grep { has_suffix_of($s,".$_"); }
 595                            @{ $cfg->{'indirect_glue'} }) and
 596                         !(grep { has_suffix_of($zone,".$_"); }
 597                            @{ $cfg->{'indirect_glue'} }));
 598             foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 599                 zone_warning("nameserver $s (glueless) in".
 600                              " serverless-glueless namespace area $cg", $ww)
 601                     if has_suffix_of(".$s",".$cg");
 602             }
 603             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
 604             foreach $a (@glue) {
 605                 $wwn= "glueless NS from $ww";
 606                 zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
 607             }
 608         }
 609         $glue= join ' ', sort @glue;
 610         push @{ $glue{$s}{$glue} }, $ww;
 611     }
 612     $s= join ' ', @s;
 613     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
 614     push @{ $delgs_or_auths->{$s} }, $ww;
 615 }
 616
 617 sub zone_ns_name ($$) {
 618     my ($name,$ww) = @_;
 619     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 620     zone_warning("published server, as $name, but configured as stealth",
 621                  $ww)
 622         if $cfg->{'s'} =~ m/u/ &&
 623            grep { $_ eq $name }
 624                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 625 }
 626
 627 sub zone_server_queue ($$$$$) {
 628     my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
 629     zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
 630     push @to_check, $addr, "$name, $wwn", $name, $is_soa;
 631 }
 632
 633 sub zone_server_addr ($$$$$) {
 634     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 635     debug_trace("zone_server_addr ".join('|',@_));
 636     $addr_is_ok{$addr}= "$name ($wwq)"
 637         if $is_soa || $cfg->{'s'} =~ m/u/;
 638     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 639         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 640     zone_warning("forbidden server address for our slave [$addr] $name",$ww)
 641         if $cfg->{'s'} =~ m/p/ and
 642            grep { $_ eq $addr } @{ $cfg->{'forbid_slave'} };
 643
 644     my ($name_is_self, $addr_is_self);
 645     $name_is_self= grep { $_ eq $name }
 646         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 647     $addr_is_self= grep { $_ eq $addr }
 648         @{ $cfg->{'self_addr'} };
 649     if ($name_is_self && !$addr_is_self) {
 650         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 651     }
 652     if (!$name_is_self && $addr_is_self) {
 653         zone_warning("we [$addr] are named in ".
 654                      ($is_soa ? "SOA" : "NS").
 655                      " by wrong name $name",
 656                      $ww);
 657     }
 658     if (!$name_is_self && !$addr_is_self &&
 659         $is_soa && $cfg->{'s'} =~ m/p/) {
 660         zone_warning("SOA MNAME $name is not us (".
 661                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 662     }
 663     $delg_to_us=1 if $addr_is_self && !$is_soa;
 664 }
 665
 666 sub zone_check_soa ($$$$) {
 667     my ($uaddr,$wa,$name,$is_ns) = @_;
 668     my ($lame,$serial,$mname,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 669     verbose("checking service at [$uaddr] $name");
 670     $lame= 'dead or lame';
 671     $ww= "[$uaddr] $wa";
 672     dig(sub {
 673         if ($dig_type eq 'flags:') {
 674             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 675         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 676             die "several SOAs ? $ww" if defined $mname;
 677             $got= $dig_rdata;
 678             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
 679             ($serial,$mname) = ($1,$2);
 680         }
 681     },
 682              $zone,'soa',$uaddr);
 683     $lame= 'broken' if !$lame && !defined $mname;
 684     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 685     progress(2, sprintf "%-16s %46s has %s%s",
 686              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
 687     push @{ $soas{$got} }, $ww;
 688     ($rcode,@soa_addrs)= lookup($mname,'a','0',"SOA MNAME");
 689     $wwn= "SOA MNAME from $ww";
 690     foreach $soa_addr (@soa_addrs) {
 691         zone_server_queue($soa_addr,$mname,$wwn,"SOA [$uaddr]",1);
 692     }
 693 }
 694
 695 sub zone_consistency() {
 696     my ($d, $org_ser, $mname, $a, $h, $self_soa, $wa);
 697     zone_consistency_set('delegations',\%delgs);
 698     foreach $d (keys %delgs) { delete $auths{$d}; }
 699     zone_consistency_set('zone nameserver rrset',\%auths);
 700     foreach $h (keys %glue) {
 701         zone_consistency_set("glue for $h", $glue{$h});
 702     }
 703     zone_consistency_set("serial number and/or SOA MNAME",\%soas);
 704     $self_soa= $cfg->{'self_soa'};
 705 }
 706
 707 sub zone_servers_ok () {
 708     my ($showok,%fs);
 709     if (%addr_is_ok) {
 710         $showok= 0;
 711         foreach $a (@{ $cfg->{'servers'} }) {
 712             next if exists $addr_is_ok{$a};
 713             zone_warning("we slave from [$a]",'')
 714                 and $showok=1;
 715         }
 716         if ($showok) {
 717             foreach $a (keys %addr_is_ok) {
 718                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 719             }
 720         }
 721     }
 722     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 723         zone_warning("we are supposedly published secondary,".
 724                      " but not listed as a nameserver",'');
 725         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 726         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 727     }
 728 }
 729
 730 sub zone_consistency_set ($%) {
 731     my ($msg,$set) = @_;
 732     my ($d,$o);
 733     if (keys(%$set) > 1) {
 734         zone_warning("inconsistent $msg:",'');
 735         foreach $d (keys %$set) {
 736             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 737         }
 738     }
 739 }
 740
 741 sub zone_check_local () {
 742     zone_servers_simplefind();
 743     zone_servers_ok();
 744 }
 745
 746 sub zone_servers_simplefind () {
 747     my ($rcode,@nsnames,$ns,@soas,$mname);
 748
 749     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 750     foreach $ns (@nsnames) {
 751         zone_ns_name($ns,"NS");
 752         zone_server_simple($ns,'NS',0);
 753     }
 754     $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
 755
 756     ($rcode,@soas)= lookup($zone,'soa','0',"SOA MNAME");
 757     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 758     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 759     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 760 }
 761
 762 sub zone_server_simple ($$$) {
 763     my ($name,$ww,$is_soa) = @_;
 764     my ($rcode,@addrs,$addr);
 765     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 766                             ($is_soa ? "SOA MNAME" : "NS"));
 767     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 768 }
 769
 770 sub zone_style ($$) {
 771     my ($stylechar, $default) = @_;
 772     local ($_) = $$cfg{'s'};
 773     $stylechar =~ s/\W/\\$&/ or die;
 774     return m/(\S*)$stylechar/ ? $1 !~ m/\!/ : $default;
 775 }
 776
 777 #-------------------- mailing
 778
 779 use vars qw($m_base $m_lastok @m_ok @m_fail
 780             $m_info $m_time $m_lock $m_m);
 781
 782 sub mail_zone_before () {
 783     my (@s1,@s2);
 784
 785     $m_base= $$cfg{'maildir'}.'/'.$zone;
 786     $m_lastok= '-';
 787     @m_ok= ();
 788     @m_fail= ();
 789
 790     for (;;) {
 791         $m_lock= new IO::File "${m_base}_lock", O_RDWR|O_CREAT, 0600
 792             or die "$quis: create lockfile ${m_base}_lock: $!\n";
 793         if (!flock($m_lock, LOCK_EX|LOCK_NB)) {
 794             <$m_lock> =~ m/^\d+ /;
 795             die "$quis: $zone: concurrrency? - flock $&$!\n";
 796             $m_lock->close;
 797             return 0;
 798         }
 799         (@s1= $m_lock->stat) or die "$quis: fstat ${m_base}_lock: $!\n";
 800         (@s2= stat "${m_base}_lock") or
 801             die "$quis: stat ${m_base}_lock: $!\n";
 802         last if ($s1[0] eq $s2[0] && $s1[1] eq $s2[1]);
 803         $m_lock->close;
 804     }
 805     (print $m_lock "$$        \n" and $m_lock->flush)
 806         or die "$quis: write pid to ${m_base}_lock: $!\n";
 807
 808     if ($m_info= new IO::File "${m_base}_info", 'r') {
 809         $!=0; $_= <$m_info>;
 810         $_ =~ m/\n/ or die "$quis: read ${m_base}_info: $!\n";
 811         m/^\d+ (\d+|-) ([0-9:]*) ([0-9:]*) / or
 812             die "$quis: ${m_base}_info malformed\n";
 813         $m_lastok= $1;
 814         if ($domail ne 'first') {
 815             if ($2 eq ':' && $3 eq ':') {
 816                 warn "$quis: $zone: mid/last run, but last".
 817                     "run already done, ignoring zone\n";
 818                 return 0;
 819             }
 820             @m_ok= split /\:/, $2;
 821             @m_fail= split /\:/, $3;
 822         }
 823     } elsif ($! != &ENOENT) {
 824         die "$quis: open ${m_base}_info: $!\n";
 825     } elsif ($domail ne 'first') {
 826         warn "$quis: $zone: first run, but not --mail-first,".
 827             " ignoring zone\n";
 828         return 0;
 829     }
 830     if ($domail eq 'first') {
 831         remove "${m_base}_history" or $!==&ENOENT
 832             or die "$quis: remove ${m_base}_history: $!\n";
 833     }
 834     $progress_fh= $warn_fh= new IO::File "${m_base}_history",'a',0666
 835         or die "$quis: open ${m_base}_history: $!\n";
 836     $m_info= new IO::File "${m_base}_info.tmp",'w',0666
 837         or die "$quis: open ${m_base}_info.tmp: $!\n";
 838
 839     $m_time= time;
 840     progress(-1, "\n".('-'x70)."\n".ptime($m_time)."\n");
 841     return 1;
 842 }
 843
 844 sub mail_zone_after () {
 845     if ($zone_warnings{$zone}) {
 846         push @m_fail, $m_time;
 847         progress(-1,"failed - $zone_warnings{$zone} warnings");
 848     } else {
 849         push @m_ok, $m_time;
 850         $m_lastok= $m_time;
 851         progress(-1,"everything is fine");
 852     }
 853     close $progress_fh or die "$quis: close ${m_base}_history: $!\n";
 854     $progress_fh= $warn_fh= $stderr_fh;
 855
 856     if ($domail =~ m/^final/) {
 857         if (100*@m_fail <= $$cfg{'mailmwarn'}*(@m_fail + @m_ok)) {
 858             printf " %-40s ok\n", $zone or die "$quis: mail ok report: $!\n";
 859         } elsif (zone_style('@',0)) {
 860             printf " %-40s mail suppressed\n", $zone
 861                 or die "$quis: mail suppress report: $!\n";
 862         } else {
 863             mail_zone_mail();
 864         }
 865     } else {
 866         printf " %-40s %d warns. OK %s Fail %s\n",
 867             $zone,
 868             defined $zone_warnings{$zone} ? $zone_warnings{$zone} : 0,
 869             join(',', map { $_ - $m_time } @m_ok),
 870             join(',', map { $_ - $m_time } @m_fail)
 871                 or die "$quis: checking progress report: $!\n";
 872     }
 873
 874     @m_fail= @m_ok= ('','')
 875         if $domail =~ m/^final/;
 876
 877     printf $m_info "%s %s %s %s \n",
 878         $m_time, $m_lastok, join(':',@m_ok), join(':',@m_fail)
 879             or die "$quis: write new ${m_base}_info: $!\n";
 880     $m_info->close or die "$quis: close new ${m_base}_info: $!\n";
 881     rename "${m_base}_info.tmp", "${m_base}_info"
 882         or die "$quis: install new ${m_base}_info: $!\n";
 883     $m_lock->close;
 884 }
 885
 886
 887 sub pmail ($) {
 888     print $m_m $_[0]
 889         or die "$quis: write ${m_base}_mail: $!\n";
 890 }
 891 sub ptime ($) {
 892     my ($time) = @_;
 893     return gmtime($time)." GMT ($time)";
 894 }
 895
 896 sub mail_zone_mail () {
 897     my ($log, $zone_to, $zterr, $c, $r, $t, @soas);
 898     $m_m= new IO::File "${m_base}_mail", 'w', 0666
 899         or die "$quis: create ${m_base}_mail: $!\n";
 900     $zone_to=''; $zterr='';
 901     if (!zone_style("\$", $$cfg{'s'} !~ m/[ps]/)) {
 902         eval {
 903             ($r,@soas)= lookup($zone,'soa','0','problem-addr');
 904             @soas==1 or die "multiple soas\n";
 905             $soas[0] =~ m/^\S+ (\S.*\@\S+) [0-9 ]+$/ or
 906                 die "bad soa \`$_'\n";
 907             $zone_to= $1;
 908         };
 909         $zterr= $@;
 910         $zterr =~ s/\n$//;
 911     }
 912     pmail <<END
 913 From: zone checker <$$cfg{'admin'}>
 914 Subject: $zone - configuration problems report
 915 END
 916 ;
 917     pmail("To: ");
 918     pmail("(testing!) ") if $domail ne 'final';
 919     pmail("SOA MNAME for $zone <$zone_to>\nCC: ") if length($zone_to);
 920     pmail($$cfg{'admin'}."\n\n");
 921     pmail <<END
 922 You are receiving this mail because your email address is listed
 923 in the SOA (Start Of Authority) record for $zone
 924 in the DNS, which means you are supposedly the DNS administrator
 925 responsible for this zone.  This report is generated automatically
 926 on behalf of $$cfg{'admin'}, who
 927 is the administrator for a server for the zone.  Please contact
 928 them if you have any problem with this report.
 929
 930 END
 931 if length $zone_to;
 932     pmail <<END
 933 Sent to $$cfg{'admin'} since SOA MNAME unavailable:
 934 $zterr
 935
 936 END
 937 if length $zterr;
 938     pmail <<END
 939 The zone has had configuration errors or persistent operational
 940 problems during recent checks.  See the logs below for details.
 941
 942 Recent check history for $zone:
 943 END
 944 ;
 945     if ($m_lastok ne '-') {
 946         pmail(" Last seen to be fine: ".ptime($m_lastok)."\n");
 947     } else {
 948         pmail(" No record of this zone ever being fine.\n");
 949     }
 950     for $t (@m_fail) {
 951         pmail(" Zone had problems at: ".ptime($t)."\n");
 952     }
 953     for $t (@m_ok) {
 954         pmail(" Everything in order at: ".ptime($t)."\n");
 955     }
 956     pmail("\n");
 957     $log= new IO::File "${m_base}_history",'r'
 958         or die "$quis: reopen ${m_base}_history: $!";
 959     undef $/;
 960     pmail($log->getline);
 961     $/= "\n";
 962     (!$log->error and $log->close)
 963         or die "$quis: reread or close ${m_base}_log: $!\n";
 964     $log->eof or die;
 965     $m_m->close or die "$quis: close ${m_base}_mail: $!\n";
 966     $m_m= new IO::File "${m_base}_mail"
 967         or die "$quis: reopen ${m_base}_mail: $!";
 968
 969     defined($c= fork) or die "$quis: fork for mail: $!\n";
 970     if (!$c) {
 971         defined dup2($m_m->fileno, 0)
 972             or die "$quis - sendmail: dup for stdin: $!\n";
 973         exec (qw(/usr/sbin/sendmail -odb -oee -oi),
 974               ($domail eq 'final' ? '-t' : $$cfg{'admin'}));
 975         die "$quis - sendmail: exec: $!\n";
 976     }
 977     $m_m->close;
 978     $!=0; $r= waitpid $c,0;
 979     $r == $c or die "$quis: waitpid sendmail ($c): $r $!";
 980     $? and warn "$quis: sendmail failed: $?\n";
 981
 982     printf " %-40s %s\n", $zone,
 983         length $zone_to ? $zone_to : 'reporting to admin'
 984             or die "$quis: write mailing report: $!\n";
 985 }
 986
 987 #-------------------- outputting
 988
 989 sub zone_output () {
 990     my ($o,$m);
 991
 992     $o= "zone \"$zone\" {\n";
 993     if ($$cfg{'s'} =~ m/p/) {
 994         $o.= "    type master;\n";
 995     } else {
 996         $o.= "    type slave;\n".
 997              "    masters {\n";
 998         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 999         $o.= "    };\n";
1000     }
1001     $o.= "    file \"$$cfg{'file'}\";\n";
1002     $o.= "};\n";
1003     return $o;
1004 }
1005
1006 sub output_files () {
1007     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
1008
1009     foreach $ofn (keys %output_contents) {
1010         $fn= $ofn; $mfn= "output file $fn";
1011         for (;;) {
1012             if (!lstat $fn) {
1013                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
1014                 $maxmode= 0666;
1015                 last;
1016             } elsif (-f _) {
1017                 $maxmode= (stat _)[2];
1018                 last;
1019             } elsif (-l _) {
1020                 defined($l= readlink $fn)
1021                     or die "$quis: readlink $mfn:\n $!\n";
1022                 $dir= $fn =~ m,^.*/, ? $& : './';
1023                 $fn= "$dir$l" unless $l =~ m,^/,;
1024                 $mfn= "output file $fn (symlink target of $ofn)";
1025             } else {
1026                 die "$quis: output file $mfn exists but is not a file".
1027                     " (or symlink to one)";
1028             }
1029         }
1030         unlink "$fn.new" or $! == &ENOENT or
1031             die "$quis: cannot clear out old .new version of $mfn:\n $!";
1032         $h= new IO::File "$fn.new",'w',$maxmode
1033             or die("$quis: create .new version of $mfn:\n $!");
1034         print $h
1035             "# generated by $quis, do not edit\n",
1036             $output_contents{$ofn}
1037             or die "$quis: write data to .new version of $mfn:\n $!";
1038         $h->close
1039             or die "$quis: close .new version of $mfn:\n $!";
1040         push @to_install, $fn,$mfn;
1041     }
1042
1043     while (($fn,$mfn, @to_install) = @to_install) {
1044         rename "$fn.new",$fn
1045             or die "$quis: install new version of $mfn:\n $!";
1046     }
1047 }
1048
1049 #-------------------- general utilities
1050
1051 sub debug_dump ($) {
1052     my ($vn);
1053     return unless $debug>1;
1054     local $Data::Dumper::Terse=1;
1055     foreach $vn (split /\s+/, $_[0]) {
1056         print "$vn := ", eval "Dumper(\\$vn)";
1057     }
1058 }
1059
1060 sub debug_trace ($) {
1061     return unless $debug;
1062     print "D $_[0]\n";
1063 }
1064
1065 sub has_suffix_of ($$) {
1066     my ($whole,$suffix) = @_;
1067     debug_trace("has_suffix_of $whole $suffix");
1068     return 0 if length $whole < length $suffix;
1069     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
1070     debug_trace("has_suffix_of $whole $suffix YES");
1071     return 1;
1072 }
1073
1074 sub lookup ($$$$) {
1075     my ($domain,$type,$okrcodes,$w) = @_;
1076     my ($c,$h,@result);
1077     debug_trace("lookup ==> (->$okrcodes) $domain $type");
1078     $h= new IO::Handle;
1079
1080     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
1081     if (!$c) {
1082         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
1083              '-',"$domain";
1084         die "$quis: exec adnshost:\n $!\n";
1085     }
1086     @result= $h->getlines();
1087     $h->error and die "$quis: read from adnshost:\n $!\n";
1088     chomp @result;
1089     $!=0; $h->close;
1090     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
1091         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
1092     debug_trace("lookup <== $? @result");
1093     return ($?,@result);
1094 }
1095
1096 sub dig (&$$$) {
1097     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
1098     # also pseudo-rr with type `flags:'
1099     my ($h,$inmid,$irdata,$c,$digwhy);
1100     local ($_);
1101
1102     debug_trace("dig ==> \@$qaddr $qowner $qtype");
1103
1104     $h= new IO::Handle;
1105     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
1106     if (!$c) {
1107         open STDERR, ">&STDOUT" or die $!;
1108         exec ('dig',
1109               '+nodef','+nosea','+nodebug','+norecurse',
1110               "\@$qaddr",'-t',$qtype,$qowner);
1111         die "$quis: exec dig:\n $!\n";
1112     }
1113     $inmid='';
1114     for (;;) {
1115         if (!defined($_= $h->getline())) {
1116             $h->error() and die "$quis: read from dig:\n $!\n";
1117             last;
1118         }
1119         chomp;
1120         if (length $inmid) {
1121             s/^\s+/ / or die "$inmid // $_ ?";
1122             s/\;.*$//;
1123             $_= $inmid.$_;
1124             $inmid='';
1125             s/$/ \(/ unless s/\s*\)\s*$//;
1126         }
1127         if (s/\s*\(\s*$//) { $inmid= $_; next; }
1128         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
1129         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
1130             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
1131             debug_trace("dig  f: $dig_rdata");
1132             &$eachrr;
1133         } elsif (m/^\;/) {
1134         } elsif (!m/\S/) {
1135         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
1136             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
1137             if ($dig_type eq 'a') {
1138                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
1139                 $dig_rdata= $&;
1140             } elsif ($dig_type eq 'ns') {
1141                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
1142                 $dig_rdata= domain_canon($irdata,$digwhy);
1143             } elsif ($dig_type eq 'soa') {
1144                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
1145                     or die "bad SOA $irdata ?";
1146                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
1147             } else {
1148                 debug_trace("ignoring uknown RR type $dig_type");
1149                 next;
1150             }
1151             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
1152             &$eachrr;
1153         } else {
1154             debug_trace("ignoring unknown dig output $_");
1155         }
1156     }
1157     $h->close;
1158     debug_trace("dig <== gave $?");
1159 }
1160
1161 sub domain_canon ($$) {
1162     my ($i,$w) = @_;
1163     $i =~ s/(.)\.$/$1/;
1164     return '.' if $i eq '.';
1165     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
1166     return lc $i;
1167 }