generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts;
  20 our $facesf;
  21 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  22
  23 sub TAU { M_PI * 2.0; }
  24 sub MM2PT { 72.0 / 25.4; }
  25
  26 our $mid;
  27
  28 # ----- region names from plag, incl. reverse mapping -----
  29
  30 our %prs2region;
  31
  32 sub prep_region_rmap () {
  33   foreach my $rn (keys %region) {
  34     my $prs = plag_prs($rn);
  35     die if $prs2region{$prs};
  36     $prs2region{$prs} = $rn;
  37   }
  38 }
  39
  40 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  41
  42 sub prs2r ($) {
  43   # bodgery for the sea and land
  44   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  45   $prs2region{$_[0]} // confess "@_ ?"
  46 }
  47 sub prs2rr ($) { $region{prs2r($_[0])} }
  48
  49 #----- file reader for plag output -----
  50
  51 sub read_faces () {
  52   # Sets
  53   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  54   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  55   #  $region{NAME}{Polygon}{Pos}
  56   #  $region{NAME}{Special}
  57   #
  58   # also incidentally
  59   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  60   #  $region{NAME}{Polygon}{Adjoins}
  61   # which should be ignored
  62
  63   open P, "<", $facesf or die $!;
  64   while (<P>) { last if m/^\&faces$/; }
  65   my $rr;
  66   my @edges;
  67   my $process_rr = sub {
  68     my $last_ai;
  69     if ($rr->{Name} eq 'NZ') {
  70       # We combined L and NZ; now we must split them again
  71       # in fact, we just throw away L and L2 entirely.
  72       # Here, when processing NZ, we keep only vertices that
  73       # are part of NZ.
  74       @edges = grep {
  75         my $evxname = $_->{VxName};
  76         my @eregions = split / \| ?/, $evxname;
  77         grep { $_ eq 'NZ' } @eregions
  78       } @edges;
  79     }
  80     $rr->{Polygon} = [ @edges ];
  81     if ($rr->{Name} ne 'NZ') {
  82       for my $ei (0..$#edges) {
  83         if (!defined $last_ai) {
  84           my $ai;
  85           for my $ai (0..$#{ $rr->{Adj} }) {
  86             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  87             $last_ai = $ai+1;
  88           }
  89           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
  90         }
  91         my $ai = ($last_ai-1+@edges) % @edges;
  92         $last_ai = $ai;
  93         my $adj = $rr->{Adj}[$ai];
  94         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
  95                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
  96             unless $adj->{Name} eq $edges[$ei]{Adjoins};
  97
  98         for my $endi (0..1) {
  99           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 100         }
 101       }
 102     }
 103     @edges = ();
 104     $rr = undef;
 105   };
 106   my $vxname;
 107   for (;;) {
 108     $!=0; $_=<P> // confess $!;
 109     last if m/^\&$/;
 110     if (m/^$sre$/) {
 111       my $new_face= $2;
 112       $process_rr->() if $rr;
 113       $rr= prs2rr($new_face);
 114     } elsif (m/^\s+$sre$/) {
 115       confess unless $rr;
 116       $vxname = $2;
 117       push @edges, { VxName => $vxname };
 118     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 119       $edges[-1]{Adjoins} = prs2r($2);
 120     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 121       my $pos = mkvec($1,$2);
 122       confess unless defined $vxname;
 123       $edges[-1]{Pos} = $pos;
 124       $vxname2pos{$vxname} = $pos;
 125     }
 126   }
 127   $process_rr->();
 128
 129   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 130 }
 131
 132 #----- geometry mangling -----
 133
 134 sub calculate_centres () {
 135   # Sets
 136   #  $region{NAME}{Centre}
 137   foreach my $rr (values %region) {
 138     next if $rr->{Special};
 139     my $sum = Math::GSL::Vector->new(2);
 140     my $wsum = 0;
 141     foreach my $adj (@{ $rr->{Adj} }) {
 142       my @ends = map { $_->{Pos} } @{ $adj->{Ends} };
 143       my $w = ($ends[1] - $ends[0])->norm();
 144       $sum += $w * $_ foreach @ends;
 145       $wsum += $w;
 146     }
 147     $rr->{Centre} = $sum * (0.5 / $wsum);
 148   }
 149 }
 150
 151 sub for_each_pos ($) {
 152   my ($f) = @_;
 153   my $call = sub {
 154     my ($pr,$rr,$why) = @_;
 155     return unless defined $$pr;
 156     $f->($pr,$rr,$why);
 157   };
 158   foreach my $rr (values %region) {
 159     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 160     foreach my $vertex (@{ $rr->{Polygon} }) {
 161       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 162     }
 163   }
 164 }
 165
 166 sub prvec ($) {
 167   my ($v) = @_;
 168   confess unless $v;
 169   sprintf "%g,%g", $v->get(0), $v->get(1);
 170 }
 171
 172 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 173
 174 sub transform_coordinates () {
 175   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 176   # until it's all in PostScript points
 177   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 178   my $dir = $or[1] - $or[0];
 179   my $theta = atan2 $dir->get(1), $dir->get(0);
 180   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 181   my $s = sin($rotateby);
 182   my $c = cos($rotateby);
 183   my $transform = Math::GSL::Matrix->new(2,2);
 184   $transform->set_row(0, [  $c, -$s ]);
 185   $transform->set_row(1, [  $s,  $c ]);
 186   print STDERR "rotate was=",prvec($dir)," theta=$theta",
 187       " rotateby=$rotateby s=$s c=$c\n";
 188   my @lims;
 189   foreach my $topend (qw(0 1)) {
 190     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 191     $lims[$topend] = mkvec($v,$v);
 192   }
 193   for_each_pos(sub {
 194     my ($pr, $rr, $why) = @_;
 195     my $y = Math::GSL::Vector->new(2);
 196     gsl_blas_dgemv($CblasNoTrans,
 197                    1.0, $transform->raw,
 198                    $$pr->raw,
 199                    0, $y->raw)
 200         and confess;
 201     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 202     gsl_blas_dcopy($y->raw, $$pr->raw)
 203         and confess;
 204     foreach my $topend (qw(0 1)) {
 205       foreach my $xy (qw(0 1)) {
 206         my $now = $y->get($xy);
 207         my $lim = $lims[$topend]->get($xy);
 208         #print STDERR "?set $topend $xy $now $lim\n";
 209         next if $topend ? ($now <= $lim) : ($now >= $lim);
 210         $lims[$topend]->set([$xy], [$now]);
 211         #print STDERR "set $topend $xy $now\n";
 212       }
 213     }
 214   });
 215   print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 216   my $translate = -$lims[0];
 217   print STDERR "translate ",prvec($translate),"\n";
 218   my $scale = $c{GraphScale} * MM2PT;
 219   for_each_pos(sub {
 220     my ($pr) = @_;
 221     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 222     gsl_vector_scale($$pr->raw, $scale) and confess;
 223   });
 224   $mid = ($lims[1] - $lims[0]) * 0.5;
 225 }
 226
 227 sub adjust_nz() {
 228   my $poly = $region{NZ}{Polygon};
 229   my %occurs;
 230   foreach my $v (@$poly) {
 231     $occurs{$v->{VxName}}++
 232   }
 233   foreach my $v (@$poly) {
 234     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 235   }
 236   print STDERR " nz ".(scalar @$poly)."\n";
 237   my $occurs_m = sub {
 238     my ($ei) = @_;
 239     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 240   };
 241   for my $ei (0..$#$poly) {
 242     next if $occurs_m->($ei);
 243     next unless $occurs_m->($ei-1);
 244     next unless $occurs_m->($ei+1);
 245     print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 246     # adjust coord outwards
 247   }
 248   for my $ei (0..$#$poly) {
 249     next unless $occurs_m->($ei);
 250     print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 251     next unless $occurs_m->($ei-1);
 252     my $dleft = mkvec(-1000,0);
 253     foreach my $which (0,-1) {
 254       my $ej = ($ei +        $which + @$poly) % @$poly;
 255       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 256       my $posj = \ $poly->[$ej]{Pos};
 257       my $posk = \ $poly->[$ek]{Pos};
 258       my $dout = $$posk - $$posj;
 259       print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 260       print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 261       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 262         print STDERR " nz adj extra\n";
 263         $$posk = $$posj + 10 * mkvec(100,-50);
 264       }
 265       $$posj = $$posj + $dleft + $dout*10;
 266       $$posk = $$posk          + $dout*10;
 267     }
 268   }
 269 }
 270
 271 sub psvec ($) {
 272   my ($pos) = @_;
 273   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 274 }
 275
 276 sub face_path ($) {
 277   my ($rr) = @_;
 278   o("% $rr->{Name}\n");
 279   o("  newpath\n");
 280   my $xto = 'moveto';
 281   foreach my $vertex (@{ $rr->{Polygon} }) {
 282     my $pos = $vertex->{Pos};
 283     o(sprintf "    %s %s\n", psvec($pos), $xto);
 284     $xto = 'lineto';
 285   }
 286   o("    closepath\n");
 287 }
 288
 289 sub pscolour ($;$) {
 290   my ($spec, $adj1) = @_;
 291   confess unless defined $spec;
 292   my @rgb = map { hex($_) / 15.0 } split //, $spec;
 293   $adj1 //= sub { };
 294   $adj1->(@rgb);
 295   my $r = join ' ',
 296       (map { sprintf "%.6f ", $_ } @rgb
 297       ),
 298            'setrgbcolor';
 299   return $r;
 300 }
 301
 302 sub preamble() {
 303   my $printeredge = 5 * MM2PT;
 304   my $xsz = 842;
 305   my $ysz = 3 * 595 - 4 * $printeredge;
 306   o(<<END);
 307 %!PS-Adobe-3.0
 308 %%BoundingBox 0 0 $xsz $ysz
 309 %%Pages: 1
 310 %%EndComments
 311 %%BeginProlog
 312 %%EndProlog
 313 %%BeginSetup
 314 /board {
 315   gsave
 316   40 0 translate
 317 END
 318   #o(" 0.52 dup scale\n") if $xopts =~ m/S/;
 319   #o("%%Box 0 0 $xsz $ysz");
 320   # xxx split into pages?
 321 }
 322
 323 sub postamble () {
 324   o(<<END);
 325   grestore
 326 } bind def
 327 %%EndSetup
 328 %%Page: 1
 329 %%BeginPageSetup
 330 /pgsave save def
 331 %%EndPageSetup
 332 board
 333 pgsave restore
 334 showpage
 335 %%EOF
 336 END
 337 }
 338
 339 sub facepscolour ($) {
 340   my ($colourname) = @_;
 341   $xopts =~ m/W/ ? '1 setgray'
 342       : pscolour($c{Colours}{$colourname},
 343                  sub { $_ = 1.0 - 0.75 * (1.0 - $_) foreach @_ });
 344 }
 345
 346 sub fill_faces() {
 347   o("clippath ", facepscolour('land'), " fill\n");
 348   foreach my $rr (values %region) {
 349     next if $rr->{Name} =~ m/^L2?$/;
 350     face_path($rr);
 351     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 352   }
 353 }
 354
 355 sub some_edge_faces (@) {
 356   o("5 setlinewidth 1 setlinejoin 0 setgray\n");
 357   foreach my $rr (@_) {
 358     next if $rr->{Name} =~ m/^L2?$/;
 359     face_path($rr);
 360     o("    stroke\n");
 361   }
 362 }
 363
 364 sub afsluitdijk() {
 365   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 366   my $dash = 20;
 367   my (@pos) = map { $_->{Pos} } @{ $adj->{Ends} };
 368   my $mid = 0.5 * ($pos[0] + $pos[1]);
 369   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 370   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 371   %% Afsluitdijk
 372   %s %s %s 0 360 arc closepath fill
 373 END
 374   some_edge_faces(()); # just sets the colour
 375   o(sprintf <<END, map { psvec($_) } @pos);
 376   newpath %s moveto %s lineto
 377   [ $dash $dash ] $dash 0.5 mul setdash
 378   stroke
 379   [] 0 setdash
 380 END
 381   one_hs('purple', $mid);
 382 }
 383
 384 sub edge_faces() {
 385   some_edge_faces($region{'NZ'});
 386   afsluitdijk();
 387   some_edge_faces(grep {
 388     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 389   } values %region);
 390 }
 391
 392 our $hs_sz = 17 * MM2PT;
 393 our $hs_lw = 3;
 394
 395 sub token_circle ($$$$) {
 396   my ($what, $pos, $fillcolour, $edgecolour) = @_;
 397   o(sprintf <<END, $what, $fillcolour, psvec($pos), $hs_sz/2, $edgecolour);
 398    %% %s
 399    newpath %s
 400      %s %f 0 360 arc closepath gsave fill grestore
 401      %s $hs_lw setlinewidth stroke
 402 END
 403 }
 404
 405 sub one_hs ($$) {
 406   my ($colour, $hspos) = @_;
 407   token_circle("HS - $colour",
 408                $hspos,
 409                pscolour($c{Colours}{$colour},
 410                         sub { $_ = 0.75 * $_ foreach @_ }),
 411                '0 setgray');
 412 }
 413
 414 sub label_faces() {
 415   my $sz = 18;
 416   my $shadow = $sz * 0.1;
 417   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 418   my %hs = map { $_ => 1 } @{ $c{HS} };
 419   foreach my $rr (values %region) {
 420     next if $rr->{Special};
 421     my $words = $rr->{DisplayName};
 422     my $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 423     if ($hs{$rr->{Name}}) {
 424       print STDERR "adjust hs $rr->{Name}\n";
 425       $pos -= mkvec(0, -$hs_sz*
 426                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 427       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 428                                + $hs_sz*0.15);
 429       one_hs($rr->{Colour}, $hspos);
 430     }
 431     # xxx water cubes
 432     o("  /words {\n");
 433     foreach my $word (@$words) {
 434       $pos += mkvec(0,-$sz);
 435       o("   ", psvec($pos), " moveto");
 436       o(<<END);
 437    2 copy rmoveto
 438    ($word) dup stringwidth pop     % word xw
 439      -0.5 mul 0 rmoveto             % word
 440      show
 441    0 -$sz rmoveto
 442 END
 443     }
 444     o(<<END);
 445   } bind def
 446     0 setgray 0 10 359 {
 447       dup  cos $shadow mul
 448       exch sin $shadow mul
 449       words pop pop
 450     } bind for
 451     1 setgray 0 0 words pop pop
 452 END
 453   }
 454 }
 455
 456 sub sea_track(){
 457   o("% sea level track");
 458   o("  gsave 200 200 translate\n");
 459   my $track = $c{SeaTrack};
 460   my $token_sz = $hs_sz;
 461   my $dy = $token_sz * 1.5;
 462   for my $i (0..$#$track) {
 463     my $pos = mkvec(0, $i*$dy);
 464 #    token_circle("SL $i", $pos,
 465 #                pscolour($c{Colours}{sea},
 466 #                         map {
 467 #                        ),
 468 #                '0.
 469   }
 470   o("  grestore\n");
 471 }
 472
 473 #----- main program -----
 474
 475 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 476
 477 ($facesf, @ARGV) = @ARGV or die;
 478 parse_input_graph();
 479 prep_region_rmap();
 480 read_faces();
 481 calculate_centres();
 482 transform_coordinates();
 483 adjust_nz();
 484
 485 preamble();
 486 fill_faces();
 487 edge_faces();
 488 # xxx dykes
 489 # xxx dyke spots
 490 label_faces();
 491 sea_track();
 492 # xxx HS initial locations
 493 # xxx HS instructions
 494 # xxx overall instructions
 495 # xxx card decks
 496 postamble();
 497
 498 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 499
 500 # Local variables:
 501 # cperl-indent-level: 2
 502 # End.