cgi-auth-flexible.pm

   1 # -*- perl -*-
   2
   3 # This is part of CGI::Auth::Flexible, a perl CGI authentication module.
   4 # Copyright (C) 2012 Ian Jackson.
   5 # Copyright (C) 2012 Citrix.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU Affero General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU Affero General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Affero General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings FATAL => 'all';
  22
  23 package CGI::Auth::Flexible;
  24 require Exporter;
  25
  26 BEGIN {
  27     use Exporter   ();
  28     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  29
  30     $VERSION     = 1.00;
  31     @ISA         = qw(Exporter);
  32     @EXPORT      = qw();
  33     %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
  34
  35     @EXPORT_OK   = qw();
  36 }
  37 our @EXPORT_OK;
  38
  39 use DBI;
  40 use CGI qw/escapeHTML/;
  41 use Locale::gettext;
  42 use URI;
  43 use IO::File;
  44 use Fcntl qw(:flock);
  45 use POSIX;
  46 use Digest;
  47 use Digest::HMAC;
  48 use Digest::SHA;
  49 use Data::Dumper;
  50 use File::Copy;
  51 use Cwd qw/realpath/;
  52
  53
  54 #---------- public utilities ----------
  55
  56 sub flatten_params ($) {
  57     my ($p) = @_;
  58     my @p;
  59     foreach my $k (keys %$p) {
  60         next if $k eq '';
  61         foreach my $v (@{ $p->{$k} }) {
  62             push @p, $k, $v;
  63         }
  64     }
  65     return @p;
  66 }
  67
  68 #---------- default callbacks ----------
  69
  70 sub has_a_param ($$) {
  71     my ($r,$cn) = @_;
  72     foreach my $pn (@{ $r->{S}{$cn} }) {
  73         return 1 if $r->_ch('get_param',$pn);
  74     }
  75     return 0;
  76 }
  77
  78 sub get_params ($) {
  79     my ($r) = @_;
  80     my $c = $r->{Cgi};
  81     my $vars = $c->Vars();
  82     my %p;
  83     foreach my $name (keys %$vars) {
  84         $p{$name} = [ split "\0", $vars->{$name} ];
  85     }
  86     return \%p;
  87 }
  88
  89 sub get_cookie_domain ($$$) {
  90     my ($c,$r) = @_;
  91     my $uri = new URI $r->_ch('get_url');
  92     return $uri->host();
  93 }
  94
  95 sub login_ok_password ($$) {
  96     my ($c, $r) = @_;
  97     my $username_params = $r->{S}{username_param_names};
  98     my $username = $r->_ch('get_param',$username_params->[0]);
  99     my $password = $r->_rp('password_param_name');
 100     my $error = $r->_ch('username_password_error', $username, $password);
 101     return defined($error) ? (undef,$error) : ($username,undef);
 102 }
 103
 104 sub do_redirect_cgi ($$$$) {
 105     my ($c, $r, $new_url, $cookie) = @_;
 106     $r->_print($c->header($r->_cgi_header_args($cookie,
 107                                                -status => '303 See other',
 108                                                -location => $new_url)),
 109                $r->_ch('gen_start_html',$r->_gt('Redirection')),
 110                '<a href="'.escapeHTML($new_url).'">',
 111                $r->_gt("If you aren't redirected, click to continue."),
 112                "</a>",
 113                $r->_ch('gen_end_html'));
 114 }
 115
 116 sub gen_some_form ($$) {
 117     my ($r, $params, $bodyfn) = @_;
 118     # Calls $bodyfn->($c,$r) which returns @formbits
 119     my $c = $r->{Cgi};
 120     my @form;
 121     my $pathinfo = '';
 122     $pathinfo .= $params->{''}[0] if $params->{''};
 123     push @form, ('<form method="POST" action="'.
 124                  escapeHTML($r->_ch('get_url').$pathinfo).'">');
 125     push @form, $bodyfn->($c,$r);
 126     foreach my $n (keys %$params) {
 127         next if $n eq '';
 128         foreach my $val (@{ $params->{$n} }) {
 129             push @form, ('<input type="hidden"'.
 130                          ' name="'.escapeHTML($n).'"'.
 131                          ' value="'.escapeHTML($val).'">');
 132         }
 133     }
 134     push @form, ('</form>');
 135     return join "\n", @form;
 136 }
 137
 138 sub gen_plain_login_form ($$) {
 139     my ($c,$r, $params) = @_;
 140     return $r->gen_some_form($params, sub {
 141         my @form;
 142         push @form, ('<table>');
 143         my $sz = 'size="'.$r->{S}{form_entry_size}.'"';
 144         foreach my $up (@{ $r->{S}{username_param_names}}) {
 145             push @form, ('<tr><td>',$r->_gt(ucfirst $up),'</td>',
 146                          '<td><input type="text" '.$sz.
 147                          ' name='.$up.'></td></tr>');
 148         }
 149         push @form, ('<tr><td>'.$r->_gt('Password').'</td>',
 150                      '<td><input type="password" '.$sz.
 151                      ' name="'.$r->{S}{password_param_name}.'"></td></tr>');
 152         push @form, ('<tr><td colspan="2">',
 153                      '<input type="submit"'.
 154                      ' name="'.$r->{S}{dummy_param_name_prefix}.'login"'.
 155                      ' value="'.$r->_gt('Login').'"></td></tr>',
 156                      '</table>');
 157         return @form;
 158     });
 159 }
 160
 161 sub gen_postmainpage_form ($$$) {
 162     my ($c,$r, $params) = @_;
 163     return $r->gen_some_form($params, sub {
 164         my @form;
 165         push @form, ('<input type="submit"',
 166                      ' name="'.$r->{S}{dummy_param_name_prefix}.'submit"'.
 167                      ' value="'.$r->_gt('Continue').'">');
 168         return @form;
 169     });
 170 }
 171
 172 sub gen_plain_login_link ($$) {
 173     my ($c,$r, $params) = @_;
 174     my $url = $r->url_with_query_params($params);
 175     return ('<a href="'.escapeHTML($url).'">'.
 176             $r->_gt('Log in again to continue.').
 177             '</a>');
 178 }
 179
 180 sub gen_srcdump_link_html ($$$$) {
 181     my ($c,$r,$anchor,$specval) = @_;
 182     my %params = ($r->{S}{srcdump_param_name} => [ $specval ]);
 183     return '<a href="'.
 184         escapeHTML($r->url_with_query_params(\%params,'SRCDUMP')).
 185         '">'.$anchor."</a>";
 186 }
 187 sub gen_plain_licence_link_html ($$) {
 188     my ($c,$r) = @_;
 189     gen_srcdump_link_html($c,$r, 'GNU Affero GPL', 'licence');
 190 }
 191 sub gen_plain_source_link_html ($$) {
 192     my ($c,$r) = @_;
 193     gen_srcdump_link_html($c,$r, 'Source available', 'source');
 194 }
 195
 196 sub gen_plain_footer_html ($$) {
 197     my ($c,$r) = @_;
 198     return ('<hr><address>',
 199             ("Powered by Free / Libre / Open Source Software".
 200              " according to the ".$r->_ch('gen_licence_link_html')."."),
 201             $r->_ch('gen_source_link_html').".",
 202             '</address>');
 203 }
 204
 205 #---------- licence and source code ----------
 206
 207 sub srcdump_dump ($$$) {
 208     my ($c,$r, $thing) = @_;
 209     die if $thing =~ m/\W/ || $thing !~ m/\w/;
 210     my $path = $r->_get_path('srcdump');
 211     my $ctf = new IO::File "$path/$thing.ctype", 'r'
 212         or die "$path/$thing.ctype $!";
 213     my $ct = <$ctf>;
 214     chomp $ct or die "$path/$thing ?";
 215     $ctf->close or die "$path/$thing $!";
 216     my $df = new IO::File "$path/$thing.data", 'r'
 217         or die "$path/$thing.data $!";
 218     $r->_ch('dump', $ct, $df);
 219 }
 220
 221 sub dump_plain ($$$$) {
 222     my ($c, $r, $ct, $df) = @_;
 223     $r->_print($c->header('-type' => $ct));
 224     my $buffer;
 225     for (;;) {
 226         my $got = read $df, $buffer, 65536;
 227         die $! unless defined $got;
 228         return if !$got;
 229         $r->_print($buffer);
 230     }
 231 }
 232
 233 sub srcdump_process_item ($$$$$$) {
 234     my ($c, $v, $dumpdir, $item, $outfn, $needlicence, $dirsdone) = @_;
 235     if ($v->_ch('srcdump_system_dir', $item)) {
 236         $outfn->("srcdump_process_item: srcdump_system_dir, skipping $item");
 237         return;
 238     }
 239     my $upwards = $item;
 240     for (;;) {
 241         $upwards =~ s#/+$##;
 242         $upwards =~ s#/+\.$##;
 243         last unless $upwards =~ m#[^/]#;
 244         foreach my $try (@{ $v->{S}{srcdump_vcs_dirs} }) {
 245 #print STDERR "TRY $item $upwards $try\n";
 246             if (!stat "$upwards/$try") {
 247                 $!==&ENOENT or $!==&ENOTDIR or die "check $upwards/$try $!";
 248                 next;
 249             }
 250 #print STDERR "VCS $item $upwards $try\n";
 251             if ($dirsdone->{$upwards}++) {
 252                 $outfn->("srcdump_process_item: did $upwards,".
 253                          " skipping $item");
 254                 return;
 255             }
 256 #print STDERR "VCS $item $upwards $try GO\n";
 257             $try =~ m/\w+/ or die;
 258             return $v->_ch('srcdump_byvcs', $dumpdir, $upwards, $outfn, lc $&);
 259         }
 260         $upwards =~ s#/*[^/]+$##;
 261     }
 262     return $v->_ch('srcdump_novcs', $dumpdir, $item, $outfn);
 263 }
 264
 265 sub srcdump_novcs ($$$$$) {
 266     my ($c, $v, $dumpdir, $item, $outfn) = @_;
 267     stat $item or die "$item $!";
 268     if (-d _) {
 269         my $script = 'find -type f -perm +004';
 270         foreach my $excl (@{ $v->{S}{srcdump_excludes} }) {
 271             $script .= " \\! -name '$excl'";
 272         }
 273         $script .= " -print0";
 274         return srcdump_dir_cpio($c,$v,$dumpdir,$item,$outfn,'novcs',$script);
 275     } elsif (-f _) {
 276         return srcdump_file($c,$v,$dumpdir,$item,$outfn);
 277     } else {
 278         die "$item not file or directory";
 279     }
 280 }
 281
 282 sub srcdump_byvcs ($$$$$$) {
 283     my ($c, $v, $dumpdir, $dir, $outfn, $vcs) = @_;
 284 #print STDERR "BYVCS GIT $dir\n";
 285     return srcdump_dir_cpio($c,$v,$dumpdir,$dir,$outfn,$vcs,
 286                             $v->{S}{"srcdump_vcsscript_$vcs"});
 287 }
 288
 289 sub srcdump_file ($$$$) {
 290     my ($c,$v,$dumpdir,$file,$outfn) = @_;
 291     my $outfile = $outfn->("srcdump_file saved $file", "src");
 292     copy($file,$outfile) or die "$file $outfile $!";
 293 }
 294
 295 sub srcdump_dir_cpio ($$$$$$$) {
 296     my ($c,$v,$dumpdir,$dir,$outfn,$how,$script) = @_;
 297     my $outfile = $outfn->("srcdump_dir_cpio $how saved $dir", "tar");
 298 #print STDERR "CPIO $dir >$script<\n";
 299     my $pid = fork();
 300     defined $pid or die $!;
 301     if (!$pid) {
 302         $SIG{__DIE__} = sub {
 303             print STDERR "CGI::Auth::Flexible srcdump error: $@\n";
 304             exit 127;
 305         };
 306         open STDOUT, ">", $outfile or die "$outfile $!";
 307         chdir $dir or die "chdir $dir: $!";
 308         exec '/bin/bash','-ec',"
 309             set -o pipefail
 310             (
 311              $script
 312             ) | (
 313              cpio -Hustar -o --quiet -0 -R 1000:1000 || \
 314              cpio -Hustar -o --quiet -0
 315             )
 316             ";
 317         die $!;
 318     }
 319     $!=0; (waitpid $pid, 0) == $pid or die "$!";
 320     die "$dir ($how $script) $outfile $?" if $?;
 321 }
 322
 323 sub srcdump_dirscan_prepare ($$) {
 324     my ($c, $v) = @_;
 325     my $dumpdir = $v->_get_path('srcdump');
 326     mkdir $dumpdir or $!==&EEXIST or die "mkdir $dumpdir $!";
 327     my $lockf = new IO::File "$dumpdir/generate.lock", 'w+'
 328         or die "$dumpdir/generate.lock $!";
 329     flock $lockf, LOCK_EX or die "$dumpdir/generate.lock $!";
 330     my $needlicence = "$dumpdir/licence.tmp";
 331     unlink $needlicence or $!==&ENOENT or die "rm $needlicence $!";
 332     if (defined $v->{S}{srcdump_licence_path}) {
 333         copy($v->{S}{srcdump_licence_path}, $needlicence)
 334             or die "$v->{S}{srcdump_licence_path} $!";
 335         $needlicence = undef;
 336     }
 337     unlink <"$dumpdir/s.[a-z][a-z][a-z].*">;
 338     my @srcfiles = qw(licence.data manifest.txt);
 339     my $srcoutcounter = 'aaa';
 340
 341     my $reportfh = new IO::File "$dumpdir/manifest.txt", 'w' or die $!;
 342     my $outfn = sub {
 343         my ($message, $extension) = @_;
 344         if (defined $extension) {
 345             my $leaf = "s.$srcoutcounter.$extension";
 346             $srcoutcounter++;
 347             push @srcfiles, $leaf;
 348             print $reportfh "$leaf: $message\n" or die $!;
 349             return "$dumpdir/$leaf";
 350         } else {
 351             print $reportfh "none: $message\n" or die $!;
 352             return undef;
 353         }
 354     };
 355     my %dirsdone;
 356     foreach my $item ($v->_ch('srcdump_listitems')) {
 357         if ($item eq '.' && $v->{S}{srcdump_filter_cwd}) {
 358             my @bad = grep { !m#^/# } values %INC;
 359             die "filtering . from srcdump items and \@INC but already".
 360                 " included @bad " if @bad;
 361             @INC = grep { $_ ne '.' } @INC;
 362             next;
 363         }
 364         if (!lstat "$item") {
 365             die "stat $item $!" unless $!==&ENOENT;
 366             $outfn->("srcdump_dirscan_prepare stat ENOENT, skipping $item");
 367             next;
 368         };
 369         if (-l _) {
 370             $item = realpath($item);
 371             if (!defined $item) {
 372                 die "realpath $item $!" unless $!==&ENOENT;
 373                 $outfn->("srcdump_dirscan_prepare realpath ENOENT,".
 374                          " skipping $item");
 375             }
 376         }
 377         if (defined $needlicence) {
 378             foreach my $try (@{ $v->{S}{srcdump_licence_files} }) {
 379                 last if copy("$item/$try", $needlicence);
 380                 $!==&ENOENT or $!==&ENOTDIR or die "copy $item/$try $!";
 381             }
 382         }
 383         $v->_ch('srcdump_process_item', $dumpdir, $item,
 384                 $outfn, \$needlicence, \%dirsdone);
 385         $dirsdone{$item}++;
 386     }
 387     close $reportfh or die $!;
 388     srcdump_install($c,$v, $dumpdir, 'licence', 'text/plain');
 389     $!=0;
 390     my @cmd = (qw(tar -zvvcf), "$dumpdir/source.tmp",
 391                "-C", $dumpdir, qw(  --), @srcfiles);
 392     my $r = system(@cmd);
 393     if ($r) {
 394         print STDERR "CGI::Auth::Flexible tar failed ($r $!) @cmd\n";
 395         die "tar failed";
 396     }
 397     die "licence file not found" unless defined $needlicence;
 398     srcdump_install($c,$v, $dumpdir, 'source', 'application/octet-stream');
 399     close $lockf or die $!;
 400 }
 401
 402 sub srcdump_install ($$$$$) {
 403     my ($c,$v, $dumpdir, $which, $ctype) = @_;
 404     rename "$dumpdir/$which.tmp", "$dumpdir/$which.data"
 405         or die "$dumpdir/$which.data $!";
 406     my $ctf = new IO::File "$dumpdir/$which.tmp", 'w'
 407         or die "$dumpdir/$which.tmp $!";
 408     print $ctf $ctype, "\n" or die $!;
 409     close $ctf or die $!;
 410     rename "$dumpdir/$which.tmp", "$dumpdir/$which.ctype"
 411         or die "$dumpdir/$which.ctype $!";
 412 }
 413
 414 #---------- verifier object methods ----------
 415
 416 sub new_verifier {
 417     my $class = shift;
 418     my $verifier = {
 419         S => {
 420             dir => undef,
 421             assocdb_dbh => undef, # must have AutoCommit=0, RaiseError=1
 422             assocdb_path => 'caf-assocs.db',
 423             keys_path => 'caf-keys',
 424             srcdump_path => 'caf-srcdump',
 425             assocdb_dsn => undef,
 426             assocdb_user => '',
 427             assocdb_password => '',
 428             assocdb_table => 'caf_assocs',
 429             random_source => '/dev/urandom',
 430             secretbits => 128, # bits
 431             hash_algorithm => "SHA-256",
 432             login_timeout => 86400, # seconds
 433             login_form_timeout => 3600, # seconds
 434             key_rollover => 86400, # seconds
 435             assoc_param_name => 'caf_assochash',
 436             dummy_param_name_prefix => 'caf__',
 437             cookie_name => "caf_assocsecret",
 438             password_param_name => 'password',
 439             srcdump_param_name => 'caf_srcdump',
 440             username_param_names => [qw(username)],
 441             form_entry_size => 60,
 442             logout_param_names => [qw(caf_logout)],
 443             loggedout_param_names => [qw(caf_loggedout)],
 444             promise_check_mutate => 0,
 445             get_param => sub { $_[0]->param($_[2]) },
 446             get_params => sub { $_[1]->get_params() },
 447             get_path_info => sub { $_[0]->path_info() },
 448             get_cookie => sub { $_[0]->cookie($_[1]->{S}{cookie_name}) },
 449             get_method => sub { $_[0]->request_method() },
 450             is_https => sub { !!$_[0]->https() },
 451             get_url => sub { $_[0]->url(); },
 452             is_login => sub { defined $_[1]->_rp('password_param_name') },
 453             login_ok => \&login_ok_password,
 454             username_password_error => sub { die },
 455             is_logout => sub { $_[1]->has_a_param('logout_param_names') },
 456             is_loggedout => sub { $_[1]->has_a_param('loggedout_param_names') },
 457             is_page => sub { return 1 },
 458             handle_divert => sub { return 0 },
 459             do_redirect => \&do_redirect_cgi, # this hook is allowed to throw
 460             cookie_path => "/",
 461             get_cookie_domain => \&get_cookie_domain,
 462             encrypted_only => 1,
 463             gen_start_html => sub { $_[0]->start_html($_[2]); },
 464             gen_footer_html => \&gen_plain_footer_html,
 465             gen_licence_link_html => \&gen_plain_licence_link_html,
 466             gen_source_link_html => \&gen_plain_source_link_html,
 467             gen_end_html => sub { $_[0]->end_html(); },
 468             gen_login_form => \&gen_plain_login_form,
 469             gen_login_link => \&gen_plain_login_link,
 470             gen_postmainpage_form => \&gen_postmainpage_form,
 471             srcdump_dump => \&srcdump_dump,
 472             srcdump_prepare => \&srcdump_dirscan_prepare,
 473             srcdump_licence_path => undef,
 474             srcdump_licence_files => [qw(AGPLv3 CGI/Auth/Flexible/AGPLv3)],
 475             srcdump_listitems => sub { (@INC, $ENV{'SCRIPT_FILENAME'}, $0); },
 476             srcdump_filter_cwd => 1,
 477             srcdump_system_dir => sub {
 478                 $_[2] =~ m#^/etc/|^/usr/(?!local/)(?!lib/cgi)#;
 479             },
 480             srcdump_process_item => \&srcdump_process_item,
 481             srcdump_vcs_dirs => [qw(.git .hg .bzr .svn CVS)],
 482             srcdump_vcsscript_git => "
 483                  git ls-files -z
 484                  git ls-files -z --others --exclude-from=.gitignore
 485                  find .git -print0
 486                             ",
 487             srcdump_vcsscript_hg => "false hg",
 488             srcdump_vcsscript_bzr => "false bzr",
 489             srcdump_vcsscript_svn => "false svn",
 490             srcdump_vcsscript_cvs => "false cvs",
 491             srcdump_byvcs => \&srcdump_byvcs,
 492             srcdump_novcs => \&srcdump_novcs,
 493             srcdump_excludes => [qw(*~ *.bak *.tmp), '#*#'],
 494             dump => \&dump_plain,
 495             gettext => sub { gettext($_[2]); },
 496             print => sub { print $_[2] or die $!; },
 497             debug => sub { }, # like print; msgs contain trailing \n
 498         },
 499         Dbh => undef,
 500     };
 501     my ($k,$v);
 502     while (($k,$v,@_) = @_) {
 503         die "unknown setting $k" unless
 504             $k =~ m/^promise_/ or
 505             exists $verifier->{S}{$k};
 506         $verifier->{S}{$k} = $v;
 507     }
 508     bless $verifier, $class;
 509     $verifier->_dbopen();
 510     $verifier->_ch('srcdump_prepare');
 511     return $verifier;
 512 }
 513
 514 sub _db_setup_do ($$) {
 515     my ($v, $sql) = @_;
 516     my $dbh = $v->{Dbh};
 517     eval {
 518         $v->_db_transaction(sub {
 519             local ($dbh->{PrintError}) = 0;
 520             $dbh->do($sql);
 521         });
 522     };
 523 }
 524
 525 sub _dbopen ($) {
 526     my ($v) = @_;
 527     my $dbh = $v->{Dbh};
 528     return $dbh if $dbh;
 529
 530     $dbh = $v->{S}{assocdb_dbh};
 531     if ($dbh) {
 532         die if $dbh->{AutoCommit};
 533         die unless $dbh->{RaiseError};
 534     } else {
 535         $v->{S}{assocdb_dsn} ||= "dbi:SQLite:dbname=".$v->_get_path('assocdb');
 536         my $dsn = $v->{S}{assocdb_dsn};
 537
 538         my $u = umask 077;
 539         $dbh = DBI->connect($dsn, $v->{S}{assocdb_user},
 540                             $v->{S}{assocdb_password}, {
 541                                 AutoCommit => 0,
 542                                 RaiseError => 1,
 543                                 ShowErrorStatement => 1,
 544                             });
 545         umask $u;
 546         die "$dsn $! ?" unless $dbh;
 547     }
 548     $v->{Dbh} = $dbh;
 549
 550     $v->_db_setup_do("CREATE TABLE $v->{S}{assocdb_table} (".
 551                      " assochash VARCHAR PRIMARY KEY,".
 552                      " username VARCHAR NOT NULL,".
 553                      " last INTEGER NOT NULL".
 554                      ")");
 555     $v->_db_setup_do("CREATE INDEX $v->{S}{assocdb_table}_timeout_index".
 556                      " ON $v->{S}{assocdb_table}".
 557                      " (last)");
 558     return $dbh;
 559 }
 560
 561 sub disconnect ($) {
 562     my ($v) = @_;
 563     my $dbh = $v->{Dbh};
 564     return unless $dbh;
 565     $dbh->disconnect();
 566 }
 567
 568 sub _db_transaction ($$) {
 569     my ($v, $fn) = @_;
 570     my $retries = 10;
 571     my $rv;
 572     my $dbh = $v->{Dbh};
 573 #print STDERR "DT entry\n";
 574     for (;;) {
 575 #print STDERR "DT loop\n";
 576         if (!eval {
 577             $rv = $fn->();
 578 #print STDERR "DT fn ok\n";
 579             1;
 580         }) {
 581 #print STDERR "DT fn error\n";
 582             { local ($@); $dbh->rollback(); }
 583 #print STDERR "DT fn throwing\n";
 584             die $@;
 585         }
 586 #print STDERR "DT fn eval ok\n";
 587         if (eval {
 588             $dbh->commit();
 589 #print STDERR "DT commit ok\n";
 590             1;
 591         }) {
 592 #print STDERR "DT commit eval ok ",Dumper($rv);
 593             return $rv;
 594         }
 595 #print STDERR "DT commit throw?\n";
 596         die $@ if !--$retries;
 597 #print STDERR "DT loop again\n";
 598     }
 599 }
 600
 601 #---------- request object methods ----------
 602
 603 sub new_request {
 604     my ($classbase, $cgi, @extra) = @_;
 605     if (!ref $classbase) {
 606         $classbase = $classbase->new_verifier(@extra);
 607     } else {
 608         die if @extra;
 609     }
 610     my $r = {
 611         V => $classbase,
 612         S => $classbase->{S},
 613         Dbh => $classbase->{Dbh},
 614         Cgi => $cgi,
 615     };
 616     bless $r, ref $classbase;
 617 }
 618
 619 sub _ch ($$@) { # calls an application hook
 620     my ($r,$methname, @args) = @_;
 621     my $methfunc = $r->{S}{$methname};
 622     die "$methname ?" unless $methfunc;
 623     return $methfunc->($r->{Cgi}, $r, @args);
 624 }
 625
 626 sub _rp ($$@) {
 627     my ($r,$pnvb) = @_;
 628     my $pn = $r->{S}{$pnvb};
 629     my $p = scalar $r->_ch('get_param',$pn)
 630 }
 631
 632 sub _debug ($@) {
 633     my ($r,@args) = @_;
 634     $r->_ch('debug',@args);
 635 }
 636
 637 sub _get_path ($$) {
 638     my ($r,$keybase) = @_;
 639     my $leaf = $r->{S}{"${keybase}_path"};
 640     return $r->_absify_path($leaf);
 641 }
 642
 643 sub _absify_path ($$) {
 644     my ($v,$leaf) = @_;
 645     return $leaf if $leaf =~ m,^/,;
 646     my $dir = $v->{S}{dir};
 647     die "relying on cwd by default ?!  set dir" unless defined $dir;
 648     return "$dir/$leaf";
 649 }
 650
 651 sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
 652 sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
 653
 654 sub construct_cookie ($$$) {
 655     my ($r, $cooks) = @_;
 656     return undef unless $cooks;
 657     my $c = $r->{Cgi};
 658 my @ca = (-name => $r->{S}{cookie_name},
 659                              -value => $cooks,
 660                              -path => $r->{S}{cookie_path},
 661                              -domain => $r->_ch('get_cookie_domain'),
 662                              -expires => '+'.$r->{S}{login_timeout}.'s',
 663                              -secure => $r->{S}{encrypted_only});
 664     my $cookie = $c->cookie(@ca);
 665 #print STDERR "CC $r $c $cooks $cookie (@ca).\n";
 666     return $cookie;
 667 }
 668
 669 # pages/param-sets are
 670 #   n normal non-mutating page
 671 #   r retrieval of information for JS etc., non-mutating
 672 #   m mutating page
 673 #   u update of information by JS etc., mutating
 674 #   i login
 675 #   o logout
 676 #   O "you have just logged out" page load
 677
 678 # in cook and par,
 679 #    -         no value supplied (represented in code as $cookt='')
 680 #    n, nN     value not in our db
 681 #    t, tN     temporary value (in our db, no logged in user yet)
 682 #    y, yN     value corresponds to logged-in user
 683 # and, aggregated conditions:
 684 #    a, aN     anything including -
 685 #    x, xN     t or y
 686 # if N differs the case applies only when the two values differ
 687 # (eg,   a1 y2   does not apply when the logged-in value is supplied twice)
 688
 689 # "stale session" means request originates from a page from a login
 690 # session which has been revoked (eg by logout); "cleared session"
 691 # means request originates from a browser which has a different (or
 692 # no) cookie.
 693
 694     # Case analysis, cookie mode, app promises re mutate:
 695     # cook parm meth form
 696     #
 697     #  any -   POST  nrmuoi   bug or attack, fail
 698     #  any -   GET    rmuoi   bug or attack, fail
 699     #  any any GET     muoi   bug or attack, fail
 700     #  any t   any   nrmu     bug or attack, fail
 701     #
 702     #  -   -   GET         O  "just logged out" page
 703     #  (any other)         O  bug or attack, fail
 704     #
 705     #  a1  a2  POST      o    logout
 706     #                           if a1 is valid, revoke it
 707     #                           if a2 is valid, revoke it
 708     #                           delete cookie
 709     #                           redirect to "just logged out" page
 710     #                             (which contains link to login form)
 711     #
 712     #  -   t   POST       i   complain about cookies being disabled
 713     #                           (with link to login form)
 714     #
 715     #  t1  t1  POST       i   login (or switch user)
 716     #                           if bad
 717     #                             show new login form
 718     #                           if good
 719     #                             upgrade t1 to y1 in our db (setting username)
 720     #                             redirect to GET of remaining params
 721     #
 722     #  y1  a2  POST       i   complain about stale login form
 723     #                           revoke y1
 724     #                           show new login form
 725     #
 726     #  (other) POST       i   complain about stale login form
 727     #                           show new login form
 728     #
 729     #  t1  a2  ANY   nrmu     treat as  - a2 ANY
 730     #
 731     #  y   -   GET   n        cross-site link
 732     #                           show data
 733     #
 734     #  y   y   GET   nr       fine, show page or send data
 735     #  y   y   POST  nrmu     mutation is OK, do operation
 736     #
 737     #  y1  y2  GET   nr       request from stale page
 738     #                           do not revoke y2 as not RESTful
 739     #                           treat as   y1 n GET
 740     #
 741     #  y1  y2  POST  nrmu     request from stale page
 742     #                           revoke y2
 743     #                           treat as   y1 n POST
 744     #
 745     #  y   n   GET   n        intra-site link from stale page,
 746     #                           treat as cross-site link, show data
 747     #
 748     #  y   n   POST  n m      intra-site form submission from stale page
 749     #                           show "session interrupted"
 750     #                           with link to main data page
 751     #
 752     #  y   n   GET    r       intra-site request from stale page
 753     #                           fail
 754     #
 755     #  y   n   POST   r u     intra-site request from stale page
 756     #                           fail
 757     #
 758     #  -/n y2  GET   nr       intra-site link from cleared session
 759     #                           do not revoke y2 as not RESTful
 760     #                           treat as   -/n n GET
 761     #
 762     #  -/n y2  POST  nrmu     request from cleared session
 763     #                           revoke y2
 764     #                           treat as   -/n n POST
 765     #
 766     #  -/n -/n GET   n        cross-site link but user not logged in
 767     #                           show login form with redirect to orig params
 768     #                           generate fresh cookie
 769     #
 770     #  -/n n   GET    rmu     user not logged in
 771     #                           fail
 772     #
 773     #  -/n n   POST  n m      user not logged in
 774     #                           show login form
 775     #
 776     #  -/n n   POST   r u     user not logged in
 777     #                           fail
 778
 779 sub _check_divert_core ($) {
 780     my ($r) = @_;
 781
 782     my $srcdump = $r->_rp('srcdump_param_name');
 783     if ($srcdump) {
 784         die if $srcdump =~ m/\W/;
 785         return ({ Kind => 'SRCDUMP-'.uc $srcdump,
 786                   Message => undef,
 787                   CookieSecret => undef,
 788                   Params => { } });
 789     }
 790
 791     my $cooks = $r->_ch('get_cookie');
 792
 793     if ($r->{S}{encrypted_only} && !$r->_ch('is_https')) {
 794         return ({ Kind => 'REDIRECT-HTTPS',
 795                   Message => $r->_gt("Redirecting to secure server..."),
 796                   CookieSecret => undef,
 797                   Params => { } });
 798     }
 799
 800     my $meth = $r->_ch('get_method');
 801     my $parmh = $r->_rp('assoc_param_name');
 802     my $cookh = defined $cooks ? $r->hash($cooks) : undef;
 803
 804     my ($cookt,$cooku) = $r->_identify($cookh, $cooks);
 805     my $parms = (defined $cooks && defined $parmh && $parmh eq $cookh)
 806         ? $cooks : undef;
 807     my ($parmt) = $r->_identify($parmh, $parms);
 808
 809     $r->_debug("_c_d_c cookt=$cookt parmt=$parmt\n");
 810
 811     if ($r->_ch('is_logout')) {
 812         $r->_must_be_post();
 813         die unless $parmt;
 814         $r->_db_revoke($cookh);
 815         $r->_db_revoke($parmh);
 816         return ({ Kind => 'REDIRECT-LOGGEDOUT',
 817                   Message => $r->_gt("Logging out..."),
 818                   CookieSecret => '',
 819                   Params => { } });
 820     }
 821     if ($r->_ch('is_loggedout')) {
 822         die unless $meth eq 'GET';
 823         die if $cookt eq 'y';
 824         die if $parmt;
 825         return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
 826                   Message => $r->_gt("You have been logged out."),
 827                   CookieSecret => '',
 828                   Params => { } });
 829     }
 830     if ($r->_ch('is_login')) {
 831         $r->_must_be_post();
 832         die unless $parmt;
 833         if (!$cookt && $parmt eq 'n') {
 834             return ({ Kind => 'SMALLPAGE-NOCOOKIE',
 835                       Message => $r->_gt("You do not seem to have cookies".
 836                                          " enabled.  You must enable cookies".
 837                                          " as we use them for login."),
 838                       CookieSecret => $r->_fresh_secret(),
 839                       Params => $r->chain_params() })
 840         }
 841         if (!$cookt || $cookt eq 'n' || $cookh ne $parmh) {
 842             $r->_db_revoke($cookh);
 843             return ({ Kind => 'LOGIN-STALE',
 844                       Message => $r->_gt("Stale session;".
 845                                          " you need to log in again."),
 846                       CookieSecret => $r->_fresh_secret(),
 847                       Params => { } })
 848         }
 849         die unless $parmt eq 't' || $parmt eq 'y';
 850         my ($username, $login_errormessage) = $r->_ch('login_ok');
 851         unless (defined $username && length $username) {
 852             $login_errormessage = $r->_gt("Incorrect username/password.")
 853                 if !$login_errormessage;
 854             return ({ Kind => 'LOGIN-BAD',
 855                       Message => $login_errormessage,
 856                       CookieSecret => $cooks,
 857                       Params => $r->chain_params() })
 858         }
 859         $r->_db_record_login_ok($parmh,$username);
 860         return ({ Kind => 'REDIRECT-LOGGEDIN',
 861                   Message => $r->_gt("Logging in..."),
 862                   CookieSecret => $cooks,
 863                   Params => $r->chain_params() });
 864     }
 865     if ($cookt eq 't') {
 866         $cookt = '';
 867     }
 868     die if $parmt eq 't';
 869
 870     if ($cookt eq 'y' && $parmt eq 'y' && $cookh ne $parmh) {
 871         $r->_db_revoke($parmh) if $meth eq 'POST';
 872         $parmt = 'n';
 873     }
 874
 875     if ($cookt ne 'y') {
 876         die unless !$cookt || $cookt eq 'n';
 877         die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
 878         my $news = $r->_fresh_secret();
 879         if ($meth eq 'GET') {
 880             return ({ Kind => 'LOGIN-INCOMINGLINK',
 881                       Message => $r->_gt("You need to log in."),
 882                       CookieSecret => $news,
 883                       Params => $r->chain_params() });
 884         } else {
 885             $r->_db_revoke($parmh);
 886             return ({ Kind => 'LOGIN-FRESH',
 887                       Message => $r->_gt("You need to log in."),
 888                       CookieSecret => $news,
 889                       Params => { } });
 890         }
 891     }
 892
 893     if (!$r->{S}{promise_check_mutate}) {
 894         if ($meth ne 'POST') {
 895             return ({ Kind => 'MAINPAGEONLY',
 896                       Message => $r->_gt('Entering via cross-site link.'),
 897                       CookieSecret => $cooks,
 898                       Params => { } });
 899             # NB caller must then ignore params & path!
 900             # if this is too hard they can spit out a small form
 901             # with a "click to continue"
 902         }
 903     }
 904
 905     die unless $cookt eq 'y';
 906     unless ($r->{S}{promise_check_mutate} && $meth eq 'GET') {
 907         die unless $parmt eq 'y';
 908         die unless $cookh eq $parmh;
 909     }
 910     $r->{ParmT} = $parmt;
 911     $r->{AssocSecret} = $cooks;
 912     $r->{UserOK} = $cooku;
 913 #print STDERR "C-D-C OK\n";
 914     return undef;
 915 }
 916
 917 sub chain_params ($) {
 918     my ($r) = @_;
 919     my %p = %{ $r->_ch('get_params') };
 920     foreach my $pncn (keys %{ $r->{S} }) {
 921         my $names;
 922         if ($pncn =~ m/_param_name$/) {
 923             my $name = $r->{S}{$pncn};
 924             die "$pncn ?" if ref $name;
 925             $names = [ $name ];
 926         } elsif ($pncn =~ m/_param_names$/) {
 927             $names = $r->{S}{$pncn};
 928         } else {
 929             next;
 930         }
 931         foreach my $name (@$names) {
 932             delete $p{$name};
 933         }
 934     }
 935     my $dummy_prefix = $r->{S}{dummy_param_name_prefix};
 936     foreach my $name (grep /^$dummy_prefix/, keys %p) {
 937         delete $p{$name};
 938     }
 939     die if exists $p{''};
 940     $p{''} = [ $r->_ch('get_path_info') ];
 941     return \%p;
 942 }
 943
 944 sub _identify ($$) {
 945     my ($r,$h,$s) = @_;
 946     # returns ($t,$username)
 947     # where $t is one of "t" "y" "n", or "" (for -)
 948     # either $s must be undef, or $h eq $r->hash($s)
 949
 950 #print STDERR "_identify\n";
 951     return '' unless defined $h && length $h;
 952 #print STDERR "_identify h=$h s=".(defined $s ? $s : '<undef>')."\n";
 953
 954     my $dbh = $r->{Dbh};
 955
 956     $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
 957              " WHERE last < ?", {},
 958              time - $r->{S}{login_timeout});
 959
 960     my $row = $dbh->selectrow_arrayref("SELECT username, last".
 961                               " FROM $r->{S}{assocdb_table}".
 962                               " WHERE assochash = ?", {}, $h);
 963     if (defined $row) {
 964 #print STDERR "_identify h=$h s=$s YES @$row\n";
 965         my ($nusername, $nlast) = @$row;
 966         return ('y', $nusername);
 967     }
 968
 969     # Well, it's not in the database.  But maybe it's a hash of a
 970     # temporary secret.
 971
 972     return 'n' unless defined $s;
 973
 974     my ($keyt, $signature, $message, $noncet, $nonce) =
 975         $s =~ m/^(\d+)\.(\w+)\.((\d+)\.(\w+))$/ or die;
 976
 977     return 'n' if time > $noncet + $r->{S}{login_form_timeout};
 978
 979 #print STDERR "_identify noncet=$noncet ok\n";
 980
 981     my $keys = $r->_open_keys();
 982     while (my ($rkeyt, $rkey, $line) = $r->_read_key($keys)) {
 983 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey\n";
 984         last if $rkeyt < $keyt; # too far down in the file
 985         my $trysignature = $r->_hmac($rkey, $message);
 986 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey try=$trysignature\n";
 987         return 't' if $trysignature eq $signature;
 988     }
 989     # oh well
 990 #print STDERR "_identify NO\n";
 991
 992     $keys->error and die $!;
 993     return 'n';
 994 }
 995
 996 sub _db_revoke ($$) {
 997     # revokes $h if it's valid; no-op if it's not
 998     my ($r,$h) = @_;
 999
1000     my $dbh = $r->{Dbh};
1001
1002     $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
1003              " WHERE assochash = ?", {}, $h);
1004 }
1005
1006 sub _db_record_login_ok ($$$) {
1007     my ($r,$h,$user) = @_;
1008     $r->_db_revoke($h);
1009     my $dbh = $r->{Dbh};
1010     $dbh->do("INSERT INTO $r->{S}{assocdb_table}".
1011              " (assochash, username, last) VALUES (?,?,?)", {},
1012              $h, $user, time);
1013 }
1014
1015 sub check_divert ($) {
1016     my ($r) = @_;
1017     if (exists $r->{Divert}) {
1018         return $r->{Divert};
1019     }
1020     my $dbh = $r->{Dbh};
1021     $r->{Divert} = $r->_db_transaction(sub { $r->_check_divert_core(); });
1022     $dbh->commit();
1023     $r->_debug(Data::Dumper->Dump([$r->{Divert}],[qw(divert)]));
1024     return $r->{Divert};
1025 }
1026
1027 sub get_divert ($) {
1028     my ($r) = @_;
1029     die "unchecked" unless exists $r->{Divert};
1030     return $r->{Divert};
1031 }
1032
1033 sub get_username ($) {
1034     my ($r) = @_;
1035     my $divert = $r->get_divert();
1036     return undef if $divert;
1037     return $r->{UserOK};
1038 }
1039
1040 sub url_with_query_params ($$;$) {
1041     my ($r, $params, $nonpagetype) = @_;
1042 #print STDERR "PARAMS ",Dumper($params);
1043     my $uri = URI->new($r->_ch('get_url'));
1044     $uri->path($uri->path() . $params->{''}[0]) if $params->{''};
1045     my @flatparams = flatten_params($params);
1046     if (defined $nonpagetype && $r->need_add_hidden('GET',$nonpagetype)) {
1047         push @flatparams, $r->{S}{assoc_param_name}, $r->secret_hidden_val();
1048     }
1049     $uri->query_form(@flatparams);
1050     return $uri->as_string();
1051 }
1052
1053 sub _cgi_header_args ($$@) {
1054     my ($r, $cookie, @ha) = @_;
1055     unshift @ha, qw(-type text/html);
1056     push @ha, (-cookie => $cookie) if defined $cookie;
1057 #print STDERR "_cgi_header_args ",join('|',@ha),".\n";
1058     return @ha;
1059 }
1060
1061 sub check_ok ($) {
1062     my ($r) = @_;
1063
1064     my ($divert) = $r->check_divert();
1065     return 1 if !$divert;
1066
1067     my $handled = $r->_ch('handle_divert',$divert);
1068     return 0 if $handled;
1069
1070     my $kind = $divert->{Kind};
1071     my $cookiesecret = $divert->{CookieSecret};
1072     my $params = $divert->{Params};
1073     my $cookie = $r->construct_cookie($cookiesecret);
1074
1075     if ($kind =~ m/^SRCDUMP-(\w+)$/) {
1076         $r->_ch('srcdump_dump', (lc $1));
1077         return 0;
1078     }
1079
1080     if ($kind =~ m/^REDIRECT-/) {
1081         # for redirects, we honour stored Params and Cookie,
1082         # as we would for non-divert
1083         if ($kind eq 'REDIRECT-LOGGEDOUT') {
1084             $params->{$r->{S}{loggedout_param_names}[0]} = [ 1 ];
1085         } elsif ($kind eq 'REDIRECT-LOGOUT') {
1086             $params->{$r->{S}{logout_param_names}[0]} = [ 1 ];
1087         } elsif ($kind =~ m/REDIRECT-(?:LOGGEDIN|HTTPS)/) {
1088         } else {
1089             die;
1090         }
1091         my $new_url = $r->url_with_query_params($params);
1092         if ($kind eq 'REDIRECT-HTTPS') {
1093             my $uri = URI->new($new_url);
1094             die unless $uri->scheme eq 'http';
1095             $uri->scheme('https');
1096             $new_url = $uri->as_string();
1097         }
1098         $r->_ch('do_redirect',$new_url, $cookie);
1099         return 0;
1100     }
1101
1102     if (defined $cookiesecret) {
1103         $params->{$r->{S}{assoc_param_name}} = [ $r->hash($cookiesecret) ];
1104     }
1105
1106     my ($title, @body);
1107     if ($kind =~ m/^LOGIN-/) {
1108         $title = $r->_gt('Login');
1109         push @body, $divert->{Message};
1110         push @body, $r->_ch('gen_login_form', $params);
1111     } elsif ($kind =~ m/^SMALLPAGE-/) {
1112         $title = $r->_gt('Not logged in');
1113         push @body, $divert->{Message};
1114         push @body, $r->_ch('gen_login_link', $params);
1115     } elsif ($kind =~ m/^MAINPAGEONLY$/) {
1116         $title = $r->_gt('Entering secure site.');
1117         push @body, $divert->{Message};
1118         push @body, $r->_ch('gen_postmainpage_form', $params);
1119     } else {
1120         die $kind;
1121     }
1122
1123     $r->_print($r->{Cgi}->header($r->_cgi_header_args($cookie)),
1124                $r->_ch('gen_start_html',$title),
1125                (join "\n", (@body,
1126                             $r->_ch('gen_footer_html'),
1127                             $r->_ch('gen_end_html'))));
1128     return 0;
1129 }
1130
1131 sub _random ($$) {
1132     my ($r, $bytes) = @_;
1133     my $v = $r->{V};
1134     my $rsf = $v->{RandomHandle};
1135     my $rsp = $r->{S}{random_source};
1136     if (!$rsf) {
1137         $v->{RandomHandle} = $rsf = new IO::File $rsp, '<' or die "$rsp $!";
1138 #print STDERR "RH $rsf\n";
1139     }
1140     my $bin;
1141     $!=0;
1142     read($rsf,$bin,$bytes) == $bytes or die "$rsp $!";
1143     my $out = unpack "H*", $bin;
1144 #print STDERR "_random out $out\n";
1145     return $out;
1146 }
1147
1148 sub _random_key ($) {
1149     my ($r) = @_;
1150 #print STDERR "_random_key\n";
1151     my $bytes = ($r->{S}{secretbits} + 7) >> 3;
1152     return $r->_random($bytes);
1153 }
1154
1155 sub _read_key ($$) {
1156     my ($r, $keys) = @_;
1157     # returns $gen_time_t, $key_value_in_hex, $complete_line
1158     while (<$keys>) {
1159         my ($gen, $k) = m/^(\d+) (\S+)$/ or die "$_ ?";
1160         my $age = time - $gen;
1161         next if $age > $r->{S}{key_rollover} &&
1162             $age > $r->{S}{login_form_timeout}*2;
1163         return ($gen, $k, $_);
1164     }
1165     return ();
1166 }
1167
1168 sub _open_keys ($) {
1169     my ($r) = @_;
1170     my $spath = $r->_get_path('keys');
1171     for (;;) {
1172 #print STDERR "_open_keys\n";
1173         my $keys = new IO::File $spath, 'r+';
1174         if ($keys) {
1175 #print STDERR "_open_keys open\n";
1176             stat $keys or die $!; # NB must not disturb stat _
1177             my $size = (stat _)[7];
1178             my $age = time - (stat _)[9];
1179 #print STDERR "_open_keys open size=$size age=$age\n";
1180             return $keys
1181                 if $size && $age <= $r->{S}{key_rollover} / 2;
1182 #print STDERR "_open_keys open bad\n";
1183         }
1184         # file doesn't exist, or is empty or too old
1185         if (!$keys) {
1186 #print STDERR "_open_keys closed\n";
1187             die "$spath $!" unless $!==&ENOENT;
1188             # doesn't exist, so create it just so we can lock it
1189             $keys = new IO::File $spath, 'a+';
1190             die "$keys $!" unless $keys;
1191             stat $keys or die $!; # NB must not disturb stat _
1192             my $size = (stat _)[7];
1193 #print STDERR "_open_keys created size=$size\n";
1194             next if $size; # oh someone else has done it, reopen and read it
1195         }
1196         # file now exists is empty or too old, we must try to replace it
1197         my $our_inum = (stat _)[1]; # last use of that stat _
1198         flock $keys, LOCK_EX or die "$spath $!";
1199         stat $spath or die "$spath $!";
1200         my $path_inum = (stat _)[1];
1201 #print STDERR "_open_keys locked our=$our_inum path=$path_inum\n";
1202         next if $our_inum != $path_inum; # someone else has done it
1203         # We now hold the lock!
1204 #print STDERR "_open_keys creating\n";
1205         my $newkeys = new IO::Handle;
1206         sysopen $newkeys, "$spath.new", O_CREAT|O_TRUNC|O_WRONLY, 0600
1207             or die "$spath.new $!";
1208         # we add the new key to the front which means it's always sorted
1209         print $newkeys time, ' ', $r->_random_key(), "\n" or die $!;
1210         while (my ($gen,$key,$line) = $r->_read_key($keys)) {
1211 #print STDERR "_open_keys copy1\n";
1212             print $newkeys, $line or die $!;
1213         }
1214         $keys->error and die $!;
1215         close $newkeys or die "$spath.new $!";
1216         rename "$spath.new", "$spath" or die "$spath: $!";
1217 #print STDERR "_open_keys installed\n";
1218         # that rename effective unlocks, since it makes the name refer
1219         #  to the new file which we haven't locked
1220         # we go round again opening the file at the beginning
1221         #  so that our caller gets a fresh handle onto the existing key file
1222     }
1223 }
1224
1225 sub _fresh_secret ($) {
1226     my ($r) = @_;
1227 #print STDERR "_fresh_secret\n";
1228
1229     my $keys = $r->_open_keys();
1230     my ($keyt, $key) = $r->_read_key($keys);
1231     die unless defined $keyt;
1232
1233     my $nonce = $r->_random_key();
1234     my $noncet = time;
1235     my $message = "$noncet.$nonce";
1236
1237     my $signature = $r->_hmac($key, $message);
1238     my $secret = "$keyt.$signature.$message";
1239 #print STDERR "FRESH $secret\n";
1240     return $secret;
1241 }
1242
1243 sub _hmac ($$$) {
1244     my ($r, $keyhex, $message) = @_;
1245     my $keybin = pack "H*", $keyhex;
1246     my $alg = $r->{S}{hash_algorithm};
1247 #print STDERR "hmac $alg\n";
1248     my $base = new Digest $alg;
1249 #print STDERR "hmac $alg $base\n";
1250     my $digest = new Digest::HMAC $keybin, $base;
1251 #print STDERR "hmac $alg $base $digest\n";
1252     $digest->add($message);
1253     return $digest->hexdigest();
1254 }
1255
1256 sub hash ($$) {
1257     my ($r, $message) = @_;
1258     my $alg = $r->{S}{hash_algorithm};
1259 #print STDERR "hash $alg\n";
1260     my $digest = new Digest $alg;
1261     $digest->add($message);
1262     return $digest->hexdigest();
1263 }
1264
1265 sub _assert_checked ($) {
1266     my ($r) = @_;
1267     die "unchecked" unless exists $r->{Divert};
1268 }
1269
1270 sub _is_post ($) {
1271     my ($r) = @_;
1272     my $meth = $r->_ch('get_method');
1273     return $meth eq 'POST';
1274 }
1275
1276 sub _must_be_post ($) {
1277     my ($r) = @_;
1278     my $meth = $r->_ch('get_method');
1279     die "mutating non-POST" if $meth ne 'POST';
1280 }
1281
1282 sub check_mutate ($) {
1283     my ($r) = @_;
1284     $r->_assert_checked();
1285     die if $r->{Divert};
1286     $r->_must_be_post();
1287 }
1288
1289 our %_resource_get_needs_secret_hidden =
1290     (map { $_ => 0 } qw(PAGE FRAME IFRAME SRCDUMP STYLESHEET FAVICON ROBOTS),
1291      map { $_ => 1 } qw(IMAGE SCRIPT AJAX-XML AJAX-JSON AJAX-OTHER));
1292
1293 sub update_get_need_add_hidden ($$;$) {
1294     my ($r, $reqtype, $value, $force) = @_;
1295     my $hash = ref $r
1296         ? ($r->{GetNeedsSecretHidden} ||= { })
1297         : \%_resource_get_needs_secret_hidden;
1298     return if !$force &&
1299         (exists $_resource_get_needs_secret_hidden{$reqtype} ||
1300          exists $hash->{$reqtype});
1301     $hash->{$reqtype} = $value;
1302 }
1303
1304 sub need_add_hidden ($$) {
1305     my ($r, $method, $reqtype) = @_;
1306     return 1 if $method ne 'GET';
1307     if (ref $r) {
1308         my $ent = $r->{GetNeedsSecretHidden}{$reqtype};
1309         return $ent if defined $ent;
1310     }
1311     my $ent = $_resource_get_needs_secret_hidden{$reqtype};
1312     return $ent if defined $ent;
1313     die "unsupported nonpage GET type $reqtype";
1314 }
1315
1316 sub check_nonpage ($$) {
1317     my ($r, $reqtype) = @_;
1318     $r->_assert_checked();
1319     return unless $r->resource_get_needs_secret_hidden($nonpagetype);
1320     return if $r->{ParmT};
1321     die "missing hidden secret parameter on nonpage request $nonpagetype";
1322 }
1323
1324 #---------- output ----------
1325
1326 sub secret_cookie_val ($) {
1327     my ($r) = @_;
1328     $r->_assert_checked();
1329     return defined $r->{AssocSecret} ? $r->{AssocSecret} : '';
1330 }
1331
1332 sub secret_hidden_val ($) {
1333     my ($r) = @_;
1334     $r->_assert_checked();
1335     return defined $r->{AssocSecret} ? $r->hash($r->{AssocSecret}) : '';
1336 }
1337
1338 sub secret_hidden_html ($) {
1339     my ($r) = @_;
1340     return $r->{Cgi}->hidden(-name => $r->{S}{assoc_param_name},
1341                              -default => $r->secret_hidden_val());
1342 }
1343
1344 sub secret_cookie ($) {
1345     my ($r) = @_;
1346     my $secret = $r->secret_cookie_val();
1347     return undef if !defined $secret;
1348 #print STDERR "SC\n";
1349     my $cookv = $r->construct_cookie($secret);
1350 #print STDERR "SC=$cookv\n";
1351     return $cookv;
1352 }
1353
1354 1;