scripts/named-conf

   1 #!/usr/bin/perl -w
   2 # This is chiark-named-conf, which is Copyright 2002 Ian Jackson.
   3 #
   4 # chiark-named-conf and its manpage are free software; you can
   5 # redistribute it and/or modify them under the terms of the GNU
   6 # General Public License as published by the Free Software Foundation;
   7 # either version 3, or (at your option) any later version.
   8 #
   9 # chiark-named-conf and its manpage are distributed in the hope that
  10 # it will be useful, but WITHOUT ANY WARRANTY; without even the
  11 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  12 # PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with this program; if not, consult the Free Software Foundation's
  16 # website at www.fsf.org, or the GNU Project website at www.gnu.org.
  17
  18 use strict;
  19 use IO::File;
  20 use Data::Dumper;
  21 use POSIX;
  22 use Fcntl qw(:DEFAULT :flock);
  23
  24 # bastard Perl wants me to do this now !
  25 sub loarg();
  26 sub soarg();
  27 sub usageerr ($);
  28 sub cfg_fail ($);
  29 sub read_config ($);
  30 sub qualify ($);
  31 sub bad_modifiers ($);
  32 sub zone_conf ($$$$$@);
  33 sub set_output($);
  34 sub progress ($$);
  35 sub verbose ($);
  36 sub process_zones (@);
  37 sub zone_warning ($$);
  38 sub zone_warnmore ($);
  39 sub zone_check_full ();
  40 sub zone_reset();
  41 sub zone_investigate();
  42 sub zone_check_nsrrset ($$$$);
  43 sub zone_ns_name ($$);
  44 sub zone_server_queue ($$$$$);
  45 sub zone_server_addr ($$$$$);
  46 sub zone_check_soa ($$$$);
  47 sub zone_consistency();
  48 sub zone_servers_ok ();
  49 sub zone_consistency_set ($%);
  50 sub zone_check_local ();
  51 sub zone_servers_simplefind ();
  52 sub zone_server_simple ($$$);
  53 sub zone_style ($$);
  54 sub mail_zone_before ();
  55 sub mail_zone_after ();
  56 sub pmail ($);
  57 sub ptime ($);
  58 sub mail_zone_mail ();
  59 sub zone_output ();
  60 sub output_files ();
  61 sub debug_dump ($);
  62 sub debug_trace ($);
  63 sub has_suffix_of ($$);
  64 sub lookup ($$$$);
  65 sub dig (&$$$);
  66 sub domain_canon ($$);
  67
  68 use vars qw($quis $stdout_fh $stderr_fh
  69             $mode $doall $domail
  70             $etcfile $where
  71             $debug $needglue $localonly $repeat $verbosity
  72             $admin $mail_state_dir $mail_max_warnfreq
  73             $progress_fh $warn_fh $modifiers
  74             %group2modcmd %group2used);
  75
  76 $|=1;
  77 $quis= $0; $quis =~ s,.*/,,;
  78
  79 $mode= '';
  80 $doall= 0;
  81 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  82 $where= '<built-in>';
  83 $debug= 0;
  84 $needglue= 1;
  85 $localonly= 0;
  86 $verbosity= 2;
  87 $admin=''; $mail_state_dir=''; $mail_max_warnfreq= 50;
  88 $repeat= 0;
  89 $domail= '';
  90 $modifiers= '';
  91 $group2modcmd{'foreign'}= '$!*@?';
  92 $group2used{'foreign'}= 1;
  93
  94 ($progress_fh= $stdout_fh= new_from_fd IO::Handle(1,'w') and
  95  $warn_fh= $stderr_fh = new_from_fd IO::Handle(2,'w'))
  96     or die "$quis: setup standard filehandles: $!\n";
  97
  98 use vars qw($dig_owner $dig_type $dig_rdata);
  99
 100 while (@ARGV && $ARGV[0] =~ m/^\-/) {
 101     $_= shift @ARGV;
 102     if (s/^\-\-//) {
 103         last if m/^$/;
 104         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; $domail=''; }
 105         elsif (m/^nothing$/) { $mode= 'x'; $domail=''; }
 106         elsif (m/^mail\-(first|middle|final|final\-test)$/) {
 107             $mode='n';
 108             $domail=$1;
 109         }
 110         elsif (m/^all$/) { $doall=1; }
 111         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
 112         elsif (m/^glueless$/) { $needglue=0; }
 113         elsif (m/^localonly$/) { $localonly=1; }
 114         elsif (m/^quiet$/) { $verbosity--; }
 115         elsif (m/^repeat$/) { $repeat=1; }
 116         elsif (m/^verbose$/) { $verbosity++; }
 117         else { usageerr("unknown option --$_"); }
 118     } else {
 119         s/^\-//;
 120         last if m/^$/;
 121         while (m/^./) {
 122             if (s/^[ynf]//) { $mode=$&; $domail=''; }
 123             elsif (s/^A//) { $doall=1; }
 124             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
 125             elsif (s/^D//) { $debug++; }
 126             elsif (s/^g//) { $needglue=0; }
 127             elsif (s/^l//) { $localonly=1; }
 128             elsif (s/^m(\w+)(\W+)$//) {
 129                 my ($g,$m) = ($1,$2);
 130                 $group2modcmd{$g}=$m;
 131                 usageerr("modifiers $m for group $g: $@") if bad_modifiers($m);
 132             }
 133             elsif (s/^q//) { $verbosity--; }
 134             elsif (s/^r//) { $repeat=1; }
 135             elsif (s/^v//) { $verbosity++; }
 136             else { usageerr("unknown option -$&"); }
 137         }
 138     }
 139 }
 140
 141 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
 142 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
 143
 144 usageerr("-q may be specified at most twice") if $verbosity<0;
 145 usageerr("-v may be specified at most once") if $verbosity>3;
 146 usageerr("-D may be specified at most twice") if $debug>2;
 147 usageerr("must specify either -f|-y|-n or zones (and not both)")
 148     if !!$mode == !!@ARGV && !$domail;
 149
 150 sub usageerr ($) {
 151     die <<END;
 152 $_[0]
 153
 154 usage: chiark-named-conf [options] -f|-y|-n|<zone>...
 155 operation modes:
 156  -f --force   install without checking
 157  -y --yes     check and install
 158  -n --no      check only (configured zones)
 159  --nothing    list zones only
 160  --mail-*     send mail about broken zones (see manpage)
 161  <zone> ...   check only (specified zones, even unconfigured ones)
 162 additional options:
 163  -A --all       report on zones marked ? (ones we know are broken)
 164  -D             debug $quis (does not help debug your DNS config)
 165  -g --glueless  do not warn about any glueless referrals (not recommended)
 166  -l --localonly full checks only on zones which we primary
 167  -q --quiet     no output for OK zones
 168  -r --repeat    repeat warnings for all sources of imperfect data
 169  -v --verbose   extra verbose info about each zone
 170  -C|--config <DIR/FILE  use FILE as default config and DIR as default dir
 171
 172 chiark-named-conf is Copyright 2002 Ian Jackson.  It is Free software, under
 173 the GNU General Public License, and you are welcome to change it and/or
 174 distribute copies under certain conditions.  There is ABSOLUTELY NO WARRANTY.
 175 END
 176 }
 177
 178 cfg_fail("config filename $etcfile should not be directory")
 179     if $etcfile =~ m,/$,;
 180
 181 use vars qw($default_dir);
 182 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
 183
 184 use vars qw($slave_dir $slave_prefix $slave_suffix);
 185 $slave_dir= 'slave';
 186 $slave_prefix= '';
 187 $slave_suffix= '';
 188
 189 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @forbid_slave
 190             @conv_glueless @indirect_glue);
 191 @self_ns= @self_soa= @self_addr= @forbid_addr= @forbid_slave= @indirect_glue= ();
 192 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
 193
 194 use vars qw(%zone_cfg @zone_cfg_list);
 195 %zone_cfg= ();
 196 @zone_cfg_list= ();
 197
 198 use vars qw($output $default_output %output_contents);
 199 $output= '';
 200 $default_output= '';
 201 %output_contents= ();
 202
 203 use vars qw($check $install);
 204 $check= $mode !~ m/^[fx]/;
 205 $install= $mode =~ m/^[yf]/;
 206
 207 read_config($etcfile);
 208 debug_dump('@zone_cfg_list %zone_cfg');
 209 process_zones(!@ARGV ? @zone_cfg_list : @ARGV);
 210 debug_dump('%output_contents');
 211 output_files() if $install;
 212
 213 $stdout_fh->close or die "$quis: write messages to stdout: $!\n";
 214 $stderr_fh->close or die "$quis: write messages to stderr: $!\n";
 215 exit 0;
 216
 217 #-------------------- configuration reading
 218
 219 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 220
 221 sub read_config ($) {
 222     my ($if) = @_;
 223     my ($fh,$z,@self,$before,$group,
 224         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 225     local ($_);
 226
 227     $fh= new IO::File $if,'r';
 228     unless ($fh) {
 229         return if $! == &ENOENT;
 230         cfg_fail("open $if:\n $!");
 231     }
 232     $before= '';
 233     for (;;) {
 234         if (!defined($_= <$fh>)) {
 235             cfg_fail("read config file $if:\n $!") if $fh->error();
 236             last;
 237         }
 238         chomp; s/\s+$//;
 239         if (s/\\$//) { $before.= $_; next; }
 240         $_= $before.$_;
 241         $before= '';
 242         s/^\s+//;
 243         $where= "$if:$.";
 244         next if m/^\#/;
 245         last if m/^end$/;
 246         next unless m/\S/;
 247         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 248             @self= split /\s+/, $2;
 249             @self_ns= @self if $1 ne '-soa';
 250             @self_soa= @self if $1 ne '-ns';
 251         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 252             @conv_glueless= split /\s+/, $1;
 253         } elsif (m/^allow\-indirect\-glue\s+(\S.*\S)/) {
 254             @indirect_glue= split /\s+/, $1;
 255         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 256             @self_addr= split /\s+/, $1;
 257         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 258             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 259         } elsif (m/^forbid\-slave(?:\s+([0-9. \t]+))?/) {
 260             @forbid_slave= defined $1 ? split /\s+/, $1 : ();
 261         } elsif (m,^
 262                  primary\-dir (\W*)
 263                  \s+ (\S+)/([^/ \t]*)
 264                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 265                   )?
 266                  $,x) {
 267             ($mod, $dir, $prefix, $suffix, $subfile) =
 268                 ($1,qualify($2),$3,$4,$5);
 269             cfg_fail("modifiers $mod for directory $dir: $@")
 270                 if bad_modifiers($mod);
 271             $suffix= '' if !defined $suffix;
 272             $subfile= '' if !defined $subfile;
 273             $suffix= '_db' if !length $suffix && !length $subfile;
 274             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 275             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 276             $lprefix= length $prefix; $lsuffix= length $suffix;
 277             while (defined($_= readdir D)) {
 278                 next if m/^\./ && !$lprefix;
 279                 next unless length > $lprefix+$lsuffix;
 280                 next unless substr($_,0,$lprefix) eq $prefix;
 281                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 282                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 283                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 284                 if (!stat $zf) {
 285                     next if length $subfile && $! == &ENOENT;
 286                     cfg_fail("cannot stat zonefile $zf:\n $!");
 287                 }
 288                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 289                 zone_conf($z,'primary','p',$mod,$zf);
 290             }
 291             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 292         } elsif (m/^primary(\W*)\s+(\S+)\s+(\S+)$/) {
 293             zone_conf($2,'primary','p',$1,qualify($3));
 294         } elsif (m/^published(\W*)\s+(\S+)\s+([0-9.\t]+)$/) {
 295             zone_conf($2,'published','s',$1,'',$3);
 296         } elsif (m/^stealth(\W*)\s+(\S+)\s+([0-9. \t]+)$/) {
 297             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 298         } elsif (m/^modifiers\s+(\W+)(?:\s+(\w+))$/) {
 299             ($mod,$group) = ($1,$2);
 300             cfg_fail("modifiers $mod for group $group: $@")
 301                 if bad_modifiers($mod);
 302             if (exists $group2modcmd{$group}) {
 303                 $mod= $group2modcmd{$group};
 304                 $group2used{$group}++;
 305             }
 306             $modifiers= $mod;
 307         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 308             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 309             $slave_prefix='' if !defined $slave_prefix;
 310             $slave_suffix='' if !defined $slave_suffix;
 311         } elsif (m/^output\s+bind8\+(\S+)$/) {
 312             cfg_fail("default output may not apply to only some zones")
 313                 if @zone_cfg_list && length $default_output;
 314             set_output(qualify($1));
 315         } elsif (m/^include\s+(\S+)$/) {
 316             read_config($1);
 317         } elsif (m/^admin\s+(\S+)$/) {
 318             $admin=$1;
 319         } elsif (m/^mail\-state\-dir\s+(\S+)$/) {
 320             $mail_state_dir= $1;
 321         } elsif (m/^mail\-max\-warnfreq\s+(\d{1,3}(?:\.\d{0,5})?)$/) {
 322             cfg_fail("mail-max-warnfreq must be <=100") if $1>100;
 323             $mail_max_warnfreq= $1;
 324         } else {
 325             cfg_fail("unknown configuration directive".
 326                      " or incorrect syntax or arguments:\n".
 327                      " \`$_'");
 328         }
 329     }
 330     foreach $group (keys %group2modcmd) {
 331         next if exists $group2used{$group};
 332         cfg_fail("command line specifies modifier group $group".
 333                  " but missing in configuration file");
 334     }
 335     $fh->close or cfg_fail("close config file $if:\n $!");
 336 }
 337
 338 sub qualify ($) {
 339     my ($i) = @_;
 340     $i= "$default_dir$i" unless $i =~ m,^/,;
 341     return $i;
 342 }
 343
 344 sub bad_modifiers ($) {
 345     local ($_) = @_;
 346     if (!eval {
 347         die "bad modifier $&" if m/[^!*\$\@~?]/;
 348         die "repeated modifier $1" if m/(.).*\1/;
 349         1;
 350     }) {
 351         $@ =~ s/\n//;
 352         return 1;
 353     }
 354     return 0;
 355 }
 356
 357 sub zone_conf_settings ($$) {
 358     my ($cfg,$zone) = @_;
 359     my ($sfx,$aref);
 360     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr forbid_slave
 361                      conv_glueless indirect_glue)) {
 362         { no strict 'refs'; $aref= [ @$sfx ]; }
 363         @$aref or cfg_fail("failed to specify $sfx before zone")
 364             if $sfx =~ m/^self/;
 365         $cfg->{$sfx}= $aref;
 366     }
 367     foreach $sfx (qw(self_soa self_ns)) {
 368         map { s/\*$/$zone/ } @{ $zone_cfg{$zone}{$sfx} };
 369     }
 370 }
 371
 372 sub zone_conf ($$$$$@) {
 373     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 374     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 375         unless length $file;
 376     if (!length $output) {
 377         $default_output= qualify('chiark-conf-gen.bind8')
 378             unless length $default_output;
 379         set_output($default_output);
 380     }
 381     cfg_fail("redefined zone $zone\n".
 382              " earlier definition $zone_cfg{$zone}{'where'}")
 383         if exists $zone_cfg{$zone};
 384     $zone_cfg{$zone}{'where'}= $where;
 385     $zone_cfg{$zone}{'file'}= $file;
 386     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 387     $zone_cfg{$zone}{'s'}= "$sabbr $mod $modifiers";
 388     # p)rimary s)econdary u)npub f)oreign
 389     # followed by modifiers, first per-zone, then default
 390     $zone_cfg{$zone}{'servers'}= [ @servers ];
 391     if ($domail) {
 392         length $admin && length $mail_state_dir or
 393             cfg_fail("mailing but failed to specify admin".
 394                      " or mail-state-dir before zone");
 395         $zone_cfg{$zone}{'admin'}= $admin;
 396         $zone_cfg{$zone}{'maildir'}= qualify($mail_state_dir);
 397         $zone_cfg{$zone}{'mailmwarn'}= $mail_max_warnfreq;
 398     }
 399     zone_conf_settings($zone_cfg{$zone}, $zone);
 400     $zone_cfg{$zone}{'output'}= $output;
 401     push @zone_cfg_list, $zone;
 402 }
 403
 404 sub set_output($) {
 405     my ($newout) = @_;
 406     $output= $newout;
 407     $output_contents{$output}= '';
 408 }
 409
 410 #-------------------- checking
 411
 412 use vars qw($zone $cfg $warnings %zone_warnings);
 413 $warnings= 0;
 414
 415 sub progress ($$) {
 416     my ($minv,$m) = @_;
 417     return if $verbosity < $minv;
 418     print $progress_fh "$m\n" or die "$quis: $zone: write log: $!\n";
 419 }
 420
 421 sub verbose ($) { progress(3, '    ' . $_[0]); }
 422
 423 sub process_zones (@) {
 424     my (@zones) = @_;
 425     local ($zone,$cfg);
 426
 427     foreach $zone (@zones) {
 428         $cfg= $zone_cfg{$zone};
 429         if (!$cfg) {
 430             $cfg= {
 431                 'style_p' => 'foreign',
 432                 's' => "f $group2modcmd{'foreign'}",
 433                 'servers' => [ ],
 434             };
 435             zone_conf_settings($cfg, $zone);
 436         }
 437
 438         mail_zone_before() or next
 439             if $domail;
 440         zone_reset();
 441         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
 442         if ($check && ($doall || !zone_style('?',0))) {
 443             eval {
 444                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 445                     zone_warning("foreign zone specified with -l",'');
 446                 } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
 447                     zone_check_local();
 448                 } else {
 449                     zone_check_full();
 450                 }
 451             };
 452             zone_warning("checks failed: $@",'') if length $@;
 453         }
 454         $output_contents{$$cfg{'output'}} .= zone_output()
 455             if $install;
 456
 457         mail_zone_after() if $domail;
 458     }
 459     if ($domail) {
 460     } elsif ($warnings) {
 461         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 462                        " %d zone(s) checked ok.\n",
 463                        $quis,
 464                        $warnings,
 465                        scalar(keys %zone_warnings),
 466                        scalar(@zones - keys %zone_warnings));
 467     } else {
 468         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
 469     }
 470 }
 471
 472 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 473 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 474 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 475 use vars qw(%soas);  # $soa{"$serial $mname"} = [ $whosaidandwhy ]
 476 use vars qw(%addr_is_ok %warned);
 477 use vars qw($delg_to_us);
 478 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
 479 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
 480
 481 sub zone_warning ($$) {
 482     my ($w,$o) = @_;
 483     my ($wk);
 484
 485     return 0 if !$repeat && $warned{$w}++;
 486
 487     $w =~ s/\n$//;
 488     $w =~ s,\n, // ,g;
 489
 490     $w .= " ($o)" if length $o;
 491     print $warn_fh "$zone: warning: $w\n" or die $!;
 492     $warnings++;
 493     $zone_warnings{$zone}++;
 494     return 1;
 495 }
 496
 497 sub zone_warnmore ($) {
 498     print $warn_fh "$zone:  $_[0]\n" or die $!;
 499 }
 500
 501 sub zone_check_full () {
 502     zone_investigate();
 503     zone_consistency();
 504     zone_servers_ok();
 505 }
 506
 507 sub zone_reset() {
 508     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 509     $delg_to_us= 0;
 510     @to_check= @to_check_soa= ();
 511 }
 512
 513 sub zone_investigate() {
 514     my ($super_zone, @start_nsnames, $start_ww,
 515         $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
 516         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
 517         $rcode, $name, $is_ns);
 518
 519     if (!zone_style('*',0)) {
 520         $super_zone= $zone;
 521         for (;;) {
 522             debug_trace("zone $zone superzone $super_zone");
 523             $super_zone eq '.'
 524                 and die "no superzone ? ($super_zone)\n";
 525             $super_zone =~ s/^[^.]+\.//
 526                 or $super_zone= '.';
 527             ($rcode,@start_nsnames)=
 528                 lookup($super_zone,'ns-','06',"superzone search");
 529             last if !$rcode;
 530         }
 531         $start_ww= "server for $super_zone";
 532     } else {
 533         ($rcode,@start_nsnames)=
 534             lookup($zone,'ns-','0',"initial nameserver search");
 535         $start_ww= "nameserver for $zone";
 536     }
 537     for $start_ns (@start_nsnames) {
 538         $start_ns= lc $start_ns;
 539         ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
 540         foreach $addr (@start_ns_addrs) {
 541             push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
 542         }
 543     }
 544     for (;;) {
 545         # We do these in order so that we always do NS RRset checks on
 546         # nameservers that came from other NS RRsets first; otherwise
 547         # we might set nsrrset_checked due to a glueless_ok check,
 548         # and then not check for gluefulness later.
 549         debug_dump('@to_check @to_check_soa');
 550         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
 551             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
 552                 if defined $name_if_auth;
 553             next if $nsrrset_checked{$addr}++;
 554             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
 555         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
 556             next if $soa_checked{$addr}++;
 557             zone_check_soa($addr,$wa,$name,$is_ns);
 558         } else {
 559             last;
 560         }
 561     }
 562 }
 563
 564 sub zone_check_nsrrset ($$$$) {
 565     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
 566     my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww, $cg);
 567     my ($rcode);
 568     $ww= "[$uaddr] $wa";
 569     verbose("checking delegation by $ww");
 570     dig(sub {
 571         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 572             $s2g{lc $dig_rdata} = [ ];
 573         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 574             $wwn= "in glue from $ww";
 575             zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 576             push @{ $s2g{$dig_owner} }, $dig_rdata;
 577         }
 578     },
 579              $zone,'ns',$uaddr);
 580     if (!%s2g) {
 581         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 582         return;
 583     } elsif (keys %s2g == 1) {
 584         zone_warning("only one nameserver ". (join '', keys %s2g),
 585                      $ww);
 586     }
 587     @s= sort keys %s2g;
 588     foreach $s (@s) {
 589         zone_ns_name($s,$ww);
 590         @glue= @{ $s2g{$s} };
 591         if (!@glue) {
 592             zone_warning("glueless NS $s", $ww)
 593                 unless $glueless_ok
 594                     or zone_style('~',!$needglue)
 595                     or grep { has_suffix_of($zone,".$_"); }
 596                            @{ $cfg->{'conv_glueless'} }
 597                     or ((grep { has_suffix_of($s,".$_"); }
 598                            @{ $cfg->{'indirect_glue'} }) and
 599                         !(grep { has_suffix_of($zone,".$_"); }
 600                            @{ $cfg->{'indirect_glue'} }));
 601             foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 602                 zone_warning("nameserver $s (glueless) in".
 603                              " serverless-glueless namespace area $cg", $ww)
 604                     if has_suffix_of(".$s",".$cg");
 605             }
 606             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
 607             foreach $a (@glue) {
 608                 $wwn= "glueless NS from $ww";
 609                 zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
 610             }
 611         }
 612         $glue= join ' ', sort @glue;
 613         push @{ $glue{$s}{$glue} }, $ww;
 614     }
 615     $s= join ' ', @s;
 616     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
 617     push @{ $delgs_or_auths->{$s} }, $ww;
 618 }
 619
 620 sub zone_ns_name ($$) {
 621     my ($name,$ww) = @_;
 622     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 623     zone_warning("published server, as $name, but configured as stealth",
 624                  $ww)
 625         if $cfg->{'s'} =~ m/u/ &&
 626            grep { $_ eq $name }
 627                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 628 }
 629
 630 sub zone_server_queue ($$$$$) {
 631     my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
 632     zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
 633     push @to_check, $addr, "$name, $wwn", $name, $is_soa;
 634 }
 635
 636 sub zone_server_addr ($$$$$) {
 637     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 638     debug_trace("zone_server_addr ".join('|',@_));
 639     $addr_is_ok{$addr}= "$name ($wwq)"
 640         if $is_soa || $cfg->{'s'} =~ m/u/;
 641     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 642         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 643     zone_warning("forbidden server address for our slave [$addr] $name",$ww)
 644         if $cfg->{'s'} =~ m/p/ and
 645            grep { $_ eq $addr } @{ $cfg->{'forbid_slave'} };
 646
 647     my ($name_is_self, $addr_is_self);
 648     $name_is_self= grep { $_ eq $name }
 649         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 650     $addr_is_self= grep { $_ eq $addr }
 651         @{ $cfg->{'self_addr'} };
 652     if ($name_is_self && !$addr_is_self) {
 653         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 654     }
 655     if (!$name_is_self && $addr_is_self) {
 656         zone_warning("we [$addr] are named in ".
 657                      ($is_soa ? "SOA" : "NS").
 658                      " by wrong name $name",
 659                      $ww);
 660     }
 661     if (!$name_is_self && !$addr_is_self &&
 662         $is_soa && $cfg->{'s'} =~ m/p/) {
 663         zone_warning("SOA MNAME $name is not us (".
 664                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 665     }
 666     $delg_to_us=1 if $addr_is_self && !$is_soa;
 667 }
 668
 669 sub zone_check_soa ($$$$) {
 670     my ($uaddr,$wa,$name,$is_ns) = @_;
 671     my ($lame,$serial,$mname,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 672     verbose("checking service at [$uaddr] $name");
 673     $lame= 'dead or lame';
 674     $ww= "[$uaddr] $wa";
 675     dig(sub {
 676         if ($dig_type eq 'flags:') {
 677             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 678         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 679             die "several SOAs ? $ww" if defined $mname;
 680             $got= $dig_rdata;
 681             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
 682             ($serial,$mname) = ($1,$2);
 683         }
 684     },
 685              $zone,'soa',$uaddr);
 686     $lame= 'broken' if !$lame && !defined $mname;
 687     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 688     progress(2, sprintf "%-16s %46s has %s%s",
 689              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
 690     push @{ $soas{$got} }, $ww;
 691     ($rcode,@soa_addrs)= lookup($mname,'a','0',"SOA MNAME");
 692     $wwn= "SOA MNAME from $ww";
 693     foreach $soa_addr (@soa_addrs) {
 694         zone_server_queue($soa_addr,$mname,$wwn,"SOA [$uaddr]",1);
 695     }
 696 }
 697
 698 sub zone_consistency() {
 699     my ($d, $org_ser, $mname, $a, $h, $self_soa, $wa);
 700     zone_consistency_set('delegations',\%delgs);
 701     foreach $d (keys %delgs) { delete $auths{$d}; }
 702     zone_consistency_set('zone nameserver rrset',\%auths);
 703     foreach $h (keys %glue) {
 704         zone_consistency_set("glue for $h", $glue{$h});
 705     }
 706     zone_consistency_set("serial number and/or SOA MNAME",\%soas);
 707     $self_soa= $cfg->{'self_soa'};
 708 }
 709
 710 sub zone_servers_ok () {
 711     my ($showok,%fs);
 712     if (%addr_is_ok) {
 713         $showok= 0;
 714         foreach $a (@{ $cfg->{'servers'} }) {
 715             next if exists $addr_is_ok{$a};
 716             zone_warning("we slave from [$a]",'')
 717                 and $showok=1;
 718         }
 719         if ($showok) {
 720             foreach $a (keys %addr_is_ok) {
 721                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 722             }
 723         }
 724     }
 725     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 726         zone_warning("we are supposedly published secondary,".
 727                      " but not listed as a nameserver",'');
 728         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 729         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 730     }
 731 }
 732
 733 sub zone_consistency_set ($%) {
 734     my ($msg,$set) = @_;
 735     my ($d,$o);
 736     if (keys(%$set) > 1) {
 737         zone_warning("inconsistent $msg:",'');
 738         foreach $d (keys %$set) {
 739             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 740         }
 741     }
 742 }
 743
 744 sub zone_check_local () {
 745     zone_servers_simplefind();
 746     zone_servers_ok();
 747 }
 748
 749 sub zone_servers_simplefind () {
 750     my ($rcode,@nsnames,$ns,@soas,$mname);
 751
 752     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 753     foreach $ns (@nsnames) {
 754         zone_ns_name($ns,"NS");
 755         zone_server_simple($ns,'NS',0);
 756     }
 757     $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
 758
 759     ($rcode,@soas)= lookup($zone,'soa','0',"SOA MNAME");
 760     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 761     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 762     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 763 }
 764
 765 sub zone_server_simple ($$$) {
 766     my ($name,$ww,$is_soa) = @_;
 767     my ($rcode,@addrs,$addr);
 768     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 769                             ($is_soa ? "SOA MNAME" : "NS"));
 770     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 771 }
 772
 773 sub zone_style ($$) {
 774     my ($stylechar, $default) = @_;
 775     local ($_) = $$cfg{'s'};
 776     $stylechar =~ s/\W/\\$&/ or die;
 777     return m/(\S*)$stylechar/ ? $1 !~ m/\!/ : $default;
 778 }
 779
 780 #-------------------- mailing
 781
 782 use vars qw($m_base $m_lastok @m_ok @m_fail
 783             $m_info $m_time $m_lock $m_m);
 784
 785 sub mail_zone_before () {
 786     my (@s1,@s2);
 787
 788     $m_base= $$cfg{'maildir'}.'/'.$zone;
 789     $m_lastok= '-';
 790     @m_ok= ();
 791     @m_fail= ();
 792
 793     for (;;) {
 794         $m_lock= new IO::File "${m_base}_lock", O_RDWR|O_CREAT, 0600
 795             or die "$quis: create lockfile ${m_base}_lock: $!\n";
 796         if (!flock($m_lock, LOCK_EX|LOCK_NB)) {
 797             <$m_lock> =~ m/^\d+ /;
 798             die "$quis: $zone: concurrrency? - flock $&$!\n";
 799             $m_lock->close;
 800             return 0;
 801         }
 802         (@s1= $m_lock->stat) or die "$quis: fstat ${m_base}_lock: $!\n";
 803         (@s2= stat "${m_base}_lock") or
 804             die "$quis: stat ${m_base}_lock: $!\n";
 805         last if ($s1[0] eq $s2[0] && $s1[1] eq $s2[1]);
 806         $m_lock->close;
 807     }
 808     (print $m_lock "$$        \n" and $m_lock->flush)
 809         or die "$quis: write pid to ${m_base}_lock: $!\n";
 810
 811     if ($m_info= new IO::File "${m_base}_info", 'r') {
 812         $!=0; $_= <$m_info>;
 813         $_ =~ m/\n/ or die "$quis: read ${m_base}_info: $!\n";
 814         m/^\d+ (\d+|-) ([0-9:]*) ([0-9:]*) / or
 815             die "$quis: ${m_base}_info malformed\n";
 816         $m_lastok= $1;
 817         if ($domail ne 'first') {
 818             if ($2 eq ':' && $3 eq ':') {
 819                 warn "$quis: $zone: mid/last run, but last".
 820                     "run already done, ignoring zone\n";
 821                 return 0;
 822             }
 823             @m_ok= split /\:/, $2;
 824             @m_fail= split /\:/, $3;
 825         }
 826     } elsif ($! != &ENOENT) {
 827         die "$quis: open ${m_base}_info: $!\n";
 828     } elsif ($domail ne 'first') {
 829         warn "$quis: $zone: first run, but not --mail-first,".
 830             " ignoring zone\n";
 831         return 0;
 832     }
 833     if ($domail eq 'first') {
 834         remove "${m_base}_history" or $!==&ENOENT
 835             or die "$quis: remove ${m_base}_history: $!\n";
 836     }
 837     $progress_fh= $warn_fh= new IO::File "${m_base}_history",'a',0666
 838         or die "$quis: open ${m_base}_history: $!\n";
 839     $m_info= new IO::File "${m_base}_info.tmp",'w',0666
 840         or die "$quis: open ${m_base}_info.tmp: $!\n";
 841
 842     $m_time= time;
 843     progress(-1, "\n".('-'x70)."\n".ptime($m_time)."\n");
 844     return 1;
 845 }
 846
 847 sub mail_zone_after () {
 848     if ($zone_warnings{$zone}) {
 849         push @m_fail, $m_time;
 850         progress(-1,"failed - $zone_warnings{$zone} warnings");
 851     } else {
 852         push @m_ok, $m_time;
 853         $m_lastok= $m_time;
 854         progress(-1,"everything is fine");
 855     }
 856     close $progress_fh or die "$quis: close ${m_base}_history: $!\n";
 857     $progress_fh= $warn_fh= $stderr_fh;
 858
 859     if ($domail =~ m/^final/) {
 860         if (100*@m_fail <= $$cfg{'mailmwarn'}*(@m_fail + @m_ok)) {
 861             printf " %-40s ok\n", $zone or die "$quis: mail ok report: $!\n";
 862         } elsif (zone_style('@',0)) {
 863             printf " %-40s mail suppressed\n", $zone
 864                 or die "$quis: mail suppress report: $!\n";
 865         } else {
 866             mail_zone_mail();
 867         }
 868     } else {
 869         printf " %-40s %d warns. OK %s Fail %s\n",
 870             $zone,
 871             defined $zone_warnings{$zone} ? $zone_warnings{$zone} : 0,
 872             join(',', map { $_ - $m_time } @m_ok),
 873             join(',', map { $_ - $m_time } @m_fail)
 874                 or die "$quis: checking progress report: $!\n";
 875     }
 876
 877     @m_fail= @m_ok= ('','')
 878         if $domail =~ m/^final/;
 879
 880     printf $m_info "%s %s %s %s \n",
 881         $m_time, $m_lastok, join(':',@m_ok), join(':',@m_fail)
 882             or die "$quis: write new ${m_base}_info: $!\n";
 883     $m_info->close or die "$quis: close new ${m_base}_info: $!\n";
 884     rename "${m_base}_info.tmp", "${m_base}_info"
 885         or die "$quis: install new ${m_base}_info: $!\n";
 886     $m_lock->close;
 887 }
 888
 889
 890 sub pmail ($) {
 891     print $m_m $_[0]
 892         or die "$quis: write ${m_base}_mail: $!\n";
 893 }
 894 sub ptime ($) {
 895     my ($time) = @_;
 896     return gmtime($time)." GMT ($time)";
 897 }
 898
 899 sub mail_zone_mail () {
 900     my ($log, $zone_to, $zterr, $c, $r, $t, @soas);
 901     $m_m= new IO::File "${m_base}_mail", 'w', 0666
 902         or die "$quis: create ${m_base}_mail: $!\n";
 903     $zone_to=''; $zterr='';
 904     if (!zone_style("\$", $$cfg{'s'} !~ m/[ps]/)) {
 905         eval {
 906             ($r,@soas)= lookup($zone,'soa','0','problem-addr');
 907             @soas==1 or die "multiple soas\n";
 908             $soas[0] =~ m/^\S+ (\S.*\@\S+) [0-9 ]+$/ or
 909                 die "bad soa \`$_'\n";
 910             $zone_to= $1;
 911         };
 912         $zterr= $@;
 913         $zterr =~ s/\n$//;
 914     }
 915     pmail <<END
 916 From: zone checker <$$cfg{'admin'}>
 917 Subject: $zone - configuration problems report
 918 END
 919 ;
 920     pmail("To: ");
 921     pmail("(testing!) ") if $domail ne 'final';
 922     pmail("SOA MNAME for $zone <$zone_to>\nCC: ") if length($zone_to);
 923     pmail($$cfg{'admin'}."\n\n");
 924     pmail <<END
 925 You are receiving this mail because your email address is listed
 926 in the SOA (Start Of Authority) record for $zone
 927 in the DNS, which means you are supposedly the DNS administrator
 928 responsible for this zone.  This report is generated automatically
 929 on behalf of $$cfg{'admin'}, who
 930 is the administrator for a server for the zone.  Please contact
 931 them if you have any problem with this report.
 932
 933 END
 934 if length $zone_to;
 935     pmail <<END
 936 Sent to $$cfg{'admin'} since SOA MNAME unavailable:
 937 $zterr
 938
 939 END
 940 if length $zterr;
 941     pmail <<END
 942 The zone has had configuration errors or persistent operational
 943 problems during recent checks.  See the logs below for details.
 944
 945 Recent check history for $zone:
 946 END
 947 ;
 948     if ($m_lastok ne '-') {
 949         pmail(" Last seen to be fine: ".ptime($m_lastok)."\n");
 950     } else {
 951         pmail(" No record of this zone ever being fine.\n");
 952     }
 953     for $t (@m_fail) {
 954         pmail(" Zone had problems at: ".ptime($t)."\n");
 955     }
 956     for $t (@m_ok) {
 957         pmail(" Everything in order at: ".ptime($t)."\n");
 958     }
 959     pmail("\n");
 960     $log= new IO::File "${m_base}_history",'r'
 961         or die "$quis: reopen ${m_base}_history: $!";
 962     undef $/;
 963     pmail($log->getline);
 964     $/= "\n";
 965     (!$log->error and $log->close)
 966         or die "$quis: reread or close ${m_base}_log: $!\n";
 967     $log->eof or die;
 968     $m_m->close or die "$quis: close ${m_base}_mail: $!\n";
 969     $m_m= new IO::File "${m_base}_mail"
 970         or die "$quis: reopen ${m_base}_mail: $!";
 971
 972     defined($c= fork) or die "$quis: fork for mail: $!\n";
 973     if (!$c) {
 974         defined dup2($m_m->fileno, 0)
 975             or die "$quis - sendmail: dup for stdin: $!\n";
 976         exec (qw(/usr/sbin/sendmail -odb -oee -oi),
 977               ($domail eq 'final' ? '-t' : $$cfg{'admin'}));
 978         die "$quis - sendmail: exec: $!\n";
 979     }
 980     $m_m->close;
 981     $!=0; $r= waitpid $c,0;
 982     $r == $c or die "$quis: waitpid sendmail ($c): $r $!";
 983     $? and warn "$quis: sendmail failed: $?\n";
 984
 985     printf " %-40s %s\n", $zone,
 986         length $zone_to ? $zone_to : 'reporting to admin'
 987             or die "$quis: write mailing report: $!\n";
 988 }
 989
 990 #-------------------- outputting
 991
 992 sub zone_output () {
 993     my ($o,$m);
 994
 995     $o= "zone \"$zone\" {\n";
 996     if ($$cfg{'s'} =~ m/p/) {
 997         $o.= "    type master;\n";
 998     } else {
 999         $o.= "    type slave;\n".
1000              "    masters {\n";
1001         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
1002         $o.= "    };\n";
1003     }
1004     $o.= "    file \"$$cfg{'file'}\";\n";
1005     $o.= "};\n";
1006     return $o;
1007 }
1008
1009 sub output_files () {
1010     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
1011
1012     foreach $ofn (keys %output_contents) {
1013         $fn= $ofn; $mfn= "output file $fn";
1014         for (;;) {
1015             if (!lstat $fn) {
1016                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
1017                 $maxmode= 0666;
1018                 last;
1019             } elsif (-f _) {
1020                 $maxmode= (stat _)[2];
1021                 last;
1022             } elsif (-l _) {
1023                 defined($l= readlink $fn)
1024                     or die "$quis: readlink $mfn:\n $!\n";
1025                 $dir= $fn =~ m,^.*/, ? $& : './';
1026                 $fn= "$dir$l" unless $l =~ m,^/,;
1027                 $mfn= "output file $fn (symlink target of $ofn)";
1028             } else {
1029                 die "$quis: output file $mfn exists but is not a file".
1030                     " (or symlink to one)";
1031             }
1032         }
1033         unlink "$fn.new" or $! == &ENOENT or
1034             die "$quis: cannot clear out old .new version of $mfn:\n $!";
1035         $h= new IO::File "$fn.new",'w',$maxmode
1036             or die("$quis: create .new version of $mfn:\n $!");
1037         print $h
1038             "# generated by $quis, do not edit\n",
1039             $output_contents{$ofn}
1040             or die "$quis: write data to .new version of $mfn:\n $!";
1041         $h->close
1042             or die "$quis: close .new version of $mfn:\n $!";
1043         push @to_install, $fn,$mfn;
1044     }
1045
1046     while (($fn,$mfn, @to_install) = @to_install) {
1047         rename "$fn.new",$fn
1048             or die "$quis: install new version of $mfn:\n $!";
1049     }
1050 }
1051
1052 #-------------------- general utilities
1053
1054 sub debug_dump ($) {
1055     my ($vn);
1056     return unless $debug>1;
1057     local $Data::Dumper::Terse=1;
1058     foreach $vn (split /\s+/, $_[0]) {
1059         print "$vn := ", eval "Dumper(\\$vn)";
1060     }
1061 }
1062
1063 sub debug_trace ($) {
1064     return unless $debug;
1065     print "D $_[0]\n";
1066 }
1067
1068 sub has_suffix_of ($$) {
1069     my ($whole,$suffix) = @_;
1070     debug_trace("has_suffix_of $whole $suffix");
1071     return 0 if length $whole < length $suffix;
1072     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
1073     debug_trace("has_suffix_of $whole $suffix YES");
1074     return 1;
1075 }
1076
1077 sub lookup ($$$$) {
1078     my ($domain,$type,$okrcodes,$w) = @_;
1079     my ($c,$h,@result);
1080     debug_trace("lookup ==> (->$okrcodes) $domain $type");
1081     $h= new IO::Handle;
1082
1083     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
1084     if (!$c) {
1085         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
1086              '-',"$domain";
1087         die "$quis: exec adnshost:\n $!\n";
1088     }
1089     @result= $h->getlines();
1090     $h->error and die "$quis: read from adnshost:\n $!\n";
1091     chomp @result;
1092     $!=0; $h->close;
1093     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
1094         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
1095     debug_trace("lookup <== $? @result");
1096     return ($?,@result);
1097 }
1098
1099 sub dig (&$$$) {
1100     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
1101     # also pseudo-rr with type `flags:'
1102     my ($h,$inmid,$irdata,$c,$digwhy);
1103     local ($_);
1104
1105     debug_trace("dig ==> \@$qaddr $qowner $qtype");
1106
1107     $h= new IO::Handle;
1108     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
1109     if (!$c) {
1110         open STDERR, ">&STDOUT" or die $!;
1111         exec ('dig',
1112               '+nodef','+nosea','+norecurse',
1113               "\@$qaddr",'-t',$qtype,$qowner);
1114         die "$quis: exec dig:\n $!\n";
1115     }
1116     $inmid='';
1117     for (;;) {
1118         if (!defined($_= $h->getline())) {
1119             $h->error() and die "$quis: read from dig:\n $!\n";
1120             last;
1121         }
1122         chomp;
1123         if (length $inmid) {
1124             s/^\s+/ / or die "$inmid // $_ ?";
1125             s/\;.*$//;
1126             $_= $inmid.$_;
1127             $inmid='';
1128             s/$/ \(/ unless s/\s*\)\s*$//;
1129         }
1130         if (s/\s*\(\s*$//) { $inmid= $_; next; }
1131         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
1132         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
1133             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
1134             debug_trace("dig  f: $dig_rdata");
1135             &$eachrr;
1136         } elsif (m/^\;/) {
1137         } elsif (!m/\S/) {
1138         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
1139             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
1140             if ($dig_type eq 'a') {
1141                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
1142                 $dig_rdata= $&;
1143             } elsif ($dig_type eq 'ns') {
1144                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
1145                 $dig_rdata= domain_canon($irdata,$digwhy);
1146             } elsif ($dig_type eq 'soa') {
1147                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
1148                     or die "bad SOA $irdata ?";
1149                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
1150             } else {
1151                 debug_trace("ignoring uknown RR type $dig_type");
1152                 next;
1153             }
1154             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
1155             &$eachrr;
1156         } else {
1157             debug_trace("ignoring unknown dig output $_");
1158         }
1159     }
1160     $h->close;
1161     debug_trace("dig <== gave $?");
1162 }
1163
1164 sub domain_canon ($$) {
1165     my ($i,$w) = @_;
1166     $i =~ s/(.)\.$/$1/;
1167     return '.' if $i eq '.';
1168     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
1169     return lc $i;
1170 }