chiark / gitweb /
694ab940adff6fdf84f0fa975127a2dd8d2beec5
[chiark-utils.git] / scripts / named-conf
1 #!/usr/bin/perl -w
2
3 use strict;
4 use IO::File;
5 use Data::Dumper;
6
7 use vars qw($quis
8             $mode $doall
9             $etcfile $where
10             $debug $needglue $localonly $verbosity);
11
12 $quis= $0; $quis =~ s,.*/,,;
13
14 $mode= '';
15 $doall= 0;
16 $etcfile= "/etc/bind/chiark-conf-gen.zones";
17 $where= '<built-in>';
18 $debug= 0;
19 $needglue= 2;
20 $localonly= 0;
21 $verbosity= 1;
22
23 use vars qw($dig_owner $dig_type $dig_rdata);
24
25 while (@ARGV && $ARGV[0] =~ m/^\-/) {
26     $_= shift @ARGV;
27     if (s/^\-\-//) {
28         last if m/^$/;
29         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
30         elsif (m/^all$/) { $doall=1; }
31         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
32         elsif (m/^glueless$/) { $needglue--; }
33         elsif (m/^localonly$/) { $localonly=1; }
34         elsif (m/^quiet$/) { $verbosity=0; }
35         elsif (m/^verbose$/) { $verbosity=2; }
36         else { usageerr("unknown option --$_"); }
37     } else {
38         s/^\-//;
39         last if m/^$/;
40         while (m/^./) {
41             if (s/^[ynf]//) { $mode=$&; }
42             elsif (s/^A//) { $doall=1; }
43             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
44             elsif (s/^D//) { $debug++; }
45             elsif (s/^g//) { $needglue--; }
46             elsif (s/^l//) { $localonly=1; }
47             elsif (s/^q//) { $verbosity=0; }
48             elsif (s/^v//) { $verbosity=2; }
49             else { usageerr("unknown option -$&"); }
50         }
51     }
52 }
53
54 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
55 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
56
57 usageerr("-g may be specified at most twice") if $needglue<0;
58 usageerr("-D may be specified at most twice") if $debug>2;
59 usageerr("must specify either -f|-y|-n or zones (and not both)")
60     if !!$mode == !!@ARGV;
61
62 sub usageerr ($) {
63     die
64 "$_[0]
65 usage: named-conf-regen [-rvq] -f|-y|-n|<zone>...\n".
66 "operation modes:\n".
67 " -f --force   install without checking\n".
68 " -y --yes     check and install\n".
69 " -n --no      check only\n".
70 "additional options:\n".
71 " -q --quiet   no output for OK zones\n".
72 " -v --verbose extra verbose\n";
73 }
74
75 cfg_fail("config filename $etcfile should have been absolute path of a file")
76     unless $etcfile =~ m,^/, && $etcfile !~ m,/$,;
77
78 use vars qw($default_dir);
79 $default_dir= $etcfile;
80 $default_dir =~ s,/[^/]+$,,;
81
82 use vars qw($slave_dir $slave_prefix $slave_suffix);
83 $slave_dir= 'slave';
84 $slave_prefix= '';
85 $slave_suffix= '';
86
87 use vars qw(@self_ns @self_soa @self_addr);
88 @self_ns= @self_soa= @self_addr= ();
89
90 use vars qw(%zone_cfg @zone_cfg_list);
91 %zone_cfg= ();
92 @zone_cfg_list= ();
93
94 use vars qw($output $default_output %output_contents);
95 $output= '';
96 $default_output= '';
97 %output_contents= ();
98
99 use vars qw($check $install);
100 $check= $mode !~ m/^f/;
101 $install= $mode =~ m/^[yf]/;
102
103 read_config($etcfile);
104 debug_dump('@zone_cfg_list %zone_cfg');
105 process_zones($mode ? @zone_cfg_list : @ARGV);
106 debug_dump('%output_contents');
107
108 exit 0;
109
110 #-------------------- configuration reading
111
112 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
113
114 sub read_config ($) {
115     my ($if) = @_;
116     my ($fh,$z,@self, $mod,$dir,$prefix,$suffix,$lprefix,$lsuffix);
117     local ($_);
118
119     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
120     $before= '';
121     for (;;) {
122         if (!defined($_= <$fh>)) {
123             cfg_fail("read config file $if:\n $!") if $fh->error();
124             last;
125         }
126         s/^\s+//; chomp; s/\s+$//;
127         if (m/\\$/) { $before.= $_; next; }
128         $_= $before.$_;
129         $before= '';
130         $where= "$if:$.";
131         next if m/^\#/;
132         last if m/^end$/;
133         next unless m/\S/;
134         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
135             @self= split /\s+/, $2;
136             @self_ns= @self if $1 ne '-soa';
137             @self_soa= @self if $1 ne '-ns';
138         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
139             @self_addr= split /\s+/, $1;
140         } elsif (m/^primary\-dir([*?]?)\s+(\S+)((?:\s+(\S+))?:\s+(\S+))?$/) {
141             ($mod, $dir, $prefix, $suffix) = ($1,qualify($2),$3,$4);
142             $suffix= '_db' if !defined $suffix;
143             $prefix= '' if !defined $prefix;
144             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
145             $lprefix= length $prefix; $lsuffix= length $suffix;
146             while (defined($_= readdir D)) {
147                 next if m/^\./ && !$lprefix;
148                 next unless length > $lprefix+$lsuffix;
149                 next unless substr($_,0,$lprefix) eq $prefix;
150                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
151                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
152                 zone_conf($z,'primary','p',$mod,"$dir/$_");
153             }
154             closedir D or cfg_fail("close primary-dir $dir:\n $!");
155         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
156             zone_conf($2,'primary','p',$1,qualify($3));
157         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
158             zone_conf($2,'published','s',$1,'',$3);
159         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
160             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
161         } elsif (m/^slave\-dir\s+(\S+)((?:\s+(\S+))?:\s+(\S+))?$/) {
162             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
163         } elsif (m/^output\s+bind8\+(\S+)$/) {
164             cfg_fail("default output may not apply to only some zones")
165                 if @zone_cfg_list && length $default_output;
166             set_output(qualify($1));
167         } elsif (m/^include\s+(\S+)$/) {
168             read_config($1);
169         } else {
170             cfg_fail("unknown configuration directive".
171                      " or incorrect syntax or arguments");
172         }
173     }
174     $fh->close or cfg_fail("close config file $if:\n $!");
175 }
176
177 sub qualify ($) {
178     my ($i) = @_;
179     $i= "$default_dir/$i" unless $i =~ m,^/,;
180     return $i;
181 }
182
183 sub zone_conf ($$$$$@) {
184     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
185     my ($sfx,$aref);
186     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
187         unless length $file;
188     if (!length $output) {
189         $default_output= qualify('chiark-conf-gen.bind8')
190             unless length $default_output;
191         set_output($default_output);
192     }
193     cfg_fail("redefined zone $zone") if exists $zone_cfg{$zone};
194     $zone_cfg{$zone}{'file'}= $file;
195     $zone_cfg{$zone}{'style_p'}= $style.$mod;
196     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
197     $zone_cfg{$zone}{'servers'}= [ @servers ];
198     foreach $sfx (qw(soa ns addr)) {
199         { no strict 'refs'; $aref= [ @{ "self_$sfx" } ]; }
200         @$aref or cfg_fail("failed to specify self-$sfx before zone");
201         $zone_cfg{$zone}{"self_$sfx"}= $aref;
202     }
203     $zone_cfg{$zone}{'output'}= $output;
204     push @zone_cfg_list, $zone;
205 }
206
207 sub set_output($) {
208     my ($newout) = @_;
209     $output= $newout;
210     $output_contents{$output}= '';
211 }
212
213
214 #-------------------- checking
215
216 use vars qw($zone $cfg $warnings);
217 $warnings= 0;
218
219 sub progress ($) {
220     return if !$verbosity;
221     print "$_[0]\n";
222 }
223
224 sub verbose ($) {
225     return if $verbosity<2;
226     print "    $_[0]\n";
227 }
228
229 sub process_zones (@) {
230     my (@zones) = @_;
231     local ($zone,$cfg);
232
233     foreach $zone (@zones) {
234         $cfg= $zone_cfg{$zone} || {
235             'style_p' => 'foreign',
236             's' => 'f',
237             'servers' => [ ],
238             };
239         progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
240         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
241             eval {
242                 if ($localonly && $cfg->{'s'} =~ m/f/) {
243                     zone_warning("foreign zone specified with -l");
244                 } elsif ($cfg->{'s'} =~ m/\*/ ||
245                          ($localonly && $cfg->{'s'} !~ m/p/)) {
246                     zone_check_local();
247                 } else {
248                     zone_check_full();
249                 }
250             };
251             zone_warning("checks failed: $@") if length $@;
252         }
253         zone_output() if $install;
254     }
255     print STDERR "$quis: $warnings warnings\n" or die $!
256         if $warnings;
257 }
258
259 sub zone_warning ($) {
260     my ($w) = @_;
261     $w =~ s/\n$//;
262     $w =~ s,\n, // ,g;
263     print STDERR "$zone: warning: $w\n" or die $!;
264     $warnings++;
265 }
266
267 sub zone_warnmore ($) {
268     print STDERR " $_[0]\n" or die $!;
269 }
270
271 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
272 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
273 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
274 use vars qw(%soas);  # $soa{"$origin $serial"} = [ $whosaidandwhy ]
275 use vars qw(%addr_is_ok %warned_glueless %warned_mynameaddr);
276 use vars qw($delg_to_us);
277 use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
278 use vars qw(@to_check_soa); # ($addr,$whyask, ...)
279
280 sub zone_check_full () {
281     zone_reset();
282     zone_investigate();
283     zone_consistency();
284     zone_servers_ok();
285 }
286
287 sub zone_reset() {
288     %delgs= %auths= %glue= %soas=
289         %warned_glueless= %warned_mynameaddr=
290             %addr_is_ok= ();
291     $delg_to_us= 0;
292     @to_check= @to_check_soa= ();
293 }
294
295 sub zone_investigate() {
296     my ($super_zone, @super_nsnames,
297         $super_ns, @super_ns_addrs, $s, $wa, $is_auth,
298         %nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);
299
300     $super_zone= $zone;
301     for (;;) {
302         debug_trace("zone $zone superzone $super_zone");
303         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
304         ($rcode,@super_nsnames)= lookup($super_zone,'ns-','06');
305         last if !$rcode;
306     }
307     for $super_ns (@super_nsnames) {
308         $super_ns= lc $super_ns;
309         ($rcode,@super_ns_addrs)= lookup($super_ns,'a','0');
310         foreach $addr (@super_ns_addrs) {
311             push @to_check,
312                  $addr,
313                  "$super_ns, server for $super_zone",
314                  0, 0;
315         }
316     }
317     for (;;) {
318         # We do these in order so that we always do NS RRset checks on
319         # nameservers that came from other NS RRsets first; otherwise
320         # we might set nsrrset_checked due to a glueless_ok check,
321         # and then not check for gluefulness later.
322         debug_dump('@to_check @to_check_soa');
323         if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
324             push @to_check_soa, $addr, $wa if $is_auth;
325             next if $nsrrset_checked{$addr}++;
326             zone_check_nsrrset($addr, "[$addr] $wa",
327                                $is_auth, $glueless_ok);
328         } elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
329             next if $soa_checked{$addr}++;
330             zone_check_soa($addr,"[$addr] $wa","[$addr] NS");
331         } else {
332             last;
333         }
334     }
335 }
336
337 sub zone_check_nsrrset ($$$$) {
338     my ($uaddr,$ww, $is_auth, $glueless_ok) = @_;
339     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn);
340     verbose("checking delegation by $ww");
341     dig(sub {
342         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
343             $s2g{lc $dig_rdata} = [ ];
344         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
345             $wwn= "in glue from $ww";
346             push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
347             zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
348             push @{ $s2g{$dig_owner} }, $dig_rdata;
349         }
350     },
351              $zone,'ns',$uaddr);
352     if (!%s2g) { zone_warning("unable to find NS RRset at $ww"); return; }
353     elsif (keys %s2g == 1) { zone_warning("only one nameserver at $ww"); }
354     @s= sort keys %s2g;
355     foreach $s (@s) {
356         @glue= @{ $s2g{$s} };
357         if (!@glue) {
358             zone_warning("glueless NS $s,".
359                          ($needglue<=1 ? " (eg)" : "").
360                          " from $ww")
361                 unless $glueless_ok || !$needglue ||
362                        ($needglue<=1 && $warned_glueless{$s}++);
363             next;
364         }
365         $glue= join ' ', sort @glue;
366         push @{ $glue{$s}{$glue} }, $ww;
367     }
368     $s= join ' ', @s;
369     $delgs_or_auths= $is_auth ? \%auths : \%delgs;
370     push @{ $delgs_or_auths->{$s} }, $ww;
371 }
372
373 sub zone_server_addr ($$$$$) {
374     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
375     $addr_is_ok{$addr}= "$name ($wwq)"
376         if $is_soa || $cfg->{'s'} =~ m/u/;
377     zone_warning("configured as stealth but we [$addr]".
378                  " are published ($name $wwq)")
379         if $cfg->{'s'} =~ m/u/ && grep { $_ eq $addr } @self_addr;
380
381     my ($name_is_self, $addr_is_self);
382     $name_is_self= grep { $_ eq $name }
383         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
384     $addr_is_self= grep { $_ eq $addr }
385         @{ $cfg->{'self_addr'} };
386     if ($name_is_self && !$addr_is_self) {
387         zone_warning("our name $name with wrong address [$addr], (eg) $ww")
388             unless $warned_mynameaddr{$name}{$addr}++;
389     } elsif (!$name_is_self && $addr_is_self) {
390         zone_warning(($is_soa ? "SOA ORIGIN maps to" : "allegedly served by").
391                      " us [$addr] with wrong name $name, (eg) $ww")
392             unless $warned_mynameaddr{$name}{$addr}++;
393     }
394     $delg_to_us=1 if $name_is_self;
395 }
396
397 sub zone_check_soa ($$$) {
398     my ($uaddr,$ww,$wwq) = @_;
399     my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$wwn);
400     verbose("checking service at $wwq");
401     $lame= 'dead or lame';
402     dig(sub {
403         if ($dig_type eq 'flags:') {
404             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
405         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
406             die "several SOAs ? $ww" if defined $origin;
407             $got= $dig_rdata;
408             $got =~ m/^(\S+) \d+/ or die "$got ?";
409             $origin= $1;
410         }
411     },
412              $zone,'soa',$uaddr);
413     $lame= 'broken' if !$lame && !defined $origin;
414     if ($lame) { zone_warning("$lame server $ww"); return; }
415     push @{ $soas{$got} }, $ww;
416     ($rcode,@soa_addrs)= lookup($origin,'a','0');
417     foreach $soa_addr (@soa_addrs) {
418         $wwn= "SOA ORIGIN from $ww";
419         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
420         push @to_check, $soa_addr, "$origin, $wwn";
421     }
422 }
423
424 sub zone_consistency() {
425     my ($d, $org_ser, $origin, $a, $h, $self_soa);
426     zone_consistency_set('delegations',\%delgs);
427     foreach $d (keys %delgs) { delete $auths{$d}; }
428     zone_consistency_set('zone nameserver rrset',\%auths);
429     foreach $h (keys %glue) {
430         zone_consistency_set("glue for $h", $glue{$h});
431     }
432     zone_consistency_set("SOA ORIGIN and SERIAL",\%soas);
433     $self_soa= $cfg->{'self_soa'};
434     if ($cfg->{'s'} =~ m/p/) {
435         foreach $org_ser (keys %soas) {
436             $org_ser =~ m/^(\S+) \d+$/ or die "$org_ser ?";
437             $origin= $1;
438             next if grep { $_ eq $origin } @$self_soa;
439             zone_warning("SOA ORIGIN $origin is not our name (@$self_soa),".
440                          " eg from ".($soas{$org_ser}[0]));
441         }
442     }
443 }
444
445 sub zone_servers_ok () {
446     my ($showok);
447     if (%addr_is_ok) {
448         $showok= 0;
449         foreach $a (@{ $cfg->{'servers'} }) {
450             next if exists $addr_is_ok{$a};
451             zone_warning("we slave from $a"); $showok=1;
452         }
453         if ($showok) {
454             foreach $a (keys %addr_is_ok) {
455                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
456             }
457         }
458     }
459     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
460         zone_warnmore("we are supposedly published secondary,".
461                       " but not listed as a nameserver");
462     }
463 }
464
465 sub zone_consistency_set ($%) {
466     my ($msg,$set) = @_;
467     my ($d,$o);
468     if (keys(%$set) > 1) {
469         zone_warning("inconsistent $msg:");
470         foreach $d (keys %$set) {
471             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
472         }
473     }
474 }
475
476 sub zone_check_local () {
477     zone_reset();
478     zone_servers_simplefind();
479     zone_servers_ok();
480 }
481
482 sub zone_servers_simplefind () {
483     my ($rcode,@nsnames,$ns,@soas,$origin);
484
485     ($rcode,@nsnames)= lookup($zone,'ns-','0');
486     foreach $ns (@nsnames) { zone_server_simple($ns,'NS',0); }
487
488     ($rcode,@soas)= lookup($zone,'soa','0');
489     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
490     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
491     zone_server_simple(domain_canon($1),'SOA',1);
492 }
493
494 sub zone_server_simple ($$$) {
495     my ($name,$ww,$is_soa) = @_;
496     my ($rcode,@addrs,$addr);
497     ($rcode,@addrs)= lookup($name,'a','0');
498     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
499 }
500
501 #-------------------- outputting
502
503 sub zone_output () {
504     $output_contents{$$cfg{'output'}}.=
505         sprintf(<<'END',
506 zone "%s" {
507     type %s;
508     file "%s";
509 };
510 END
511                 $zone,
512                 $$cfg{'s'} =~ m/p/ ? 'master' : 'slave',
513                 $$cfg{'file'});
514 }
515
516
517 #-------------------- general utilities
518
519 sub debug_dump ($) {
520     my ($vn);
521     return unless $debug>1;
522     local $Data::Dumper::Terse=1;
523     foreach $vn (split /\s+/, $_[0]) {
524         print "$vn := ", eval "Dumper(\\$vn)";
525     }
526 }
527
528 sub debug_trace ($) {
529     return unless $debug;
530     print "D $_[0]\n";
531 }
532
533 sub lookup ($$$) {
534     my ($domain,$type,$okrcodes) = @_;
535     my ($c,$h,@result);
536     debug_trace("lookup ==> (->$okrcodes) $domain $type");
537     $h= new IO::Handle;
538
539     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
540     if (!$c) {
541         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
542              '-',"$domain.";
543         die "$quis: exec adnshost:\n $!\n";
544     }
545     @result= $h->getlines();
546     $h->error and die "$quis: read from adnshost:\n $!\n";
547     chomp @result;
548     $!=0; $h->close;
549     die "$quis: lookup -t$type $domain $okrcodes failed $? $!\n"
550         if $! or $?>6 or index($okrcodes,$?)<0;
551     debug_trace("lookup <== $? @result");
552     return ($?,@result);
553 }
554
555
556 sub dig (&$$$) {
557     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
558     # also pseudo-rr with type `flags:'
559     my ($h,$inmid,$irdata,$c);
560     local ($_);
561
562     debug_trace("dig ==> \@$qaddr $qowner $qtype");
563
564     $h= new IO::Handle;
565     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
566     if (!$c) {
567         open STDERR, ">&STDOUT" or die $!;
568         exec ('dig',
569               '+nodef','+nosea','+nodebug','+norecurse',
570               "\@$qaddr",'-t',$qtype,$qowner);
571         die "$quis: exec dig:\n $!\n";
572     }
573     $inmid='';
574     for (;;) {
575         if (!defined($_= $h->getline())) {
576             $h->error() and die "$quis: read from dig:\n $!\n";
577             last;
578         }
579         chomp;
580         if (length $inmid) {
581             s/^\s+/ / or die "$inmid // $_ ?";
582             s/\;.*$//;
583             $_= $inmid.$_;
584             $inmid='';
585             s/$/ \(/ unless s/\s*\)\s*$//;
586         }
587         if (s/\s*\(\s*$//) { $inmid= $_; next; }
588         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
589             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
590             debug_trace("dig  f: $dig_rdata");
591             &$eachrr;
592         } elsif (m/^\;/) {
593         } elsif (!m/\S/) {
594         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
595             $dig_owner=domain_canon($1); $dig_type=lc $2; $irdata=$3;
596             if ($dig_type eq 'a') {
597                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
598                 $dig_rdata= $&;
599             } elsif ($dig_type eq 'ns') {
600                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
601                 $dig_rdata= domain_canon($irdata);
602             } elsif ($dig_type eq 'soa') {
603                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
604                     or die "bad SOA $irdata ?";
605                 $dig_rdata= domain_canon($1).' '.$2;
606             } else {
607                 debug_trace("ignoring uknown RR type $dig_type");
608                 next;
609             }
610             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
611             &$eachrr;
612         } else {
613             debug_trace("ignoring unknown dig output $_");
614         }
615     }
616     $h->close;
617     debug_trace("dig <== gave $?");
618 }
619
620 sub domain_canon ($) {
621     local ($_) = @_;
622     s/(.)\.$/$1/;
623     die "domain $_ ?" unless m/^[0-9a-z]/i;
624     return lc $_;
625 }