#!/usr/bin/perl -w
use strict;
use utf8;
use autodie;

use Data::Printer;
use Graph::Directed;

binmode STDIN, 'encoding(UTF-8)';
binmode STDOUT, 'encoding(UTF-8)';
binmode STDERR, 'encoding(UTF-8)';

our @choices;
our %choices;
our @invotes;
our $defcho;
our $quorum = 0;

sub addchoice {
    my $choname = shift @_;
    my $cho = $choices{$choname} = { @_, Index => (scalar @choices) };
    push @choices, $choname;
    return $cho;
}

while (<>) {
    s/\s+$//;
    next if m/^\s*\#/;
    next unless m/\S/;
    if (m/^([A-Z]+)\s*\=\s*(\S.*)$/) {
	my ($choname, $desc) = ($1,$2);
	my $cho = addchoice($choname, Desc => $desc);
	if ($desc =~ m/\[(\d+):(\d+)\]/) {
	    $cho->{Smaj} = [$1,$2];
	} elsif ($desc =~ m/\[default\]/) {
	    $defcho = $cho;
	}
    } elsif (m/^V:\s+(\S+)\s+(\S.*)/) {
	push @invotes, [ $1, $2 ];
    } elsif (m/^quorum = ([0-9.]+)$/) {
	$quorum = $1+0.0;
    } else {
	die "invalid input";
    }
}

$defcho ||= $choices{FD};
if (!$defcho) {
    $defcho = addchoice('FD', Desc => "Further Discussion");
}
my $defi = $defcho->{Index};
die "FD has smaj?!" if $defcho->{Smaj};

our @vab;
# $vab[$ia][$ib] = V(A,B)
# Actually, it's a list of voters who prefer A to B (A.6(3)(1))

# Go through the voters and construct V(A,B)

print "\nDefeats matrix\n";

foreach my $iv (@invotes) {
    my ($votestr,$voter) = @$iv;
    eval {
	length $votestr eq @choices or die "wrong vote vector length";
	my @vs = split //, $votestr;
	foreach my $ix (0..$#vs) {
	    my $vchr = $vs[$ix];
	    if ($vchr eq '-') {
		$vs[$ix] = 1000;
	    } elsif ($vchr =~ m/[0-9a-z]/) {
		$vs[$ix] = ord($vchr);
	    } else {
		die "bad vote char";
	    }
	}
	foreach my $ia (0..$#vs) {
	    foreach my $ib ($ia+1..$#vs) {
		my $va = $vs[$ia];
		my $vb = $vs[$ib];
		if ($va < $vb) { push @{ $vab[$ia][$ib] }, $voter }
		elsif ($vb < $va) { push @{ $vab[$ib][$ia] }, $voter }
	    }
	}
    };
    die "voter $voter $@" if $@;
}

our @ch = map { $choices{$_} } @choices;

# Print the counts V(A,B)
foreach my $iy (-2..$#ch) {
    foreach my $ix (-2..$#ch) {
	if ($iy==-1) {
	    if ($ix==-1) {
		printf "+";
	    } else {
		printf "------";
	    }
	} elsif ($ix==-1) {
	    printf "|";
	} elsif ($ix==-2 && $iy==-2) {
	    printf "V(Y,X)";
	} elsif ($iy==-2) {
	    printf "%5s ", $choices[$ix];
	} elsif ($ix==-2) {
	    printf "%5s ", $choices[$iy];
	} else {
	    my $v = \( $vab[$iy][$ix] );
	    $$v ||= [ ];
	    if (@$$v) {
		printf "%5d ", (scalar @$$v);
	    } else {
		printf "%5s ", "";
	    }
	}
    }
    printf "\n";
}

sub drop ($$) {
    my ($i,$why) = @_;
    print "dropping $choices[$i]: $why\n";
    $ch[$i]{Dropped} = $why;
}

print "\nQuorum A.6(2) (quorum is $quorum)\n";

foreach my $i (0..$#choices) {
    next if $ch[$i]{Dropped};
    next if $i == $defi;
    my $v = $vab[$i][$defi];
    next if $v >= $quorum;
    drop $i, "quorum ($v < $quorum)";
}

print "\nMajority ratio A.6(3)\n";

foreach my $i (0..$#choices) {
    next if $ch[$i]{Dropped};
    next if $i == $defi;
    my $majr = $ch[$i]{Smaj};
    $majr ||= [1,1]; # A.6(3)(3)
    my $vad = scalar @{ $vab[$i][$defi] };
    my $vda = scalar @{ $vab[$defi][$i] };
    next if $vad * $majr->[1] > $vda * $majr->[0];
    drop $i, "majority ratio ($vad * $majr->[1] <= $vda * $majr->[0])";
}

my $defeats = Graph::Directed->new; # A.6(4)

sub chremain () {
    return grep { !$ch[$_]{Dropped} } (0..$#ch);
}

foreach my $ia (chremain()) {
    $defeats->add_vertex($ia);
    foreach my $ib (chremain()) {
	my $vab = scalar @{ $vab[$ia][$ib] };
	my $vba = scalar @{ $vab[$ib][$ia] };
	next unless $vab > $vba;
	print "defeat: $choices[$ia] beats $choices[$ib] ($vab > $vba)\n";
	$defeats->add_vertex($ia,$ib);
    }
}

sub weaker ($$) {
    # A.6(7)(1)
    my ($def1,$def2) = @_;
    my ($ia,$ix) = @$def1;
    my ($ib,$iy) = @$def1;
    return 1 if $vab[$ia][$ix] < $vab[$ib][$iy];
    return 1 if $vab[$ia][$ix] == $vab[$ib][$iy]
	&& $vab[$ix][$ia] > $vab[$iy][$ib];
    return 0;
}

our $schwartz;

for (;;) {
    # loop from A6(5)

    print "defeats graph: $defeats\n";

    print "\nTransitive closure A.6(5)\n";

    my $tdefeats = $defeats->transitive_closure();

    print "closure graph: $tdefeats\n";

    print "\nSchwartz set A.6(6)\n";
    
    $schwartz = $defeats->copy();

    foreach my $ia (chremain()) {
	foreach my $ib (chremain()) {
	    next if $tdefeats->has_edge($ia,$ib);
	    next if !$tdefeats->has_edge($ib,$ia);
	    print "not in Schwartz set: $choices[$ia] because $choices[$ib]\n";
	    $schwartz->delete_vertex($ia);
	    last;
	}
    }

    print "\nDropping weakest defeats A.6(7)\n";

    our @weakest = ();

    foreach my $edge ($schwartz->edges()) {
	if (!@weakest) {
	    # no weakest edges yet
	} elsif (weaker($edge, $weakest[0])) {
	    # this edge is weaker than previous weakest, start new set
	    @weakest = ();
	} elsif (weaker($weakest[0], $edge)) {
	    # weakest edge is weaker than this one, ignore this one
	    next;
	} else {
	    # weakest edge is exactly as weak as this one, add this one
	}
	push @weakest, $edge;
    }

    last unless @weakest;
    
    printf "weakest defeats %d > %d", 
	(scalar @{ $vab[$_->[0]][$_->[1]] }),
	(scalar @{ $vab[$_->[1]][$_->[0]] });
    foreach my $weakest (@weakest) {
	my ($ia,$ib) = @$weakest;
	print "weakest defeat $choices[$ia] > $choices[$ib]\n";
	$defeats->delete_edge($ia,$ib);
    }

    print "defeats within the Schwartz set, round again\n";
}

print "no defeats within the Schwartz set\n";
print "final schwartz set:\n\n";

if ($schwartz->vertices() == 1) {
    print "WINNER IS:\n";
} else {
    print "WINNER IS ONE OF (CASTING VOTE DECIDES):\n";
}

printf "    %-5s %s\n", $choices[$_], $ch[$_]{Desc}
    foreach ($schwartz->vertices());

print ".\n";

#p %choices;
#p @vab;