chiark / gitweb /
stv: wip debug
[appendix-a6.git] / stv
1 #!/usr/bin/perl -w
2 #
3 # Does STV according to
4 #  http://www.rosenstiel.co.uk/stvrules/av/index.htm
5
6 use strict;
7 use utf8;
8 use autodie;
9 use bigrat;
10 use Carp;
11 use Data::Dumper;
12 use List::Util qw(sum0);
13 use List::MoreUtils qw(nsort_by);
14
15 # vote is
16 #  { Voter => opaque,
17 #    Prefs => [ list ],
18 #    Weight => 1.0 }
19
20 our $stage=0;
21 our @allvotes;
22
23 our $places = shift @ARGV;
24 die unless $places eq ($places + 0);
25
26 open DEBUG, ">.stv.log" or die $!;
27
28 while (<>) {
29     next if m/^\w+$/;
30     m/^(\w+) ([A-Z]+)$/ or die "$_ ?";
31     my $prefs = $2;
32     my $vote = {
33         Voter => $1,
34         Weight => 1.0,
35         Prefs => [ split //, $prefs ],
36     };
37     push @allvotes, $vote;
38 }
39
40 sub pr ($) {
41     my ($f) = @_;
42     confess unless defined $f;
43     return sprintf "%10.6f = %-10s", $f, $f;
44 }
45
46 sub votelog ($$) {
47     my ($vote,$m) = @_;
48     push @{ $vote->{Log} }, "stage $stage: $m";
49 }
50
51 sub filterout ($$) {
52     my ($cand, $why) = @_;
53     foreach my $vote (@allvotes) {
54         my $oldprefs = $vote->{Prefs};
55         my @prefs = grep { $_ ne $cand } $oldprefs;
56         next if @prefs == @$oldprefs;
57         votelog $vote, "crossed out candidate $cand: $why";
58     }
59 }
60
61 our @elected; # $elected[] = $candidate
62
63 our @unsorted = @allvotes;
64
65 our %sorted;
66 # $sorted{$firstpref}{Votes} = [ $vote, ... ]
67 # $sorted{$firstpref}{Cand} = $firstpref
68 # $sorted{$firstpref}{Total} = $totalweight
69 our @surpluses; # values same as %sorted
70
71 our @exhausted; # votes
72
73 our %continuing; # $continuing{$candidate}=1
74
75 our @stagerecord; # $stagerecord[]{$candidate} = $total
76
77 foreach my $vote (@allvotes) {
78     $continuing{$_}=1 foreach @{ $vote->{Prefs} };
79 }
80
81 sub equalpiles ($@) {
82     my ($how, @sorted) = @_;
83     return () unless @sorted;
84     my $s = $sorted[0];
85     my $eqtotal = $s->{Total};
86     my $count = 0;
87     while ($count < @sorted && $sorted[$count]{Total} == $eqtotal) {
88         printf "%7s %10s %s\n", $how, $sorted[$count]{Cand},
89             pr $sorted[$count]{Total};
90         $count++;
91     }
92     return @sorted[ 0 .. $count-1 ];
93 }
94
95 sub historically_prefer ($@) {
96     my ($signum, @choices) = @_;
97
98     return $choices[0] if @choices < 2;
99
100     my $compare = sub {
101         foreach my $sr (@stagerecord) {
102             my $d = $sr->{ $a->{Cand} } <=> $sr->{ $b->{Cand} };
103             return $d * $signum if $d;
104         }
105         return 0;
106     };
107
108     @choices = sort $compare, @choices;
109     $a = $choices[0];
110     my $numequal = 0;
111     for (;;) {
112         last unless $numequal >= @choices;
113         $b = $choices[$numequal];
114         last if $compare->();
115     }
116
117     die 'random choice unimplemented' if $numequal > 1;
118     return $choices[0];
119 }
120
121 for (;;) {
122     $stage++;
123
124     printf "----- stage %d -----\n", $stage;
125
126     print DEBUG "#################### $stage ####################\n",
127         Data::Dumper->Dump(
128 [ \@stagerecord, \@elected, \@unsorted, \%sorted, \@surpluses, \%continuing ],
129 [qw( _@stagerecord _@elected _@unsorted _%sorted _@surpluses _%continuing )]
130            );
131
132     while (my $vote = shift @unsorted) {
133         my ($firstpref) = grep { $continuing{$_} } @{ $vote->{Prefs} };
134         if (!defined $firstpref) {
135             votelog $vote, "ballot exhausted";
136             push @exhausted, $vote;
137         } else {
138             push @{ $sorted{$firstpref}{Votes} }, $vote;
139         }
140     }
141     $sorted{$_}{Cand} = $_ foreach keys %sorted;
142     foreach my $firstpref (sort keys %sorted) {
143         foreach my $vote (@{ $sorted{$firstpref}{Votes} }) {
144             votelog $vote, "counted $vote->{Weight} for $firstpref";
145         }
146     }
147     my @sorted;
148     my $things_update = sub {
149         foreach my $s (@surpluses, values %sorted) {
150             $s->{Total} = sum0 map { $_->{Weight} } @{ $s->{Votes } };
151         }
152         @sorted = nsort_by { -$_->{Total} } values %sorted;
153     };
154     $things_update->();
155
156     print DEBUG "SORTED\n", Dumper(\@sorted);
157
158     push @stagerecord, { map { ($_->{Cand}, $_->{Total}) } @sorted };
159
160     my $totalvalid = 0;
161     my $countvalid = sub {
162         my ($l, $what) = @_;
163         foreach my $s (@$l) {
164             printf "%-7s %10s %s\n", $what, $s->{Cand}, pr $s->{Total};
165             $totalvalid += $s->{Total};
166         }
167     };
168     $countvalid->(\@sorted,    '1stpref');
169     $countvalid->(\@surpluses, 'surplus');
170
171     printf "%7s %10s %s\n", 'TOTAL', '-----', pr $totalvalid;
172
173     unless ($totalvalid > 0) {
174         printf "No more votes!\n";
175         last;
176     }
177
178     my $placesremain = $places - @elected;
179
180     unless ($placesremain > 0) {
181         printf "Complete.\n";
182         last;
183     }
184
185     my $quota = $totalvalid / ($placesremain + 1);
186     printf "%7s %10s %s\n", 'quota', '', pr $quota;
187
188     my $need_to_transfer_surplus = 1;
189
190     # Look for people to elect.
191     # We elect as many as we can, rather than recomputing the (lower) quota
192     # (ERS rules 5.4.9)
193     for (;;) {
194         my $s = $sorted[0];
195         my $topvoters = $s->{Total};
196         my $surplus = $topvoters - $quota;
197         last unless $surplus > 0;
198
199         printf "%7s %10s ***************\n", 'ELECTED', $s->{Cand};
200         push @elected, $s->{Cand};
201
202         my $derate = $topvoters / $surplus;
203         printf "%7s %10s %s\n", 'derate', $s->{Cand}, pr $derate;
204
205         foreach my $vote (@{ $s->{Votes} }) {
206             votelog $vote, "elected $s->{Cand}, derated $derate";
207             $vote->{Weight} /= $derate;
208         }
209         push @surpluses, $s;
210         delete $sorted{ $s->{Cand} };
211         delete $continuing{ $s->{Cand} };
212
213         $things_update->();
214         printf "%7s %10s %s\n", 'surplus', $s->{Cand}, pr $s->{Total};
215
216         $need_to_transfer_surplus = 0;
217         # before actually transferring a surplus, we will consider
218         # eliminating, and then reconsider with a lower quota
219     }
220
221     my $deferredsurplus = sum0 map { $_->{Total} } @surpluses;
222     printf "%18s %s\n", 'deferred surplus', pr $deferredsurplus;
223
224     # Look for people to eliminate
225     # We eliminate before trying to transfer surpluses
226     # ERS 5.2.5
227     for (;;) {
228         last unless @sorted;
229
230         printf "%18s\n", 'elimination round';
231
232         my @elim = equalpiles 'elim?', reverse @sorted;
233         my $elimvotetotal = sum0 map { $_->{Total} } @elim;
234
235         if (@surpluses) {
236             if (@sorted == @elim) {
237                 printf "%18s\n", 'no-elim, un-defer, (all-equal)';
238                 last;
239             }
240             my $nextup = $sorted[ $#sorted - @elim ];
241             printf "%7s %10s %s\n", 'nextup', $nextup->{Cand},
242                 pr $nextup->{Total};
243             my $aheadby = $nextup->{Total} - $elimvotetotal;
244             unless ($deferredsurplus <= $aheadby) {
245                 # rule 5.2.2 (b)
246                 printf "%18s %s\n", 'no-elim, un-defer', pr $aheadby;
247                 last;
248             }
249         }
250
251         if ((scalar keys %continuing) - (scalar @elim) < $placesremain) {
252             # eliminate only one then, and try again
253             printf "elim-tie!\n";
254             @elim = historically_prefer -1, @elim;
255         }
256
257         foreach my $s (@elim) {
258             my $c = $s->{Cand};
259             printf "%7s %10s %s\n", 'ELIM', $c, '----------';
260             my $votes = $s->{Votes};
261             votelog $_, "failed to stop $c elimination" foreach @$votes;
262             delete $continuing{$c};
263             delete $sorted{$c};
264             push @unsorted, @$votes;
265         }
266         
267         $things_update->();
268         $need_to_transfer_surplus = 0;
269     }
270     
271     next unless $need_to_transfer_surplus;
272
273     @surpluses = nsort_by { $_->{Total} } @surpluses;
274     my @surplusxfer = equalpiles 'xfer?', @surpluses;
275     die unless @surplusxfer;
276
277     if (@surplusxfer > 1) {
278         @surplusxfer = historically_prefer +1, @surplusxfer;
279     }
280
281     my $s = $surplusxfer[0];
282     my $c = $s->{Cand};
283     printf "%7s %10s\n", 'xfer', $c;
284     my $votes = $s->{Votes};
285     votelog $_, "surplus transferred" foreach @$votes;
286     @surpluses = grep { $_->{Cand} ne $c } @surpluses;
287     push @unsorted, @$votes;
288 }
289
290 print "done.\n";