#!/usr/bin/perl -w

use strict;
use Carp;
use Data::Dumper;
use Math::GSL::Vector qw/:all/;
use Math::GSL::Matrix qw/:all/;
use Math::GSL::Const;
use Math::GSL::BLAS qw/:all/;
use Math::GSL::CBLAS qw/:all/;
use Math::GSL::Machine qw/:all/;

use POSIX qw(M_PI);

BEGIN { unshift @INC, qw(.); }

use Parse;

our $xopts;
our $facesf;
our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector

sub TAU { M_PI * 2.0; }
sub MM2PT { 72.0 / 25.4; }

our $mid;

# ----- region names from plag, incl. reverse mapping -----

our %prs2region;

sub prep_region_rmap () {
  foreach my $rn (keys %region) {
    my $prs = plag_prs($rn);
    die if $prs2region{$prs};
    $prs2region{$prs} = $rn;
  }
}

our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name

sub prs2r ($) {
  # bodgery for the sea and land
  return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  $prs2region{$_[0]} // confess "@_ ?"
}
sub prs2rr ($) { $region{prs2r($_[0])} }

#----- file reader for plag output -----

sub read_faces () {
  # Sets
  #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  #  $region{NAME}{Polygon}{Pos}
  #  $region{NAME}{Special}
  #
  # also incidentally
  #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  #  $region{NAME}{Polygon}{Adjoins}
  # which should be ignored

  open P, "<", $facesf or die $!;
  while (<P>) { last if m/^\&faces$/; }
  my $rr;
  my @edges;
  my $process_rr = sub {
    my $last_ai;
    if ($rr->{Name} eq 'NZ') {
      # We combined L and NZ; now we must split them again
      # in fact, we just throw away L and L2 entirely.
      # Here, when processing NZ, we keep only vertices that
      # are part of NZ.
      @edges = grep {
	my $evxname = $_->{VxName};
	my @eregions = split / \| ?/, $evxname;
	grep { $_ eq 'NZ' } @eregions
      } @edges;
    }
    $rr->{Polygon} = [ @edges ];
    if ($rr->{Name} ne 'NZ') {
      for my $ei (0..$#edges) {
	if (!defined $last_ai) {
	  my $ai;
	  for my $ai (0..$#{ $rr->{Adj} }) {
	    next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
	    $last_ai = $ai+1;
	  }
	  confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
	}
	my $ai = ($last_ai-1+@edges) % @edges;
	$last_ai = $ai;
	my $adj = $rr->{Adj}[$ai];
	confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
		       $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
	    unless $adj->{Name} eq $edges[$ei]{Adjoins};
      
	for my $endi (0..1) {
	  $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
	}
      }
    }
    @edges = ();
    $rr = undef;
  };
  my $vxname;
  for (;;) {
    $!=0; $_=<P> // confess $!;
    last if m/^\&$/;
    if (m/^$sre$/) {
      my $new_face= $2;
      $process_rr->() if $rr;
      $rr= prs2rr($new_face);
    } elsif (m/^\s+$sre$/) {
      confess unless $rr;
      $vxname = $2;
      push @edges, { VxName => $vxname };
    } elsif (m/^\s+\^adjoins\s+$sre$/) {
      $edges[-1]{Adjoins} = prs2r($2);
    } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
      my $pos = mkvec($1,$2);
      confess unless defined $vxname;
      $edges[-1]{Pos} = $pos;
      $vxname2pos{$vxname} = $pos;
    }
  }
  $process_rr->();

  $region{$_}{Special} = 1 foreach qw(NZ L L2);
}

#----- geometry mangling -----

sub calculate_centres () {
  # Sets
  #  $region{NAME}{Centre}
  foreach my $rr (values %region) {
    next if $rr->{Special};
    my $sum = Math::GSL::Vector->new(2);
    my $wsum = 0;
    foreach my $adj (@{ $rr->{Adj} }) {
      my @ends = map { $_->{Pos} } @{ $adj->{Ends} };
      my $w = ($ends[1] - $ends[0])->norm();
      $sum += $w * $_ foreach @ends;
      $wsum += $w;
    }
    $rr->{Centre} = $sum * (0.5 / $wsum);
  }
}

sub for_each_pos ($) {
  my ($f) = @_;
  my $call = sub {
    my ($pr,$rr,$why) = @_;
    return unless defined $$pr;
    $f->($pr,$rr,$why);
  };
  foreach my $rr (values %region) {
    $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
    foreach my $vertex (@{ $rr->{Polygon} }) {
      $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
    }
  }
}

sub prvec ($) {
  my ($v) = @_;
  confess unless $v;
  sprintf "%g,%g", $v->get(0), $v->get(1);
}

sub mkvec ($$) { Math::GSL::Vector->new(\@_) }

sub transform_coordinates () {
  # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
  # until it's all in PostScript points
  my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
  my $dir = $or[1] - $or[0];
  my $theta = atan2 $dir->get(1), $dir->get(0);
  my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
  my $s = sin($rotateby);
  my $c = cos($rotateby);
  my $transform = Math::GSL::Matrix->new(2,2);
  $transform->set_row(0, [  $c, -$s ]);
  $transform->set_row(1, [  $s,  $c ]);
  print STDERR "rotate was=",prvec($dir)," theta=$theta",
      " rotateby=$rotateby s=$s c=$c\n";
  my @lims;
  foreach my $topend (qw(0 1)) {
    my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
    $lims[$topend] = mkvec($v,$v);
  }
  for_each_pos(sub {
    my ($pr, $rr, $why) = @_;
    my $y = Math::GSL::Vector->new(2);
    gsl_blas_dgemv($CblasNoTrans,
		   1.0, $transform->raw,
		   $$pr->raw,
		   0, $y->raw)
	and confess;
    #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
    gsl_blas_dcopy($y->raw, $$pr->raw)
	and confess;
    foreach my $topend (qw(0 1)) {
      foreach my $xy (qw(0 1)) {
	my $now = $y->get($xy);
	my $lim = $lims[$topend]->get($xy);
	#print STDERR "?set $topend $xy $now $lim\n";
	next if $topend ? ($now <= $lim) : ($now >= $lim);
	$lims[$topend]->set([$xy], [$now]);
	#print STDERR "set $topend $xy $now\n";
      }
    }
  });
  print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
  my $translate = -$lims[0];
  print STDERR "translate ",prvec($translate),"\n";
  my $scale = $c{GraphScale} * MM2PT;
  for_each_pos(sub {
    my ($pr) = @_;
    gsl_vector_add($$pr->raw, $translate->raw) and confess;
    gsl_vector_scale($$pr->raw, $scale) and confess;
  });
  $mid = ($lims[1] - $lims[0]) * 0.5;
}

sub adjust_nz() {
  my $poly = $region{NZ}{Polygon};
  my %occurs;
  foreach my $v (@$poly) {
    $occurs{$v->{VxName}}++
  }
  foreach my $v (@$poly) {
    $v->{NZ_Occurs} = $occurs{$v->{VxName}};
  }
  print STDERR " nz ".(scalar @$poly)."\n";
  my $occurs_m = sub {
    my ($ei) = @_;
    $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
  };
  for my $ei (0..$#$poly) {
    next if $occurs_m->($ei);
    next unless $occurs_m->($ei-1);
    next unless $occurs_m->($ei+1);
    print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
    # adjust coord outwards
  }
  for my $ei (0..$#$poly) {
    next unless $occurs_m->($ei);
    print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
    next unless $occurs_m->($ei-1);
    my $dleft = mkvec(-1000,0);
    foreach my $which (0,-1) {
      my $ej = ($ei +        $which + @$poly) % @$poly;
      my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
      my $posj = \ $poly->[$ej]{Pos};
      my $posk = \ $poly->[$ek]{Pos};
      my $dout = $$posk - $$posj;
      print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
      print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
      if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
	print STDERR " nz adj extra\n";
	$$posk = $$posj + 10 * mkvec(100,-50);
      }
      $$posj = $$posj + $dleft + $dout*10;
      $$posk = $$posk          + $dout*10;
    }
  }
}

sub psvec ($) {
  my ($pos) = @_;
  sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
}

sub face_path ($) {
  my ($rr) = @_;
  o("% $rr->{Name}\n");
  o("  newpath\n");
  my $xto = 'moveto';
  foreach my $vertex (@{ $rr->{Polygon} }) {
    my $pos = $vertex->{Pos};
    o(sprintf "    %s %s\n", psvec($pos), $xto);
    $xto = 'lineto';
  }
  o("    closepath\n");
}

sub pscolour ($;$) {
  my ($spec, $adj1) = @_;
  confess unless defined $spec;
  my @rgb = map { hex($_) / 15.0 } split //, $spec;
  $adj1 //= sub { };
  $adj1->(@rgb);
  my $r = join ' ',
      (map { sprintf "%.6f ", $_ } @rgb
      ),
	   'setrgbcolor';
  return $r;
}

sub preamble() {
  my $printeredge = 5 * MM2PT;
  my $xsz = 842;
  my $ysz = 3 * 595 - 4 * $printeredge;
  o(<<END);
%!PS-Adobe-3.0
%%BoundingBox 0 0 $xsz $ysz
%%Pages: 1
%%EndComments
%%BeginProlog
%%EndProlog
%%BeginSetup
/board {
  gsave
  40 0 translate
END
  #o(" 0.52 dup scale\n") if $xopts =~ m/S/;
  #o("%%Box 0 0 $xsz $ysz");
  # xxx split into pages?
}

sub postamble () {
  o(<<END);
  grestore
} bind def
%%EndSetup
%%Page: 1
%%BeginPageSetup
/pgsave save def
%%EndPageSetup
board
pgsave restore
showpage
%%EOF
END
}

sub facepscolour ($) {
  my ($colourname) = @_;
  $xopts =~ m/W/ ? '1 setgray'
      : pscolour($c{Colours}{$colourname},
		 sub { $_ = 1.0 - 0.75 * (1.0 - $_) foreach @_ });
}
    
sub fill_faces() {
  o("clippath ", facepscolour('land'), " fill\n");
  foreach my $rr (values %region) {
    next if $rr->{Name} =~ m/^L2?$/;
    face_path($rr);
    o(" ", facepscolour($rr->{Colour}), " eofill\n");
  }
}

sub some_edge_faces (@) {
  o("5 setlinewidth 1 setlinejoin 0 setgray\n");
  foreach my $rr (@_) {
    next if $rr->{Name} =~ m/^L2?$/;
    face_path($rr);
    o("    stroke\n");
  }
}

sub afsluitdijk() {
  my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
  my $dash = 20;
  my (@pos) = map { $_->{Pos} } @{ $adj->{Ends} };
  my $mid = 0.5 * ($pos[0] + $pos[1]);
  my $r = 0.5 * ($pos[1] - $pos[0])->norm();
  o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
  %% Afsluitdijk
  %s %s %s 0 360 arc closepath fill
END
  some_edge_faces(()); # just sets the colour
  o(sprintf <<END, map { psvec($_) } @pos);
  newpath %s moveto %s lineto
  [ $dash $dash ] $dash 0.5 mul setdash
  stroke
  [] 0 setdash
END
}

sub edge_faces() {
  some_edge_faces($region{'NZ'});
  afsluitdijk();
  some_edge_faces(grep {
    $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
  } values %region);
}

our $hs_sz = 17 * MM2PT;
our $hs_lw = 3;

sub one_hs ($$) {
  my ($colour, $hspos) = @_;
  o(sprintf <<END
   %% HS
   newpath %s %s %f 0 360 arc closepath gsave fill grestore
   0 setgray $hs_lw setlinewidth stroke
END
	, pscolour($colour,
		   sub { $_ = 0.75 * $_ foreach @_ }),
	psvec($hspos), $hs_sz/2);
}

sub label_faces() {
  my $sz = 18;
  my $shadow = $sz * 0.1;
  o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
  my %hs = map { $_ => 1 } @{ $c{HS} };
  foreach my $rr (values %region) {
    next if $rr->{Special};
    my $words = $rr->{DisplayName};
    my $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
    if ($hs{$rr->{Name}}) {
      print STDERR "adjust hs $rr->{Name}\n";
      $pos -= mkvec(0, -$hs_sz*
		    ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
      my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
			       + $hs_sz*0.15);
      one_hs($c{Colours}{$rr->{Colour}}, $hspos);
    }
    # xxx water cubes
    o("  /words {\n");
    foreach my $word (@$words) {
      $pos += mkvec(0,-$sz);
      o("   ", psvec($pos), " moveto");
      o(<<END);
   2 copy rmoveto
   ($word) dup stringwidth pop     % word xw
     -0.5 mul 0 rmoveto             % word
     show
   0 -$sz rmoveto
END
    }
    o(<<END);
  } bind def
    0 setgray 0 10 359 {
      dup  cos $shadow mul
      exch sin $shadow mul
      words pop pop
    } bind for
    1 setgray 0 0 words pop pop
END
  }
}

#----- main program -----

$xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;

($facesf, @ARGV) = @ARGV or die;
parse_input_graph();
prep_region_rmap();
read_faces();
calculate_centres();
transform_coordinates();
adjust_nz();

preamble();
fill_faces();
edge_faces();
# xxx dykes
# xxx dyke spots
label_faces();
# xxx water track
# xxx HS initial locations
# xxx HS instructions
# xxx overall instructions
# xxx card decks
postamble();

print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};

# Local variables:
# cperl-indent-level: 2
# End.