generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $facesf;
  20 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  21
  22 sub TAU { M_PI * 2.0; }
  23 sub MM2PT { 72.0 / 25.4; }
  24
  25 our $mid;
  26
  27 # ----- region names from plag, incl. reverse mapping -----
  28
  29 our %prs2region;
  30
  31 sub prep_region_rmap () {
  32   foreach my $rn (keys %region) {
  33     my $prs = plag_prs($rn);
  34     die if $prs2region{$prs};
  35     $prs2region{$prs} = $rn;
  36   }
  37
  38   # bodgery for the sea and land
  39   $prs2region{'NZ | L'} = 'NZ';
  40   $prs2region{'L | NZ'} = 'NZ';
  41 }
  42
  43 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  44
  45 sub prs2r ($) { $prs2region{$_[0]} // confess "@_ ?" }
  46 sub prs2rr ($) { $region{prs2r($_[0])} }
  47
  48 #----- file reader for plag output -----
  49
  50 sub read_faces () {
  51   # Sets
  52   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  53   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  54   #  $region{NAME}{Polygon}{Pos}
  55   #  $region{NAME}{Special}
  56   #
  57   # also incidentally
  58   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  59   #  $region{NAME}{Polygon}{Adjoins}
  60   # which should be ignored
  61
  62   open P, "<", $facesf or die $!;
  63   while (<P>) { last if m/^\&faces$/; }
  64   my $rr;
  65   my @edges;
  66   my $process_rr = sub {
  67     my $last_ai;
  68     if ($rr->{Name} eq 'NZ') {
  69       # We combined L and NZ; now we must split them again
  70       # in fact, we just throw away L entirely.
  71       # Here, when processing NZ, we keep only vertices that
  72       # are part of NZ.
  73       @edges = grep {
  74         my $evxname = $_->{VxName};
  75         my @eregions = split / \| ?/, $evxname;
  76         grep { $_ eq 'NZ' } @eregions
  77       } @edges;
  78     }
  79     $rr->{Polygon} = [ @edges ];
  80     if ($rr->{Name} ne 'NZ') {
  81       for my $ei (0..$#edges) {
  82         my $ej = $ei % @edges;
  83         if (!defined $last_ai) {
  84           my $ai;
  85           for my $ai (0..$#{ $rr->{Adj} }) {
  86             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  87             $last_ai = $ai+1;
  88           }
  89           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
  90         }
  91         my $ai = ($last_ai-1+@edges) % @edges;
  92         $last_ai = $ai;
  93         my $adj = $rr->{Adj}[$ai];
  94         confess Dumper($rr, \@edges, $ei, $ej, $adj, $last_ai, $ai)." ?"
  95             unless $adj->{Name} eq $edges[$ei]{Adjoins};
  96
  97         for my $endi (0..1) {
  98           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
  99         }
 100       }
 101     }
 102     @edges = ();
 103     $rr = undef;
 104   };
 105   my $vxname;
 106   for (;;) {
 107     $!=0; $_=<P> // confess $!;
 108     last if m/^\&$/;
 109     if (m/^$sre$/) {
 110       my $new_face= $2;
 111       $process_rr->() if $rr;
 112       $rr= prs2rr($new_face);
 113     } elsif (m/^\s+$sre$/) {
 114       confess unless $rr;
 115       $vxname = $2;
 116       push @edges, { VxName => $vxname };
 117     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 118       $edges[-1]{Adjoins} = prs2r($2);
 119     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 120       my $pos = Math::GSL::Vector->new([$1,$2]);
 121       confess unless defined $vxname;
 122       $edges[-1]{Pos} = $pos;
 123       $vxname2pos{$vxname} = $pos;
 124     }
 125   }
 126   $process_rr->();
 127
 128   $region{$_}{Special} = 1 foreach qw(NZ L);
 129 }
 130
 131 #----- geometry mangling -----
 132
 133 sub calculate_centres () {
 134   # Sets
 135   #  $region{NAME}{Centre}
 136   foreach my $rr (values %region) {
 137     next if $rr->{Special};
 138     my $poly = $rr->{Polygon};
 139     my $sum = Math::GSL::Vector->new(2);
 140     $sum += $_->{Pos} foreach @$poly;
 141     $rr->{Centre} = $sum * (1.0 / @$poly);
 142   }
 143 }
 144
 145 sub for_each_pos ($) {
 146   my ($f) = @_;
 147   my $call = sub {
 148     my ($pr,$rr,$why) = @_;
 149     return unless defined $$pr;
 150     $f->($pr,$rr,$why);
 151   };
 152   foreach my $rr (values %region) {
 153     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 154     foreach my $vertex (@{ $rr->{Polygon} }) {
 155       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 156     }
 157   }
 158 }
 159
 160 sub prvec ($) {
 161   my ($v) = @_;
 162   confess unless $v;
 163   sprintf "%g,%g", $v->get(0), $v->get(1);
 164 }
 165
 166 sub transform_coordinates () {
 167   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 168   # until it's all in PostScript points
 169   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 170   my $dir = $or[1] - $or[0];
 171   my $theta = atan2 $dir->get(1), $dir->get(0);
 172   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 173   my $s = sin($rotateby);
 174   my $c = cos($rotateby);
 175   my $transform = Math::GSL::Matrix->new(2,2);
 176   $transform->set_row(0, [  $c, -$s ]);
 177   $transform->set_row(1, [  $s,  $c ]);
 178   print STDERR "rotate was=",prvec($dir)," theta=$theta",
 179       " rotateby=$rotateby s=$s c=$c\n";
 180   my @lims;
 181   foreach my $topend (qw(0 1)) {
 182     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 183     $lims[$topend] = Math::GSL::Vector->new([$v,$v]);
 184   }
 185   for_each_pos(sub {
 186     my ($pr, $rr, $why) = @_;
 187     my $y = Math::GSL::Vector->new(2);
 188     gsl_blas_dgemv($CblasNoTrans,
 189                    1.0, $transform->raw,
 190                    $$pr->raw,
 191                    0, $y->raw)
 192         and confess;
 193     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 194     gsl_blas_dcopy($y->raw, $$pr->raw)
 195         and confess;
 196     foreach my $topend (qw(0 1)) {
 197       foreach my $xy (qw(0 1)) {
 198         my $now = $y->get($xy);
 199         my $lim = $lims[$topend]->get($xy);
 200         #print STDERR "?set $topend $xy $now $lim\n";
 201         next if $topend ? ($now <= $lim) : ($now >= $lim);
 202         $lims[$topend]->set([$xy], [$now]);
 203         #print STDERR "set $topend $xy $now\n";
 204       }
 205     }
 206   });
 207   print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 208   my $translate = -$lims[0];
 209   print STDERR "translate ",prvec($translate),"\n";
 210   my $scale = $c{GraphScale} * MM2PT;
 211   for_each_pos(sub {
 212     my ($pr) = @_;
 213     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 214     gsl_vector_scale($$pr->raw, $scale) and confess;
 215   });
 216   $mid = ($lims[1] - $lims[0]) * 0.5;
 217 }
 218
 219 sub adjust_nz() {
 220   my $poly = $region{NZ}{Polygon};
 221   my %occurs;
 222   foreach my $v (@$poly) {
 223     $occurs{$v->{VxName}}++
 224   }
 225   foreach my $v (@$poly) {
 226     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 227   }
 228   print STDERR " nz ".(scalar @$poly)."\n";
 229   my $occurs_m = sub {
 230     my ($ei) = @_;
 231     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 232   };
 233   for my $ei (0..$#$poly) {
 234     next if $occurs_m->($ei);
 235     next unless $occurs_m->($ei-1);
 236     next unless $occurs_m->($ei+1);
 237     print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 238     # adjust coord outwards
 239   }
 240   for my $ei (0..$#$poly) {
 241     next unless $occurs_m->($ei);
 242     print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 243     next unless $occurs_m->($ei-1);
 244     my $dleft = Math::GSL::Vector->new([-1000,0]);
 245     foreach my $which (0,-1) {
 246       my $ej = ($ei +        $which + @$poly) % @$poly;
 247       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 248       my $posj = \ $poly->[$ej]{Pos};
 249       my $posk = \ $poly->[$ek]{Pos};
 250       my $dout = $$posk - $$posj;
 251       print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 252       print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 253       $$posj = $$posj + $dleft + $dout*10;
 254       $$posk = $$posk          + $dout*10;
 255     }
 256   }
 257 }
 258
 259 sub psvec ($) {
 260   my ($pos) = @_;
 261   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 262 }
 263
 264 sub face_path ($) {
 265   my ($rr) = @_;
 266   o("% $rr->{Name}\n");
 267   o("  newpath\n");
 268   my $xto = 'moveto';
 269   foreach my $vertex (@{ $rr->{Polygon} }) {
 270     my $pos = $vertex->{Pos};
 271     o(sprintf "    %s %s\n", psvec($pos), $xto);
 272     $xto = 'lineto';
 273   }
 274   o("    closepath\n");
 275 }
 276
 277 sub pscolour ($) {
 278   my ($spec) = @_;
 279   confess unless defined $spec;
 280   join ' ',
 281       (map { sprintf "%.6f ", hex($_) / 15.0 }
 282        split //, $spec),
 283            'setrgbcolor';
 284 }
 285
 286 sub preamble() {
 287   o("%!\n");
 288   o(" 0.52 dup scale\n"); # xxx bodge, want boundingbox or something
 289 }
 290
 291 sub fill_faces() {
 292   o("clippath ", pscolour($c{Colours}{land}), " fill\n");
 293   foreach my $rr (values %region) {
 294     next if $rr->{Name} eq 'L';
 295     face_path($rr);
 296     o(" ", pscolour($c{Colours}{$rr->{Colour}}), " eofill\n");
 297   }
 298 }
 299
 300 sub edge_faces() {
 301   o("5 setlinewidth 1 setlinejoin 0 setgray\n");
 302   foreach my $rr (values %region) {
 303     next if $rr->{Name} eq 'L';
 304     face_path($rr);
 305     o("    stroke\n");
 306   }
 307 }
 308
 309 sub label_faces() {
 310   o("  1 setgray  /Helvetica-Bold findfont  18 scalefont setfont\n");
 311   foreach my $rr (values %region) {
 312     next if $rr->{Special};
 313     o("   ", psvec($rr->{Centre}), " moveto");
 314     foreach my $word (@{ $rr->{DisplayName} }) {
 315       o("   (",$word,") show");
 316       o("   0 -18 rmoveto");
 317     }
 318   }
 319 }
 320
 321 #----- main program -----
 322
 323 ($facesf, @ARGV) = @ARGV or die;
 324 parse_input_graph();
 325 prep_region_rmap();
 326 read_faces();
 327 calculate_centres();
 328 transform_coordinates();
 329 adjust_nz();
 330
 331 preamble();
 332 fill_faces();
 333 edge_faces();
 334 label_faces();
 335
 336 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 337
 338 # Local variables:
 339 # cperl-indent-level: 2
 340 # End.