#

# Assorted useful functions used by the backup scripts.

sub printdate () {
    print scalar(localtime),"\n";
}

# Set status info -- we write the current status to a file 
# so if we hang or crash the last thing written to the file
# will tell us where we were when things went pear-shaped.
sub setstatus ($) {
    open S, ">this-status.new" or die $!;
    print S $_[0],"\n" or die $!;
    close S or die $!;
    rename "this-status.new","this-status" or die $!;
}

# startprocess, endprocesses, killprocesses are 
# used to implement the funky pipeline stuff.
sub startprocess ($$$) {
    my ($i,$o,$c) = @_;
    print LOG "  $c\n" or die $!;
    print "  $c\n" or die $!;
    defined($p= fork) or die $!;
    if ($p) { $processes{$p}= $c; return; }
    open STDIN,"$i" or die "$c stdin $i: $!";
    open STDOUT,"$o" or die "$c stdout $o: $!";
    &closepipes;
    exec $c; die "$c: $!";
}

sub endprocesses () {
    while (keys %processes) {
	$p= waitpid(-1,0) or die "wait: $!";
	if (!exists $processes{$p}) { warn "unknown pid exited: $p, code $?\n"; next; }
	$c= $processes{$p};
	delete $processes{$p};
	$? && die "error: command gave code $?: $c\n";
    }
    print LOG "  ok\n" or die $!;
    print "  ok\n" or die $!;
}

sub killprocesses {
    for $p (keys %processes) {
	kill 15,$p or warn "kill process $p: $!";
    }
    undef %processes;
}

# Read a fsys.foo filesystem group definition file.
# Syntax is: empty lines and those beginning with '#' are ignored.
# Trailing whitespace is ignored. Lines of the form 'prefix foo bar'
# are handled specially, as arex lines 'exclude regexp'; otherwise 
# we just shove the line into @fsys and let parsefsys deal with it.
sub readfsys ($) {
    my ($fsnm) = @_;
    open F, "$etc/fsys.$fsnm" or die "Filesystems $fsnm unknown ($!).\n";
    for (;;) {
	$_= <F> or die "unexpected EOF in $etc/fsys.$fsnm\n"; chomp; s/\s*$//;
	last if m/^end$/;
	next unless m/\S/;
	next if m/^\#/;
	if (m/^prefix\s+(\w+)\s+(\S.*\S)$/) {
	    $prefix{$1}= $2;
	    next;
	}
        if (m/^excludedir\s+(\S.*\S)$/) {
            push @excldir,$1;
            next;
        }
        if (m/^exclude\s+(\S.*\S)$/) {
            push @excl,$1;
            next;
        }
	push @fsys,$_;
    }
    close F or die $!;
}

# Parse a line from a filesystem definition file. We expect the line
# to be in $tf.
sub parsefsys () {
    if ($tf =~ m,^(/\S*)\s+(\w+)$,) {
        # Line of form '/file/system	dumptype'
	$atf= $1;
	$tm= $2;
	$prefix= '<local>';
	stat $atf or die "stat $atf: $!";
	-d _ or die "not a dir: $atf";
	$rstr= '';
    } elsif ($tf =~ m,^(/\S*)\s+(\w+)\s+(\w+)$,) {
        # Line of form '/file/system dumptype prefix'
        # (used for remote backups, I think)
	$atf= $1;
	$tm= $2;
	$prefix= $3;
	defined($prefix{$prefix}) or die "prefix $prefix in $tf ?\n";
	$rstr= $prefix{$prefix}.' ';
    }
}

sub openlog () {
    unlink 'log';
    $u= umask(007);
    open LOG, ">log" or die $!;
    umask $u;
    select(LOG); $|=1; select(STDOUT);
}

$SIG{'__DIE__'}= 'killprocesses';

1;
