chiark / gitweb /
12a4f52cdff44f3f412b6ce0cc4ca32574609393
[chiark-utils.git] / scripts / git-cache-proxy
1 #!/usr/bin/perl -w
2 #
3 # git caching proxy
4
5 # usage: run it on some port, and then clone or fetch
6 #  "git://<realhost>:<realport>/<real-git-url>[ <options>]"
7 # where <real-git-url> is http://<host>/... or git://<host>/...
8 # and <options> is zero or more (whitespace-separated) of
9 #    [<some-option>]      will be ignored if not recognised
10 #    {<some-option>}      error if not recognised
11 # options currently known:
12 #    fetch=must           fail if the fetch/clone from upstream fails
13 #    fetch=no             just use what is in the cache
14 #    fetch=try            use what is in the cache if the fetch/clone fails
15 #    timeout=<seconds>    length of time to allow for fetch/clone
16
17 # git-cache-proxy is free software; you can redistribute it and/or
18 # modify them under the terms of the GNU General Public License as
19 # published by the Free Software Foundation; either version 3, or (at
20 # your option) any later version.
21
22 # git-cache-proxy is distributed in the hope that it will be useful,
23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
25 # General Public License for more details.
26
27 # You should have received a copy of the GNU General Public License along
28 # with this program; if not, consult the Free Software Foundation's
29 # website at www.fsf.org, or the GNU Project website at www.gnu.org.
30
31 # (Some code taken from userv-utils's git-daemon.in and git-service.in
32 # which were written by Tony Finch <dot@dotat.at> and subsequently
33 # heavily modified by Ian Jackson <ijackson@chiark.greenend.org.uk>
34 # and were released under CC0 1.0.  The whole program is now GPLv3+.)
35
36 use strict;
37 use warnings;
38
39 use POSIX;
40 use Socket;
41 use Sys::Syslog;
42 use Fcntl qw(:flock SEEK_SET);
43 use File::Path qw(remove_tree);
44
45 our $us = 'git-cache-proxy';
46
47 #---------- error handling and logging ----------
48
49 # This is a bit fiddly, because we want to catch errors sent to stderr
50 # and dump them to syslog if we can, but only if we are running as an
51 # inetd service.
52
53 our $log; # filehandle (ref), or "1" meaning syslog
54
55 sub ntoa {
56     my $sockaddr = shift;
57     return ('(local)') unless defined $sockaddr;
58     my ($port,$addr) = sockaddr_in $sockaddr;
59     $addr = inet_ntoa $addr;
60     return ("[$addr]:$port",$addr,$port);
61 }
62
63 our ($client) = ntoa getpeername STDIN;
64 our ($server) = ntoa getsockname STDIN;
65
66 sub ensurelog () {
67     return if $log;
68     openlog $us, qw(pid), 'daemon';
69     $log = 1;
70 }
71
72 sub logm ($$) {
73     my ($pri, $msg) = @_;
74     if ($client eq '(local)') {
75         print STDERR "$us: $pri: $msg\n" or die $!;
76         exit 1;
77     }
78     ensurelog();
79     my $mainmsg = sprintf "%s-%s: %s", $server, $client, $msg;
80     if (ref $log) {
81         my $wholemsg = sprintf("%s [%d] %s: %s\n",
82                                strftime("%Y-%m-%d %H:%M:%S Z", gmtime),
83                                $$,
84                                $pri,
85                                $mainmsg);
86         print $log $wholemsg;
87     } else {
88         syslog $pri, $mainmsg;
89     }
90 }
91
92 if ($client ne '(local)') {
93     open STDERR, ">/dev/null" or exit 255;
94     open TEMPERR, "+>", undef or exit 255;
95     open STDERR, ">&TEMPERR" or exit 255;
96 }
97
98 END {
99     if ($client ne '(local)') {
100         if ($?) { logm 'crit', "crashing ($?)"; }
101         seek TEMPERR, 0, SEEK_SET;
102         while (<TEMPERR>) {
103             chomp;
104             logm 'crit', $_;
105         }
106     }
107     exit $?;
108 }
109
110 sub fail ($) {
111     my ($msg) = @_;
112     logm 'err', $msg;
113     exit 0;
114 }
115
116 sub gitfail ($) {
117     my ($msg) = @_;
118     close LOCK;
119     alarm 60;
120     logm 'notice', $msg;
121     my $gitmsg = "ERR $us: $msg";
122     $gitmsg = substr($gitmsg,0,65535); # just in case
123     printf "%04x%s", length($gitmsg)+4, $gitmsg;
124     flush STDOUT;
125     exit 0;
126 }
127
128 #---------- argument parsing ----------
129
130 our $housekeepingthreshdays = 1;
131 our $treeexpiredays = 21;
132 our $fetchtimeout = 1800;
133 our $maxfetchtimeout = 3600;
134 our $cachedir = '/var/cache/git-cache-proxy';
135
136 for (;;) {
137     last unless @ARGV;
138     last unless $ARGV[0] =~ m/^-/;
139     $_ = shift @ARGV;
140     for (;;) {
141         last unless m/^-./;
142         if (s/^-L(.*)$//) {
143             my $logfile = $_;
144             open STDERR, ">>", $logfile or fail "open $logfile: $!";
145             $log = \*STDERR;
146         } elsif (s/^-d(.*)$//) {
147             $cachedir = $1;
148         } elsif (s/^--(maxfetchtimeout|fetchtimeout)=(\d+)$//) {
149             ${ $::{$1} } = $2;
150         } else {
151             fail "bad usage: unknown option `$_'";
152         }
153     }
154 }
155
156 !@ARGV or fail "bad usage: no non-option arguments permitted";
157
158 #---------- main program ----------
159
160 chdir $cachedir or fail "chdir $cachedir: $!";
161
162 our ($service,$specpath,$spechost,$subdir);
163 our ($tmpd,$gitd,$lock);
164 our ($fetch,$url);
165
166 sub xread {
167     my $length = shift;
168     my $buffer = "";
169     while ($length > length $buffer) {
170         my $ret = sysread STDIN, $buffer, $length, length $buffer;
171         fail "expected $length bytes, got ".length $buffer
172                             if defined $ret and $ret == 0;
173         fail "read: $!" if not defined $ret and $! != EINTR and $! != EAGAIN;
174     }
175     return $buffer;
176 }
177
178 sub servinfo ($) {
179     my ($msg) = @_;
180     logm 'info', "service `$specpath': $msg";
181 }
182
183 sub readcommand () {
184     $SIG{ALRM} = sub { fail "timeout" };
185     alarm 30;
186
187     my $hex_len = xread 4;
188     fail "Bad hex in packet length" unless $hex_len =~ m|^[0-9a-fA-F]{4}$|;
189     my $line = xread -4 + hex $hex_len;
190     unless (($service,$specpath,$spechost) = $line =~
191             m|^(git-[a-z-]+) /*([!-~ ]+)\0host=([!-~]+)\0$|) {
192         $line =~ s|[^ -~]+| |g;
193         gitfail "unknown/unsupported instruction `$line'"
194     }
195
196     alarm 0;
197
198     $service eq 'git-upload-pack'
199         or gitfail "unknown/unsupported service `$service'";
200
201     $fetch = 2; # 0:don't; 1:try; 2:force
202     $url = $specpath;
203
204     while ($url =~ s#\s+(\[)([^][{}]+)\]$## ||
205            $url =~ s#\s+(\{)([^][{}]+)\}$##) {
206         $_ = $2;
207         my $must = $1 eq '{';
208         if (m/^fetch=try$/) {
209             $fetch = 1;
210         } elsif (m/^fetch=no$/) {
211             $fetch = 0;
212         } elsif (m/^fetch=must$/) {
213             $fetch = 2; # the default
214         } elsif (m/^timeout=(\d+)$/) {
215             $fetchtimeout = $1 <= $maxfetchtimeout ? $1 : $maxfetchtimeout;
216         } elsif ($must) {
217             gitfail "unknown/unsupported option `$_'";
218         }
219     }
220
221     $url =~ m{^(?:https?|git)://[-.0-9a-z]+/}
222         or gitfail "unknown/unsupported url scheme or format `$url'";
223
224     $subdir = $url;
225     $subdir =~ s|\\|\\\\|g;
226     $subdir =~ s|,|\\,|g;
227     $subdir =~ s|/|,|g;
228
229     $tmpd= "$subdir\\.tmp";
230     $gitd= "$subdir\\.git";
231     $lock = "$subdir\\.lock";
232
233     servinfo "locking";
234 }
235
236 sub clonefetch () {
237     open LOCK, "+>", $lock or fail "open/create $lock: $!";
238     flock LOCK, LOCK_EX or fail "lock exclusive $lock: $!";
239
240     my $exists = stat $gitd;
241     $exists or $!==ENOENT or fail "stat $gitd: $!";
242
243     our $fetchfail = '';
244
245     if ($fetch) {
246
247         our @cmd;
248
249         if (!$exists) {
250             system qw(rm -rf --), $tmpd;
251             @cmd = (qw(git clone -q --mirror), $url, $tmpd);
252             servinfo "cloning";
253         } else {
254             @cmd = (qw(git remote update --prune));
255             servinfo "fetching";
256         }
257         my $cmd = "@cmd[0..1]";
258
259         my $child = open FETCHERR, "-|";
260         defined $child or fail "fork: $!";
261         if (!$child) {
262             if ($exists) {
263                 chdir $gitd or fail "chdir $gitd: $!";
264             }
265             setpgrp or fail "setpgrp: $!";
266             open STDERR, ">&STDOUT" or fail "redirect stderr: $!";
267             exec @cmd or fail "exec $cmd[0]: $!";
268         }
269
270         my $fetcherr = '';
271         my $timedout = 0;
272         {
273             local $SIG{ALRM} = sub {
274                 servinfo "fetch/clone timeout";
275                 $timedout=1; kill 9, -$child;
276             };
277             alarm($fetchtimeout);
278             $!=0; { local $/=undef; $fetcherr = <FETCHERR>; }
279             !FETCHERR->error or fail "read pipe from fetch/clone: $!";
280             alarm(10);
281         }
282
283         kill -9, $child or fail "kill fetch/clone: $!";
284         $!=0; $?=0; if (!close FETCHERR) {
285             fail "reap fetch/clone: $!" if $!;
286             my $fetchfail =
287                 !($? & 255) ? "$cmd died with error exit code ".($? >> 8) :
288                 $? != 9 ? "$cmd died due to fatal signa, status $?" :
289                 $timedout ? "$cmd timed out (${fetchtimeout}s)" :
290                 "$cmd died due to unexpected SIGKILL";
291             if (length $fetcherr) {
292                 $fetchfail .= "\n$fetcherr";
293                 $fetchfail =~ s/\n$//;
294                 $fetchfail =~ s{\n}{ // }g;
295             }
296             if ($fetch >= 2) {
297                 gitfail $fetchfail;
298             } else {
299                 servinfo "fetch/clone failed: $fetchfail";
300             }
301         }
302
303         if (!$exists) {
304             rename $tmpd, $gitd or fail "rename fresh $tmpd to $gitd: $!";
305             $exists = 1;
306         }
307     } else {
308         $fetchfail = 'not attempted';
309     }
310
311     if (!$exists) {
312         gitfail "no cached data, and not cloned: $fetchfail";
313     }
314
315     servinfo "sharing";
316     flock LOCK, LOCK_UN or fail "unlock $lock: $!";
317     flock LOCK, LOCK_SH or fail "lock shared $lock: $!";
318     # actually, just relocking as shared would have the same semantics
319     # but it's best to be explicit
320
321     if (chdir $gitd) {
322         return 1;
323     }
324     $!==ENOENT or fail "chdir $gitd: $!";
325
326     # Well, err, someone must have taken the lock in between
327     # and garbage collected it.  How annoying.
328     return 0;
329 }
330
331 sub housekeeping () {
332     foreach $lock (<[a-z]*\\.lock>) {
333         if (!lstat $lock) {
334             $! == ENOENT or fail "housekeeping: $lock: stat: $!";
335             next;
336         }
337         if (-M _ <= $treeexpiredays) {
338             logm 'debug', "housekeeping: $lock: not too old";
339             next;
340         }
341         my $subdir = $lock;  $subdir =~ s/\\.lock$//;
342         my $ok = 1;
343         foreach my $suffix (qw(tmp git)) {
344             my $dir = "${subdir}\\.$suffix";
345             my $errs;
346             remove_tree($dir, { safe=>1, error=>\$errs });
347             $ok = 0 if @$errs;
348             foreach my $err (@$errs) {
349                 logm 'warning', "problem deleting: $err[0]: $err[1]";
350             }
351         }
352         if ($ok) {
353             
354
355 sub housekeepingcheck ($$) {
356     my ($dofork, $force) = @_;
357     open HLOCK, "+>", "Housekeeping.lock" 
358         or fail "open/create Housekeeping.lock: $!";
359     if (!$force) {
360         if (flock HLOCK, LOCK_EX|LOCK_NB) {
361             logm 'debug', "housekeeping lock taken, not running";
362             close HLOCK;
363             return 0;
364         }
365     }
366     if ($force) {
367         logm 'info', "housekeeping forced";
368     } elsif (!lstat "Housekeeping.stamp") {
369         $! == ENOENT or fail "stat housekeeping.stamp: $!";
370         logm 'info', "housekeeping stamp missing, will run";
371     } elsif (-M _ <= $housekeepingthreshdays) {
372         logm 'debug', "housekeeping done recently";
373         close HLOCK;
374         return 0;
375     }
376     if ($dofork) {
377         my $child = fork;
378         defined $child or fail "fork for housekeeping: $!";
379         if (!$child) {
380             housekeeping();
381             exit 0;
382         }
383         return 1;
384     } else {
385         housekeeping();
386         return 1;
387     }
388 }
389
390 sub runcommand () {
391     servinfo "servicing";
392     exec qw(git-upload-pack --strict --timeout=1000 .)
393         or fail "exec git-upload-pack: $!";
394 }
395
396 sub daemonservice () {
397     readcommand();
398     while (!clonefetch()) { }
399     runcommand();
400 }
401
402 daemonservice();