+ bless $r, ref $classbase;
+}
+
+sub _ch ($$@) { # calls an application hook
+ my ($r,$methname, @args) = @_;
+ my $methfunc = $r->{S}{$methname};
+ die "$methname ?" unless $methfunc;
+ return $methfunc->($r->{Cgi}, $r, @args);
+}
+
+sub _rp ($$@) {
+ my ($r,$pnvb) = @_;
+ my $pn = $r->{S}{$pnvb};
+ my $p = scalar $r->_ch('get_param',$pn)
+}
+
+sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
+sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
+
+sub construct_cookie ($$$) {
+ my ($r, $cooks) = @_;
+ return undef unless $cooks;
+ my $c = $r->{Cgi};
+my @ca = (-name => $r->{S}{cookie_name},
+ -value => $cooks,
+ -path => $r->{S}{cookie_path},
+ -domain => $r->_ch('get_cookie_domain'),
+ -expires => '+'.$r->{S}{login_timeout}.'s',
+ -secure => $r->{S}{encrypted_only});
+ my $cookie = $c->cookie(@ca);
+print STDERR "CC $r $c $cooks $cookie (@ca).\n";
+ return $cookie;
+}
+
+# pages/param-sets are
+# n normal non-mutating page
+# r retrieval of information for JS, non-mutating
+# m mutating page
+# u update of information by JS, mutating
+# i login
+# o logout
+# O "you have just logged out" page load
+
+# in cook and par,
+# - no value supplied (represented in code as $cookt='')
+# n, nN value not in our db
+# t, tN temporary value (in our db, no logged in user yet)
+# y, yN value corresponds to logged-in user
+# and, aggregated conditions:
+# a, aN anything including -
+# x, xN t or y
+# if N differs the case applies only when the two values differ
+# (eg, a1 y2 does not apply when the logged-in value is supplied twice)
+
+# "stale session" means request originates from a page from a login
+# session which has been revoked (eg by logout); "cleared session"
+# means request originates from a browser which has a different (or
+# no) cookie.
+
+ # Case analysis, cookie mode, app promises re mutate:
+ # cook parm meth form
+ #
+ # any - POST nrmuoi bug or attack, fail
+ # any - GET rmuoi bug or attack, fail
+ # any any GET muoi bug or attack, fail
+ # any t any nrmu bug or attack, fail
+ #
+ # - - GET O "just logged out" page
+ # (any other) O bug or attack, fail
+ #
+ # a1 a2 POST o logout
+ # if a1 is valid, revoke it
+ # if a2 is valid, revoke it
+ # delete cookie
+ # redirect to "just logged out" page
+ # (which contains link to login form)
+ #
+ # - t POST i complain about cookies being disabled
+ # (with link to login form)
+ #
+ # t1 t1 POST i login (or switch user)
+ # if bad
+ # show new login form
+ # if good
+ # upgrade t1 to y1 in our db (setting username)
+ # redirect to GET of remaining params
+ #
+ # y1 a2 POST i complain about stale login form
+ # revoke y1
+ # show new login form
+ #
+ # (other) POST i complain about stale login form
+ # show new login form
+ #
+ # t1 a2 ANY nrmu treat as - a2 ANY
+ #
+ # y - GET n cross-site link
+ # show data
+ #
+ # y y GET nr fine, show page or send data
+ # y y POST nrmu mutation is OK, do operation
+ #
+ # y1 y2 GET nr request from stale page
+ # do not revoke y2 as not RESTful
+ # treat as y1 n GET
+ #
+ # y1 y2 POST nrmu request from stale page
+ # revoke y2
+ # treat as y1 n POST
+ #
+ # y n GET n intra-site link from stale page,
+ # treat as cross-site link, show data
+ #
+ # y n POST n m intra-site form submission from stale page
+ # show "session interrupted"
+ # with link to main data page
+ #
+ # y n GET r intra-site request from stale page
+ # fail
+ #
+ # y n POST r u intra-site request from stale page
+ # fail
+ #
+ # -/n y2 GET nr intra-site link from cleared session
+ # do not revoke y2 as not RESTful
+ # treat as -/n n GET
+ #
+ # -/n y2 POST nrmu request from cleared session
+ # revoke y2
+ # treat as -/n n POST
+ #
+ # -/n -/n GET n cross-site link but user not logged in
+ # show login form with redirect to orig params
+ # generate fresh cookie
+ #
+ # -/n n GET rmu user not logged in
+ # fail
+ #
+ # -/n n POST n m user not logged in
+ # show login form
+ #
+ # -/n n POST r u user not logged in
+ # fail
+
+sub _check_divert_core ($) {
+ my ($r) = @_;
+
+ my $meth = $r->_ch('get_method');
+ my $cooks = $r->_ch('get_cookie');
+ my $parmh = $r->_rp('assoc_param_name');
+ my $cookh = defined $cooks ? $r->hash($cooks) : undef;
+
+ my ($cookt,$cooku) = $r->_identify($cookh, $cooks);
+ my $parmt = $r->_identify($parmh, undef);
+
+ print STDERR "_c_d_c cookt=$cookt parmt=$parmt\n";
+
+ if ($r->_ch('is_logout')) {
+ $r->_must_be_post();
+ die unless $parmt;
+ $r->_db_revoke($cookh);
+ $r->_db_revoke($parmh);
+ return ({ Kind => 'REDIRECT-LOGGEDOUT',
+ Message => "Logging out...",
+ CookieSecret => '',
+ Params => { } });
+ }
+ if ($r->_ch('is_loggedout')) {
+ die unless $meth eq 'GET';
+ die unless $cookt;
+ die unless $parmt;
+ return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
+ Message => "You have been logged out.",
+ CookieSecret => '',
+ Params => { } });
+ }
+ if ($r->_ch('is_login')) {
+ $r->_must_be_post();
+ die unless $parmt;
+ if (!$cookt && $parmt eq 't') {
+ return ({ Kind => 'SMALLPAGE-NOCOOKIE',
+ Message => "You do not seem to have cookies enabled. ".
+ "You must enable cookies as we use them for login.",
+ CookieSecret => $r->_fresh_secret(),
+ Params => $r->_chain_params() })
+ }
+ if (!$cookt || $cookt eq 'n' || $cookh ne $parmh) {
+ $r->_db_revoke($cookh);
+ return ({ Kind => 'LOGIN-STALE',
+ Message => "Stale session; you need to log in again.",
+ CookieSecret => $r->_fresh_secret(),
+ Params => { } })
+ }
+ die unless $parmt eq 't' || $parmt eq 'y';
+ my $username = $r->_ch('login_ok');
+ unless (defined $username && length $username) {
+ return ({ Kind => 'LOGIN-BAD',
+ Message => "Incorrect username/password.",
+ CookieSecret => $cooks,
+ Params => $r->_chain_params() })
+ }
+ $r->_db_record_login_ok($parmh,$username);
+ return ({ Kind => 'REDIRECT-LOGGEDIN',
+ Message => "Logging in...",
+ CookieSecret => $cooks,
+ Params => $r->_chain_params() });
+ }
+ if ($cookt eq 't') {
+ $cookt = '';
+ }
+ die if $parmt eq 't';
+
+ if ($cookt eq 'y' && $parmt eq 'y' && $cookh ne $parmh) {
+ $r->_db_revoke($parmh) if $meth eq 'POST';
+ $parmt = 'n';
+ }
+
+ if ($cookt ne 'y') {
+ die unless !$cookt || $cookt eq 'n';
+ die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
+ my $news = $r->_fresh_secret();
+ if ($meth eq 'GET') {
+ return ({ Kind => 'LOGIN-INCOMINGLINK',
+ Message => "You need to log in again.",
+ CookieSecret => $news,
+ Params => $r->_chain_params() });
+ } else {
+ $r->_db_revoke($parmh);
+ return ({ Kind => 'LOGIN-FRESH',
+ Message => "You need to log in again.",
+ CookieSecret => $news,
+ Params => { } });
+ }
+ }
+
+ if (!$r->{S}{promise_check_mutate}) {
+ if ($meth ne 'POST') {
+ return ({ Kind => 'MAINPAGEONLY',
+ Message => 'Entering via cross-site link.',
+ CookieSecret => $cooks,
+ Params => { } });
+ # NB caller must then ignore params & path!
+ # if this is too hard they can spit out a small form
+ # with a "click to continue"
+ }
+ }
+
+ die unless $cookt eq 'y';
+ die unless $parmt eq 'y';
+ die unless $cookh eq $parmh;
+ $r->{AssocSecret} = $cooks;
+ $r->{UserOK} = $cooku;
+ print STDERR "C-D-C OK\n";
+ return undef;
+}
+
+sub _chain_params ($) {
+ my ($r) = @_;
+ my %p = %{ $r->_ch('get_params') };
+ foreach my $pncn (keys %{ $r->{S} }) {
+ my $names;
+ if ($pncn =~ m/_param_name$/) {
+ my $name = $r->{S}{$pncn};
+ die "$pncn ?" if ref $name;
+ $names = [ $name ];
+ } elsif ($pncn =~ m/_param_names$/) {
+ $names = $r->{S}{$pncn};
+ } else {
+ next;
+ }
+ foreach my $name (@$names) {
+ delete $p{$name};
+ }
+ }
+ return \%p;
+}
+
+sub _identify ($$) {
+ my ($r,$h,$s) = @_;
+ # returns ($t,$username)
+ # where $t is one of "t" "y" "n", or "" (for -)
+ # either $s must be undef, or $h eq $r->hash($s)
+
+ return '' unless defined $h && length $h;
+
+ my $dbh = $r->{Dbh};
+
+ $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
+ " WHERE last < ?", {},
+ time - $r->{S}{login_timeout});
+
+ my $row = $dbh->selectrow_arrayref("SELECT username, last".
+ " FROM $r->{S}{assocdb_table}".
+ " WHERE assochash = ?", {}, $h);
+ if (defined $row) {
+ my ($nusername, $nlast) = @$row;
+ return ('y', $nusername);
+ }
+
+ # Well, it's not in the database. But maybe it's a hash of a
+ # temporary secret.
+
+ return 'n' unless defined $s;
+
+ my ($keyt, $signature, $message, $noncet, $nonce) =
+ $s =~ m/^(\d+)\.(\w+)\.((\d+)\.(\w+))$/ or die;
+
+ return 'n' if time > $noncet + $r->{S}{form_timeout};
+
+ my $keys = $r->_open_keys();
+ while (my ($rkeyt, $rkey, $line) = $r->_read_key($keys)) {
+ last if $rkeyt < $keyt; # too far down in the file
+ my $trysignature = $r->_hmac($rkey, $message);
+ return 't' if $trysignature eq $signature;
+ }
+ # oh well
+
+ $keys->error and die $!;
+ return 'n';
+}
+
+sub _db_revoke ($$) {
+ # revokes $h if it's valid; no-op if it's not
+ my ($r,$h) = @_;
+
+ my $dbh = $r->{Dbh};
+
+ $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
+ " WHERE assochash = ?", {}, $h);
+}
+
+sub _db_record_login_ok ($$$) {
+ my ($r,$h,$user) = @_;
+ $r->_db_revoke($h);
+ my $dbh = $r->{Dbh};
+ $dbh->do("INSERT INTO $r->{S}{assocdb_table}".
+ " (associd, username, last) VALUES (?,?,?)", {},
+ $h, $user, time);
+}
+
+sub check_divert ($) {
+ my ($r) = @_;
+ if (exists $r->{Divert}) {
+ return $r->{Divert};
+ }
+ my $dbh = $r->{Dbh};
+ $r->{Divert} = $r->_db_transaction(sub { $r->_check_divert_core(); });
+ $dbh->commit();
+ print STDERR Dumper($r->{Divert});
+ return $r->{Divert};
+}
+
+sub get_divert ($) {
+ my ($r) = @_;
+ die "unchecked" unless exists $r->{Divert};
+ return $r->{Divert};
+}
+
+sub get_username ($) {
+ my ($r) = @_;
+ my $divert = $r->get_divert();
+ return undef if $divert;
+ return $r->{UserOK};