generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts;
  20 our $facesf;
  21 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  22
  23 sub TAU { M_PI * 2.0; }
  24 sub MM2PT { 72.0 / 25.4; }
  25
  26 our $mid;
  27
  28 # ----- region names from plag, incl. reverse mapping -----
  29
  30 our %prs2region;
  31
  32 sub prep_region_rmap () {
  33   foreach my $rn (keys %region) {
  34     my $prs = plag_prs($rn);
  35     die if $prs2region{$prs};
  36     $prs2region{$prs} = $rn;
  37   }
  38 }
  39
  40 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  41
  42 sub prs2r ($) {
  43   # bodgery for the sea and land
  44   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  45   $prs2region{$_[0]} // confess "@_ ?"
  46 }
  47 sub prs2rr ($) { $region{prs2r($_[0])} }
  48
  49 #----- file reader for plag output -----
  50
  51 sub read_faces () {
  52   # Sets
  53   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  54   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  55   #  $region{NAME}{Polygon}{Pos}
  56   #  $region{NAME}{Special}
  57   #
  58   # also incidentally
  59   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  60   #  $region{NAME}{Polygon}{Adjoins}
  61   # which should be ignored
  62
  63   open P, "<", $facesf or die $!;
  64   while (<P>) { last if m/^\&faces$/; }
  65   my $rr;
  66   my @edges;
  67   my $process_rr = sub {
  68     my $last_ai;
  69     if ($rr->{Name} eq 'NZ') {
  70       # We combined L and NZ; now we must split them again
  71       # in fact, we just throw away L and L2 entirely.
  72       # Here, when processing NZ, we keep only vertices that
  73       # are part of NZ.
  74       @edges = grep {
  75         my $evxname = $_->{VxName};
  76         my @eregions = split / \| ?/, $evxname;
  77         grep { $_ eq 'NZ' } @eregions
  78       } @edges;
  79     }
  80     $rr->{Polygon} = [ @edges ];
  81     if ($rr->{Name} ne 'NZ') {
  82       for my $ei (0..$#edges) {
  83         if (!defined $last_ai) {
  84           my $ai;
  85           for my $ai (0..$#{ $rr->{Adj} }) {
  86             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  87             $last_ai = $ai+1;
  88           }
  89           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
  90         }
  91         my $ai = ($last_ai-1+@edges) % @edges;
  92         $last_ai = $ai;
  93         my $adj = $rr->{Adj}[$ai];
  94         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
  95                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
  96             unless $adj->{Name} eq $edges[$ei]{Adjoins};
  97
  98         for my $endi (0..1) {
  99           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 100         }
 101       }
 102     }
 103     @edges = ();
 104     $rr = undef;
 105   };
 106   my $vxname;
 107   for (;;) {
 108     $!=0; $_=<P> // confess $!;
 109     last if m/^\&$/;
 110     if (m/^$sre$/) {
 111       my $new_face= $2;
 112       $process_rr->() if $rr;
 113       $rr= prs2rr($new_face);
 114     } elsif (m/^\s+$sre$/) {
 115       confess unless $rr;
 116       $vxname = $2;
 117       push @edges, { VxName => $vxname };
 118     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 119       $edges[-1]{Adjoins} = prs2r($2);
 120     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 121       my $pos = mkvec($1,$2);
 122       confess unless defined $vxname;
 123       $edges[-1]{Pos} = $pos;
 124       $vxname2pos{$vxname} = $pos;
 125     }
 126   }
 127   $process_rr->();
 128
 129   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 130 }
 131
 132 #----- geometry mangling -----
 133
 134 sub calculate_centres () {
 135   # Sets
 136   #  $region{NAME}{Centre}
 137   foreach my $rr (values %region) {
 138     next if $rr->{Special};
 139     my $poly = $rr->{Polygon};
 140     my $sum = Math::GSL::Vector->new(2);
 141     $sum += $_->{Pos} foreach @$poly;
 142     $rr->{Centre} = $sum * (1.0 / @$poly);
 143     # xxx use mean edge location (ie weight by edge length)
 144   }
 145 }
 146
 147 sub for_each_pos ($) {
 148   my ($f) = @_;
 149   my $call = sub {
 150     my ($pr,$rr,$why) = @_;
 151     return unless defined $$pr;
 152     $f->($pr,$rr,$why);
 153   };
 154   foreach my $rr (values %region) {
 155     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 156     foreach my $vertex (@{ $rr->{Polygon} }) {
 157       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 158     }
 159   }
 160 }
 161
 162 sub prvec ($) {
 163   my ($v) = @_;
 164   confess unless $v;
 165   sprintf "%g,%g", $v->get(0), $v->get(1);
 166 }
 167
 168 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 169
 170 sub transform_coordinates () {
 171   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 172   # until it's all in PostScript points
 173   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 174   my $dir = $or[1] - $or[0];
 175   my $theta = atan2 $dir->get(1), $dir->get(0);
 176   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 177   my $s = sin($rotateby);
 178   my $c = cos($rotateby);
 179   my $transform = Math::GSL::Matrix->new(2,2);
 180   $transform->set_row(0, [  $c, -$s ]);
 181   $transform->set_row(1, [  $s,  $c ]);
 182   print STDERR "rotate was=",prvec($dir)," theta=$theta",
 183       " rotateby=$rotateby s=$s c=$c\n";
 184   my @lims;
 185   foreach my $topend (qw(0 1)) {
 186     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 187     $lims[$topend] = mkvec($v,$v);
 188   }
 189   for_each_pos(sub {
 190     my ($pr, $rr, $why) = @_;
 191     my $y = Math::GSL::Vector->new(2);
 192     gsl_blas_dgemv($CblasNoTrans,
 193                    1.0, $transform->raw,
 194                    $$pr->raw,
 195                    0, $y->raw)
 196         and confess;
 197     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 198     gsl_blas_dcopy($y->raw, $$pr->raw)
 199         and confess;
 200     foreach my $topend (qw(0 1)) {
 201       foreach my $xy (qw(0 1)) {
 202         my $now = $y->get($xy);
 203         my $lim = $lims[$topend]->get($xy);
 204         #print STDERR "?set $topend $xy $now $lim\n";
 205         next if $topend ? ($now <= $lim) : ($now >= $lim);
 206         $lims[$topend]->set([$xy], [$now]);
 207         #print STDERR "set $topend $xy $now\n";
 208       }
 209     }
 210   });
 211   print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 212   my $translate = -$lims[0];
 213   print STDERR "translate ",prvec($translate),"\n";
 214   my $scale = $c{GraphScale} * MM2PT;
 215   for_each_pos(sub {
 216     my ($pr) = @_;
 217     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 218     gsl_vector_scale($$pr->raw, $scale) and confess;
 219   });
 220   $mid = ($lims[1] - $lims[0]) * 0.5;
 221 }
 222
 223 sub adjust_nz() {
 224   my $poly = $region{NZ}{Polygon};
 225   my %occurs;
 226   foreach my $v (@$poly) {
 227     $occurs{$v->{VxName}}++
 228   }
 229   foreach my $v (@$poly) {
 230     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 231   }
 232   print STDERR " nz ".(scalar @$poly)."\n";
 233   my $occurs_m = sub {
 234     my ($ei) = @_;
 235     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 236   };
 237   for my $ei (0..$#$poly) {
 238     next if $occurs_m->($ei);
 239     next unless $occurs_m->($ei-1);
 240     next unless $occurs_m->($ei+1);
 241     print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 242     # adjust coord outwards
 243   }
 244   for my $ei (0..$#$poly) {
 245     next unless $occurs_m->($ei);
 246     print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 247     next unless $occurs_m->($ei-1);
 248     my $dleft = mkvec(-1000,0);
 249     foreach my $which (0,-1) {
 250       my $ej = ($ei +        $which + @$poly) % @$poly;
 251       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 252       my $posj = \ $poly->[$ej]{Pos};
 253       my $posk = \ $poly->[$ek]{Pos};
 254       my $dout = $$posk - $$posj;
 255       print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 256       print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 257       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 258         print STDERR " nz adj extra\n";
 259         $$posk = $$posj + 10 * mkvec(100,-50);
 260       }
 261       $$posj = $$posj + $dleft + $dout*10;
 262       $$posk = $$posk          + $dout*10;
 263     }
 264   }
 265 }
 266
 267 sub psvec ($) {
 268   my ($pos) = @_;
 269   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 270 }
 271
 272 sub face_path ($) {
 273   my ($rr) = @_;
 274   o("% $rr->{Name}\n");
 275   o("  newpath\n");
 276   my $xto = 'moveto';
 277   foreach my $vertex (@{ $rr->{Polygon} }) {
 278     my $pos = $vertex->{Pos};
 279     o(sprintf "    %s %s\n", psvec($pos), $xto);
 280     $xto = 'lineto';
 281   }
 282   o("    closepath\n");
 283 }
 284
 285 sub pscolour ($;$) {
 286   my ($spec, $adj1) = @_;
 287   confess unless defined $spec;
 288   my @rgb = map { hex($_) / 15.0 } split //, $spec;
 289   $adj1 //= sub { };
 290   $adj1->(@rgb);
 291   my $r = join ' ',
 292       (map { sprintf "%.6f ", $_ } @rgb
 293       ),
 294            'setrgbcolor';
 295   return $r;
 296 }
 297
 298 sub preamble() {
 299   o("%!\n");
 300   o(" 0.52 dup scale\n") if $xopts =~ m/S/;
 301   # xxx bodge, want boundingbox or something
 302 }
 303
 304 sub facepscolour ($) {
 305   my ($colourname) = @_;
 306   $xopts =~ m/W/ ? '1 setgray'
 307       : pscolour($c{Colours}{$colourname},
 308                  sub { $_ = 1.0 - 0.75 * (1.0 - $_) foreach @_ });
 309 }
 310
 311 sub fill_faces() {
 312   o("clippath ", facepscolour('land'), " fill\n");
 313   foreach my $rr (values %region) {
 314     next if $rr->{Name} =~ m/^L2?$/;
 315     face_path($rr);
 316     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 317   }
 318 }
 319
 320 sub some_edge_faces (@) {
 321   o("5 setlinewidth 1 setlinejoin 0 setgray\n");
 322   foreach my $rr (@_) {
 323     next if $rr->{Name} =~ m/^L2?$/;
 324     face_path($rr);
 325     o("    stroke\n");
 326   }
 327 }
 328
 329 sub afsluitdijk() {
 330   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 331   my $dash = 20;
 332   my (@pos) = map { $_->{Pos} } @{ $adj->{Ends} };
 333   my $mid = 0.5 * ($pos[0] + $pos[1]);
 334   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 335   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 336   %% Afsluitdijk
 337   %s %s %s 0 360 arc closepath fill
 338 END
 339   some_edge_faces(()); # just sets the colour
 340   o(sprintf <<END, map { psvec($_) } @pos);
 341   newpath %s moveto %s lineto
 342   [ $dash $dash ] $dash 0.5 mul setdash
 343   stroke
 344   [] 0 setdash
 345 END
 346 }
 347
 348 sub edge_faces() {
 349   some_edge_faces($region{'NZ'});
 350   afsluitdijk();
 351   some_edge_faces(grep {
 352     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 353   } values %region);
 354 }
 355
 356 sub label_faces() {
 357   my $sz = 18;
 358   my $hs_sz = 17 * MM2PT;
 359   my $hs_lw = 3;
 360   my $shadow = $sz * 0.1;
 361   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 362   my %hs = map { $_ => 1 } @{ $c{HS} };
 363   foreach my $rr (values %region) {
 364     next if $rr->{Special};
 365     my $words = $rr->{DisplayName};
 366     my $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 367     if ($hs{$rr->{Name}}) {
 368       print STDERR "adjust hs $rr->{Name}\n";
 369       # xxx HS placements in regions >=5 sides, further
 370       # xxx or maybe something involving total edge length
 371       $pos -= mkvec(0, -$hs_sz/2);
 372       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw);
 373       o(sprintf <<END
 374    %% HS
 375    newpath %s %s %f 0 360 arc closepath gsave fill grestore
 376    0 setgray $hs_lw setlinewidth stroke
 377 END
 378         , pscolour($c{Colours}{$rr->{Colour}},
 379                    sub { $_ = 0.75 * $_ foreach @_ }),
 380         psvec($hspos), $hs_sz/2);
 381     }
 382     # xxx water cubes
 383     o("  /words {\n");
 384     foreach my $word (@$words) {
 385       $pos += mkvec(0,-$sz);
 386       o("   ", psvec($pos), " moveto");
 387       o(<<END);
 388    2 copy rmoveto
 389    ($word) dup stringwidth pop     % word xw
 390      -0.5 mul 0 rmoveto             % word
 391      show
 392    0 -$sz rmoveto
 393 END
 394     }
 395     o(<<END);
 396   } bind def
 397     0 setgray 0 10 359 {
 398       dup  cos $shadow mul
 399       exch sin $shadow mul
 400       words pop pop
 401     } bind for
 402     1 setgray 0 0 words pop pop
 403 END
 404   }
 405 }
 406
 407 sub postamble () {
 408   o("showpage\n");
 409 }
 410
 411 #----- main program -----
 412
 413 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 414
 415 ($facesf, @ARGV) = @ARGV or die;
 416 parse_input_graph();
 417 prep_region_rmap();
 418 read_faces();
 419 calculate_centres();
 420 transform_coordinates();
 421 adjust_nz();
 422
 423 preamble();
 424 fill_faces();
 425 edge_faces();
 426 # xxx dykes
 427 # xxx dyke spots
 428 label_faces();
 429 # xxx water track
 430 # xxx HS initial locations
 431 # xxx HS instructions
 432 # xxx overall instructions
 433 # xxx card decks
 434 postamble();
 435
 436 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 437
 438 # Local variables:
 439 # cperl-indent-level: 2
 440 # End.