Parse.pm

   1
   2 package Parse;
   3
   4 use strict;
   5 use Carp;
   6 use Graph;
   7
   8 use Exporter;
   9
  10 our @ISA = qw(Exporter);
  11 our @EXPORT = qw(parse_input_graph o plag_prs %region %c);
  12
  13 our %c;
  14 require 'misc-data.pl';
  15
  16 our %region;
  17 # $region{NAME}{Colour}
  18 # $region{NAME}{Water}
  19 # $region{NAME}{Name}
  20 # $region{NAME}{L} # line number
  21 # $region{NAME}{Adj}[]{Name}
  22 # $region{NAME}{Adj}[]{DisplayName}[]
  23 # $region{NAME}{Adj}[]{Pattern}
  24 # $region{NAME}{Adj}[]{Regexp}
  25 # $region{NAME}{Adj}[]{Dykes}
  26 # $region{NAME}{Adj}[]{L}
  27
  28 our %adj;
  29 # $adj{EARLIER}{LATER}{Dykes}
  30 # $adj{EARLIER}{LATER}{L}[]
  31 # $adj{EARLIER}{LATER}{T}[]
  32
  33 sub read_in () {
  34   my $ccolour;
  35   my $cregion;
  36
  37   while (<>) {
  38     next if m{^\s*\#};
  39     next unless m{\S};
  40     s{\s+$}{} or confess;
  41     if (m{^\w+}) {
  42       $ccolour = $&;
  43       next;
  44     }
  45     if (my ($name, $water) = m{^\t(\S.*\w|L2?)(?: \[(\d+)\])?$}) {
  46       confess unless defined $ccolour;
  47       my $dname = $c{DisplayNames}{$name} // $name;
  48       $name =~ s{/}{}g;
  49       confess "$name ?" if $region{$name};
  50       $region{$name}{Colour} = $ccolour;
  51       $region{$name}{Water} = $water;
  52       $region{$name}{L} = $.;
  53       if ($dname =~ m{/}) {
  54         $dname =~ s{(?<!-)/(?! )}{-/}g;
  55         $region{$name}{DisplayName} = [ grep m/./, split m{ */ *}, $dname ];
  56       } else {
  57         $region{$name}{DisplayName} = [ split m{(?<=-)| }, $dname ];
  58       }
  59       $cregion = $name;
  60       next;
  61     }
  62     if (my ($aref, $adykes, $dwdyke) =
  63         m{^\t\t(\S.*[A-Za-z.]|L2?)(?: (\+\+?)(\@?))?$}) {
  64       my $adj = { Dykes => (length $adykes // 0), L => $. };
  65       if ($aref =~ m{\.}) {
  66         $adj->{Pattern} = $aref;
  67         $aref =~ s{\-}{[^- ]*-}g;
  68         $aref =~ s{\.+}{
  69             length $& eq 1 ? qr{[^- ]* ?} :
  70             length $& eq 2 ? qr{.*}       : confess "$aref"
  71         }ge;
  72         $adj->{Regexp} = $aref;
  73       } else {
  74         $adj->{Name} = $aref;
  75       }
  76       push @{ $region{$cregion}{Adj} }, $adj;
  77       next;
  78     }
  79     confess "$_ ?";
  80   }
  81 }
  82
  83 sub unique_aref ($$) {
  84   my ($ra, $adja) = @_;
  85   my $re = $adja->{Regexp};
  86   return $adja->{Name} unless defined $re;
  87   my @cands;
  88   foreach my $rb (sort keys %region) {
  89     #print STDERR "?? $ra -> $re $rb ?\n";
  90     foreach my $adjb (@{ $region{$rb}{Adj} }) {
  91       my $adjbn = $adjb->{Name};
  92       next unless defined $adjbn;
  93       #print STDERR "?? $ra -> $re $rb ?? $adjbn\n";
  94       next unless $adjbn eq $ra;
  95       push @cands, [ $rb, "$region{$rb}{L},$adjb->{L}" ];
  96     }
  97   }
  98   my @found = grep { $_->[0] =~ m{^$re$} } @cands;
  99   my $pr = sub {
 100     join ' / ', map { "$_->[0] ($_->[1])" } @_;
 101   };
 102   confess "$adja->{L} $adja->{Pattern} /$re/ | ".$pr->(@cands)
 103       ." | ".$pr->(@found)." | ?"
 104       unless @found==1;
 105   my $r = $found[0][0];
 106   #print STDERR "resolve $ra -> $adja->{Pattern} = $r\n";
 107   return $r;
 108 }
 109
 110 sub region_cmp {
 111   ($a eq 'L' ) <=> ($b eq 'L' ) or
 112   ($a eq 'L2') <=> ($b eq 'L2') or
 113   ($a eq 'NZ') <=> ($b eq 'NZ') or
 114    $a          cmp  $b
 115 }
 116
 117 sub resolve_arefs () {
 118   #print Dumper(\%region);
 119   foreach my $ra (sort keys %region) {
 120     foreach my $adj (@{ $region{$ra}{Adj} }) {
 121       next if defined $adj->{Name};
 122       $adj->{ProspectiveName} = unique_aref $ra, $adj;
 123     }
 124   }
 125   foreach my $ra (sort keys %region) {
 126     foreach my $adj (@{ $region{$ra}{Adj} }) {
 127       $adj->{Name} //= $adj->{ProspectiveName};
 128     }
 129   }
 130   foreach my $ra (sort keys %region) {
 131     foreach my $adj (@{ $region{$ra}{Adj} }) {
 132       confess unless $adj->{Name} eq unique_aref $ra, $adj;
 133     }
 134   }
 135 }
 136
 137 sub adjacencies () {
 138   foreach my $ra (sort keys %region) {
 139     my $adjs = $region{$ra}{Adj};
 140     foreach my $adji (0..$#$adjs) {
 141       my $adja = $adjs->[$adji];
 142       my $rb = $adja->{Name};
 143       my ($r0,$r1) = sort region_cmp ($ra,$rb);
 144       push @{ $adj{$r0}{$r1}{L} }, $adja->{L};
 145       push @{ $adj{$r0}{$r1}{T} }, substr($ra,0,1)."#".$adji;
 146       my $e = $adj{$r0}{$r1};
 147       $e->{Dykes} //= $adja->{Dykes};
 148       confess "$r0 - $r1 | @{ $e->{L} } | $e->{Dykes} $adja->{Dykes} ?"
 149           unless $e->{Dykes} == $adja->{Dykes};
 150     }
 151   }
 152   my $ndykes = 0;
 153   foreach my $r0 (sort keys %adj) {
 154     foreach my $r1 (sort keys %{ $adj{$r0} }) {
 155       my $e = $adj{$r0}{$r1};
 156       confess "$r0 / $r1 : @{ $e->{L} } ?" unless @{ $e->{L} } == 2;
 157       $ndykes += $e->{Dykes};
 158     }
 159   }
 160   #print STDERR "total $ndykes dykes\n";
 161 }
 162
 163 sub names () {
 164   foreach my $r (sort keys %region) {
 165     $region{$r}{Name} = $r;
 166   }
 167 }
 168
 169 sub edge_id_to_other_id ($$) {
 170   my ($ra, $adjia) = @_;
 171   my $adjsa = $region{$ra}{Adj};
 172   my $adja = $adjsa->[$adjia];
 173   my $rb = $adja->{Name};
 174   my $adjsb = $region{$rb}{Adj};
 175   foreach my $adjib (0..$#$adjsb) {
 176     my $adjb = $adjsb->[$adjib];
 177     next unless $adjb->{Name} eq $ra;
 178     # $adjb is the same edge seen from the other side
 179     return ($rb, $adjib);
 180   }
 181   confess "$ra $adjia ?";
 182 }
 183
 184 sub o { print @_ or die $!; }
 185
 186 sub plag_prs ($) {
 187     my ($t) = @_;
 188     $t = $` if $t =~ m/\n/;
 189     $t =~ s/ //g;
 190     $t =~ s/-//g;
 191     return "$t";
 192 }
 193
 194 sub parse_input_graph () {
 195   read_in();
 196   resolve_arefs();
 197   adjacencies();
 198   names();
 199 }
 200
 201 1;