scripts/named-conf

   1 #!/usr/bin/perl -w
   2 # This is chiark-named-conf, which is Copyright 2002 Ian Jackson.
   3 #
   4 # chiark-named-conf and its manpage are free software; you can
   5 # redistribute it and/or modify them under the terms of the GNU
   6 # General Public License as published by the Free Software Foundation;
   7 # either version 2, or (at your option) any later version.
   8 #
   9 # chiark-named-conf and its manpage are distributed in the hope that
  10 # it will be useful, but WITHOUT ANY WARRANTY; without even the
  11 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  12 # PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with this program; if not, write to the Free Software Foundation, Inc.,
  16 # 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17
  18 use strict;
  19 use IO::File;
  20 use Data::Dumper;
  21 use POSIX;
  22 use Fcntl qw(:DEFAULT :flock);
  23
  24 # bastard Perl wants me to do this now !
  25 sub loarg();
  26 sub soarg();
  27 sub usageerr ($);
  28 sub cfg_fail ($);
  29 sub read_config ($);
  30 sub qualify ($);
  31 sub bad_modifiers ($);
  32 sub zone_conf ($$$$$@);
  33 sub set_output($);
  34 sub progress ($$);
  35 sub verbose ($);
  36 sub process_zones (@);
  37 sub zone_warning ($$);
  38 sub zone_warnmore ($);
  39 sub zone_check_full ();
  40 sub zone_reset();
  41 sub zone_investigate();
  42 sub zone_check_nsrrset ($$$$);
  43 sub zone_ns_name ($$);
  44 sub zone_server_queue ($$$$$);
  45 sub zone_server_addr ($$$$$);
  46 sub zone_check_soa ($$$$);
  47 sub zone_consistency();
  48 sub zone_servers_ok ();
  49 sub zone_consistency_set ($%);
  50 sub zone_check_local ();
  51 sub zone_servers_simplefind ();
  52 sub zone_server_simple ($$$);
  53 sub zone_style ($$);
  54 sub mail_zone_before ();
  55 sub mail_zone_after ();
  56 sub pmail ($);
  57 sub ptime ($);
  58 sub mail_zone_mail ();
  59 sub zone_output ();
  60 sub output_files ();
  61 sub debug_dump ($);
  62 sub debug_trace ($);
  63 sub has_suffix_of ($$);
  64 sub lookup ($$$$);
  65 sub dig (&$$$);
  66 sub domain_canon ($$);
  67
  68 use vars qw($quis $stdout_fh $stderr_fh
  69             $mode $doall $domail
  70             $etcfile $where
  71             $debug $needglue $localonly $repeat $verbosity
  72             $admin $mail_state_dir $mail_max_warnfreq
  73             $progress_fh $warn_fh $modifiers
  74             %group2modcmd %group2used);
  75
  76 $quis= $0; $quis =~ s,.*/,,;
  77
  78 $mode= '';
  79 $doall= 0;
  80 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  81 $where= '<built-in>';
  82 $debug= 0;
  83 $needglue= 1;
  84 $localonly= 0;
  85 $verbosity= 2;
  86 $admin=''; $mail_state_dir=''; $mail_max_warnfreq= 50;
  87 $repeat= 0;
  88 $domail= '';
  89 $modifiers= '';
  90 $group2modcmd{'foreign'}= '$!*@?';
  91 $group2used{'foreign'}= 1;
  92
  93 ($progress_fh= $stdout_fh= new_from_fd IO::Handle(1,'w') and
  94  $warn_fh= $stderr_fh = new_from_fd IO::Handle(2,'w'))
  95     or die "$quis: setup standard filehandles: $!\n";
  96
  97 use vars qw($dig_owner $dig_type $dig_rdata);
  98
  99 while (@ARGV && $ARGV[0] =~ m/^\-/) {
 100     $_= shift @ARGV;
 101     if (s/^\-\-//) {
 102         last if m/^$/;
 103         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; $domail=''; }
 104         elsif (m/^nothing$/) { $mode= 'x'; $domail=''; }
 105         elsif (m/^mail\-(first|middle|final|final\-test)$/) {
 106             $mode='n';
 107             $domail=$1;
 108         }
 109         elsif (m/^all$/) { $doall=1; }
 110         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
 111         elsif (m/^glueless$/) { $needglue=0; }
 112         elsif (m/^localonly$/) { $localonly=1; }
 113         elsif (m/^quiet$/) { $verbosity--; }
 114         elsif (m/^repeat$/) { $repeat=1; }
 115         elsif (m/^verbose$/) { $verbosity++; }
 116         else { usageerr("unknown option --$_"); }
 117     } else {
 118         s/^\-//;
 119         last if m/^$/;
 120         while (m/^./) {
 121             if (s/^[ynf]//) { $mode=$&; $domail=''; }
 122             elsif (s/^A//) { $doall=1; }
 123             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
 124             elsif (s/^D//) { $debug++; }
 125             elsif (s/^g//) { $needglue=0; }
 126             elsif (s/^l//) { $localonly=1; }
 127             elsif (s/^m(\w+)(\W+)$//) {
 128                 my ($g,$m) = ($1,$2);
 129                 $group2modcmd{$g}=$m;
 130                 usageerr("modifiers $m for group $g: $@") if bad_modifiers($m);
 131             }
 132             elsif (s/^q//) { $verbosity--; }
 133             elsif (s/^r//) { $repeat=1; }
 134             elsif (s/^v//) { $verbosity++; }
 135             else { usageerr("unknown option -$&"); }
 136         }
 137     }
 138 }
 139
 140 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
 141 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
 142
 143 usageerr("-q may be specified at most twice") if $verbosity<0;
 144 usageerr("-v may be specified at most once") if $verbosity>3;
 145 usageerr("-D may be specified at most twice") if $debug>2;
 146 usageerr("must specify either -f|-y|-n or zones (and not both)")
 147     if !!$mode == !!@ARGV && !$domail;
 148
 149 sub usageerr ($) {
 150     die <<END;
 151 $_[0]
 152
 153 usage: chiark-named-conf [options] -f|-y|-n|<zone>...
 154 operation modes:
 155  -f --force   install without checking
 156  -y --yes     check and install
 157  -n --no      check only (configured zones)
 158  --nothing    list zones only
 159  --mail-*     send mail about broken zones (see manpage)
 160  <zone> ...   check only (specified zones, even unconfigured ones)
 161 additional options:
 162  -A --all       report on zones marked ? (ones we know are broken)
 163  -D             debug $quis (does not help debug your DNS config)
 164  -g --glueless  do not warn about any glueless referrals (not recommended)
 165  -l --localonly full checks only on zones which we primary
 166  -q --quiet     no output for OK zones
 167  -r --repeat    repeat warnings for all sources of imperfect data
 168  -v --verbose   extra verbose info about each zone
 169  -C|--config <DIR/FILE  use FILE as default config and DIR as default dir
 170
 171 chiark-named-conf is Copyright 2002 Ian Jackson.  It is Free software, under
 172 the GNU General Public License, and you are welcome to change it and/or
 173 distribute copies under certain conditions.  There is ABSOLUTELY NO WARRANTY.
 174 END
 175 }
 176
 177 cfg_fail("config filename $etcfile should not be directory")
 178     if $etcfile =~ m,/$,;
 179
 180 use vars qw($default_dir);
 181 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
 182
 183 use vars qw($slave_dir $slave_prefix $slave_suffix);
 184 $slave_dir= 'slave';
 185 $slave_prefix= '';
 186 $slave_suffix= '';
 187
 188 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
 189 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
 190 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
 191
 192 use vars qw(%zone_cfg @zone_cfg_list);
 193 %zone_cfg= ();
 194 @zone_cfg_list= ();
 195
 196 use vars qw($output $default_output %output_contents);
 197 $output= '';
 198 $default_output= '';
 199 %output_contents= ();
 200
 201 use vars qw($check $install);
 202 $check= $mode !~ m/^[fx]/;
 203 $install= $mode =~ m/^[yf]/;
 204
 205 read_config($etcfile);
 206 debug_dump('@zone_cfg_list %zone_cfg');
 207 process_zones(!@ARGV ? @zone_cfg_list : @ARGV);
 208 debug_dump('%output_contents');
 209 output_files() if $install;
 210
 211 $stdout_fh->close or die "$quis: write messages to stdout: $!\n";
 212 $stderr_fh->close or die "$quis: write messages to stderr: $!\n";
 213 exit 0;
 214
 215 #-------------------- configuration reading
 216
 217 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 218
 219 sub read_config ($) {
 220     my ($if) = @_;
 221     my ($fh,$z,@self,$before,$group,
 222         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 223     local ($_);
 224
 225     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 226     $before= '';
 227     for (;;) {
 228         if (!defined($_= <$fh>)) {
 229             cfg_fail("read config file $if:\n $!") if $fh->error();
 230             last;
 231         }
 232         chomp; s/\s+$//;
 233         if (s/\\$//) { $before.= $_; next; }
 234         $_= $before.$_;
 235         $before= '';
 236         s/^\s+//;
 237         $where= "$if:$.";
 238         next if m/^\#/;
 239         last if m/^end$/;
 240         next unless m/\S/;
 241         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 242             @self= split /\s+/, $2;
 243             @self_ns= @self if $1 ne '-soa';
 244             @self_soa= @self if $1 ne '-ns';
 245         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 246             @conv_glueless= split /\s+/, $1;
 247         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 248             @self_addr= split /\s+/, $1;
 249         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 250             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 251         } elsif (m,^
 252                  primary\-dir (\W*)
 253                  \s+ (\S+)/([^/ \t]*)
 254                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 255                   )?
 256                  $,x) {
 257             ($mod, $dir, $prefix, $suffix, $subfile) =
 258                 ($1,qualify($2),$3,$4,$5);
 259             cfg_fail("modifiers $mod for directory $dir: $@")
 260                 if bad_modifiers($mod);
 261             $suffix= '' if !defined $suffix;
 262             $subfile= '' if !defined $subfile;
 263             $suffix= '_db' if !length $suffix && !length $subfile;
 264             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 265             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 266             $lprefix= length $prefix; $lsuffix= length $suffix;
 267             while (defined($_= readdir D)) {
 268                 next if m/^\./ && !$lprefix;
 269                 next unless length > $lprefix+$lsuffix;
 270                 next unless substr($_,0,$lprefix) eq $prefix;
 271                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 272                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 273                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 274                 if (!stat $zf) {
 275                     next if length $subfile && $! == &ENOENT;
 276                     cfg_fail("cannot stat zonefile $zf:\n $!");
 277                 }
 278                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 279                 zone_conf($z,'primary','p',$mod,$zf);
 280             }
 281             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 282         } elsif (m/^primary(\W*)\s+(\S+)\s+(\S+)$/) {
 283             zone_conf($2,'primary','p',$1,qualify($3));
 284         } elsif (m/^published(\W*)\s+(\S+)\s+([0-9.\t]+)$/) {
 285             zone_conf($2,'published','s',$1,'',$3);
 286         } elsif (m/^stealth(\W*)\s+(\S+)\s+([0-9. \t]+)$/) {
 287             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 288         } elsif (m/^modifiers\s+(\W+)(?:\s+(\w+))$/) {
 289             ($mod,$group) = ($1,$2);
 290             cfg_fail("modifiers $mod for group $group: $@")
 291                 if bad_modifiers($mod);
 292             if (exists $group2modcmd{$group}) {
 293                 $mod= $group2modcmd{$group};
 294                 $group2used{$group}++;
 295             }
 296             $modifiers= $mod;
 297         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 298             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 299             $slave_prefix='' if !defined $slave_prefix;
 300             $slave_suffix='' if !defined $slave_suffix;
 301         } elsif (m/^output\s+bind8\+(\S+)$/) {
 302             cfg_fail("default output may not apply to only some zones")
 303                 if @zone_cfg_list && length $default_output;
 304             set_output(qualify($1));
 305         } elsif (m/^include\s+(\S+)$/) {
 306             read_config($1);
 307         } elsif (m/^admin\s+(\S+)$/) {
 308             $admin=$1;
 309         } elsif (m/^mail\-state\-dir\s+(\S+)$/) {
 310             $mail_state_dir= $1;
 311         } elsif (m/^mail\-max\-warnfreq\s+(\d{1,3}(?:\.\d{0,5})?)$/) {
 312             cfg_fail("mail-max-warnfreq must be <=100") if $1>100;
 313             $mail_max_warnfreq= $1;
 314         } else {
 315             cfg_fail("unknown configuration directive".
 316                      " or incorrect syntax or arguments:\n".
 317                      " \`$_'");
 318         }
 319     }
 320     foreach $group (keys %group2modcmd) {
 321         next if exists $group2used{$group};
 322         cfg_fail("command line specifies modifier group $group".
 323                  " but missing in configuration file");
 324     }
 325     $fh->close or cfg_fail("close config file $if:\n $!");
 326 }
 327
 328 sub qualify ($) {
 329     my ($i) = @_;
 330     $i= "$default_dir$i" unless $i =~ m,^/,;
 331     return $i;
 332 }
 333
 334 sub bad_modifiers ($) {
 335     local ($_) = @_;
 336     if (!eval {
 337         die "bad modifier $&" if m/[^!*\$\@~?]/;
 338         die "repeated modifier $1" if m/(.).*\1/;
 339         1;
 340     }) {
 341         $@ =~ s/\n//;
 342         return 1;
 343     }
 344     return 0;
 345 }
 346
 347 sub zone_conf ($$$$$@) {
 348     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 349     my ($sfx,$aref);
 350     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 351         unless length $file;
 352     if (!length $output) {
 353         $default_output= qualify('chiark-conf-gen.bind8')
 354             unless length $default_output;
 355         set_output($default_output);
 356     }
 357     cfg_fail("redefined zone $zone\n".
 358              " earlier definition $zone_cfg{$zone}{'where'}")
 359         if exists $zone_cfg{$zone};
 360     $zone_cfg{$zone}{'where'}= $where;
 361     $zone_cfg{$zone}{'file'}= $file;
 362     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 363     $zone_cfg{$zone}{'s'}= "$sabbr $mod $modifiers";
 364     # p)rimary s)econdary u)npub f)oreign
 365     # followed by modifiers, first per-zone, then default
 366     $zone_cfg{$zone}{'servers'}= [ @servers ];
 367     if ($domail) {
 368         length $admin && length $mail_state_dir or
 369             cfg_fail("mailing but failed to specify admin".
 370                      " or mail-state-dir before zone");
 371         $zone_cfg{$zone}{'admin'}= $admin;
 372         $zone_cfg{$zone}{'maildir'}= qualify($mail_state_dir);
 373         $zone_cfg{$zone}{'mailmwarn'}= $mail_max_warnfreq;
 374     }
 375     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr conv_glueless)) {
 376         { no strict 'refs'; $aref= [ @$sfx ]; }
 377         @$aref or cfg_fail("failed to specify $sfx before zone")
 378             if $sfx =~ m/^self/;
 379         $zone_cfg{$zone}{$sfx}= $aref;
 380     }
 381     foreach $sfx (qw(self_soa self_ns)) {
 382         map { s/\*$/$zone/ } @{ $zone_cfg{$zone}{$sfx} };
 383     }
 384     $zone_cfg{$zone}{'output'}= $output;
 385     push @zone_cfg_list, $zone;
 386 }
 387
 388 sub set_output($) {
 389     my ($newout) = @_;
 390     $output= $newout;
 391     $output_contents{$output}= '';
 392 }
 393
 394 #-------------------- checking
 395
 396 use vars qw($zone $cfg $warnings %zone_warnings);
 397 $warnings= 0;
 398
 399 sub progress ($$) {
 400     my ($minv,$m) = @_;
 401     return if $verbosity < $minv;
 402     print $progress_fh "$m\n" or die "$quis: $zone: write log: $!\n";
 403 }
 404
 405 sub verbose ($) { progress(3, '    ' . $_[0]); }
 406
 407 sub process_zones (@) {
 408     my (@zones) = @_;
 409     local ($zone,$cfg);
 410
 411     foreach $zone (@zones) {
 412         $cfg= $zone_cfg{$zone} || {
 413             'style_p' => 'foreign',
 414             's' => "f $group2modcmd{'foreign'}",
 415             'servers' => [ ],
 416             };
 417
 418         mail_zone_before() or next
 419             if $domail;
 420         zone_reset();
 421         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
 422         if ($check && ($doall || !zone_style('?',0))) {
 423             eval {
 424                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 425                     zone_warning("foreign zone specified with -l",'');
 426                 } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
 427                     zone_check_local();
 428                 } else {
 429                     zone_check_full();
 430                 }
 431             };
 432             zone_warning("checks failed: $@",'') if length $@;
 433         }
 434         $output_contents{$$cfg{'output'}} .= zone_output()
 435             if $install;
 436
 437         mail_zone_after() if $domail;
 438     }
 439     if ($domail) {
 440     } elsif ($warnings) {
 441         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 442                        " %d zone(s) checked ok.\n",
 443                        $quis,
 444                        $warnings,
 445                        scalar(keys %zone_warnings),
 446                        scalar(@zones - keys %zone_warnings));
 447     } else {
 448         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
 449     }
 450 }
 451
 452 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 453 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 454 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 455 use vars qw(%soas);  # $soa{"$serial $origin"} = [ $whosaidandwhy ]
 456 use vars qw(%addr_is_ok %warned);
 457 use vars qw($delg_to_us);
 458 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
 459 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
 460
 461 sub zone_warning ($$) {
 462     my ($w,$o) = @_;
 463     my ($wk);
 464
 465     return 0 if !$repeat && $warned{$w}++;
 466
 467     $w =~ s/\n$//;
 468     $w =~ s,\n, // ,g;
 469
 470     $w .= " ($o)" if length $o;
 471     print $warn_fh "$zone: warning: $w\n" or die $!;
 472     $warnings++;
 473     $zone_warnings{$zone}++;
 474     return 1;
 475 }
 476
 477 sub zone_warnmore ($) {
 478     print $warn_fh "$zone:  $_[0]\n" or die $!;
 479 }
 480
 481 sub zone_check_full () {
 482     zone_investigate();
 483     zone_consistency();
 484     zone_servers_ok();
 485 }
 486
 487 sub zone_reset() {
 488     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 489     $delg_to_us= 0;
 490     @to_check= @to_check_soa= ();
 491 }
 492
 493 sub zone_investigate() {
 494     my ($super_zone, @start_nsnames, $start_ww,
 495         $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
 496         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
 497         $rcode, $name, $is_ns);
 498
 499     if (!zone_style('*',0)) {
 500         $super_zone= $zone;
 501         for (;;) {
 502             debug_trace("zone $zone superzone $super_zone");
 503             $super_zone eq '.'
 504                 and die "no superzone ? ($super_zone)\n";
 505             $super_zone =~ s/^[^.]+\.//
 506                 or $super_zone= '.';
 507             ($rcode,@start_nsnames)=
 508                 lookup($super_zone,'ns-','06',"superzone search");
 509             last if !$rcode;
 510         }
 511         $start_ww= "server for $super_zone";
 512     } else {
 513         ($rcode,@start_nsnames)=
 514             lookup($zone,'ns-','0',"initial nameserver search");
 515         $start_ww= "nameserver for $zone";
 516     }
 517     for $start_ns (@start_nsnames) {
 518         $start_ns= lc $start_ns;
 519         ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
 520         foreach $addr (@start_ns_addrs) {
 521             push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
 522         }
 523     }
 524     for (;;) {
 525         # We do these in order so that we always do NS RRset checks on
 526         # nameservers that came from other NS RRsets first; otherwise
 527         # we might set nsrrset_checked due to a glueless_ok check,
 528         # and then not check for gluefulness later.
 529         debug_dump('@to_check @to_check_soa');
 530         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
 531             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
 532                 if defined $name_if_auth;
 533             next if $nsrrset_checked{$addr}++;
 534             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
 535         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
 536             next if $soa_checked{$addr}++;
 537             zone_check_soa($addr,$wa,$name,$is_ns);
 538         } else {
 539             last;
 540         }
 541     }
 542 }
 543
 544 sub zone_check_nsrrset ($$$$) {
 545     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
 546     my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 547     my ($rcode);
 548     $ww= "[$uaddr] $wa";
 549     verbose("checking delegation by $ww");
 550     dig(sub {
 551         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 552             $s2g{lc $dig_rdata} = [ ];
 553         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 554             $wwn= "in glue from $ww";
 555             zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 556             push @{ $s2g{$dig_owner} }, $dig_rdata;
 557         }
 558     },
 559              $zone,'ns',$uaddr);
 560     if (!%s2g) {
 561         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 562         return;
 563     } elsif (keys %s2g == 1) {
 564         zone_warning("only one nameserver ". (join '', keys %s2g),
 565                      $ww);
 566     }
 567     @s= sort keys %s2g;
 568     foreach $s (@s) {
 569         zone_ns_name($s,$ww);
 570         @glue= @{ $s2g{$s} };
 571         if (!@glue) {
 572             zone_warning("glueless NS $s", $ww)
 573                 unless $glueless_ok || zone_style('~',!$needglue) ||
 574                        grep { has_suffix_of($zone,".$_"); }
 575                            @{ $cfg->{'conv_glueless'} };
 576             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
 577             foreach $a (@glue) {
 578                 $wwn= "glueless NS from $ww";
 579                 zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
 580             }
 581         }
 582         $glue= join ' ', sort @glue;
 583         push @{ $glue{$s}{$glue} }, $ww;
 584     }
 585     $s= join ' ', @s;
 586     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
 587     push @{ $delgs_or_auths->{$s} }, $ww;
 588 }
 589
 590 sub zone_ns_name ($$) {
 591     my ($name,$ww) = @_;
 592     my ($cg);
 593     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 594     foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 595         zone_warning("nameserver $name in serverless-glueless".
 596                      " namespace area $cg",
 597                      $ww)
 598             if has_suffix_of(".$name",".$cg");
 599     }
 600     zone_warning("published server, as $name, but configured as stealth",
 601                  $ww)
 602         if $cfg->{'s'} =~ m/u/ &&
 603            grep { $_ eq $name }
 604                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 605 }
 606
 607 sub zone_server_queue ($$$$$) {
 608     my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
 609     zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
 610     push @to_check, $addr, "$name, $wwn", $name, $is_soa;
 611 }
 612
 613 sub zone_server_addr ($$$$$) {
 614     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 615     debug_trace("zone_server_addr ".join '|',@_);
 616     $addr_is_ok{$addr}= "$name ($wwq)"
 617         if $is_soa || $cfg->{'s'} =~ m/u/;
 618     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 619         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 620
 621     my ($name_is_self, $addr_is_self);
 622     $name_is_self= grep { $_ eq $name }
 623         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 624     $addr_is_self= grep { $_ eq $addr }
 625         @{ $cfg->{'self_addr'} };
 626     if ($name_is_self && !$addr_is_self) {
 627         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 628     }
 629     if (!$name_is_self && $addr_is_self) {
 630         zone_warning("we [$addr] are named in ".
 631                      ($is_soa ? "SOA" : "NS").
 632                      " by wrong name $name",
 633                      $ww);
 634     }
 635     if (!$name_is_self && !$addr_is_self &&
 636         $is_soa && $cfg->{'s'} =~ m/p/) {
 637         zone_warning("SOA ORIGIN $name is not us (".
 638                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 639     }
 640     $delg_to_us=1 if $addr_is_self && !$is_soa;
 641 }
 642
 643 sub zone_check_soa ($$$$) {
 644     my ($uaddr,$wa,$name,$is_ns) = @_;
 645     my ($lame,$serial,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 646     verbose("checking service at [$uaddr] $name");
 647     $lame= 'dead or lame';
 648     $ww= "[$uaddr] $wa";
 649     dig(sub {
 650         if ($dig_type eq 'flags:') {
 651             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 652         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 653             die "several SOAs ? $ww" if defined $origin;
 654             $got= $dig_rdata;
 655             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
 656             ($serial,$origin) = ($1,$2);
 657         }
 658     },
 659              $zone,'soa',$uaddr);
 660     $lame= 'broken' if !$lame && !defined $origin;
 661     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 662     progress(2, sprintf "%-16s %46s has %s%s",
 663              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
 664     push @{ $soas{$got} }, $ww;
 665     ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
 666     $wwn= "SOA ORIGIN from $ww";
 667     foreach $soa_addr (@soa_addrs) {
 668         zone_server_queue($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 669     }
 670 }
 671
 672 sub zone_consistency() {
 673     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
 674     zone_consistency_set('delegations',\%delgs);
 675     foreach $d (keys %delgs) { delete $auths{$d}; }
 676     zone_consistency_set('zone nameserver rrset',\%auths);
 677     foreach $h (keys %glue) {
 678         zone_consistency_set("glue for $h", $glue{$h});
 679     }
 680     zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
 681     $self_soa= $cfg->{'self_soa'};
 682 }
 683
 684 sub zone_servers_ok () {
 685     my ($showok,%fs);
 686     if (%addr_is_ok) {
 687         $showok= 0;
 688         foreach $a (@{ $cfg->{'servers'} }) {
 689             next if exists $addr_is_ok{$a};
 690             zone_warning("we slave from [$a]",'')
 691                 and $showok=1;
 692         }
 693         if ($showok) {
 694             foreach $a (keys %addr_is_ok) {
 695                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 696             }
 697         }
 698     }
 699     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 700         zone_warning("we are supposedly published secondary,".
 701                      " but not listed as a nameserver",'');
 702         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 703         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 704     }
 705 }
 706
 707 sub zone_consistency_set ($%) {
 708     my ($msg,$set) = @_;
 709     my ($d,$o);
 710     if (keys(%$set) > 1) {
 711         zone_warning("inconsistent $msg:",'');
 712         foreach $d (keys %$set) {
 713             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 714         }
 715     }
 716 }
 717
 718 sub zone_check_local () {
 719     zone_servers_simplefind();
 720     zone_servers_ok();
 721 }
 722
 723 sub zone_servers_simplefind () {
 724     my ($rcode,@nsnames,$ns,@soas,$origin);
 725
 726     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 727     foreach $ns (@nsnames) {
 728         zone_ns_name($ns,"NS");
 729         zone_server_simple($ns,'NS',0);
 730     }
 731     $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
 732
 733     ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
 734     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 735     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 736     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 737 }
 738
 739 sub zone_server_simple ($$$) {
 740     my ($name,$ww,$is_soa) = @_;
 741     my ($rcode,@addrs,$addr);
 742     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 743                             ($is_soa ? "SOA ORIGIN" : "NS"));
 744     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 745 }
 746
 747 sub zone_style ($$) {
 748     my ($stylechar, $default) = @_;
 749     local ($_) = $$cfg{'s'};
 750     $stylechar =~ s/\W/\\$&/ or die;
 751     return m/(\S*)$stylechar/ ? $1 !~ m/\!/ : $default;
 752 }
 753
 754 #-------------------- mailing
 755
 756 use vars qw($m_base $m_lastok @m_ok @m_fail
 757             $m_info $m_time $m_lock $m_m);
 758
 759 sub mail_zone_before () {
 760     my (@s1,@s2);
 761
 762     $m_base= $$cfg{'maildir'}.'/'.$zone;
 763     $m_lastok= '-';
 764     @m_ok= ();
 765     @m_fail= ();
 766
 767     for (;;) {
 768         $m_lock= new IO::File "${m_base}_lock", O_RDWR|O_CREAT, 0600
 769             or die "$quis: create lockfile ${m_base}_lock: $!\n";
 770         if (!flock($m_lock, LOCK_EX|LOCK_NB)) {
 771             <$m_lock> =~ m/^\d+ /;
 772             die "$quis: $zone: concurrrency? - flock $&$!\n";
 773             $m_lock->close;
 774             return 0;
 775         }
 776         (@s1= $m_lock->stat) or die "$quis: fstat ${m_base}_lock: $!\n";
 777         (@s2= stat "${m_base}_lock") or
 778             die "$quis: stat ${m_base}_lock: $!\n";
 779         last if ($s1[0] eq $s2[0] && $s1[1] eq $s2[1]);
 780         $m_lock->close;
 781     }
 782     (print $m_lock "$$        \n" and $m_lock->flush)
 783         or die "$quis: write pid to ${m_base}_lock: $!\n";
 784
 785     if ($m_info= new IO::File "${m_base}_info", 'r') {
 786         $!=0; $_= <$m_info>;
 787         $_ =~ m/\n/ or die "$quis: read ${m_base}_info: $!\n";
 788         m/^\d+ (\d+|-) ([0-9:]*) ([0-9:]*) / or
 789             die "$quis: ${m_base}_info malformed\n";
 790         $m_lastok= $1;
 791         if ($domail ne 'first') {
 792             if ($2 eq ':' && $3 eq ':') {
 793                 warn "$quis: $zone: mid/last run, but last".
 794                     "run already done, ignoring zone\n";
 795                 return 0;
 796             }
 797             @m_ok= split /\:/, $2;
 798             @m_fail= split /\:/, $3;
 799         }
 800     } elsif ($! != &ENOENT) {
 801         die "$quis: open ${m_base}_info: $!\n";
 802     } elsif ($domail ne 'first') {
 803         warn "$quis: $zone: first run, but not --mail-first,".
 804             " ignoring zone\n";
 805         return 0;
 806     }
 807     if ($domail eq 'first') {
 808         remove "${m_base}_history" or $!==&ENOENT
 809             or die "$quis: remove ${m_base}_history: $!\n";
 810     }
 811     $progress_fh= $warn_fh= new IO::File "${m_base}_history",'a',0666
 812         or die "$quis: open ${m_base}_history: $!\n";
 813     $m_info= new IO::File "${m_base}_info.tmp",'w',0666
 814         or die "$quis: open ${m_base}_info.tmp: $!\n";
 815
 816     $m_time= time;
 817     progress(-1, "\n".('-'x70)."\n".ptime($m_time)."\n");
 818     return 1;
 819 }
 820
 821 sub mail_zone_after () {
 822     if ($zone_warnings{$zone}) {
 823         push @m_fail, $m_time;
 824         progress(-1,"failed - $zone_warnings{$zone} warnings");
 825     } else {
 826         push @m_ok, $m_time;
 827         $m_lastok= $m_time;
 828         progress(-1,"everything is fine");
 829     }
 830     close $progress_fh or die "$quis: close ${m_base}_history: $!\n";
 831     $progress_fh= $warn_fh= $stderr_fh;
 832
 833     if ($domail =~ m/^final/) {
 834         if (100*@m_fail <= $$cfg{'mailmwarn'}*(@m_fail + @m_ok)) {
 835             printf " %-40s ok\n", $zone or die "$quis: mail ok report: $!\n";
 836         } elsif (zone_style('@',0)) {
 837             printf " %-40s mail suppressed\n", $zone
 838                 or die "$quis: mail suppress report: $!\n";
 839         } else {
 840             mail_zone_mail();
 841         }
 842     } else {
 843         printf " %-40s %d warns. OK %s Fail %s\n",
 844             $zone,
 845             defined $zone_warnings{$zone} ? $zone_warnings{$zone} : 0,
 846             join(',', map { $_ - $m_time } @m_ok),
 847             join(',', map { $_ - $m_time } @m_fail)
 848                 or die "$quis: checking progress report: $!\n";
 849     }
 850
 851     @m_fail= @m_ok= ('','')
 852         if $domail =~ m/^final/;
 853
 854     printf $m_info "%s %s %s %s \n",
 855         $m_time, $m_lastok, join(':',@m_ok), join(':',@m_fail)
 856             or die "$quis: write new ${m_base}_info: $!\n";
 857     $m_info->close or die "$quis: close new ${m_base}_info: $!\n";
 858     rename "${m_base}_info.tmp", "${m_base}_info"
 859         or die "$quis: install new ${m_base}_info: $!\n";
 860     $m_lock->close;
 861 }
 862
 863
 864 sub pmail ($) {
 865     print $m_m $_[0]
 866         or die "$quis: write ${m_base}_mail: $!\n";
 867 }
 868 sub ptime ($) {
 869     my ($time) = @_;
 870     return gmtime($time)." GMT ($time)";
 871 }
 872
 873 sub mail_zone_mail () {
 874     my ($log, $zone_to, $zterr, $c, $r, $t, @soas);
 875     $m_m= new IO::File "${m_base}_mail", 'w', 0666
 876         or die "$quis: create ${m_base}_mail: $!\n";
 877     $zone_to=''; $zterr='';
 878     if (!zone_style("\$", $$cfg{'s'} !~ m/[ps]/)) {
 879         eval {
 880             ($r,@soas)= lookup($zone,'soa','0','problem-addr');
 881             @soas==1 or die "multiple soas\n";
 882             $soas[0] =~ m/^\S+ (\S.*\@\S+) [0-9 ]+$/ or
 883                 die "bad soa \`$_'\n";
 884             $zone_to= $1;
 885         };
 886         $zterr= $@;
 887         $zterr =~ s/\n$//;
 888     }
 889     pmail <<END
 890 From: zone checker <$$cfg{'admin'}>
 891 Subject: $zone - configuration problems report
 892 END
 893 ;
 894     pmail("To: ");
 895     pmail("(testing!) ") if $domail ne 'final';
 896     pmail("SOA MNAME for $zone <$zone_to>\nCC: ") if length($zone_to);
 897     pmail($$cfg{'admin'}."\n\n");
 898     pmail <<END
 899 You are receiving this mail because your email address is listed
 900 in the SOA (Start Of Authority) record for $zone
 901 in the DNS, which means you are supposedly the DNS administrator
 902 responsible for this zone.  This report is generated automatically
 903 on behalf of $$cfg{'admin'}, who
 904 is the administrator for a server for the zone.  Please contact
 905 them if you have any problem with this report.
 906
 907 END
 908 if length $zone_to;
 909     pmail <<END
 910 Sent to $$cfg{'admin'} since SOA MNAME unavailable:
 911 $zterr
 912
 913 END
 914 if length $zterr;
 915     pmail <<END
 916 The zone has had configuration errors or persistent operational
 917 problems during recent checks.  See the logs below for details.
 918
 919 Recent check history for $zone:
 920 END
 921 ;
 922     if ($m_lastok ne '-') {
 923         pmail(" Last seen to be fine: ".ptime($m_lastok)."\n");
 924     } else {
 925         pmail(" No record of this zone ever being fine.\n");
 926     }
 927     for $t (@m_fail) {
 928         pmail(" Zone had problems at: ".ptime($t)."\n");
 929     }
 930     for $t (@m_ok) {
 931         pmail(" Everything in order at: ".ptime($t)."\n");
 932     }
 933     pmail("\n");
 934     $log= new IO::File "${m_base}_history",'r'
 935         or die "$quis: reopen ${m_base}_history: $!";
 936     undef $/;
 937     pmail($log->getline);
 938     $/= "\n";
 939     (!$log->error and $log->close)
 940         or die "$quis: reread or close ${m_base}_log: $!\n";
 941     $log->eof or die;
 942     $m_m->close or die "$quis: close ${m_base}_mail: $!\n";
 943     $m_m= new IO::File "${m_base}_mail"
 944         or die "$quis: reopen ${m_base}_mail: $!";
 945
 946     defined($c= fork) or die "$quis: fork for mail: $!\n";
 947     if (!$c) {
 948         defined dup2($m_m->fileno, 0)
 949             or die "$quis - sendmail: dup for stdin: $!\n";
 950         exec (qw(/usr/sbin/sendmail -odb -oee -oi),
 951               ($domail eq 'final' ? '-t' : $$cfg{'admin'}));
 952         die "$quis - sendmail: exec: $!\n";
 953     }
 954     $m_m->close;
 955     $!=0; $r= waitpid $c,0;
 956     $r == $c or die "$quis: waitpid sendmail ($c): $r $!";
 957     $? and warn "$quis: sendmail failed: $?\n";
 958
 959     printf " %-40s %s\n", $zone,
 960         length $zone_to ? $zone_to : 'reporting to admin'
 961             or die "$quis: write mailing report: $!\n";
 962 }
 963
 964 #-------------------- outputting
 965
 966 sub zone_output () {
 967     my ($o,$m);
 968
 969     $o= "zone \"$zone\" {\n";
 970     if ($$cfg{'s'} =~ m/p/) {
 971         $o.= "    type master;\n";
 972     } else {
 973         $o.= "    type slave;\n".
 974              "    masters {\n";
 975         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 976         $o.= "    };\n";
 977     }
 978     $o.= "    file \"$$cfg{'file'}\";\n";
 979     $o.= "};\n";
 980     return $o;
 981 }
 982
 983 sub output_files () {
 984     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 985
 986     foreach $ofn (keys %output_contents) {
 987         $fn= $ofn; $mfn= "output file $fn";
 988         for (;;) {
 989             if (!lstat $fn) {
 990                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 991                 $maxmode= 0666;
 992                 last;
 993             } elsif (-f _) {
 994                 $maxmode= (stat _)[2];
 995                 last;
 996             } elsif (-l _) {
 997                 defined($l= readlink $fn)
 998                     or die "$quis: readlink $mfn:\n $!\n";
 999                 $dir= $fn =~ m,^.*/, ? $& : './';
1000                 $fn= "$dir$l" unless $l =~ m,^/,;
1001                 $mfn= "output file $fn (symlink target of $ofn)";
1002             } else {
1003                 die "$quis: output file $mfn exists but is not a file".
1004                     " (or symlink to one)";
1005             }
1006         }
1007         unlink "$fn.new" or $! == &ENOENT or
1008             die "$quis: cannot clear out old .new version of $mfn:\n $!";
1009         $h= new IO::File "$fn.new",'w',$maxmode
1010             or die("$quis: create .new version of $mfn:\n $!");
1011         print $h
1012             "# generated by $quis, do not edit\n",
1013             $output_contents{$ofn}
1014             or die "$quis: write data to .new version of $mfn:\n $!";
1015         $h->close
1016             or die "$quis: close .new version of $mfn:\n $!";
1017         push @to_install, $fn,$mfn;
1018     }
1019
1020     while (($fn,$mfn, @to_install) = @to_install) {
1021         rename "$fn.new",$fn
1022             or die "$quis: install new version of $mfn:\n $!";
1023     }
1024 }
1025
1026 #-------------------- general utilities
1027
1028 sub debug_dump ($) {
1029     my ($vn);
1030     return unless $debug>1;
1031     local $Data::Dumper::Terse=1;
1032     foreach $vn (split /\s+/, $_[0]) {
1033         print "$vn := ", eval "Dumper(\\$vn)";
1034     }
1035 }
1036
1037 sub debug_trace ($) {
1038     return unless $debug;
1039     print "D $_[0]\n";
1040 }
1041
1042 sub has_suffix_of ($$) {
1043     my ($whole,$suffix) = @_;
1044     debug_trace("has_suffix_of $whole $suffix");
1045     return 0 if length $whole < length $suffix;
1046     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
1047     debug_trace("has_suffix_of $whole $suffix YES");
1048     return 1;
1049 }
1050
1051 sub lookup ($$$$) {
1052     my ($domain,$type,$okrcodes,$w) = @_;
1053     my ($c,$h,@result);
1054     debug_trace("lookup ==> (->$okrcodes) $domain $type");
1055     $h= new IO::Handle;
1056
1057     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
1058     if (!$c) {
1059         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
1060              '-',"$domain";
1061         die "$quis: exec adnshost:\n $!\n";
1062     }
1063     @result= $h->getlines();
1064     $h->error and die "$quis: read from adnshost:\n $!\n";
1065     chomp @result;
1066     $!=0; $h->close;
1067     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
1068         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
1069     debug_trace("lookup <== $? @result");
1070     return ($?,@result);
1071 }
1072
1073 sub dig (&$$$) {
1074     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
1075     # also pseudo-rr with type `flags:'
1076     my ($h,$inmid,$irdata,$c,$digwhy);
1077     local ($_);
1078
1079     debug_trace("dig ==> \@$qaddr $qowner $qtype");
1080
1081     $h= new IO::Handle;
1082     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
1083     if (!$c) {
1084         open STDERR, ">&STDOUT" or die $!;
1085         exec ('dig',
1086               '+nodef','+nosea','+nodebug','+norecurse',
1087               "\@$qaddr",'-t',$qtype,$qowner);
1088         die "$quis: exec dig:\n $!\n";
1089     }
1090     $inmid='';
1091     for (;;) {
1092         if (!defined($_= $h->getline())) {
1093             $h->error() and die "$quis: read from dig:\n $!\n";
1094             last;
1095         }
1096         chomp;
1097         if (length $inmid) {
1098             s/^\s+/ / or die "$inmid // $_ ?";
1099             s/\;.*$//;
1100             $_= $inmid.$_;
1101             $inmid='';
1102             s/$/ \(/ unless s/\s*\)\s*$//;
1103         }
1104         if (s/\s*\(\s*$//) { $inmid= $_; next; }
1105         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
1106         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
1107             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
1108             debug_trace("dig  f: $dig_rdata");
1109             &$eachrr;
1110         } elsif (m/^\;/) {
1111         } elsif (!m/\S/) {
1112         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
1113             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
1114             if ($dig_type eq 'a') {
1115                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
1116                 $dig_rdata= $&;
1117             } elsif ($dig_type eq 'ns') {
1118                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
1119                 $dig_rdata= domain_canon($irdata,$digwhy);
1120             } elsif ($dig_type eq 'soa') {
1121                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
1122                     or die "bad SOA $irdata ?";
1123                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
1124             } else {
1125                 debug_trace("ignoring uknown RR type $dig_type");
1126                 next;
1127             }
1128             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
1129             &$eachrr;
1130         } else {
1131             debug_trace("ignoring unknown dig output $_");
1132         }
1133     }
1134     $h->close;
1135     debug_trace("dig <== gave $?");
1136 }
1137
1138 sub domain_canon ($$) {
1139     my ($i,$w) = @_;
1140     $i =~ s/(.)\.$/$1/;
1141     return '.' if $i eq '.';
1142     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
1143     return lc $i;
1144 }