cgi-auth-flexible.pm

   1 # -*- perl -*-
   2
   3 # This is part of CGI::Auth::Flexible, a perl CGI authentication module.
   4 # Copyright (C) 2012 Ian Jackson.
   5 # Copyright (C) 2012 Citrix.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU Affero General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU Affero General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Affero General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings FATAL => 'all';
  22
  23 package CGI::Auth::Flexible;
  24 require Exporter;
  25
  26 BEGIN {
  27     use Exporter   ();
  28     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  29
  30     $VERSION     = 1.00;
  31     @ISA         = qw(Exporter);
  32     @EXPORT      = qw();
  33     %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
  34 }
  35 our @EXPORT_OK;
  36
  37 use DBI;
  38 use CGI qw/escapeHTML/;
  39 use Locale::gettext;
  40 use URI;
  41 use IO::File;
  42 use Fcntl qw(:flock);
  43 use POSIX;
  44 use Digest;
  45 use Digest::HMAC;
  46 use Digest::SHA;
  47 use Data::Dumper;
  48 use File::Copy;
  49 use Cwd qw/realpath/;
  50
  51
  52 #---------- public utilities ----------
  53
  54 sub flatten_params ($) {
  55     my ($p) = @_;
  56     my @p;
  57     foreach my $k (keys %$p) {
  58         next if $k eq '';
  59         foreach my $v (@{ $p->{$k} }) {
  60             push @p, $k, $v;
  61         }
  62     }
  63     return @p;
  64 }
  65
  66 #---------- default callbacks ----------
  67
  68 sub has_a_param ($$) {
  69     my ($r,$cn) = @_;
  70     foreach my $pn (@{ $r->{S}{$cn} }) {
  71         return 1 if $r->_ch('get_param',$pn);
  72     }
  73     return 0;
  74 }
  75
  76 sub get_params ($) {
  77     my ($r) = @_;
  78     my $c = $r->{Cgi};
  79     my $vars = $c->Vars();
  80     my %p;
  81     foreach my $name (keys %$vars) {
  82         $p{$name} = [ split "\0", $vars->{$name} ];
  83     }
  84     return \%p;
  85 }
  86
  87 sub get_cookie_domain ($$$) {
  88     my ($c,$r) = @_;
  89     my $uri = new URI $r->_ch('get_url');
  90     return $uri->host();
  91 }
  92
  93 sub login_ok_password ($$) {
  94     my ($c, $r) = @_;
  95     my $username_params = $r->{S}{username_param_names};
  96     my $username = $r->_ch('get_param',$username_params->[0]);
  97     my $password = $r->_rp('password_param_name');
  98     my $error = $r->_ch('username_password_error', $username, $password);
  99     return defined($error) ? (undef,$error) : ($username,undef);
 100 }
 101
 102 sub do_redirect_cgi ($$$$) {
 103     my ($c, $r, $new_url, $cookie) = @_;
 104     $r->_print($c->header($r->_cgi_header_args($cookie,
 105                                                -status => '303 See other',
 106                                                -location => $new_url)),
 107                $r->_ch('gen_start_html',$r->_gt('Redirection')),
 108                '<a href="'.escapeHTML($new_url).'">',
 109                $r->_gt("If you aren't redirected, click to continue."),
 110                "</a>",
 111                $r->_ch('gen_end_html'));
 112 }
 113
 114 sub gen_some_form ($$) {
 115     my ($r, $params, $bodyfn) = @_;
 116     # Calls $bodyfn->($c,$r) which returns @formbits
 117     my $c = $r->{Cgi};
 118     my @form;
 119     my $pathinfo = '';
 120     $pathinfo .= $params->{''}[0] if $params->{''};
 121     push @form, ('<form method="POST" action="'.
 122                  escapeHTML($r->_ch('get_url').$pathinfo).'">');
 123     push @form, $bodyfn->($c,$r);
 124     foreach my $n (keys %$params) {
 125         next if $n eq '';
 126         foreach my $val (@{ $params->{$n} }) {
 127             push @form, ('<input type="hidden"'.
 128                          ' name="'.escapeHTML($n).'"'.
 129                          ' value="'.escapeHTML($val).'">');
 130         }
 131     }
 132     push @form, ('</form>');
 133     return join "\n", @form;
 134 }
 135
 136 sub gen_plain_login_form ($$) {
 137     my ($c,$r, $params) = @_;
 138     return $r->gen_some_form($params, sub {
 139         my @form;
 140         push @form, ('<table>');
 141         my $sz = 'size="'.$r->{S}{form_entry_size}.'"';
 142         foreach my $up (@{ $r->{S}{username_param_names}}) {
 143             push @form, ('<tr><td>',$r->_gt(ucfirst $up),'</td>',
 144                          '<td><input type="text" '.$sz.
 145                          ' name='.$up.'></td></tr>');
 146         }
 147         push @form, ('<tr><td>'.$r->_gt('Password').'</td>',
 148                      '<td><input type="password" '.$sz.
 149                      ' name="'.$r->{S}{password_param_name}.'"></td></tr>');
 150         push @form, ('<tr><td colspan="2">',
 151                      '<input type="submit"'.
 152                      ' name="'.$r->{S}{dummy_param_name_prefix}.'login"'.
 153                      ' value="'.$r->_gt('Login').'"></td></tr>',
 154                      '</table>');
 155         return @form;
 156     });
 157 }
 158
 159 sub gen_postmainpage_form ($$$) {
 160     my ($c,$r, $params) = @_;
 161     return $r->gen_some_form($params, sub {
 162         my @form;
 163         push @form, ('<input type="submit"',
 164                      ' name="'.$r->{S}{dummy_param_name_prefix}.'submit"'.
 165                      ' value="'.$r->_gt('Continue').'">');
 166         return @form;
 167     });
 168 }
 169
 170 sub gen_plain_login_link ($$) {
 171     my ($c,$r, $params) = @_;
 172     my $url = $r->url_with_query_params($params);
 173     return ('<a href="'.escapeHTML($url).'">'.
 174             $r->_gt('Log in again to continue.').
 175             '</a>');
 176 }
 177
 178 sub gen_srcdump_link_html ($$$$) {
 179     my ($c,$r,$anchor,$specval) = @_;
 180     my %params = ($r->{S}{srcdump_param_name} => [ $specval ]);
 181     return '<a href="'.
 182         escapeHTML($r->url_with_query_params(\%params,'SRCDUMP')).
 183         '">'.$anchor."</a>";
 184 }
 185 sub gen_plain_licence_link_html ($$) {
 186     my ($c,$r) = @_;
 187     gen_srcdump_link_html($c,$r, 'GNU Affero GPL', 'licence');
 188 }
 189 sub gen_plain_source_link_html ($$) {
 190     my ($c,$r) = @_;
 191     gen_srcdump_link_html($c,$r, 'Source available', 'source');
 192 }
 193
 194 sub gen_plain_footer_html ($$) {
 195     my ($c,$r) = @_;
 196     return ('<hr><address>',
 197             ("Powered by Free / Libre / Open Source Software".
 198              " according to the ".$r->_ch('gen_licence_link_html')."."),
 199             $r->_ch('gen_source_link_html').".",
 200             '</address>');
 201 }
 202
 203 #---------- licence and source code ----------
 204
 205 sub srcdump_dump ($$$) {
 206     my ($c,$r, $thing) = @_;
 207     die if $thing =~ m/\W/ || $thing !~ m/\w/;
 208     my $path = $r->_get_path('srcdump');
 209     my $ctf = new IO::File "$path/$thing.ctype", 'r'
 210         or die "$path/$thing.ctype $!";
 211     my $ct = <$ctf>;
 212     chomp $ct or die "$path/$thing ?";
 213     $ctf->close or die "$path/$thing $!";
 214     my $df = new IO::File "$path/$thing.data", 'r'
 215         or die "$path/$thing.data $!";
 216     $r->_ch('dump', $ct, $df);
 217 }
 218
 219 sub dump_plain ($$$$) {
 220     my ($c, $r, $ct, $df) = @_;
 221     $r->_print($c->header('-type' => $ct));
 222     my $buffer;
 223     for (;;) {
 224         my $got = read $df, $buffer, 65536;
 225         die $! unless defined $got;
 226         return if !$got;
 227         $r->_print($buffer);
 228     }
 229 }
 230
 231 sub srcdump_process_item ($$$$$$) {
 232     my ($c, $v, $dumpdir, $item, $outfn, $needlicence, $dirsdone) = @_;
 233     if ($v->_ch('srcdump_system_dir', $item)) {
 234         $outfn->("srcdump_process_item: srcdump_system_dir, skipping $item");
 235         return;
 236     }
 237     my $upwards = $item;
 238     for (;;) {
 239         $upwards =~ s#/+$##;
 240         $upwards =~ s#/+\.$##;
 241         last unless $upwards =~ m#[^/]#;
 242         foreach my $try (@{ $v->{S}{srcdump_vcs_dirs} }) {
 243 #print STDERR "TRY $item $upwards $try\n";
 244             if (!stat "$upwards/$try") {
 245                 $!==&ENOENT or $!==&ENOTDIR or die "check $upwards/$try $!";
 246                 next;
 247             }
 248 #print STDERR "VCS $item $upwards $try\n";
 249             if ($dirsdone->{$upwards}++) {
 250                 $outfn->("srcdump_process_item: did $upwards,".
 251                          " skipping $item");
 252                 return;
 253             }
 254 #print STDERR "VCS $item $upwards $try GO\n";
 255             $try =~ m/\w+/ or die;
 256             return $v->_ch('srcdump_byvcs', $dumpdir, $upwards, $outfn, lc $&);
 257         }
 258         $upwards =~ s#/*[^/]+$##;
 259     }
 260     return $v->_ch('srcdump_novcs', $dumpdir, $item, $outfn);
 261 }
 262
 263 sub srcdump_novcs ($$$$$) {
 264     my ($c, $v, $dumpdir, $item, $outfn) = @_;
 265     stat $item or die "$item $!";
 266     if (-d _) {
 267         my $script = 'find -type f -perm +004';
 268         foreach my $excl (@{ $v->{S}{srcdump_excludes} }) {
 269             $script .= " \\! -name '$excl'";
 270         }
 271         $script .= " -print0";
 272         return srcdump_dir_cpio($c,$v,$dumpdir,$item,$outfn,'novcs',$script);
 273     } elsif (-f _) {
 274         return srcdump_file($c,$v,$dumpdir,$item,$outfn);
 275     } else {
 276         die "$item not file or directory";
 277     }
 278 }
 279
 280 sub srcdump_byvcs ($$$$$$) {
 281     my ($c, $v, $dumpdir, $dir, $outfn, $vcs) = @_;
 282 #print STDERR "BYVCS GIT $dir\n";
 283     my $script = $v->{S}{"srcdump_vcsscript"}{$vcs};
 284     die "no script for vcs $vcs" unless defined $script;
 285     return srcdump_dir_cpio($c,$v,$dumpdir,$dir,$outfn,$vcs,$script);
 286 }
 287
 288 sub srcdump_file ($$$$) {
 289     my ($c,$v,$dumpdir,$file,$outfn) = @_;
 290     my $outfile = $outfn->("srcdump_file saved $file", "src");
 291     copy($file,$outfile) or die "$file $outfile $!";
 292 }
 293
 294 sub srcdump_dir_cpio ($$$$$$$) {
 295     my ($c,$v,$dumpdir,$dir,$outfn,$how,$script) = @_;
 296     my $outfile = $outfn->("srcdump_dir_cpio $how saved $dir", "tar");
 297 #print STDERR "CPIO $dir >$script<\n";
 298     my $pid = fork();
 299     defined $pid or die $!;
 300     if (!$pid) {
 301         $SIG{__DIE__} = sub {
 302             print STDERR "CGI::Auth::Flexible srcdump error: $@\n";
 303             exit 127;
 304         };
 305         open STDOUT, ">", $outfile or die "$outfile $!";
 306         chdir $dir or die "chdir $dir: $!";
 307         exec '/bin/bash','-ec',"
 308             set -o pipefail
 309             (
 310              $script
 311             ) | (
 312              cpio -Hustar -o --quiet -0 -R 1000:1000 || \
 313              cpio -Hustar -o --quiet -0
 314             )
 315             ";
 316         die $!;
 317     }
 318     $!=0; (waitpid $pid, 0) == $pid or die "$!";
 319     die "$dir ($how $script) $outfile $?" if $?;
 320 }
 321
 322 sub srcdump_dirscan_prepare ($$) {
 323     my ($c, $v) = @_;
 324     my $dumpdir = $v->_get_path('srcdump');
 325     mkdir $dumpdir or $!==&EEXIST or die "mkdir $dumpdir $!";
 326     my $lockf = new IO::File "$dumpdir/generate.lock", 'w+'
 327         or die "$dumpdir/generate.lock $!";
 328     flock $lockf, LOCK_EX or die "$dumpdir/generate.lock $!";
 329     my $needlicence = "$dumpdir/licence.tmp";
 330     unlink $needlicence or $!==&ENOENT or die "rm $needlicence $!";
 331     if (defined $v->{S}{srcdump_licence_path}) {
 332         copy($v->{S}{srcdump_licence_path}, $needlicence)
 333             or die "$v->{S}{srcdump_licence_path} $!";
 334         $needlicence = undef;
 335     }
 336     unlink <"$dumpdir/s.[a-z][a-z][a-z].*">;
 337     my @srcfiles = qw(licence.data manifest.txt);
 338     my $srcoutcounter = 'aaa';
 339
 340     my $reportfh = new IO::File "$dumpdir/manifest.txt", 'w' or die $!;
 341     my $outfn = sub {
 342         my ($message, $extension) = @_;
 343         if (defined $extension) {
 344             my $leaf = "s.$srcoutcounter.$extension";
 345             $srcoutcounter++;
 346             push @srcfiles, $leaf;
 347             print $reportfh "$leaf: $message\n" or die $!;
 348             return "$dumpdir/$leaf";
 349         } else {
 350             print $reportfh "none: $message\n" or die $!;
 351             return undef;
 352         }
 353     };
 354     my %dirsdone;
 355     foreach my $item ($v->_ch('srcdump_listitems')) {
 356         if ($item eq '.' && $v->{S}{srcdump_filter_cwd}) {
 357             my @bad = grep { !m#^/# } values %INC;
 358             die "filtering . from srcdump items and \@INC but already".
 359                 " included @bad " if @bad;
 360             @INC = grep { $_ ne '.' } @INC;
 361             next;
 362         }
 363         if (!lstat "$item") {
 364             die "stat $item $!" unless $!==&ENOENT;
 365             $outfn->("srcdump_dirscan_prepare stat ENOENT, skipping $item");
 366             next;
 367         };
 368         if (-l _) {
 369             $item = realpath($item);
 370             if (!defined $item) {
 371                 die "realpath $item $!" unless $!==&ENOENT;
 372                 $outfn->("srcdump_dirscan_prepare realpath ENOENT,".
 373                          " skipping $item");
 374             }
 375         }
 376         if (defined $needlicence) {
 377             foreach my $try (@{ $v->{S}{srcdump_licence_files} }) {
 378                 last if copy("$item/$try", $needlicence);
 379                 $!==&ENOENT or $!==&ENOTDIR or die "copy $item/$try $!";
 380             }
 381         }
 382         $v->_ch('srcdump_process_item', $dumpdir, $item,
 383                 $outfn, \$needlicence, \%dirsdone);
 384         $dirsdone{$item}++;
 385     }
 386     close $reportfh or die $!;
 387     srcdump_install($c,$v, $dumpdir, 'licence', 'text/plain');
 388     $!=0;
 389     my @cmd = (qw(tar -zvvcf), "$dumpdir/source.tmp",
 390                "-C", $dumpdir, qw(  --), @srcfiles);
 391     my $r = system(@cmd);
 392     if ($r) {
 393         print STDERR "CGI::Auth::Flexible tar failed ($r $!) @cmd\n";
 394         die "tar failed";
 395     }
 396     die "licence file not found" unless defined $needlicence;
 397     srcdump_install($c,$v, $dumpdir, 'source', 'application/octet-stream');
 398     close $lockf or die $!;
 399 }
 400
 401 sub srcdump_install ($$$$$) {
 402     my ($c,$v, $dumpdir, $which, $ctype) = @_;
 403     rename "$dumpdir/$which.tmp", "$dumpdir/$which.data"
 404         or die "$dumpdir/$which.data $!";
 405     my $ctf = new IO::File "$dumpdir/$which.tmp", 'w'
 406         or die "$dumpdir/$which.tmp $!";
 407     print $ctf $ctype, "\n" or die $!;
 408     close $ctf or die $!;
 409     rename "$dumpdir/$which.tmp", "$dumpdir/$which.ctype"
 410         or die "$dumpdir/$which.ctype $!";
 411 }
 412
 413 #---------- verifier object methods ----------
 414
 415 sub new_verifier {
 416     my $class = shift;
 417     my $verifier = {
 418         S => {
 419             dir => undef,
 420             db_dbh => undef, # must have AutoCommit=0, RaiseError=1
 421             db_path => 'caf.db',
 422             keys_path => 'caf-keys',
 423             srcdump_path => 'caf-srcdump',
 424             db_dsn => undef,
 425             db_user => '',
 426             db_password => '',
 427             db_prefix => 'caf',
 428             random_source => '/dev/urandom',
 429             secretbits => 128, # bits
 430             hash_algorithm => "SHA-256",
 431             login_timeout => 86400, # seconds
 432             login_form_timeout => 3600, # seconds
 433             key_rollover => 86400, # seconds
 434             assoc_param_name => 'caf_assochash',
 435             dummy_param_name_prefix => 'caf__',
 436             cookie_name => "caf_assocsecret",
 437             password_param_name => 'password',
 438             srcdump_param_name => 'caf_srcdump',
 439             username_param_names => [qw(username)],
 440             form_entry_size => 60,
 441             logout_param_names => [qw(caf_logout)],
 442             loggedout_param_names => [qw(caf_loggedout)],
 443             promise_check_mutate => 0,
 444             get_param => sub { $_[0]->param($_[2]) },
 445             get_params => sub { $_[1]->get_params() },
 446             get_path_info => sub { $_[0]->path_info() },
 447             get_cookie => sub { $_[0]->cookie($_[1]->{S}{cookie_name}) },
 448             get_method => sub { $_[0]->request_method() },
 449             is_https => sub { !!$_[0]->https() },
 450             get_url => sub { $_[0]->url(); },
 451             is_login => sub { defined $_[1]->_rp('password_param_name') },
 452             login_ok => \&login_ok_password,
 453             username_password_error => sub { die },
 454             is_logout => sub { $_[1]->has_a_param('logout_param_names') },
 455             is_loggedout => sub { $_[1]->has_a_param('loggedout_param_names') },
 456             handle_divert => sub { return 0 },
 457             do_redirect => \&do_redirect_cgi, # this hook is allowed to throw
 458             cookie_path => "/",
 459             get_cookie_domain => \&get_cookie_domain,
 460             encrypted_only => 1,
 461             gen_start_html => sub { $_[0]->start_html($_[2]); },
 462             gen_footer_html => \&gen_plain_footer_html,
 463             gen_licence_link_html => \&gen_plain_licence_link_html,
 464             gen_source_link_html => \&gen_plain_source_link_html,
 465             gen_end_html => sub { $_[0]->end_html(); },
 466             gen_login_form => \&gen_plain_login_form,
 467             gen_login_link => \&gen_plain_login_link,
 468             gen_postmainpage_form => \&gen_postmainpage_form,
 469             srcdump_dump => \&srcdump_dump,
 470             srcdump_prepare => \&srcdump_dirscan_prepare,
 471             srcdump_licence_path => undef,
 472             srcdump_licence_files => [qw(AGPLv3 CGI/Auth/Flexible/AGPLv3)],
 473             srcdump_listitems => sub { (@INC, $ENV{'SCRIPT_FILENAME'}, $0); },
 474             srcdump_filter_cwd => 1,
 475             srcdump_system_dir => sub {
 476                 $_[2] =~ m#^/etc/|^/usr/(?!local/)(?!lib/cgi)#;
 477             },
 478             srcdump_process_item => \&srcdump_process_item,
 479             srcdump_vcs_dirs => [qw(.git .hg .bzr .svn)],
 480             srcdump_vcsscript => [git => "
 481                  git ls-files -z
 482                  git ls-files -z --others --exclude-from=.gitignore
 483                  find .git -print0
 484                             "],
 485             srcdump_byvcs => \&srcdump_byvcs,
 486             srcdump_novcs => \&srcdump_novcs,
 487             srcdump_excludes => [qw(*~ *.bak *.tmp), '#*#'],
 488             dump => \&dump_plain,
 489             gettext => sub { gettext($_[2]); },
 490             print => sub { print $_[2] or die $!; },
 491             debug => sub { }, # like print; msgs contain trailing \n
 492         },
 493         Dbh => undef,
 494     };
 495     my ($k,$v);
 496     while (($k,$v,@_) = @_) {
 497         die "unknown setting $k" unless
 498             $k =~ m/^promise_/ or
 499             exists $verifier->{S}{$k};
 500         $verifier->{S}{$k} = $v;
 501     }
 502     $verifier->{S}{db_setup_stmts} //=
 503         ["CREATE TABLE $v->{S}{db_prefix}_assocs (".
 504          " assochash VARCHAR PRIMARY KEY,".
 505          " username VARCHAR NOT NULL,".
 506          " last INTEGER NOT NULL".
 507          ")"
 508          ,
 509          "CREATE INDEX $v->{S}{db_prefix}_assocs_timeout_index".
 510          " ON $v->{S}{db_prefix}_assocs".
 511          " (last)"
 512         ];
 513     bless $verifier, $class;
 514     $verifier->_dbopen();
 515     $verifier->_ch('srcdump_prepare');
 516     return $verifier;
 517 }
 518
 519 sub _db_setup_do ($$) {
 520     my ($v, $sql) = @_;
 521     my $dbh = $v->{Dbh};
 522     eval {
 523         $v->_db_transaction(sub {
 524             local ($dbh->{PrintError}) = 0;
 525             $dbh->do($sql);
 526         });
 527     };
 528 }
 529
 530 sub _dbopen ($) {
 531     my ($v) = @_;
 532     my $dbh = $v->{Dbh};
 533     return $dbh if $dbh;
 534
 535     $dbh = $v->{S}{db_dbh};
 536     if ($dbh) {
 537         die if $dbh->{AutoCommit};
 538         die unless $dbh->{RaiseError};
 539     } else {
 540         $v->{S}{db_dsn} ||= "dbi:SQLite:dbname=".$v->_get_path('db');
 541         my $dsn = $v->{S}{db_dsn};
 542
 543         my $u = umask 077;
 544         $dbh = DBI->connect($dsn, $v->{S}{db_user},
 545                             $v->{S}{db_password}, {
 546                                 AutoCommit => 0,
 547                                 RaiseError => 1,
 548                                 ShowErrorStatement => 1,
 549                             });
 550         umask $u;
 551         die "$dsn $! ?" unless $dbh;
 552     }
 553     $v->{Dbh} = $dbh;
 554
 555     foreach my $stmt (@{ $v->{S}{db_setup_stmts} }) {
 556         $v->_db_setup_do($stmt);
 557     }
 558     return $dbh;
 559 }
 560
 561 sub disconnect ($) {
 562     my ($v) = @_;
 563     my $dbh = $v->{Dbh};
 564     return unless $dbh;
 565     $dbh->disconnect();
 566 }
 567
 568 sub _db_transaction ($$) {
 569     my ($v, $fn) = @_;
 570     my $retries = 10;
 571     my $rv;
 572     my $dbh = $v->{Dbh};
 573 #print STDERR "DT entry\n";
 574     for (;;) {
 575 #print STDERR "DT loop\n";
 576         if (!eval {
 577             $rv = $fn->();
 578 #print STDERR "DT fn ok\n";
 579             1;
 580         }) {
 581 #print STDERR "DT fn error\n";
 582             { local ($@); $dbh->rollback(); }
 583 #print STDERR "DT fn throwing\n";
 584             die $@;
 585         }
 586 #print STDERR "DT fn eval ok\n";
 587         if (eval {
 588             $dbh->commit();
 589 #print STDERR "DT commit ok\n";
 590             1;
 591         }) {
 592 #print STDERR "DT commit eval ok ",Dumper($rv);
 593             return $rv;
 594         }
 595 #print STDERR "DT commit throw?\n";
 596         die $@ if !--$retries;
 597 #print STDERR "DT loop again\n";
 598     }
 599 }
 600
 601 #---------- request object methods ----------
 602
 603 sub new_request {
 604     my ($classbase, $cgi, @extra) = @_;
 605     if (!ref $classbase) {
 606         $classbase = $classbase->new_verifier(@extra);
 607     } else {
 608         die if @extra;
 609     }
 610     my $r = {
 611         V => $classbase,
 612         S => $classbase->{S},
 613         Dbh => $classbase->{Dbh},
 614         Cgi => $cgi,
 615     };
 616     bless $r, ref $classbase;
 617 }
 618
 619 sub _ch ($$@) { # calls an application hook
 620     my ($r,$methname, @args) = @_;
 621     my $methfunc = $r->{S}{$methname};
 622     die "$methname ?" unless $methfunc;
 623     return $methfunc->($r->{Cgi}, $r, @args);
 624 }
 625
 626 sub _rp ($$@) {
 627     my ($r,$pnvb) = @_;
 628     my $pn = $r->{S}{$pnvb};
 629     my $p = scalar $r->_ch('get_param',$pn)
 630 }
 631
 632 sub _debug ($@) {
 633     my ($r,@args) = @_;
 634     $r->_ch('debug',@args);
 635 }
 636
 637 sub _get_path ($$) {
 638     my ($r,$keybase) = @_;
 639     my $leaf = $r->{S}{"${keybase}_path"};
 640     return $r->_absify_path($leaf);
 641 }
 642
 643 sub _absify_path ($$) {
 644     my ($v,$leaf) = @_;
 645     return $leaf if $leaf =~ m,^/,;
 646     my $dir = $v->{S}{dir};
 647     die "relying on cwd by default ?!  set dir" unless defined $dir;
 648     return "$dir/$leaf";
 649 }
 650
 651 sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
 652 sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
 653
 654 sub construct_cookie ($$$) {
 655     my ($r, $cooks) = @_;
 656     return undef unless $cooks;
 657     my $c = $r->{Cgi};
 658     my @ca = (
 659         -name => $r->{S}{cookie_name},
 660         -value => $cooks,
 661         -path => $r->{S}{cookie_path},
 662         -domain => $r->_ch('get_cookie_domain'),
 663         -expires => '+'.$r->{S}{login_timeout}.'s',
 664         -secure => $r->{S}{encrypted_only}
 665         );
 666     my $cookie = $c->cookie(@ca);
 667 #print STDERR "CC $r $c $cooks $cookie (@ca).\n";
 668     return $cookie;
 669 }
 670
 671 # pages/param-sets are
 672 #   n normal non-mutating page
 673 #   r retrieval of information for JS etc., non-mutating
 674 #   m mutating page
 675 #   u update of information by JS etc., mutating
 676 #   i login
 677 #   o logout
 678 #   O "you have just logged out" page load
 679
 680 # in cook and par,
 681 #    -         no value supplied (represented in code as $cookt='')
 682 #    n, nN     value not in our db
 683 #    t, tN     temporary value (in our db, no logged in user yet)
 684 #    y, yN     value corresponds to logged-in user
 685 # and, aggregated conditions:
 686 #    a, aN     anything including -
 687 #    x, xN     t or y
 688 # if N differs the case applies only when the two values differ
 689 # (eg,   a1 y2   does not apply when the logged-in value is supplied twice)
 690
 691 # "stale session" means request originates from a page from a login
 692 # session which has been revoked (eg by logout); "cleared session"
 693 # means request originates from a browser which has a different (or
 694 # no) cookie.
 695
 696     # Case analysis, cookie mode, app promises re mutate:
 697     # cook parm meth form
 698     #
 699     #  any -   POST  nrmuoi   bug or attack, fail
 700     #  any -   GET    rmuoi   bug or attack, fail
 701     #  any any GET     muoi   bug or attack, fail
 702     #  any t   any   nrmu     bug or attack, fail
 703     #
 704     #  -   -   GET         O  "just logged out" page
 705     #  (any other)         O  bug or attack, fail
 706     #
 707     #  a1  a2  POST      o    logout
 708     #                           if a1 is valid, revoke it
 709     #                           if a2 is valid, revoke it
 710     #                           delete cookie
 711     #                           redirect to "just logged out" page
 712     #                             (which contains link to login form)
 713     #
 714     #  -   t   POST       i   complain about cookies being disabled
 715     #                           (with link to login form)
 716     #
 717     #  t1  t1  POST       i   login (or switch user)
 718     #                           if bad
 719     #                             show new login form
 720     #                           if good
 721     #                             upgrade t1 to y1 in our db (setting username)
 722     #                             redirect to GET of remaining params
 723     #
 724     #  y1  a2  POST       i   complain about stale login form
 725     #                           revoke y1
 726     #                           show new login form
 727     #
 728     #  (other) POST       i   complain about stale login form
 729     #                           show new login form
 730     #
 731     #  t1  a2  ANY   nrmu     treat as  - a2 ANY
 732     #
 733     #  y   -   GET   n        cross-site link
 734     #                           show data
 735     #
 736     #  y   y   GET   nr       fine, show page or send data
 737     #  y   y   POST  nrmu     mutation is OK, do operation
 738     #
 739     #  y1  y2  GET   nr       request from stale page
 740     #                           do not revoke y2 as not RESTful
 741     #                           treat as   y1 n GET
 742     #
 743     #  y1  y2  POST  nrmu     request from stale page
 744     #                           revoke y2
 745     #                           treat as   y1 n POST
 746     #
 747     #  y   n   GET   n        intra-site link from stale page,
 748     #                           treat as cross-site link, show data
 749     #
 750     #  y   n   POST  n m      intra-site form submission from stale page
 751     #                           show "session interrupted"
 752     #                           with link to main data page
 753     #
 754     #  y   n   GET    r       intra-site request from stale page
 755     #                           fail
 756     #
 757     #  y   n   POST   r u     intra-site request from stale page
 758     #                           fail
 759     #
 760     #  -/n y2  GET   nr       intra-site link from cleared session
 761     #                           do not revoke y2 as not RESTful
 762     #                           treat as   -/n n GET
 763     #
 764     #  -/n y2  POST  nrmu     request from cleared session
 765     #                           revoke y2
 766     #                           treat as   -/n n POST
 767     #
 768     #  -/n -/n GET   n        cross-site link but user not logged in
 769     #                           show login form with redirect to orig params
 770     #                           generate fresh cookie
 771     #
 772     #  -/n n   GET    rmu     user not logged in
 773     #                           fail
 774     #
 775     #  -/n n   POST  n m      user not logged in
 776     #                           show login form
 777     #
 778     #  -/n n   POST   r u     user not logged in
 779     #                           fail
 780
 781 sub _check_divert_core ($) {
 782     my ($r) = @_;
 783
 784     my $srcdump = $r->_rp('srcdump_param_name');
 785     if ($srcdump) {
 786         die if $srcdump =~ m/\W/;
 787         return ({ Kind => 'SRCDUMP-'.uc $srcdump,
 788                   Message => undef,
 789                   CookieSecret => undef,
 790                   Params => { } });
 791     }
 792
 793     my $cooks = $r->_ch('get_cookie');
 794
 795     if ($r->{S}{encrypted_only} && !$r->_ch('is_https')) {
 796         return ({ Kind => 'REDIRECT-HTTPS',
 797                   Message => $r->_gt("Redirecting to secure server..."),
 798                   CookieSecret => undef,
 799                   Params => { } });
 800     }
 801
 802     my $meth = $r->_ch('get_method');
 803     my $parmh = $r->_rp('assoc_param_name');
 804     my $cookh = defined $cooks ? $r->hash($cooks) : undef;
 805
 806     my ($cookt,$cooku) = $r->_identify($cookh, $cooks);
 807     my $parms = (defined $cooks && defined $parmh && $parmh eq $cookh)
 808         ? $cooks : undef;
 809     my ($parmt) = $r->_identify($parmh, $parms);
 810
 811     $r->_debug("_c_d_c cookt=$cookt parmt=$parmt\n");
 812
 813     if ($r->_ch('is_logout')) {
 814         $r->_must_be_post();
 815         die unless $parmt;
 816         $r->_db_revoke($cookh);
 817         $r->_db_revoke($parmh);
 818         return ({ Kind => 'REDIRECT-LOGGEDOUT',
 819                   Message => $r->_gt("Logging out..."),
 820                   CookieSecret => '',
 821                   Params => { } });
 822     }
 823     if ($r->_ch('is_loggedout')) {
 824         die unless $meth eq 'GET';
 825         die if $cookt eq 'y';
 826         die if $parmt;
 827         return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
 828                   Message => $r->_gt("You have been logged out."),
 829                   CookieSecret => '',
 830                   Params => { } });
 831     }
 832     if ($r->_ch('is_login')) {
 833         $r->_must_be_post();
 834         die unless $parmt;
 835         if (!$cookt && $parmt eq 'n') {
 836             return ({ Kind => 'SMALLPAGE-NOCOOKIE',
 837                       Message => $r->_gt("You do not seem to have cookies".
 838                                          " enabled.  You must enable cookies".
 839                                          " as we use them for login."),
 840                       CookieSecret => $r->_fresh_secret(),
 841                       Params => $r->_chain_params() })
 842         }
 843         if (!$cookt || $cookt eq 'n' || $cookh ne $parmh) {
 844             $r->_db_revoke($cookh);
 845             return ({ Kind => 'LOGIN-STALE',
 846                       Message => $r->_gt("Stale session;".
 847                                          " you need to log in again."),
 848                       CookieSecret => $r->_fresh_secret(),
 849                       Params => { } })
 850         }
 851         die unless $parmt eq 't' || $parmt eq 'y';
 852         my ($username, $login_errormessage) = $r->_ch('login_ok');
 853         unless (defined $username && length $username) {
 854             $login_errormessage = $r->_gt("Incorrect username/password.")
 855                 if !$login_errormessage;
 856             return ({ Kind => 'LOGIN-BAD',
 857                       Message => $login_errormessage,
 858                       CookieSecret => $cooks,
 859                       Params => $r->_chain_params() })
 860         }
 861         $r->_db_record_login_ok($parmh,$username);
 862         return ({ Kind => 'REDIRECT-LOGGEDIN',
 863                   Message => $r->_gt("Logging in..."),
 864                   CookieSecret => $cooks,
 865                   Params => $r->_chain_params() });
 866     }
 867     if ($cookt eq 't') {
 868         $cookt = '';
 869     }
 870     die if $parmt eq 't';
 871
 872     if ($cookt eq 'y' && $parmt eq 'y' && $cookh ne $parmh) {
 873         $r->_db_revoke($parmh) if $meth eq 'POST';
 874         $parmt = 'n';
 875     }
 876
 877     if ($cookt ne 'y') {
 878         die unless !$cookt || $cookt eq 'n';
 879         die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
 880         my $news = $r->_fresh_secret();
 881         if ($meth eq 'GET') {
 882             return ({ Kind => 'LOGIN-INCOMINGLINK',
 883                       Message => $r->_gt("You need to log in."),
 884                       CookieSecret => $news,
 885                       Params => $r->_chain_params() });
 886         } else {
 887             $r->_db_revoke($parmh);
 888             return ({ Kind => 'LOGIN-FRESH',
 889                       Message => $r->_gt("You need to log in."),
 890                       CookieSecret => $news,
 891                       Params => { } });
 892         }
 893     }
 894
 895     if (!$r->{S}{promise_check_mutate}) {
 896         if ($meth ne 'POST') {
 897             return ({ Kind => 'MAINPAGEONLY',
 898                       Message => $r->_gt('Entering via cross-site link.'),
 899                       CookieSecret => $cooks,
 900                       Params => { } });
 901             # NB caller must then ignore params & path!
 902             # if this is too hard they can spit out a small form
 903             # with a "click to continue"
 904         }
 905     }
 906
 907     die unless $cookt eq 'y';
 908     unless ($r->{S}{promise_check_mutate} && $meth eq 'GET') {
 909         die unless $parmt eq 'y';
 910         die unless $cookh eq $parmh;
 911     }
 912     $r->{ParmT} = $parmt;
 913     $r->{AssocSecret} = $cooks;
 914     $r->{UserOK} = $cooku;
 915 #print STDERR "C-D-C OK\n";
 916     return undef;
 917 }
 918
 919 sub _chain_params ($) {
 920 # =item C<< $authreq->_chain_params() >>
 921 #
 922 # Returns a hash of the "relevant" parameters to this request, in a form
 923 # used by C<url_with_query_params>.  This is all of the query parameters
 924 # which are not related to CGI::Auth::Flexible.  The PATH_INFO from the
 925 # request is returned as the parameter C<< '' >>.
 926
 927     my ($r) = @_;
 928     my %p = %{ $r->_ch('get_params') };
 929     foreach my $pncn (keys %{ $r->{S} }) {
 930         my $names;
 931         if ($pncn =~ m/_param_name$/) {
 932             my $name = $r->{S}{$pncn};
 933             die "$pncn ?" if ref $name;
 934             $names = [ $name ];
 935         } elsif ($pncn =~ m/_param_names$/) {
 936             $names = $r->{S}{$pncn};
 937         } else {
 938             next;
 939         }
 940         foreach my $name (@$names) {
 941             delete $p{$name};
 942         }
 943     }
 944     my $dummy_prefix = $r->{S}{dummy_param_name_prefix};
 945     foreach my $name (grep /^$dummy_prefix/, keys %p) {
 946         delete $p{$name};
 947     }
 948     die if exists $p{''};
 949     $p{''} = [ $r->_ch('get_path_info') ];
 950     return \%p;
 951 }
 952
 953 sub _identify ($$) {
 954     my ($r,$h,$s) = @_;
 955     # returns ($t,$username)
 956     # where $t is one of "t" "y" "n", or "" (for -)
 957     # either $s must be undef, or $h eq $r->hash($s)
 958
 959 #print STDERR "_identify\n";
 960     return '' unless defined $h && length $h;
 961 #print STDERR "_identify h=$h s=".(defined $s ? $s : '<undef>')."\n";
 962
 963     my $dbh = $r->{Dbh};
 964
 965     $dbh->do("DELETE FROM $r->{S}{db_prefix}_assocs".
 966              " WHERE last < ?", {},
 967              time - $r->{S}{login_timeout});
 968
 969     my $row = $dbh->selectrow_arrayref("SELECT username, last".
 970                               " FROM $r->{S}{db_prefix}_assocs".
 971                               " WHERE assochash = ?", {}, $h);
 972     if (defined $row) {
 973 #print STDERR "_identify h=$h s=$s YES @$row\n";
 974         my ($nusername, $nlast) = @$row;
 975         return ('y', $nusername);
 976     }
 977
 978     # Well, it's not in the database.  But maybe it's a hash of a
 979     # temporary secret.
 980
 981     return 'n' unless defined $s;
 982
 983     my ($keyt, $signature, $message, $noncet, $nonce) =
 984         $s =~ m/^(\d+)\.(\w+)\.((\d+)\.(\w+))$/ or die;
 985
 986     return 'n' if time > $noncet + $r->{S}{login_form_timeout};
 987
 988 #print STDERR "_identify noncet=$noncet ok\n";
 989
 990     my $keys = $r->_open_keys();
 991     while (my ($rkeyt, $rkey, $line) = $r->_read_key($keys)) {
 992 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey\n";
 993         last if $rkeyt < $keyt; # too far down in the file
 994         my $trysignature = $r->_hmac($rkey, $message);
 995 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey try=$trysignature\n";
 996         return 't' if $trysignature eq $signature;
 997     }
 998     # oh well
 999 #print STDERR "_identify NO\n";
1000
1001     $keys->error and die $!;
1002     return 'n';
1003 }
1004
1005 sub _db_revoke ($$) {
1006     # revokes $h if it's valid; no-op if it's not
1007     my ($r,$h) = @_;
1008
1009     my $dbh = $r->{Dbh};
1010
1011     $dbh->do("DELETE FROM $r->{S}{db_prefix}_assocs".
1012              " WHERE assochash = ?", {}, $h);
1013 }
1014
1015 sub _db_record_login_ok ($$$) {
1016     my ($r,$h,$user) = @_;
1017     $r->_db_revoke($h);
1018     my $dbh = $r->{Dbh};
1019     $dbh->do("INSERT INTO $r->{S}{db_prefix}_assocs".
1020              " (assochash, username, last) VALUES (?,?,?)", {},
1021              $h, $user, time);
1022 }
1023
1024 sub check_divert ($) {
1025     my ($r) = @_;
1026     if (exists $r->{Divert}) {
1027         return $r->{Divert};
1028     }
1029     my $dbh = $r->{Dbh};
1030     $r->{Divert} = $r->_db_transaction(sub { $r->_check_divert_core(); });
1031     $dbh->commit();
1032     $r->_debug(Data::Dumper->Dump([$r->{Divert}],[qw(divert)]));
1033     return $r->{Divert};
1034 }
1035
1036 sub get_divert ($) {
1037     my ($r) = @_;
1038     die "unchecked" unless exists $r->{Divert};
1039     return $r->{Divert};
1040 }
1041
1042 sub get_username ($) {
1043     my ($r) = @_;
1044     my $divert = $r->get_divert();
1045     return undef if $divert;
1046     return $r->{UserOK};
1047 }
1048
1049 sub url_with_query_params ($$;$) {
1050     my ($r, $params, $nonpagetype) = @_;
1051 #print STDERR "PARAMS ",Dumper($params);
1052     my $uri = URI->new($r->_ch('get_url'));
1053     $uri->path($uri->path() . $params->{''}[0]) if $params->{''};
1054     my @flatparams = flatten_params($params);
1055     if (defined $nonpagetype && $r->need_add_hidden('GET',$nonpagetype)) {
1056         push @flatparams, $r->{S}{assoc_param_name}, $r->secret_hidden_val();
1057     }
1058     $uri->query_form(@flatparams);
1059     return $uri->as_string();
1060 }
1061
1062 sub _cgi_header_args ($$@) {
1063     my ($r, $cookie, @ha) = @_;
1064     unshift @ha, qw(-type text/html);
1065     push @ha, (-cookie => $cookie) if defined $cookie;
1066 #print STDERR "_cgi_header_args ",join('|',@ha),".\n";
1067     return @ha;
1068 }
1069
1070 sub check_ok ($) {
1071     my ($r) = @_;
1072
1073     my ($divert) = $r->check_divert();
1074     return 1 if !$divert;
1075
1076     my $handled = $r->_ch('handle_divert',$divert);
1077     return 0 if $handled;
1078
1079     my $kind = $divert->{Kind};
1080     my $cookiesecret = $divert->{CookieSecret};
1081     my $params = $divert->{Params};
1082     my $cookie = $r->construct_cookie($cookiesecret);
1083
1084     if ($kind =~ m/^SRCDUMP-(\w+)$/) {
1085         $r->_ch('srcdump_dump', (lc $1));
1086         return 0;
1087     }
1088
1089     if ($kind =~ m/^REDIRECT-/) {
1090         # for redirects, we honour stored Params and Cookie,
1091         # as we would for non-divert
1092         if ($kind eq 'REDIRECT-LOGGEDOUT') {
1093             $params->{$r->{S}{loggedout_param_names}[0]} = [ 1 ];
1094         } elsif ($kind eq 'REDIRECT-LOGOUT') {
1095             $params->{$r->{S}{logout_param_names}[0]} = [ 1 ];
1096         } elsif ($kind =~ m/REDIRECT-(?:LOGGEDIN|HTTPS)/) {
1097         } else {
1098             die;
1099         }
1100         my $new_url = $r->url_with_query_params($params);
1101         if ($kind eq 'REDIRECT-HTTPS') {
1102             my $uri = URI->new($new_url);
1103             die unless $uri->scheme eq 'http';
1104             $uri->scheme('https');
1105             $new_url = $uri->as_string();
1106         }
1107         $r->_ch('do_redirect',$new_url, $cookie);
1108         return 0;
1109     }
1110
1111     if (defined $cookiesecret) {
1112         $params->{$r->{S}{assoc_param_name}} = [ $r->hash($cookiesecret) ];
1113     }
1114
1115     my ($title, @body);
1116     if ($kind =~ m/^LOGIN-/) {
1117         $title = $r->_gt('Login');
1118         push @body, $divert->{Message};
1119         push @body, $r->_ch('gen_login_form', $params);
1120     } elsif ($kind =~ m/^SMALLPAGE-/) {
1121         $title = $r->_gt('Not logged in');
1122         push @body, $divert->{Message};
1123         push @body, $r->_ch('gen_login_link', $params);
1124     } elsif ($kind =~ m/^MAINPAGEONLY$/) {
1125         $title = $r->_gt('Entering secure site.');
1126         push @body, $divert->{Message};
1127         push @body, $r->_ch('gen_postmainpage_form', $params);
1128     } else {
1129         die $kind;
1130     }
1131
1132     $r->_print($r->{Cgi}->header($r->_cgi_header_args($cookie)),
1133                $r->_ch('gen_start_html',$title),
1134                (join "\n", (@body,
1135                             $r->_ch('gen_footer_html'),
1136                             $r->_ch('gen_end_html'))));
1137     return 0;
1138 }
1139
1140 sub _random ($$) {
1141     my ($r, $bytes) = @_;
1142     my $v = $r->{V};
1143     my $rsf = $v->{RandomHandle};
1144     my $rsp = $r->{S}{random_source};
1145     if (!$rsf) {
1146         $v->{RandomHandle} = $rsf = new IO::File $rsp, '<' or die "$rsp $!";
1147 #print STDERR "RH $rsf\n";
1148     }
1149     my $bin;
1150     $!=0;
1151     read($rsf,$bin,$bytes) == $bytes or die "$rsp $!";
1152     my $out = unpack "H*", $bin;
1153 #print STDERR "_random out $out\n";
1154     return $out;
1155 }
1156
1157 sub _random_key ($) {
1158     my ($r) = @_;
1159 #print STDERR "_random_key\n";
1160     my $bytes = ($r->{S}{secretbits} + 7) >> 3;
1161     return $r->_random($bytes);
1162 }
1163
1164 sub _read_key ($$) {
1165     my ($r, $keys) = @_;
1166     # returns $gen_time_t, $key_value_in_hex, $complete_line
1167     while (<$keys>) {
1168         my ($gen, $k) = m/^(\d+) (\S+)$/ or die "$_ ?";
1169         my $age = time - $gen;
1170         next if $age > $r->{S}{key_rollover} &&
1171             $age > $r->{S}{login_form_timeout}*2;
1172         return ($gen, $k, $_);
1173     }
1174     return ();
1175 }
1176
1177 sub _open_keys ($) {
1178     my ($r) = @_;
1179     my $spath = $r->_get_path('keys');
1180     for (;;) {
1181 #print STDERR "_open_keys\n";
1182         my $keys = new IO::File $spath, 'r+';
1183         if ($keys) {
1184 #print STDERR "_open_keys open\n";
1185             stat $keys or die $!; # NB must not disturb stat _
1186             my $size = (stat _)[7];
1187             my $age = time - (stat _)[9];
1188 #print STDERR "_open_keys open size=$size age=$age\n";
1189             return $keys
1190                 if $size && $age <= $r->{S}{key_rollover} / 2;
1191 #print STDERR "_open_keys open bad\n";
1192         }
1193         # file doesn't exist, or is empty or too old
1194         if (!$keys) {
1195 #print STDERR "_open_keys closed\n";
1196             die "$spath $!" unless $!==&ENOENT;
1197             # doesn't exist, so create it just so we can lock it
1198             $keys = new IO::File $spath, 'a+';
1199             die "$keys $!" unless $keys;
1200             stat $keys or die $!; # NB must not disturb stat _
1201             my $size = (stat _)[7];
1202 #print STDERR "_open_keys created size=$size\n";
1203             next if $size; # oh someone else has done it, reopen and read it
1204         }
1205         # file now exists is empty or too old, we must try to replace it
1206         my $our_inum = (stat _)[1]; # last use of that stat _
1207         flock $keys, LOCK_EX or die "$spath $!";
1208         stat $spath or die "$spath $!";
1209         my $path_inum = (stat _)[1];
1210 #print STDERR "_open_keys locked our=$our_inum path=$path_inum\n";
1211         next if $our_inum != $path_inum; # someone else has done it
1212         # We now hold the lock!
1213 #print STDERR "_open_keys creating\n";
1214         my $newkeys = new IO::Handle;
1215         sysopen $newkeys, "$spath.new", O_CREAT|O_TRUNC|O_WRONLY, 0600
1216             or die "$spath.new $!";
1217         # we add the new key to the front which means it's always sorted
1218         print $newkeys time, ' ', $r->_random_key(), "\n" or die $!;
1219         while (my ($gen,$key,$line) = $r->_read_key($keys)) {
1220 #print STDERR "_open_keys copy1\n";
1221             print $newkeys, $line or die $!;
1222         }
1223         $keys->error and die $!;
1224         close $newkeys or die "$spath.new $!";
1225         rename "$spath.new", "$spath" or die "$spath: $!";
1226 #print STDERR "_open_keys installed\n";
1227         # that rename effective unlocks, since it makes the name refer
1228         #  to the new file which we haven't locked
1229         # we go round again opening the file at the beginning
1230         #  so that our caller gets a fresh handle onto the existing key file
1231     }
1232 }
1233
1234 sub _fresh_secret ($) {
1235     my ($r) = @_;
1236 #print STDERR "_fresh_secret\n";
1237
1238     my $keys = $r->_open_keys();
1239     my ($keyt, $key) = $r->_read_key($keys);
1240     die unless defined $keyt;
1241
1242     my $nonce = $r->_random_key();
1243     my $noncet = time;
1244     my $message = "$noncet.$nonce";
1245
1246     my $signature = $r->_hmac($key, $message);
1247     my $secret = "$keyt.$signature.$message";
1248 #print STDERR "FRESH $secret\n";
1249     return $secret;
1250 }
1251
1252 sub _hmac ($$$) {
1253     my ($r, $keyhex, $message) = @_;
1254     my $keybin = pack "H*", $keyhex;
1255     my $alg = $r->{S}{hash_algorithm};
1256 #print STDERR "hmac $alg\n";
1257     my $base = new Digest $alg;
1258 #print STDERR "hmac $alg $base\n";
1259     my $digest = new Digest::HMAC $keybin, $base;
1260 #print STDERR "hmac $alg $base $digest\n";
1261     $digest->add($message);
1262     return $digest->hexdigest();
1263 }
1264
1265 sub hash ($$) {
1266     my ($r, $message) = @_;
1267     my $alg = $r->{S}{hash_algorithm};
1268 #print STDERR "hash $alg\n";
1269     my $digest = new Digest $alg;
1270     $digest->add($message);
1271     return $digest->hexdigest();
1272 }
1273
1274 sub _assert_checked ($) {
1275     my ($r) = @_;
1276     die "unchecked" unless exists $r->{Divert};
1277 }
1278
1279 sub _is_post ($) {
1280     my ($r) = @_;
1281     my $meth = $r->_ch('get_method');
1282     return $meth eq 'POST';
1283 }
1284
1285 sub _must_be_post ($) {
1286     my ($r) = @_;
1287     my $meth = $r->_ch('get_method');
1288     die "mutating non-POST" if $meth ne 'POST';
1289 }
1290
1291 sub check_mutate ($) {
1292     my ($r) = @_;
1293     $r->_assert_checked();
1294     die if $r->{Divert};
1295     $r->_must_be_post();
1296 }
1297
1298 our %_resource_get_needs_secret_hidden =
1299     (map { $_ => 0 } qw(PAGE FRAME IFRAME SRCDUMP STYLESHEET FAVICON ROBOTS),
1300      map { $_ => 1 } qw(IMAGE SCRIPT AJAX-XML AJAX-JSON AJAX-OTHER));
1301
1302 sub update_get_need_add_hidden ($$;$) {
1303     my ($r, $reqtype, $value, $force) = @_;
1304     my $hash = ref $r
1305         ? ($r->{GetNeedsSecretHidden} ||= { })
1306         : \%_resource_get_needs_secret_hidden;
1307     return if !$force &&
1308         (exists $_resource_get_needs_secret_hidden{$reqtype} ||
1309          exists $hash->{$reqtype});
1310     $hash->{$reqtype} = $value;
1311 }
1312
1313 sub need_add_hidden ($$) {
1314     my ($r, $method, $reqtype) = @_;
1315     return 1 if $method ne 'GET';
1316     if (ref $r) {
1317         my $ent = $r->{GetNeedsSecretHidden}{$reqtype};
1318         return $ent if defined $ent;
1319     }
1320     my $ent = $_resource_get_needs_secret_hidden{$reqtype};
1321     return $ent if defined $ent;
1322     die "unsupported nonpage GET type $reqtype";
1323 }
1324
1325 sub check_nonpage ($$) {
1326     my ($r, $reqtype) = @_;
1327     $r->_assert_checked();
1328     return unless $r->resource_get_needs_secret_hidden($reqtype);
1329     return if $r->{ParmT};
1330     die "missing hidden secret parameter on nonpage request $reqtype";
1331 }
1332
1333 #---------- output ----------
1334
1335 sub secret_cookie_val ($) {
1336     my ($r) = @_;
1337     $r->_assert_checked();
1338     return defined $r->{AssocSecret} ? $r->{AssocSecret} : '';
1339 }
1340
1341 sub secret_hidden_val ($) {
1342     my ($r) = @_;
1343     $r->_assert_checked();
1344     return defined $r->{AssocSecret} ? $r->hash($r->{AssocSecret}) : '';
1345 }
1346
1347 sub secret_hidden_html ($) {
1348     my ($r) = @_;
1349     return $r->{Cgi}->hidden(-name => $r->{S}{assoc_param_name},
1350                              -default => $r->secret_hidden_val());
1351 }
1352
1353 sub secret_cookie ($) {
1354     my ($r) = @_;
1355     my $secret = $r->secret_cookie_val();
1356     return undef if !defined $secret;
1357 #print STDERR "SC\n";
1358     my $cookv = $r->construct_cookie($secret);
1359 #print STDERR "SC=$cookv\n";
1360     return $cookv;
1361 }
1362
1363 1;